scm/define-markup-commands.scm

   1 ;;;; define-markup-commands.scm -- markup commands
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c)  2000--2004  Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6 ;;;;                  Jan Nieuwenhuizen <janneke@gnu.org>
   7
   8 ;;; markup commands
   9 ;;; TODO:
  10 ;;;  * each markup function should have a doc string with
  11 ;;     syntax, description and example.
  12
  13
  14 (def-markup-command (word paper props str) (string?)
  15   "A single word."
  16   (interpret-markup paper props str))
  17
  18 (def-markup-command (simple paper props str) (string?)
  19   "A simple text-string; @code{\\markup @{ foo @}} is equivalent with
  20 @code{\\markup @{ \\simple #\"foo\" @}}."
  21     (interpret-markup paper props
  22                       (make-line-markup
  23                        (map make-word-markup (string-tokenize str)))))
  24
  25 (define-public empty-markup
  26   (make-simple-markup ""))
  27
  28 ;;(def-markup-command (fill-line paper props line-width markups)
  29 ;;  (number? markup-list?)
  30 ;; no parser tag -- should make number? markuk-list? thingy
  31 (def-markup-command (fill-line paper props markups)
  32   (markup-list?)
  33   "Put @var{markups} in a horizontal line of width @var{line-width}.
  34    The markups are spaced/flushed to fill the entire line."
  35
  36   (let* ((stencils (map (lambda (x) (interpret-markup paper props x))
  37                         markups))
  38          (text-width (apply + (map interval-length
  39                                    (map (lambda (x)
  40                                           (ly:stencil-extent x X))
  41                                         stencils))))
  42         (word-count (length markups))
  43         (word-space (chain-assoc-get 'word-space props))
  44         (line-width (chain-assoc-get 'linewidth props))
  45         (fill-space (if (< line-width text-width)
  46                         word-space
  47                         (/ (- line-width text-width)
  48                            (if (= word-count 1) 2 (- word-count 1)))))
  49         (line-stencils (if (= word-count 1)
  50                            (map (lambda (x) (interpret-markup paper props x))
  51                                 (list (make-word-markup "")
  52                                       (car markups)
  53                                       (make-word-markup "")))
  54                                 stencils)))
  55     (stack-stencil-line fill-space line-stencils)))
  56
  57 (define (font-markup qualifier value)
  58   (lambda (paper props arg)
  59     (interpret-markup paper
  60                       (prepend-alist-chain qualifier value props)
  61                       arg)))
  62
  63 (def-markup-command (line paper props args) (markup-list?)
  64   "Put @var{args} in a horizontal line.  The property @code{word-space}
  65 determines the space between each markup in @var{args}."
  66   (stack-stencil-line
  67    (chain-assoc-get 'word-space props)
  68    (map (lambda (m) (interpret-markup paper props m)) args)))
  69
  70 (def-markup-command (combine paper props m1 m2) (markup? markup?)
  71   "Print two markups on top of each other."
  72   (ly:stencil-add
  73    (interpret-markup paper props m1)
  74    (interpret-markup paper props m2)))
  75
  76 (def-markup-command (finger paper props arg) (markup?)
  77   "Set the argument as small numbers."
  78   (interpret-markup paper
  79                     (cons '((font-size . -5) (font-family . number)) props)
  80                     arg))
  81
  82 (def-markup-command (fontsize paper props mag arg) (number? markup?)
  83   "This sets the relative font size, eg.
  84 @example
  85 A \\fontsize #2 @{ B C @} D
  86 @end example
  87
  88
  89 This will enlarge the B and the C by two steps.
  90 "
  91   (interpret-markup
  92    paper
  93    (prepend-alist-chain 'font-size mag props)
  94    arg))
  95
  96 (def-markup-command (magnify paper props sz arg) (number? markup?)
  97   "This sets the font magnification for the its argument. In the following
  98 example, the middle A will be 10% larger:
  99 @example
 100 A \\magnify #1.1 @{ A @} A
 101 @end example
 102
 103 Note: magnification only works if a font-name is explicitly selected.
 104 Use @code{\\fontsize} otherwise."
 105
 106   (interpret-markup
 107    paper
 108    (prepend-alist-chain 'font-magnification sz props)
 109    arg))
 110
 111 (def-markup-command (bold paper props arg) (markup?)
 112   "Switch to bold font-series"
 113   (interpret-markup paper (prepend-alist-chain 'font-series 'bold props) arg))
 114
 115 (def-markup-command (sans paper props arg) (markup?)
 116   "Switch to the sans-serif family"
 117   (interpret-markup paper (prepend-alist-chain 'font-family 'sans props) arg))
 118
 119 (def-markup-command (number paper props arg) (markup?)
 120   "Set font family to @code{number}, which yields the font used for
 121 time signatures and fingerings.  This font only contains numbers and
 122 some punctuation. It doesn't have any letters.  "
 123   (interpret-markup paper (prepend-alist-chain 'font-family 'number props) arg))
 124
 125 (def-markup-command (roman paper props arg) (markup?)
 126   "Set font family to @code{roman}."
 127   (interpret-markup paper (prepend-alist-chain 'font-family 'roman props) arg))
 128
 129 (def-markup-command (huge paper props arg) (markup?)
 130   "Set font size to +2."
 131   (interpret-markup paper (prepend-alist-chain 'font-size 2 props) arg))
 132
 133 (def-markup-command (large paper props arg) (markup?)
 134   "Set font size to +1."
 135   (interpret-markup paper (prepend-alist-chain 'font-size 1 props) arg))
 136
 137 (def-markup-command (normalsize paper props arg) (markup?)
 138   "Set font size to default."
 139   (interpret-markup paper (prepend-alist-chain 'font-size 0 props) arg))
 140
 141 (def-markup-command (small paper props arg) (markup?)
 142   "Set font size to -1."
 143   (interpret-markup paper (prepend-alist-chain 'font-size -1 props) arg))
 144
 145 (def-markup-command (tiny paper props arg) (markup?)
 146   "Set font size to -2."
 147   (interpret-markup paper (prepend-alist-chain 'font-size -2 props) arg))
 148
 149 (def-markup-command (teeny paper props arg) (markup?)
 150   "Set font size to -3."
 151   (interpret-markup paper (prepend-alist-chain 'font-size -3 props) arg))
 152
 153 (def-markup-command (caps paper props arg) (markup?)
 154   "Set font shape to @code{caps}."
 155   (interpret-markup paper (prepend-alist-chain 'font-shape 'caps props) arg))
 156
 157 (def-markup-command (latin-i paper props arg) (markup?)
 158   "TEST latin1 encoding."
 159   (interpret-markup paper (prepend-alist-chain 'font-shape 'latin1 props) arg))
 160
 161 (def-markup-command (dynamic paper props arg) (markup?)
 162   "Use the dynamic font.  This font only contains @b{s}, @b{f}, @b{m},
 163 @b{z}, @b{p}, and @b{r}.  When producing phrases, like ``piu @b{f}'', the
 164 normal words (like ``piu'') should be done in a different font.  The
 165 recommend font for this is bold and italic"
 166   (interpret-markup
 167    paper (prepend-alist-chain 'font-family 'dynamic props) arg))
 168
 169 (def-markup-command (italic paper props arg) (markup?)
 170   "Use italic @code{font-shape} for @var{arg}. "
 171   (interpret-markup paper (prepend-alist-chain 'font-shape 'italic props) arg))
 172
 173 (def-markup-command (typewriter paper props arg) (markup?)
 174   "Use @code{font-family} typewriter for @var{arg}."
 175   (interpret-markup
 176    paper (prepend-alist-chain 'font-family 'typewriter props) arg))
 177
 178 (def-markup-command (upright paper props arg) (markup?)
 179   "Set font shape to @code{upright}."
 180   (interpret-markup
 181    paper (prepend-alist-chain 'font-shape 'upright props) arg))
 182
 183 (def-markup-command (doublesharp paper props) ()
 184   "Draw a double sharp symbol."
 185
 186   (interpret-markup paper props (markup #:musicglyph "accidentals-4")))
 187 (def-markup-command (sesquisharp paper props) ()
 188   "Draw a 3/2 sharp symbol."
 189   (interpret-markup paper props (markup #:musicglyph "accidentals-3")))
 190
 191 (def-markup-command (sharp paper props) ()
 192   "Draw a sharp symbol."
 193   (interpret-markup paper props (markup #:musicglyph "accidentals-2")))
 194 (def-markup-command (semisharp paper props) ()
 195   "Draw a semi sharp symbol."
 196   (interpret-markup paper props (markup #:musicglyph "accidentals-1")))
 197 (def-markup-command (natural paper props) ()
 198   "Draw a natural symbol."
 199
 200   (interpret-markup paper props (markup #:musicglyph "accidentals-0")))
 201 (def-markup-command (semiflat paper props) ()
 202   "Draw a semiflat."
 203   (interpret-markup paper props (markup #:musicglyph "accidentals--1")))
 204 (def-markup-command (flat paper props) ()
 205   "Draw a flat symbol."
 206
 207   (interpret-markup paper props (markup #:musicglyph "accidentals--2")))
 208 (def-markup-command (sesquiflat paper props) ()
 209   "Draw a 3/2 flat symbol."
 210
 211   (interpret-markup paper props (markup #:musicglyph "accidentals--3")))
 212 (def-markup-command (doubleflat paper props) ()
 213   "Draw a double flat symbol."
 214
 215   (interpret-markup paper props (markup #:musicglyph "accidentals--4")))
 216
 217
 218 (def-markup-command (column paper props args) (markup-list?)
 219   "Stack the markups in @var{args} vertically."
 220   (stack-lines
 221    -1 0.0 (chain-assoc-get 'baseline-skip props)
 222    (map (lambda (m) (interpret-markup paper props m)) args)))
 223
 224 (def-markup-command (dir-column paper props args) (markup-list?)
 225   "Make a column of args, going up or down, depending on the setting
 226 of the @code{#'direction} layout property."
 227   (let* ((dir (chain-assoc-get 'direction props)))
 228     (stack-lines
 229      (if (number? dir) dir -1)
 230      0.0
 231       (chain-assoc-get 'baseline-skip props)
 232      (map (lambda (x) (interpret-markup paper props x)) args))))
 233
 234 (def-markup-command (center-align paper props args) (markup-list?)
 235   "Put @code{args} in a centered column. "
 236   (let* ((mols (map (lambda (x) (interpret-markup paper props x)) args))
 237          (cmols (map (lambda (x) (ly:stencil-align-to! x X CENTER)) mols)))
 238     (stack-lines -1 0.0 (chain-assoc-get 'baseline-skip props) mols)))
 239
 240 (def-markup-command (right-align paper props arg) (markup?)
 241   (let* ((m (interpret-markup paper props arg)))
 242     (ly:stencil-align-to! m X RIGHT)
 243     m))
 244
 245 (def-markup-command (left-align paper props arg) (markup?)
 246   "Align @var{arg} on its left edge. "
 247
 248   (let* ((m (interpret-markup paper props arg)))
 249     (ly:stencil-align-to! m X LEFT)
 250     m))
 251
 252 (def-markup-command (halign paper props dir arg) (number? markup?)
 253   "Set horizontal alignment. If @var{dir} is -1, then it is
 254 left-aligned, while+1 is right. Values in between interpolate alignment
 255 accordingly."
 256
 257
 258   (let* ((m (interpret-markup paper props arg)))
 259     (ly:stencil-align-to! m X dir)
 260     m))
 261
 262 (def-markup-command (musicglyph paper props glyph-name) (string?)
 263   "This is converted to a musical symbol, e.g. @code{\\musicglyph
 264 #\"accidentals-0\"} will select the natural sign from the music font.
 265 See @usermanref{The Feta font} for  a complete listing of the possible glyphs.
 266 "
 267   (ly:find-glyph-by-name
 268    (ly:paper-get-font paper (cons '((font-encoding . music))
 269                                   props))
 270    glyph-name))
 271
 272
 273 (def-markup-command (lookup paper props glyph-name) (string?)
 274   "Lookup a glyph by name."
 275   (ly:find-glyph-by-name (ly:paper-get-font paper props)
 276                          glyph-name))
 277
 278 (def-markup-command (char paper props num) (integer?)
 279   "This produces a single character, e.g. @code{\\char #65} produces the
 280 letter 'A'."
 281   (ly:get-glyph (ly:paper-get-font paper props) num))
 282
 283 (def-markup-command (raise paper props amount arg) (number? markup?)
 284   "
 285 This  raises  @var{arg}, by the distance @var{amount}.
 286 A negative @var{amount} indicates lowering:
 287 @c
 288 @lilypond[verbatim,fragment,relative=1]
 289  c1^\\markup { C \\small \\raise #1.0 \\bold { \"9/7+\" }}
 290 @end lilypond
 291 The argument to @code{\\raise} is the vertical displacement amount,
 292 measured in (global) staff spaces.  @code{\\raise} and @code{\\super}
 293 raise objects in relation to their surrounding markups.
 294
 295 If the text object itself is positioned above or below the staff, then
 296 @code{\\raise} cannot be used to move it, since the mechanism that
 297 positions it next to the staff cancels any shift made with
 298 @code{\\raise}. For vertical positioning, use the @code{padding}
 299 and/or @code{extra-offset} properties. "
 300
 301
 302   (ly:stencil-translate-axis (interpret-markup paper props arg)
 303                               amount Y))
 304
 305 (def-markup-command (fraction paper props arg1 arg2) (markup? markup?)
 306   "Make a fraction of two markups."
 307
 308   (let* ((m1 (interpret-markup paper props arg1))
 309          (m2 (interpret-markup paper props arg2)))
 310     (ly:stencil-align-to! m1 X CENTER)
 311     (ly:stencil-align-to! m2 X CENTER)
 312     (let* ((x1 (ly:stencil-extent m1 X))
 313            (x2 (ly:stencil-extent m2 X))
 314            (line (ly:round-filled-box (interval-union x1 x2) '(-0.05 . 0.05) 0.0))
 315            ;; should stack mols separately, to maintain LINE on baseline
 316            (stack (stack-lines -1 0.2 0.6 (list m1 line m2))))
 317       (ly:stencil-align-to! stack Y CENTER)
 318       (ly:stencil-align-to! stack X LEFT)
 319       ;; should have EX dimension
 320       ;; empirical anyway
 321       (ly:stencil-translate-axis stack 0.75 Y))))
 322
 323
 324 ;; TODO: better syntax.
 325
 326 (def-markup-command (note-by-number paper props log dot-count dir) (number? number? number?)
 327   "Construct a note symbol, with stem.  By using fractional values for
 328 @var{dir}, you can obtain longer or shorter stems."
 329
 330   (let* ((font (ly:paper-get-font paper (cons '((font-encoding . music)) props)))
 331          (stemlen (max 3 (- log 1)))
 332          (headgl (ly:find-glyph-by-name
 333                   font
 334                   (string-append "noteheads-" (number->string (min log 2)))))
 335          (stemth 0.13)
 336          (stemy (* dir stemlen))
 337          (attachx (if (> dir 0)
 338                       (- (cdr (ly:stencil-extent headgl X)) stemth)
 339                       0))
 340          (attachy (* dir 0.28))
 341          (stemgl (and (> log 0)
 342                       (ly:round-filled-box
 343                        (cons attachx (+ attachx  stemth))
 344                        (cons (min stemy attachy)
 345                              (max stemy attachy))
 346                        (/ stemth 3))))
 347          (dot (ly:find-glyph-by-name font "dots-dot"))
 348          (dotwid (interval-length (ly:stencil-extent dot X)))
 349          (dots (and (> dot-count 0)
 350                     (apply ly:stencil-add
 351                            (map (lambda (x)
 352                                   (ly:stencil-translate-axis
 353                                    dot  (* (+ 1 (* 2 x)) dotwid) X) )
 354                                 (iota dot-count 1)))))
 355          (flaggl (and (> log 2)
 356                       (ly:stencil-translate
 357                        (ly:find-glyph-by-name font
 358                                               (string-append "flags-"
 359                                                              (if (> dir 0) "u" "d")
 360                                                              (number->string log)))
 361                        (cons (+ attachx (/ stemth 2)) stemy)))))
 362     (if flaggl
 363         (set! stemgl (ly:stencil-add flaggl stemgl)))
 364     (if (ly:stencil? stemgl)
 365         (set! stemgl (ly:stencil-add stemgl headgl))
 366         (set! stemgl headgl))
 367     (if (ly:stencil? dots)
 368         (set! stemgl
 369               (ly:stencil-add
 370                (ly:stencil-translate-axis dots
 371                                            (+ (if (and (> dir 0) (> log 2))
 372                                                   (* 1.5 dotwid)
 373                                                   0)
 374                                               ;; huh ? why not necessary?
 375                                               ;;(cdr (ly:stencil-extent headgl X))
 376                                               dotwid)
 377                                            X)
 378                stemgl)))
 379     stemgl))
 380
 381 (use-modules (ice-9 regex))
 382
 383 (define-public log2
 384   (let ((divisor (log 2)))
 385     (lambda (z) (inexact->exact (/ (log z) divisor)))))
 386
 387 (define (parse-simple-duration duration-string)
 388   "Parse the `duration-string', eg ''4..'' or ''breve.'', and return a (log dots) list."
 389   (let ((match (regexp-exec (make-regexp "(breve|longa|maxima|[0-9]+)(\\.*)") duration-string)))
 390     (if (and match (string=? duration-string (match:substring match 0)))
 391         (let ((len  (match:substring match 1))
 392               (dots (match:substring match 2)))
 393           (list (cond ((string=? len "breve")  -1)
 394                       ((string=? len "longa")  -2)
 395                       ((string=? len "maxima") -3)
 396                       (else (log2 (string->number len))))
 397                 (if dots (string-length dots) 0)))
 398         (error "This is not a valid duration string:" duration-string))))
 399
 400 (def-markup-command (note paper props duration dir) (string? number?)
 401   "This produces a note with a stem pointing in @var{dir} direction, with
 402 the @var{duration} for the note head type and augmentation dots. For
 403 example, @code{\\note #\"4.\" #-0.75} creates a dotted quarter note, with
 404 a shortened down stem."
 405
 406   (let ((parsed (parse-simple-duration duration)))
 407     (note-by-number-markup paper props (car parsed) (cadr parsed) dir)))
 408
 409 (def-markup-command (normal-size-super paper props arg) (markup?)
 410   "A superscript which does not use a smaller font."
 411
 412   (ly:stencil-translate-axis (interpret-markup
 413                                paper
 414                                props arg)
 415                               (* 0.5  (chain-assoc-get 'baseline-skip props))
 416                               Y))
 417
 418 (def-markup-command (super paper props arg) (markup?)
 419   "
 420 @cindex raising text
 421 @cindex lowering text
 422 @cindex moving text
 423 @cindex translating text
 424
 425 @cindex @code{\\super}
 426
 427
 428 Raising and lowering texts can be done with @code{\\super} and
 429 @code{\\sub}:
 430
 431 @lilypond[verbatim,fragment,relative=1]
 432  c1^\\markup { E \"=\" mc \\super \"2\" }
 433 @end lilypond
 434
 435 "
 436
 437   (ly:stencil-translate-axis
 438    (interpret-markup
 439     paper
 440     (cons `((font-size . ,(- (chain-assoc-get 'font-size props 0) 3))) props)
 441     arg)
 442    (* 0.5 (chain-assoc-get 'baseline-skip props))
 443    Y))
 444
 445 (def-markup-command (translate paper props offset arg) (number-pair? markup?)
 446   "This translates an object. Its first argument is a cons of numbers
 447 @example
 448 A \\translate #(cons 2 -3) @{ B C @} D
 449 @end example
 450 This moves `B C' 2 spaces to the right, and 3 down, relative to its
 451 surroundings. This command cannot be used to move isolated scripts
 452 vertically, for the same reason that @code{\\raise} cannot be used for
 453 that.
 454
 455 . "
 456   (ly:stencil-translate (interpret-markup  paper props arg)
 457                          offset))
 458
 459 (def-markup-command (sub paper props arg) (markup?)
 460   "Set @var{arg} in subscript."
 461
 462   (ly:stencil-translate-axis
 463    (interpret-markup
 464     paper
 465     (cons `((font-size . ,(- (chain-assoc-get 'font-size props 0) 3))) props)
 466     arg)
 467    (* -0.5 (chain-assoc-get 'baseline-skip props))
 468    Y))
 469
 470 (def-markup-command (normal-size-sub paper props arg) (markup?)
 471   "Set @var{arg} in subscript, in a normal font size."
 472
 473   (ly:stencil-translate-axis
 474    (interpret-markup paper props arg)
 475    (* -0.5 (chain-assoc-get 'baseline-skip props))
 476    Y))
 477
 478 (def-markup-command (hbracket paper props arg) (markup?)
 479   "Draw horizontal brackets around @var{arg}."
 480   (let ((th 0.1) ;; todo: take from GROB.
 481         (m (interpret-markup paper props arg)))
 482     (bracketify-stencil m X th (* 2.5 th) th)))
 483
 484 (def-markup-command (bracket paper props arg) (markup?)
 485   "Draw vertical brackets around @var{arg}."
 486   (let ((th 0.1) ;; todo: take from GROB.
 487         (m (interpret-markup paper props arg)))
 488     (bracketify-stencil m Y th (* 2.5 th) th)))
 489
 490 ;; todo: fix negative space
 491 (def-markup-command (hspace paper props amount) (number?)
 492   "This produces a invisible object taking horizontal space.
 493 @example
 494 \\markup @{ A \\hspace #2.0 B @}
 495 @end example
 496 will put extra space between A and B, on top of the space that is
 497 normally inserted before elements on a line.
 498 "
 499   (if (> amount 0)
 500       (ly:make-stencil "" (cons 0 amount) '(-1 . 1) )
 501       (ly:make-stencil "" (cons amount amount) '(-1 . 1))))
 502
 503 (def-markup-command (override paper props new-prop arg) (pair? markup?)
 504   "Add the first argument in to the property list.  Properties may be
 505 any sort of property supported by @internalsref{font-interface} and
 506 @internalsref{text-interface}, for example
 507
 508 @verbatim
 509 \\override #'(font-family . married) \"bla\"
 510 @end verbatim
 511
 512 "
 513   (interpret-markup paper (cons (list new-prop) props) arg))
 514
 515 (def-markup-command (smaller paper props arg) (markup?)
 516   "Decrease the font size relative to current setting"
 517   (let* ((fs (chain-assoc-get 'font-size props 0))
 518          (entry (cons 'font-size (- fs 1))))
 519     (interpret-markup paper (cons (list entry) props) arg)))
 520
 521
 522 (def-markup-command (bigger paper props arg) (markup?)
 523   "Increase the font size relative to current setting"
 524   (let* ((fs (chain-assoc-get 'font-size props 0))
 525          (entry (cons 'font-size (+ fs 1))))
 526     (interpret-markup paper (cons (list entry) props) arg)))
 527
 528 (def-markup-command larger (markup?)
 529   bigger-markup)
 530
 531 (def-markup-command (box paper props arg) (markup?)
 532   "Draw a box round @var{arg}"
 533
 534   (let ((th 0.1)
 535         (pad 0.2)
 536         (m (interpret-markup paper props arg)))
 537     (box-stencil m th pad)))
 538
 539 (def-markup-command (strut paper props) ()
 540
 541   "Create a box of the same height as the space in the current font.
 542
 543 FIXME: is this working?
 544 "
 545
 546   (let ((m (Text_item::interpret_markup paper props " ")))
 547     (ly:stencil-set-extent! m X '(1000 . -1000))
 548     m))
 549
 550 (define number->mark-letter-vector (make-vector 25 #\A))
 551
 552 (do ((i 0 (1+ i))
 553      (j 0 (1+ j)))
 554     ((>= i 26))
 555   (if (= i (- (char->integer #\I) (char->integer #\A)))
 556       (set! i (1+ i)))
 557   (vector-set! number->mark-letter-vector j
 558                (integer->char (+ i (char->integer #\A)))))
 559
 560 (define (number->markletter-string n)
 561   "Double letters for big marks."
 562   (let*
 563       ((l (vector-length number->mark-letter-vector)))
 564
 565   (if (>= n l)
 566       (string-append (number->markletter-string (1- (quotient n l)))
 567                      (number->markletter-string (remainder n l)))
 568       (make-string 1 (vector-ref number->mark-letter-vector n)))))
 569
 570
 571 (def-markup-command (markletter paper props num) (integer?)
 572    "Make a markup letter for @var{num}.  The letters start with A to Z
 573  (skipping I), and continues with double letters."
 574
 575    (Text_item::interpret_markup paper props (number->markletter-string num)))
 576
 577
 578
 579
 580 (def-markup-command (bracketed-y-column paper props indices args)
 581   (list? markup-list?)
 582   "Make a column of the markups in @var{args}, putting brackets around
 583 the elements marked in @var{indices}, which is a list of numbers."
 584
 585     (define (sublist l start stop)
 586     (take (drop l start)  (- (1+ stop) start)) )
 587
 588   (define (stencil-list-extent ss axis)
 589     (cons
 590      (apply min (map (lambda (x) (car (ly:stencil-extent x axis))) ss))
 591      (apply max (map (lambda (x) (cdr (ly:stencil-extent x axis))) ss))))
 592
 593   (define (stack-stencils stencils bskip last-stencil)
 594     (cond
 595      ((null? stencils) '())
 596      ((not last-stencil)
 597       (cons (car stencils)
 598             (stack-stencils (cdr stencils) bskip (car stencils))))
 599      (else
 600       (let*
 601           ((orig (car stencils))
 602            (dir (chain-assoc-get 'direction  props DOWN))
 603            (new (ly:stencil-moved-to-edge last-stencil Y dir
 604                                           orig
 605                                           0.1 bskip))
 606            )
 607
 608         (cons new (stack-stencils (cdr stencils) bskip new))))
 609     ))
 610
 611   (define (make-brackets stencils indices acc)
 612     (if (and stencils
 613              (pair? indices)
 614              (pair? (cdr indices)))
 615         (let*
 616             ((encl (sublist stencils (car indices) (cadr indices)))
 617              (x-ext (stencil-list-extent encl X))
 618              (y-ext (stencil-list-extent encl Y))
 619              (thick 0.10)
 620              (pad 0.35)
 621              (protusion (* 2.5 thick))
 622              (lb
 623               (ly:stencil-translate-axis
 624                (ly:bracket Y y-ext thick protusion)
 625                (- (car x-ext) pad) X))
 626              (rb (ly:stencil-translate-axis
 627                   (ly:bracket Y y-ext thick (- protusion))
 628                   (+ (cdr x-ext) pad) X))
 629              )
 630
 631           (make-brackets
 632            stencils (cddr indices)
 633            (append
 634             (list lb rb)
 635              acc)))
 636         acc))
 637
 638   (let*
 639       ((stencils
 640         (map (lambda (x)
 641                (interpret-markup
 642                 paper
 643                 props
 644                 x)) args))
 645        (leading
 646          (chain-assoc-get 'baseline-skip props))
 647        (stacked (stack-stencils stencils 1.25 #f))
 648        (brackets (make-brackets stacked indices '()))
 649        )
 650
 651     (apply ly:stencil-add
 652            (append stacked brackets)
 653            )))
 654
 655
 656
 657
 658
 659
 660
 661