scm/define-music-display-methods.scm

   1 ;;; define-music-display-methods.scm -- data for displaying music
   2 ;;; expressions using LilyPond notation.
   3 ;;;
   4 ;;; Copyright (C) 2005--2014 Nicolas Sceaux  <nicolas.sceaux@free.fr>
   5 ;;;
   6
   7 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   8 ;;;
   9 ;;; Display method implementation
  10 ;;;
  11
  12 (define-module (scm display-lily))
  13
  14 ;;;
  15 ;;; Scheme forms
  16 ;;;
  17 (define (scheme-expr->lily-string scm-arg)
  18   (cond ((or (number? scm-arg)
  19              (string? scm-arg)
  20              (boolean? scm-arg))
  21          (format #f "~s" scm-arg))
  22         ((or (symbol? scm-arg)
  23              (list? scm-arg))
  24          (format #f "'~s" scm-arg))
  25         ((procedure? scm-arg)
  26          (format #f "~a"
  27                  (or (procedure-name scm-arg)
  28                      (with-output-to-string
  29                        (lambda ()
  30                          (pretty-print (procedure-source scm-arg)))))))
  31         (else
  32          (format #f "~a"
  33                  (with-output-to-string
  34                    (lambda ()
  35                      (display-scheme-music scm-arg)))))))
  36 ;;;
  37 ;;; Markups
  38 ;;;
  39
  40 (define-public (markup->lily-string markup-expr)
  41   "Return a string describing, in LilyPond syntax, the given markup
  42 expression."
  43   (define (proc->command proc)
  44     (let ((cmd-markup (symbol->string (procedure-name proc))))
  45       (substring cmd-markup 0 (- (string-length cmd-markup)
  46                                  (string-length "-markup")))))
  47   (define (arg->string arg)
  48     (cond ((string? arg)
  49            (format #f "~s" arg))
  50           ((markup? arg) ;; a markup
  51            (markup->lily-string-aux arg))
  52           ((and (pair? arg) (every markup? arg)) ;; a markup list
  53            (format #f "{~{ ~a~}}" (map-in-order markup->lily-string-aux arg)))
  54           (else          ;; a scheme argument
  55            (format #f "#~a" (scheme-expr->lily-string arg)))))
  56   (define (markup->lily-string-aux expr)
  57     (if (string? expr)
  58         (format #f "~s" expr)
  59         (let ((cmd (car expr))
  60               (args (cdr expr)))
  61           (if (eqv? cmd simple-markup) ;; a simple markup
  62               (format #f "~s" (car args))
  63               (format #f "\\~a~{ ~a~}"
  64                       (proc->command cmd)
  65                       (map-in-order arg->string args))))))
  66   (cond ((string? markup-expr)
  67          (format #f "~s" markup-expr))
  68         ((eqv? (car markup-expr) simple-markup)
  69          (format #f "~s" (second markup-expr)))
  70         (else
  71          (format #f "\\markup ~a"
  72                  (markup->lily-string-aux markup-expr)))))
  73
  74 ;;;
  75 ;;; pitch names
  76 ;;;
  77
  78 ;; It is a pity that there is no rassoc in Scheme.
  79 (define* (rassoc item alist #:optional (test equal?))
  80   (do ((alist alist (cdr alist))
  81        (result #f result))
  82       ((or result (null? alist)) result)
  83     (if (and (car alist) (test item (cdar alist)))
  84         (set! result (car alist)))))
  85
  86 (define-public (note-name->lily-string ly-pitch parser)
  87   ;; here we define a custom pitch= function, since we do not want to
  88   ;; test whether octaves are also equal. (otherwise, we would be using equal?)
  89   (define (pitch= pitch1 pitch2)
  90     (and (= (ly:pitch-notename pitch1) (ly:pitch-notename pitch2))
  91          (= (ly:pitch-alteration pitch1) (ly:pitch-alteration pitch2))))
  92   (let ((result (rassoc ly-pitch (ly:parser-lookup parser 'pitchnames) pitch=)))
  93     (if result
  94         (car result)
  95         #f)))
  96
  97 (define-public (octave->lily-string pitch)
  98   (let ((octave (ly:pitch-octave pitch)))
  99     (cond ((>= octave 0)
 100            (make-string (1+ octave) #\'))
 101           ((< octave -1)
 102            (make-string (1- (* -1 octave)) #\,))
 103           (else ""))))
 104
 105 ;;;
 106 ;;; durations
 107 ;;;
 108 (define*-public (duration->lily-string ly-duration #:key (prev-duration (*previous-duration*))
 109                                        (force-duration (*force-duration*))
 110                                        (time-scale (*time-scale*))
 111                                        remember)
 112   (if remember (*previous-duration* ly-duration))
 113   (let ((log2    (ly:duration-log ly-duration))
 114         (dots    (ly:duration-dot-count ly-duration))
 115         (scale (ly:duration-scale ly-duration)))
 116     (if (or force-duration (not prev-duration) (not (equal? ly-duration prev-duration)))
 117         (string-append (case log2
 118                          ((-1) "\\breve")
 119                          ((-2) "\\longa")
 120                          ((-3) "\\maxima")
 121                          (else (number->string (expt 2 log2))))
 122                        (make-string dots #\.)
 123                        (let ((end-scale (/ scale time-scale)))
 124                          (if (= end-scale 1) ""
 125                              (format #f "*~a" end-scale))))
 126         "")))
 127
 128 ;;;
 129 ;;; post events
 130 ;;;
 131
 132 (define (post-event? m)
 133   (music-is-of-type? m 'post-event))
 134
 135 (define* (event-direction->lily-string event #:optional (required #t))
 136   (let ((direction (ly:music-property event 'direction)))
 137     (cond ((or (not direction) (null? direction) (= CENTER direction))
 138            (if required "-" ""))
 139           ((= UP direction) "^")
 140           ((= DOWN direction) "_")
 141           (else ""))))
 142
 143 (define-macro (define-post-event-display-method type vars direction-required str)
 144   `(define-display-method ,type ,vars
 145      (format #f "~a~a"
 146              (event-direction->lily-string ,(car vars) ,direction-required)
 147              ,str)))
 148
 149 (define-macro (define-span-event-display-method type vars direction-required str-start str-stop)
 150   `(define-display-method ,type ,vars
 151      (format #f "~a~a"
 152              (event-direction->lily-string ,(car vars) ,direction-required)
 153              (if (= START (ly:music-property ,(car vars) 'span-direction))
 154                  ,str-start
 155                  ,str-stop))))
 156
 157 (define-display-method HyphenEvent (event parser)
 158   " --")
 159 (define-display-method ExtenderEvent (event parser)
 160   " __")
 161 (define-display-method TieEvent (event parser)
 162   " ~")
 163 (define-display-method BeamForbidEvent (event parser)
 164   "\\noBeam")
 165 (define-display-method StringNumberEvent (event parser)
 166   (format #f "\\~a" (ly:music-property event 'string-number)))
 167
 168
 169 (define-display-method TremoloEvent (event parser)
 170   (let ((tremolo-type (ly:music-property event 'tremolo-type)))
 171     (format #f ":~a" (if (= 0 tremolo-type)
 172                          ""
 173                          tremolo-type))))
 174
 175 (define-display-method ArticulationEvent (event parser) #t
 176   (let* ((articulation  (ly:music-property event 'articulation-type))
 177          (shorthand
 178           (case (string->symbol articulation)
 179             ((marcato) "^")
 180             ((stopped) "+")
 181             ((tenuto)    "-")
 182             ((staccatissimo) "!")
 183             ((accent) ">")
 184             ((staccato) ".")
 185             ((portato) "_")
 186             (else #f))))
 187     (format #f "~a~:[\\~;~]~a"
 188             (event-direction->lily-string event shorthand)
 189             shorthand
 190             (or shorthand articulation))))
 191
 192 (define-post-event-display-method FingeringEvent (event parser) #t
 193   (ly:music-property event 'digit))
 194
 195 (define-post-event-display-method TextScriptEvent (event parser) #t
 196   (markup->lily-string (ly:music-property event 'text)))
 197
 198 (define-post-event-display-method MultiMeasureTextEvent (event parser) #t
 199   (markup->lily-string (ly:music-property event 'text)))
 200
 201 (define-post-event-display-method BendAfterEvent (event parser) #f
 202   (format #f "\\bendAfter #~a " (ly:music-property event 'delta-step)))
 203
 204 (define-post-event-display-method HarmonicEvent (event parser) #f "\\harmonic")
 205 (define-post-event-display-method GlissandoEvent (event parser) #f "\\glissando")
 206 (define-post-event-display-method ArpeggioEvent (event parser) #f "\\arpeggio")
 207 (define-post-event-display-method AbsoluteDynamicEvent (event parser) #f
 208   (format #f "\\~a" (ly:music-property event 'text)))
 209
 210 (define-post-event-display-method StrokeFingerEvent (event parser) #f
 211   (format #f "\\rightHandFinger #~a " (ly:music-property event 'digit)))
 212
 213 (define-span-event-display-method BeamEvent (event parser) #f "[" "]")
 214 (define-span-event-display-method SlurEvent (event parser) #f "(" ")")
 215 (define-span-event-display-method CrescendoEvent (event parser) #f "\\<" "\\!")
 216 (define-span-event-display-method DecrescendoEvent (event parser) #f "\\>" "\\!")
 217 (define-span-event-display-method EpisemaEvent (event parser) #f "\\episemInitium" "\\episemFinis")
 218 (define-span-event-display-method PhrasingSlurEvent (event parser) #f "\\(" "\\)")
 219 (define-span-event-display-method SustainEvent (event parser) #f "\\sustainOn" "\\sustainOff")
 220 (define-span-event-display-method SostenutoEvent (event parser) #f "\\sostenutoOn" "\\sostenutoOff")
 221 (define-span-event-display-method TextSpanEvent (event parser) #f "\\startTextSpan" "\\stopTextSpan")
 222 (define-span-event-display-method TrillSpanEvent (event parser) #f "\\startTrillSpan" "\\stopTrillSpan")
 223 (define-span-event-display-method StaffSpanEvent (event parser) #f "\\startStaff" "\\stopStaff")
 224 (define-span-event-display-method NoteGroupingEvent (event parser) #f "\\startGroup" "\\stopGroup")
 225 (define-span-event-display-method UnaCordaEvent (event parser) #f "\\unaCorda" "\\treCorde")
 226
 227 ;;;
 228 ;;; Graces
 229 ;;;
 230
 231 (define-display-method GraceMusic (expr parser)
 232   (format #f "\\grace ~a"
 233           (music->lily-string (ly:music-property expr 'element) parser)))
 234
 235 ;; \acciaccatura \appoggiatura \grace
 236 ;; TODO: it would be better to compare ?start and ?stop
 237 ;; with startAppoggiaturaMusic and stopAppoggiaturaMusic,
 238 ;; using a custom music equality predicate.
 239 (define-extra-display-method GraceMusic (expr parser)
 240   "Display method for appoggiatura."
 241   (with-music-match (expr (music
 242                            'GraceMusic
 243                            element (music
 244                                     'SequentialMusic
 245                                     elements (?start
 246                                               ?music
 247                                               ?stop))))
 248                     ;; we check whether ?start and ?stop look like
 249                     ;; startAppoggiaturaMusic stopAppoggiaturaMusic
 250                     (and (with-music-match (?start (music
 251                                                     'SequentialMusic
 252                                                     elements ((music
 253                                                                'EventChord
 254                                                                elements
 255                                                                ((music
 256                                                                  'SlurEvent
 257                                                                  span-direction START))))))
 258                                            #t)
 259                          (with-music-match (?stop (music
 260                                                    'SequentialMusic
 261                                                    elements ((music
 262                                                               'EventChord
 263                                                               elements
 264                                                               ((music
 265                                                                 'SlurEvent
 266                                                                 span-direction STOP))))))
 267                                            (format #f "\\appoggiatura ~a" (music->lily-string ?music parser))))))
 268
 269
 270 (define-extra-display-method GraceMusic (expr parser)
 271   "Display method for acciaccatura."
 272   (with-music-match (expr (music
 273                            'GraceMusic
 274                            element (music
 275                                     'SequentialMusic
 276                                     elements (?start
 277                                               ?music
 278                                               ?stop))))
 279                     ;; we check whether ?start and ?stop look like
 280                     ;; startAcciaccaturaMusic stopAcciaccaturaMusic
 281                     (and (with-music-match (?start (music
 282                                                     'SequentialMusic
 283                                                     elements ((music
 284                                                                'EventChord
 285                                                                elements
 286                                                                ((music
 287                                                                  'SlurEvent
 288                                                                  span-direction START)))
 289                                                               (music
 290                                                                'ContextSpeccedMusic
 291                                                                element (music
 292                                                                         'OverrideProperty
 293                                                                         grob-property-path '(stroke-style)
 294                                                                         grob-value "grace"
 295                                                                         symbol 'Flag)))))
 296                                            #t)
 297                          (with-music-match (?stop (music
 298                                                    'SequentialMusic
 299                                                    elements ((music
 300                                                               'ContextSpeccedMusic
 301                                                               element (music
 302                                                                        'RevertProperty
 303                                                                        grob-property-path '(stroke-style)
 304                                                                        symbol 'Flag))
 305
 306                                                              (music
 307                                                               'EventChord
 308                                                               elements
 309                                                               ((music
 310                                                                 'SlurEvent
 311                                                                 span-direction STOP))))))
 312                                            (format #f "\\acciaccatura ~a" (music->lily-string ?music parser))))))
 313
 314 (define-extra-display-method GraceMusic (expr parser)
 315   "Display method for grace."
 316   (with-music-match (expr (music
 317                            'GraceMusic
 318                            element (music
 319                                     'SequentialMusic
 320                                     elements (?start
 321                                               ?music
 322                                               ?stop))))
 323                     ;; we check whether ?start and ?stop look like
 324                     ;; startGraceMusic stopGraceMusic
 325                     (and (null? (ly:music-property ?start 'elements))
 326                          (null? (ly:music-property ?stop 'elements))
 327                          (format #f "\\grace ~a" (music->lily-string ?music parser)))))
 328
 329 ;;;
 330 ;;; Music sequences
 331 ;;;
 332
 333 (define-display-method SequentialMusic (seq parser)
 334   (let ((force-line-break (and (*force-line-break*)
 335                                ;; hm
 336                                (> (length (ly:music-property seq 'elements))
 337                                   (*max-element-number-before-break*))))
 338         (elements (ly:music-property seq 'elements))
 339         (chord? (make-music-type-predicate 'EventChord))
 340         (note-or-chord? (make-music-type-predicate 'EventChord 'NoteEvent
 341                                                    'LyricEvent 'RestEvent
 342                                                    'ClusterNoteEvent))
 343         (cluster? (make-music-type-predicate 'ClusterNoteEvent))
 344         (note? (make-music-type-predicate 'NoteEvent)))
 345     (format #f "~a~a{~v%~v_~{~a~^ ~}~v%~v_}"
 346             (if (any (lambda (e)
 347                        (or (cluster? e)
 348                            (and (chord? e)
 349                                 (any cluster? (ly:music-property e 'elements)))))
 350                      elements)
 351                 "\\makeClusters "
 352                 "")
 353             (if (*explicit-mode*)
 354                 ;; if the sequence contains EventChord which contains figures ==> figuremode
 355                 ;; if the sequence contains EventChord which contains lyrics ==> lyricmode
 356                 ;; if the sequence contains EventChord which contains drum notes ==> drummode
 357                 (cond ((any (lambda (chord)
 358                               (any (make-music-type-predicate 'BassFigureEvent)
 359                                    (ly:music-property chord 'elements)))
 360                             (filter chord? elements))
 361                        "\\figuremode ")
 362                       ((any (lambda (chord)
 363                               (any (make-music-type-predicate 'LyricEvent)
 364                                    (cons chord
 365                                          (ly:music-property chord 'elements))))
 366                             (filter note-or-chord? elements))
 367                        "\\lyricmode ")
 368                       ((any (lambda (chord)
 369                               (any (lambda (event)
 370                                      (and (note? event)
 371                                           (not (null? (ly:music-property event 'drum-type)))))
 372                                    (cons chord
 373                                          (ly:music-property chord 'elements))))
 374                             (filter note-or-chord? elements))
 375                        "\\drummode ")
 376                       (else ;; TODO: other modes?
 377                        ""))
 378                 "")
 379             (if force-line-break 1 0)
 380             (if force-line-break (+ 2 (*indent*)) 1)
 381             (parameterize ((*indent* (+ 2 (*indent*))))
 382                           (map-in-order (lambda (music)
 383                                           (music->lily-string music parser))
 384                                         elements))
 385             (if force-line-break 1 0)
 386             (if force-line-break (*indent*) 1))))
 387
 388 (define-display-method SimultaneousMusic (sim parser)
 389   (parameterize ((*indent* (+ 3 (*indent*))))
 390                 (format #f "<< ~{~a ~}>>"
 391                         (map-in-order (lambda (music)
 392                                         (music->lily-string music parser))
 393                                       (ly:music-property sim 'elements)))))
 394
 395 (define-extra-display-method SimultaneousMusic (expr parser)
 396   "If `sim' is an \afterGrace expression, return \"\\afterGrace ...\".
 397 Otherwise, return #f."
 398   ;; TODO: do something with afterGraceFraction?
 399   (with-music-match (expr (music 'SimultaneousMusic
 400                                  elements (?before-grace
 401                                            (music 'SequentialMusic
 402                                                   elements ((music 'SkipMusic)
 403                                                             (music 'GraceMusic
 404                                                                    element ?grace))))))
 405                     (format #f "\\afterGrace ~a ~a"
 406                             (music->lily-string ?before-grace parser)
 407                             (music->lily-string ?grace parser))))
 408
 409 ;;;
 410 ;;; Chords
 411 ;;;
 412
 413 (define-display-method EventChord (chord parser)
 414   ;; event_chord : command_element
 415   ;;               | note_chord_element
 416
 417   ;; TODO : tagged post_events
 418   ;; post_events : ( post_event | tagged_post_event )*
 419   ;; tagged_post_event: '-' \tag embedded_scm post_event
 420
 421   (let* ((elements (append (ly:music-property chord 'elements)
 422                            (ly:music-property chord 'articulations)))
 423          (chord-repeat (ly:music-property chord 'duration)))
 424     (call-with-values
 425         (lambda ()
 426           (partition (lambda (m) (music-is-of-type? m 'rhythmic-event))
 427                      elements))
 428       (lambda (chord-elements other-elements)
 429         (cond ((pair? chord-elements)
 430                ;; note_chord_element :
 431                ;; '<' (notepitch | drumpitch)* '>" duration post_events
 432                (let ((duration (duration->lily-string (ly:music-property
 433                                                        (car chord-elements)
 434                                                        'duration)
 435                                                       #:remember #t)))
 436                  ;; Format duration first so that it does not appear on
 437                  ;; chord elements
 438                  (format #f "< ~{~a ~}>~a~:{~:[-~;~]~a~^ ~}"
 439                          (map-in-order (lambda (music)
 440                                          (music->lily-string music parser))
 441                                        chord-elements)
 442                          duration
 443                          (map-in-order (lambda (music)
 444                                          (list
 445                                           (post-event? music)
 446                                           (music->lily-string music parser)))
 447                                        other-elements))))
 448               ((ly:duration? chord-repeat)
 449                (let ((duration (duration->lily-string chord-repeat
 450                                                       #:remember #t)))
 451                  (format #f "q~a~:{~:[-~;~]~a~^ ~}"
 452                          duration
 453                          (map-in-order (lambda (music)
 454                                          (list
 455                                           (post-event? music)
 456                                           (music->lily-string music parser)))
 457                                        other-elements))))
 458
 459               ((and (= 1 (length other-elements))
 460                     (not (post-event? (car other-elements))))
 461                (format #f (music->lily-string (car other-elements) parser)))
 462               (else
 463                (format #f "< >~:{~:[-~;~]~a~^ ~}"
 464                        (map-in-order (lambda (music)
 465                                        (list
 466                                         (post-event? music)
 467                                         (music->lily-string music parser)))
 468                                      other-elements))))))))
 469
 470 (define-display-method MultiMeasureRestMusic (mmrest parser)
 471   (format #f "R~a~{~a~^ ~}"
 472           (duration->lily-string (ly:music-property mmrest 'duration)
 473                                  #:remember #t)
 474           (map-in-order (lambda (music)
 475                           (music->lily-string music parser))
 476                         (ly:music-property mmrest 'articulations))))
 477
 478 (define-display-method SkipMusic (skip parser)
 479   (format #f "\\skip ~a" (duration->lily-string (ly:music-property skip 'duration) #:force-duration #t)))
 480
 481 (define-display-method OttavaMusic (ottava parser)
 482   (format #f "\\ottava #~a" (ly:music-property ottava 'ottava-number)))
 483
 484 ;;;
 485 ;;; Notes, rests, skips...
 486 ;;;
 487
 488 (define (simple-note->lily-string event parser)
 489   (format #f "~a~a~a~a~a~a~:{~:[-~;~]~a~}" ; pitchname octave !? octave-check duration optional_rest articulations
 490           (note-name->lily-string (ly:music-property event 'pitch) parser)
 491           (octave->lily-string (ly:music-property event 'pitch))
 492           (let ((forced (ly:music-property event 'force-accidental))
 493                 (cautionary (ly:music-property event 'cautionary)))
 494             (cond ((and (not (null? forced))
 495                         forced
 496                         (not (null? cautionary))
 497                         cautionary)
 498                    "?")
 499                   ((and (not (null? forced)) forced) "!")
 500                   (else "")))
 501           (let ((octave-check (ly:music-property event 'absolute-octave)))
 502             (if (not (null? octave-check))
 503                 (format #f "=~a" (cond ((>= octave-check 0)
 504                                         (make-string (1+ octave-check) #\'))
 505                                        ((< octave-check -1)
 506                                         (make-string (1- (* -1 octave-check)) #\,))
 507                                        (else "")))
 508                 ""))
 509           (duration->lily-string (ly:music-property event 'duration)
 510                                  #:remember #t)
 511           (if ((make-music-type-predicate 'RestEvent) event)
 512               "\\rest" "")
 513           (map-in-order (lambda (event)
 514                           (list
 515                            (post-event? event)
 516                            (music->lily-string event parser)))
 517                         (ly:music-property event 'articulations))))
 518
 519 (define-display-method NoteEvent (note parser)
 520   (cond ((not (null? (ly:music-property note 'pitch))) ;; note
 521          (simple-note->lily-string note parser))
 522         ((not (null? (ly:music-property note 'drum-type))) ;; drum
 523          (format #f "~a~a~{~a~}" (ly:music-property note 'drum-type)
 524                  (duration->lily-string (ly:music-property note 'duration)
 525                                         #:remember #t)
 526                  (map-in-order (lambda (event)
 527                                  (music->lily-string event parser))
 528                                (ly:music-property note 'articulations))))
 529         (else
 530          ;; pure duration
 531          ;; FIXME: { c4 c4 4 4 } must not be output as { c4 c 4 4 }
 532          ;; quite tricky to do.  Do it when outputting sequences?
 533          (format #f "~a~{~a~}"
 534                  (duration->lily-string (ly:music-property note 'duration)
 535                                         #:force-duration #t
 536                                         #:remember #t)
 537                  (map-in-order (lambda (event)
 538                                  (music->lily-string event parser))
 539                                (ly:music-property note 'articulations))))))
 540
 541 (define-display-method ClusterNoteEvent (note parser)
 542   (simple-note->lily-string note parser))
 543
 544 (define-display-method RestEvent (rest parser)
 545   (if (not (null? (ly:music-property rest 'pitch)))
 546       (simple-note->lily-string rest parser)
 547       (format #f "r~a~{~a~}"
 548               (duration->lily-string (ly:music-property rest 'duration)
 549                                      #:remember #t)
 550               (map-in-order (lambda (event)
 551                               (music->lily-string event parser))
 552                             (ly:music-property rest 'articulations)))))
 553
 554 (define-display-method MultiMeasureRestEvent (rest parser)
 555   (string-append "R" (duration->lily-string (ly:music-property rest 'duration)
 556                                             #:remember #t)))
 557
 558 (define-display-method SkipEvent (rest parser)
 559   (format #f "s~a~{~a~}"
 560           (duration->lily-string (ly:music-property rest 'duration)
 561                                  #:remember #t)
 562           (map-in-order (lambda (event)
 563                           (music->lily-string event parser))
 564                         (ly:music-property rest 'articulations))))
 565
 566 (define-display-method RepeatedChord (chord parser)
 567   (music->lily-string (ly:music-property chord 'element) parser))
 568
 569 (define-display-method MarkEvent (mark parser)
 570   (let ((label (ly:music-property mark 'label)))
 571     (if (null? label)
 572         "\\mark \\default"
 573         (format #f "\\mark ~a" (markup->lily-string label)))))
 574
 575 (define-display-method KeyChangeEvent (key parser)
 576   (let ((pitch-alist (ly:music-property key 'pitch-alist))
 577         (tonic (ly:music-property key 'tonic)))
 578     (if (or (null? pitch-alist)
 579             (null? tonic))
 580         "\\key \\default"
 581         (let ((c-pitch-alist (ly:transpose-key-alist pitch-alist
 582                                                      (ly:pitch-diff (ly:make-pitch 0 0 0) tonic))))
 583           (format #f "\\key ~a \\~a~a"
 584                   (note-name->lily-string (ly:music-property key 'tonic) parser)
 585                   (any (lambda (mode)
 586                          (if (and parser
 587                                   (equal? (ly:parser-lookup parser mode) c-pitch-alist))
 588                              (symbol->string mode)
 589                              #f))
 590                        '(major minor ionian locrian aeolian mixolydian lydian phrygian dorian))
 591                   (new-line->lily-string))))))
 592
 593 (define-display-method RelativeOctaveCheck (octave parser)
 594   (let ((pitch (ly:music-property octave 'pitch)))
 595     (format #f "\\octaveCheck ~a~a"
 596             (note-name->lily-string pitch parser)
 597             (octave->lily-string pitch))))
 598
 599 (define-display-method VoiceSeparator (sep parser)
 600   "\\\\")
 601
 602 (define-display-method LigatureEvent (ligature parser)
 603   (if (= START (ly:music-property ligature 'span-direction))
 604       "\\["
 605       "\\]"))
 606
 607 (define-display-method BarCheck (check parser)
 608   (format #f "|~a" (new-line->lily-string)))
 609
 610 (define-display-method PesOrFlexaEvent (expr parser)
 611   "\\~")
 612
 613 (define-display-method BassFigureEvent (figure parser)
 614   (let ((alteration (ly:music-property figure 'alteration))
 615         (fig (ly:music-property figure 'figure))
 616         (bracket-start (ly:music-property figure 'bracket-start))
 617         (bracket-stop (ly:music-property figure 'bracket-stop)))
 618
 619     (format #f "~a~a~a~a"
 620             (if (null? bracket-start) "" "[")
 621             (cond ((null? fig) "_")
 622                   ((markup? fig) (second fig)) ;; fig: (<number-markup> "number")
 623                   (else fig))
 624             (if (null? alteration)
 625                 ""
 626                 (cond
 627                  ((= alteration DOUBLE-FLAT) "--")
 628                  ((= alteration FLAT) "-")
 629                  ((= alteration NATURAL) "!")
 630                  ((= alteration SHARP) "+")
 631                  ((= alteration DOUBLE-SHARP) "++")
 632                  (else "")))
 633             (if (null? bracket-stop) "" "]"))))
 634
 635 (define-display-method LyricEvent (lyric parser)
 636   (format "~a~{~a~^ ~}"
 637           (let ((text (ly:music-property lyric 'text)))
 638             (if (or (string? text)
 639                     (eqv? (first text) simple-markup))
 640                 ;; a string or a simple markup
 641                 (let ((string (if (string? text)
 642                                   text
 643                                   (second text))))
 644                   (if (string-match "(\"| |[0-9])" string)
 645                       ;; TODO check exactly in which cases double quotes should be used
 646                       (format #f "~s" string)
 647                       string))
 648                 (markup->lily-string text)))
 649           (map-in-order (lambda (m) (music->lily-string m parser))
 650                         (ly:music-property lyric 'articulations))))
 651
 652 (define-display-method BreathingEvent (event parser)
 653   "\\breathe")
 654
 655 ;;;
 656 ;;; Staff switches
 657 ;;;
 658
 659 (define-display-method AutoChangeMusic (m parser)
 660   (format #f "\\autochange ~a"
 661           (music->lily-string (ly:music-property m 'element) parser)))
 662
 663 (define-display-method ContextChange (m parser)
 664   (format #f "\\change ~a = \"~a\""
 665           (ly:music-property m 'change-to-type)
 666           (ly:music-property m 'change-to-id)))
 667
 668 ;;;
 669
 670 (define-display-method TimeScaledMusic (times parser)
 671   (let* ((num (ly:music-property times 'numerator))
 672          (den (ly:music-property times 'denominator))
 673          (span (ly:music-property times 'duration #f))
 674          ;; need to format before changing time scale
 675          (formatted-span
 676           (and span (duration->lily-string span #:force-duration #t)))
 677          (scale (/ num den))
 678          (time-scale (*time-scale*)))
 679     (*previous-duration* #f)
 680     (let ((result
 681            (parameterize ((*force-line-break* #f)
 682                           (*time-scale* (* time-scale scale)))
 683                          (format #f "\\tuplet ~a/~a ~@[~a ~]~a"
 684                                  den
 685                                  num
 686                                  formatted-span
 687                                  (music->lily-string (ly:music-property times 'element) parser)))))
 688       (*previous-duration* #f)
 689       result)))
 690
 691 (define-display-method RelativeOctaveMusic (m parser)
 692   (music->lily-string (ly:music-property m 'element) parser))
 693
 694 (define-display-method TransposedMusic (m parser)
 695   (music->lily-string (ly:music-property m 'element) parser))
 696
 697 ;;;
 698 ;;; Repeats
 699 ;;;
 700
 701 (define-display-method AlternativeEvent (alternative parser) "")
 702
 703 (define (repeat->lily-string expr repeat-type parser)
 704   (let* ((main (music->lily-string (ly:music-property expr 'element) parser)))
 705     (format #f "\\repeat ~a ~a ~a ~a"
 706             repeat-type
 707             (ly:music-property expr 'repeat-count)
 708             main
 709             (let ((alternatives (ly:music-property expr 'elements)))
 710               (if (null? alternatives)
 711                   ""
 712                   (format #f "\\alternative { ~{~a ~}}"
 713                           (map-in-order (lambda (music)
 714                                           (music->lily-string music parser))
 715                                         alternatives)))))))
 716
 717 (define-display-method VoltaRepeatedMusic (expr parser)
 718   (repeat->lily-string expr "volta" parser))
 719
 720 (define-display-method UnfoldedRepeatedMusic (expr parser)
 721   (repeat->lily-string expr "unfold" parser))
 722
 723 (define-display-method PercentRepeatedMusic (expr parser)
 724   (repeat->lily-string expr "percent" parser))
 725
 726 (define-display-method TremoloRepeatedMusic (expr parser)
 727   (repeat->lily-string expr "tremolo" parser))
 728
 729 ;;;
 730 ;;; Contexts
 731 ;;;
 732
 733 (define-display-method ContextSpeccedMusic (expr parser)
 734   (let ((id    (ly:music-property expr 'context-id))
 735         (create-new (ly:music-property expr 'create-new))
 736         (music (ly:music-property expr 'element))
 737         (operations (ly:music-property expr 'property-operations))
 738         (ctype (ly:music-property expr 'context-type)))
 739     (format #f "~a ~a~a~a ~a"
 740             (if (and (not (null? create-new)) create-new)
 741                 "\\new"
 742                 "\\context")
 743             ctype
 744             (if (null? id)
 745                 ""
 746                 (format #f " = ~s" id))
 747             (if (null? operations)
 748                 ""
 749                 (format #f " \\with {~{~a~}~%~v_}"
 750                         (parameterize ((*indent* (+ (*indent*) 2)))
 751                                       (map (lambda (op)
 752                                              (format #f "~%~v_\\~a ~s"
 753                                                      (*indent*)
 754                                                      (first op)
 755                                                      (second op)))
 756                                            operations))
 757                         (*indent*)))
 758             (parameterize ((*current-context* ctype))
 759                           (music->lily-string music parser)))))
 760
 761 ;; special cases: \figures \lyrics \drums
 762 (define-extra-display-method ContextSpeccedMusic (expr parser)
 763   (with-music-match (expr (music 'ContextSpeccedMusic
 764                                  create-new #t
 765                                  property-operations ?op
 766                                  context-type ?context-type
 767                                  element ?sequence))
 768                     (if (null? ?op)
 769                         (parameterize ((*explicit-mode* #f))
 770                                       (case ?context-type
 771                                         ((FiguredBass)
 772                                          (format #f "\\figures ~a" (music->lily-string ?sequence parser)))
 773                                         ((Lyrics)
 774                                          (format #f "\\lyrics ~a" (music->lily-string ?sequence parser)))
 775                                         ((DrumStaff)
 776                                          (format #f "\\drums ~a" (music->lily-string ?sequence parser)))
 777                                         (else
 778                                          #f)))
 779                         #f)))
 780
 781 ;;; Context properties
 782
 783 (define-extra-display-method ContextSpeccedMusic (expr parser)
 784   (let ((element (ly:music-property expr 'element))
 785         (property-tuning? (make-music-type-predicate 'PropertySet
 786                                                      'PropertyUnset
 787                                                      'OverrideProperty
 788                                                      'RevertProperty))
 789         (sequence? (make-music-type-predicate 'SequentialMusic)))
 790     (if (and (ly:music? element)
 791              (or (property-tuning? element)
 792                  (and (sequence? element)
 793                       (every property-tuning? (ly:music-property element 'elements)))))
 794         (parameterize ((*current-context* (ly:music-property expr 'context-type)))
 795                       (music->lily-string element parser))
 796         #f)))
 797
 798 (define-public (value->lily-string arg parser)
 799   (cond ((ly:music? arg)
 800          (music->lily-string arg parser))
 801         ((string? arg)
 802          (format #f "#~s" arg))
 803         ((markup? arg)
 804          (markup->lily-string arg))
 805         ((ly:duration? arg)
 806          (format #f "##{ ~a #}" (duration->lily-string arg #:force-duration #t)))
 807         ((ly:pitch? arg)
 808          (format #f "~a~a"
 809                  (note-name->lily-string arg parser)
 810                  (octave->lily-string arg)))
 811         (else
 812          (format #f "#~a" (scheme-expr->lily-string arg)))))
 813
 814 (define-display-method PropertySet (expr parser)
 815   (let ((property (ly:music-property expr 'symbol))
 816         (value (ly:music-property expr 'value))
 817         (once (ly:music-property expr 'once)))
 818     (format #f "~a\\set ~a~a = ~a~a"
 819             (if (and (not (null? once)))
 820                 "\\once "
 821                 "")
 822             (if (eqv? (*current-context*) 'Bottom)
 823                 ""
 824                 (format #f "~a . " (*current-context*)))
 825             property
 826             (value->lily-string value parser)
 827             (new-line->lily-string))))
 828
 829 (define-display-method PropertyUnset (expr parser)
 830   (format #f "\\unset ~a~a~a"
 831           (if (eqv? (*current-context*) 'Bottom)
 832               ""
 833               (format #f "~a . " (*current-context*)))
 834           (ly:music-property expr 'symbol)
 835           (new-line->lily-string)))
 836
 837 ;;; Layout properties
 838
 839 (define-display-method OverrideProperty (expr parser)
 840   (let* ((symbol          (ly:music-property expr 'symbol))
 841          (properties   (ly:music-property expr 'grob-property-path
 842                                           (list (ly:music-property expr 'grob-property))))
 843          (value   (ly:music-property expr 'grob-value))
 844          (once    (ly:music-property expr 'once)))
 845
 846     (format #f "~a\\override ~{~a~^.~} = ~a~a"
 847             (if (or (null? once)
 848                     (not once))
 849                 ""
 850                 "\\once ")
 851             (if (eqv? (*current-context*) 'Bottom)
 852                 (cons symbol properties)
 853                 (cons* (*current-context*) symbol properties))
 854             (value->lily-string value parser)
 855             (new-line->lily-string))))
 856
 857 (define-display-method RevertProperty (expr parser)
 858   (let* ((symbol (ly:music-property expr 'symbol))
 859          (properties (ly:music-property expr 'grob-property-path
 860                                         (list (ly:music-property expr 'grob-property)))))
 861     (format #f "\\revert ~{~a~^.~}~a"
 862             (if (eqv? (*current-context*) 'Bottom)
 863                 (cons symbol properties)
 864                 (cons* (*current-context*) symbol properties))
 865             (new-line->lily-string))))
 866
 867 (define-display-method TimeSignatureMusic (expr parser)
 868   (let* ((num (ly:music-property expr 'numerator))
 869          (den (ly:music-property expr 'denominator))
 870          (structure (ly:music-property expr 'beat-structure)))
 871     (if (null? structure)
 872         (format #f
 873                 "\\time ~a/~a~a"
 874                 num den
 875                 (new-line->lily-string))
 876         (format #f
 877                 "\\time #'~a ~a/~a~a"
 878                 structure num den
 879                 (new-line->lily-string)))))
 880
 881 ;;; \melisma and \melismaEnd
 882 (define-extra-display-method ContextSpeccedMusic (expr parser)
 883   "If expr is a melisma, return \"\\melisma\", otherwise, return #f."
 884   (with-music-match (expr (music 'ContextSpeccedMusic
 885                                  element (music 'PropertySet
 886                                                 value #t
 887                                                 symbol 'melismaBusy)))
 888                     "\\melisma"))
 889
 890 (define-extra-display-method ContextSpeccedMusic (expr parser)
 891   "If expr is a melisma end, return \"\\melismaEnd\", otherwise, return #f."
 892   (with-music-match (expr (music 'ContextSpeccedMusic
 893                                  element (music 'PropertyUnset
 894                                                 symbol 'melismaBusy)))
 895                     "\\melismaEnd"))
 896
 897 ;;; \tempo
 898 (define-extra-display-method SequentialMusic (expr parser)
 899   (with-music-match (expr (music 'SequentialMusic
 900                                  elements ((music 'TempoChangeEvent
 901                                                   text ?text
 902                                                   tempo-unit ?unit
 903                                                   metronome-count ?count)
 904                                            (music 'ContextSpeccedMusic
 905                                                   element (music 'PropertySet
 906                                                                  symbol 'tempoWholesPerMinute)))))
 907                     (format #f "\\tempo ~{~a~a~}~a = ~a~a"
 908                             (if (markup? ?text)
 909                                 (list (markup->lily-string ?text) " ")
 910                                 '())
 911                             (duration->lily-string ?unit #:force-duration #t)
 912                             (if (pair? ?count)
 913                                 (format #f "~a - ~a" (car ?count) (cdr ?count))
 914                                 ?count)
 915                             (new-line->lily-string))))
 916
 917 (define-display-method TempoChangeEvent (expr parser)
 918   (let ((text (ly:music-property expr 'text)))
 919     (format #f "\\tempo ~a~a"
 920             (markup->lily-string text)
 921             (new-line->lily-string))))
 922
 923 ;;; \clef
 924 (define clef-name-alist #f)
 925 (define-public (memoize-clef-names clefs)
 926   "Initialize @code{clef-name-alist}, if not already set."
 927   (if (not clef-name-alist)
 928       (set! clef-name-alist
 929             (map (lambda (name+vals)
 930                    (cons (cdr name+vals)
 931                          (car name+vals)))
 932                  clefs))))
 933
 934 (define-extra-display-method ContextSpeccedMusic (expr parser)
 935   "If @var{expr} is a clef change, return \"\\clef ...\".
 936 Otherwise, return @code{#f}."
 937   (with-music-match (expr (music 'ContextSpeccedMusic
 938                                  context-type 'Staff
 939                                  element (music 'SequentialMusic
 940                                                 elements ((music 'PropertySet
 941                                                                  value ?clef-glyph
 942                                                                  symbol 'clefGlyph)
 943                                                           (music 'PropertySet
 944                                                                  symbol 'middleCClefPosition)
 945                                                           (music 'PropertySet
 946                                                                  value ?clef-position
 947                                                                  symbol 'clefPosition)
 948                                                           (music 'PropertySet
 949                                                                  value ?clef-transposition
 950                                                                  symbol 'clefTransposition)
 951                                                           (music 'ApplyContext
 952                                                                  procedure ly:set-middle-C!)))))
 953                     (let ((clef-name (assoc-get (list ?clef-glyph ?clef-position 0)
 954                                                 clef-name-alist)))
 955                       (if clef-name
 956                           (format #f "\\clef \"~a~{~a~a~}\"~a"
 957                                   clef-name
 958                                   (cond ((= 0 ?clef-transposition)
 959                                          (list "" ""))
 960                                         ((> ?clef-transposition 0)
 961                                          (list "^" (1+ ?clef-transposition)))
 962                                         (else
 963                                          (list "_" (- 1 ?clef-transposition))))
 964                                   (new-line->lily-string))
 965                           #f))))
 966
 967 ;;; \bar
 968 (define-extra-display-method ContextSpeccedMusic (expr parser)
 969   "If `expr' is a bar, return \"\\bar ...\".
 970 Otherwise, return #f."
 971   (with-music-match (expr (music 'ContextSpeccedMusic
 972                                  context-type 'Timing
 973                                  element (music 'PropertySet
 974                                                 value ?bar-type
 975                                                 symbol 'whichBar)))
 976                     (format #f "\\bar \"~a\"~a" ?bar-type (new-line->lily-string))))
 977
 978 ;;; \partial
 979 (define-extra-display-method ContextSpeccedMusic (expr parser)
 980   "If `expr' is a partial measure, return \"\\partial ...\".
 981 Otherwise, return #f."
 982   (with-music-match (expr (music
 983                            'ContextSpeccedMusic
 984                            element (music
 985                                     'ContextSpeccedMusic
 986                                     context-type 'Timing
 987                                     element (music
 988                                              'PartialSet
 989                                              duration ?duration))))
 990
 991                     (and ?duration
 992                          (format #f "\\partial ~a"
 993                                  (duration->lily-string ?duration #:force-duration #t)))))
 994
 995 ;;;
 996 ;;;
 997
 998 (define-display-method ApplyOutputEvent (applyoutput parser)
 999   (let ((proc (ly:music-property applyoutput 'procedure))
1000         (ctx  (ly:music-property applyoutput 'context-type)))
1001     (format #f "\\applyOutput #'~a #~a"
1002             ctx
1003             (or (procedure-name proc)
1004                 (with-output-to-string
1005                   (lambda ()
1006                     (pretty-print (procedure-source proc))))))))
1007
1008 (define-display-method ApplyContext (applycontext parser)
1009   (let ((proc (ly:music-property applycontext 'procedure)))
1010     (format #f "\\applyContext #~a"
1011             (or (procedure-name proc)
1012                 (with-output-to-string
1013                   (lambda ()
1014                     (pretty-print (procedure-source proc))))))))
1015
1016 ;;; \partcombine
1017 (define-display-method PartCombineMusic (expr parser)
1018   (format #f "\\partcombine ~{~a ~}"
1019           (map-in-order (lambda (music)
1020                           (music->lily-string music parser))
1021                         (ly:music-property expr 'elements))))
1022
1023 (define-extra-display-method PartCombineMusic (expr parser)
1024   (with-music-match (expr (music 'PartCombineMusic
1025                                  elements ((music 'UnrelativableMusic
1026                                                   element (music 'ContextSpeccedMusic
1027                                                                  context-id "one"
1028                                                                  context-type 'Voice
1029                                                                  element ?sequence1))
1030                                            (music 'UnrelativableMusic
1031                                                   element (music 'ContextSpeccedMusic
1032                                                                  context-id "two"
1033                                                                  context-type 'Voice
1034                                                                  element ?sequence2)))))
1035                     (format #f "\\partcombine ~a~a~a"
1036                             (music->lily-string ?sequence1 parser)
1037                             (new-line->lily-string)
1038                             (music->lily-string ?sequence2 parser))))
1039
1040 (define-display-method UnrelativableMusic (expr parser)
1041   (music->lily-string (ly:music-property expr 'element) parser))
1042
1043 ;;; Cue notes
1044 (define-display-method QuoteMusic (expr parser)
1045   (or (with-music-match (expr (music
1046                                'QuoteMusic
1047                                quoted-voice-direction ?quoted-voice-direction
1048                                quoted-music-name ?quoted-music-name
1049                                quoted-context-id "cue"
1050                                quoted-context-type 'CueVoice
1051                                element ?music))
1052                         (format #f "\\cueDuring #~s #~a ~a"
1053                                 ?quoted-music-name
1054                                 ?quoted-voice-direction
1055                                 (music->lily-string ?music parser)))
1056       (format #f "\\quoteDuring #~s ~a"
1057               (ly:music-property expr 'quoted-music-name)
1058               (music->lily-string (ly:music-property expr 'element) parser))))
1059
1060 ;;;
1061 ;;; Breaks
1062 ;;;
1063 (define-display-method LineBreakEvent (expr parser)
1064   (if (null? (ly:music-property expr 'break-permission))
1065       "\\noBreak"
1066       "\\break"))
1067
1068 (define-display-method PageBreakEvent (expr parser)
1069   (if (null? (ly:music-property expr 'break-permission))
1070       "\\noPageBreak"
1071       "\\pageBreak"))
1072
1073 (define-display-method PageTurnEvent (expr parser)
1074   (if (null? (ly:music-property expr 'break-permission))
1075       "\\noPageTurn"
1076       "\\pageTurn"))
1077
1078 (define-extra-display-method EventChord (expr parser)
1079   (with-music-match (expr (music 'EventChord
1080                                  elements ((music 'LineBreakEvent
1081                                                   break-permission 'force)
1082                                            (music 'PageBreakEvent
1083                                                   break-permission 'force))))
1084                     "\\pageBreak"))
1085
1086 (define-extra-display-method EventChord (expr parser)
1087   (with-music-match (expr (music 'EventChord
1088                                  elements ((music 'LineBreakEvent
1089                                                   break-permission 'force)
1090                                            (music 'PageBreakEvent
1091                                                   break-permission 'force)
1092                                            (music 'PageTurnEvent
1093                                                   break-permission 'force))))
1094                     "\\pageTurn"))
1095
1096 ;;;
1097 ;;; Lyrics
1098 ;;;
1099
1100 ;;; \lyricsto
1101 (define-display-method LyricCombineMusic (expr parser)
1102   (format #f "\\lyricsto ~s ~a"
1103           (ly:music-property expr 'associated-context)
1104           (parameterize ((*explicit-mode* #f))
1105                         (music->lily-string (ly:music-property expr 'element) parser))))
1106
1107 ;; \addlyrics
1108 (define-extra-display-method SimultaneousMusic (expr parser)
1109   (with-music-match (expr (music 'SimultaneousMusic
1110                                  elements ((music 'ContextSpeccedMusic
1111                                                   context-id ?id
1112                                                   context-type 'Voice
1113                                                   element ?note-sequence)
1114                                            (music 'ContextSpeccedMusic
1115                                                   context-type 'Lyrics
1116                                                   create-new #t
1117                                                   element (music 'LyricCombineMusic
1118                                                                  associated-context ?associated-id
1119                                                                  element ?lyric-sequence)))))
1120                     (if (string=? ?id ?associated-id)
1121                         (format #f "~a~a \\addlyrics ~a"
1122                                 (music->lily-string ?note-sequence parser)
1123                                 (new-line->lily-string)
1124                                 (parameterize ((*explicit-mode* #f))
1125                                               (music->lily-string ?lyric-sequence parser)))
1126                         #f)))
1127
1128 ;; Silence internal event sent at end of each lyrics block
1129 (define-display-method CompletizeExtenderEvent (expr parser)
1130   "")