scm/define-markup-commands.scm

   1
   2
   3 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   4 ;;; markup commands
   5 ;; TODO:
   6 ;; each markup function should have a doc string with
   7 ;; syntax, description and example.
   8 ;;
   9
  10
  11 (def-markup-command (simple paper props str) (string?)
  12   "A simple text-string; @code{\\markup @{ foo @}} is equivalent with
  13 @code{\\markup @{ \\simple #\"foo\" @}}.
  14 "
  15   (interpret-markup paper props str))
  16
  17 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  18 ;; fonts
  19
  20 (define (font-markup qualifier value)
  21   (lambda (paper props arg)
  22     (interpret-markup paper
  23                       (prepend-alist-chain qualifier value props)
  24                       arg)))
  25
  26
  27
  28 (define-public empty-markup
  29   (make-simple-markup ""))
  30
  31 (def-markup-command (line paper props args) (markup-list?)
  32   "Put @var{args} in a horizontal line. The property @code{word-space} determines
  33 the space between each markup in @var{args}.
  34 "
  35   (stack-stencil-line
  36    (cdr (chain-assoc 'word-space props))
  37    (map (lambda (m) (interpret-markup paper props m)) args)))
  38
  39 (def-markup-command (combine paper props m1 m2) (markup? markup?)
  40   "Print two markups on top of each other."
  41   (ly:stencil-add
  42    (interpret-markup paper props m1)
  43    (interpret-markup paper props m2)))
  44
  45
  46 (def-markup-command (finger paper props arg) (markup?)
  47   "Set the argument as small numbers."
  48   (interpret-markup paper
  49                     (cons '((font-size . -4) (font-family . number)) props)
  50                     arg))
  51
  52
  53 (def-markup-command (fontsize paper props mag arg) (number? markup?)
  54   "This sets the relative font size, eg.
  55 @example
  56 A \\fontsize #2 @{ B C @} D
  57 @end example
  58
  59
  60 This will enlarge the B and the C by two steps.
  61 "
  62   (interpret-markup
  63    paper
  64    (prepend-alist-chain 'font-size mag props)
  65    arg))
  66
  67 (def-markup-command (magnify paper props sz arg) (number? markup?)
  68   "This sets the font magnification for the its argument. In the following
  69 example, the middle A will be 10% larger:
  70 @example
  71 A \\magnify #1.1 @{ A @} A
  72 @end example
  73
  74 Note: magnification only works if a font-name is explicitly selected.
  75 Use @code{\\fontsize} otherwise."
  76
  77   (interpret-markup
  78    paper
  79    (prepend-alist-chain 'font-magnification sz props)
  80    arg))
  81
  82 (def-markup-command (bold paper props arg) (markup?)
  83   "Switch to bold font-series"
  84   (interpret-markup paper (prepend-alist-chain 'font-series 'bold props) arg))
  85
  86 (def-markup-command (sans paper props arg) (markup?)
  87   "Switch to the sans-serif family"
  88   (interpret-markup paper (prepend-alist-chain 'font-family 'sans props) arg))
  89
  90 (def-markup-command (number paper props arg) (markup?)
  91   "Set font family to @code{number}, which yields the font used for
  92 time signatures and fingerings.  This font only contains numbers and
  93 some punctuation. It doesn't have any letters.  "
  94   (interpret-markup paper (prepend-alist-chain 'font-family 'number props) arg))
  95
  96 (def-markup-command (roman paper props arg) (markup?)
  97   "Set font family to @code{roman}."
  98   (interpret-markup paper (prepend-alist-chain 'font-family 'roman props) arg))
  99
 100 (def-markup-command (huge paper props arg) (markup?)
 101   "Set font size to +2."
 102   (interpret-markup paper (prepend-alist-chain 'font-size 2 props) arg))
 103
 104 (def-markup-command (large paper props arg) (markup?)
 105   "Set font size to +1."
 106   (interpret-markup paper (prepend-alist-chain 'font-size 1 props) arg))
 107
 108 (def-markup-command (normalsize paper props arg) (markup?)
 109   "Set font size to default."
 110   (interpret-markup paper (prepend-alist-chain 'font-size 0 props) arg))
 111
 112 (def-markup-command (small paper props arg) (markup?)
 113   "Set font size to -1."
 114   (interpret-markup paper (prepend-alist-chain 'font-size -1 props) arg))
 115
 116 (def-markup-command (tiny paper props arg) (markup?)
 117   "Set font size to -2."
 118   (interpret-markup paper (prepend-alist-chain 'font-size -2 props) arg))
 119
 120 (def-markup-command (teeny paper props arg) (markup?)
 121   "Set font size to -3."
 122   (interpret-markup paper (prepend-alist-chain 'font-size -3 props) arg))
 123
 124 (def-markup-command (caps paper props arg) (markup?)
 125   (interpret-markup paper (prepend-alist-chain 'font-shape 'caps props) arg))
 126
 127 (def-markup-command (dynamic paper props arg) (markup?)
 128   "Use the dynamic font.  This font only contains s, f, m, z, p, and
 129 r.  When producing phrases, like ``piu f'', the normal words (like
 130 ``piu'') should be done in a different font.  The recommend font for
 131 this is bold and italic
 132 "
 133   (interpret-markup
 134    paper (prepend-alist-chain 'font-family 'dynamic props) arg))
 135
 136 (def-markup-command (italic paper props arg) (markup?)
 137   (interpret-markup paper (prepend-alist-chain 'font-shape 'italic props) arg))
 138
 139 (def-markup-command (typewriter paper props arg) (markup?)
 140   (interpret-markup
 141    paper (prepend-alist-chain 'font-family 'typewriter props) arg))
 142
 143 (def-markup-command (doublesharp paper props) ()
 144   (interpret-markup paper props (markup #:musicglyph "accidentals-4")))
 145 (def-markup-command (threeqsharp paper props) ()
 146   (interpret-markup paper props (markup #:musicglyph "accidentals-3")))
 147 (def-markup-command (sharp paper props) ()
 148   (interpret-markup paper props (markup #:musicglyph "accidentals-2")))
 149 (def-markup-command (semisharp paper props) ()
 150   (interpret-markup paper props (markup #:musicglyph "accidentals-1")))
 151 (def-markup-command (natural paper props) ()
 152   (interpret-markup paper props (markup #:musicglyph "accidentals-0")))
 153 (def-markup-command (semiflat paper props) ()
 154   (interpret-markup paper props (markup #:musicglyph "accidentals--1")))
 155 (def-markup-command (flat paper props) ()
 156   (interpret-markup paper props (markup #:musicglyph "accidentals--2")))
 157 (def-markup-command (threeqflat paper props) ()
 158   (interpret-markup paper props (markup #:musicglyph "accidentals--3")))
 159 (def-markup-command (doubleflat paper props) ()
 160   (interpret-markup paper props (markup #:musicglyph "accidentals--4")))
 161
 162
 163 (def-markup-command (column paper props args) (markup-list?)
 164   (stack-lines
 165    -1 0.0 (cdr (chain-assoc 'baseline-skip props))
 166    (map (lambda (m) (interpret-markup paper props m)) args)))
 167
 168 (def-markup-command (dir-column paper props args) (markup-list?)
 169   "Make a column of args, going up or down, depending on the setting
 170 of the #'direction layout property."
 171   (let* ((dir (cdr (chain-assoc 'direction props))))
 172     (stack-lines
 173      (if (number? dir) dir -1)
 174      0.0
 175      (cdr (chain-assoc 'baseline-skip props))
 176      (map (lambda (x) (interpret-markup paper props x)) args))))
 177
 178 (def-markup-command (center paper props args) (markup-list?)
 179   (let* ((mols (map (lambda (x) (interpret-markup paper props x)) args))
 180          (cmols (map (lambda (x) (ly:stencil-align-to! x X CENTER)) mols)))
 181     (stack-lines -1 0.0 (cdr (chain-assoc 'baseline-skip props)) mols)))
 182
 183 (def-markup-command (right-align paper props arg) (markup?)
 184   (let* ((m (interpret-markup paper props arg)))
 185     (ly:stencil-align-to! m X RIGHT)
 186     m))
 187
 188 (def-markup-command (left-align paper props arg) (markup?)
 189   (let* ((m (interpret-markup paper props arg)))
 190     (ly:stencil-align-to! m X LEFT)
 191     m))
 192
 193 (def-markup-command (halign paper props dir arg) (number? markup?)
 194   "Set horizontal alignment. @var{dir} = -1 is left, @var{dir} = 1 is
 195 right, values in between vary alignment accordingly."
 196
 197
 198   (let* ((m (interpret-markup paper props arg)))
 199     (ly:stencil-align-to! m X dir)
 200     m))
 201
 202 (def-markup-command (musicglyph paper props glyph-name) (string?)
 203   "This is converted to a musical symbol, e.g. @code{\\musicglyph
 204 #\"accidentals-0\"} will select the natural sign from the music font.
 205 See @usermanref{The Feta font} for  a complete listing of the possible glyphs.
 206 "
 207   (ly:find-glyph-by-name
 208    (ly:paper-get-font paper (cons '((font-name . ())
 209                                     (font-shape . *)
 210                                     (font-series . *)
 211                                     (font-family . music))
 212                                   props))
 213    glyph-name))
 214
 215
 216 (def-markup-command (lookup paper props glyph-name) (string?)
 217   "Lookup a glyph by name."
 218   (ly:find-glyph-by-name (ly:paper-get-font paper props)
 219                          glyph-name))
 220
 221 (def-markup-command (char paper props num) (integer?)
 222   "This produces a single character, e.g. @code{\\char #65} produces the
 223 letter 'A'."
 224   (ly:get-glyph (ly:paper-get-font paper props) num))
 225
 226 (def-markup-command (raise paper props amount arg) (number? markup?)
 227   "
 228 This  raises  @var{arg}, by the distance @var{amount}.
 229 A negative @var{amount} indicates lowering:
 230 @c
 231 @lilypond[verbatim,fragment,relative=1,quote]
 232  c1^\\markup { C \\small \\raise #1.0 \\bold { \"9/7+\" }}
 233 @end lilypond
 234 The argument to @code{\\raise} is the vertical displacement amount,
 235 measured in (global) staff spaces.  @code{\\raise} and @code{\\super}
 236 raise objects in relation to their surrounding markups.
 237
 238 If the text object itself is positioned above or below the staff, then
 239 @code{\\raise} cannot be used to move it, since the mechanism that
 240 positions it next to the staff cancels any shift made with
 241 @code{\\raise}. For vertical positioning, use the @code{padding}
 242 and/or @code{extra-offset} properties. "
 243
 244
 245   (ly:stencil-translate-axis (interpret-markup paper props arg)
 246                               amount Y))
 247
 248 (def-markup-command (fraction paper props arg1 arg2) (markup? markup?)
 249   "Make a fraction of two markups.
 250
 251 Syntax: \\fraction MARKUP1 MARKUP2."
 252   (let* ((m1 (interpret-markup paper props arg1))
 253          (m2 (interpret-markup paper props arg2)))
 254     (ly:stencil-align-to! m1 X CENTER)
 255     (ly:stencil-align-to! m2 X CENTER)
 256     (let* ((x1 (ly:stencil-get-extent m1 X))
 257            (x2 (ly:stencil-get-extent m2 X))
 258            (line (ly:round-filled-box (interval-union x1 x2) '(-0.05 . 0.05) 0.0))
 259            ;; should stack mols separately, to maintain LINE on baseline
 260            (stack (stack-lines -1 0.2 0.6 (list m1 line m2))))
 261       (ly:stencil-align-to! stack Y CENTER)
 262       (ly:stencil-align-to! stack X LEFT)
 263       ;; should have EX dimension
 264       ;; empirical anyway
 265       (ly:stencil-translate-axis stack 0.75 Y))))
 266
 267
 268 ;; TODO: better syntax.
 269
 270 (def-markup-command (note-by-number paper props log dot-count dir) (number? number? number?)
 271   "Syntax: \\note-by-number #LOG #DOTS #DIR.  By using fractional values
 272 for DIR, you can obtain longer or shorter stems."
 273   (let* ((font (ly:paper-get-font paper (cons '((font-family .  music)) props)))
 274          (stemlen (max 3 (- log 1)))
 275          (headgl (ly:find-glyph-by-name
 276                   font
 277                   (string-append "noteheads-" (number->string (min log 2)))))
 278          (stemth 0.13)
 279          (stemy (* dir stemlen))
 280          (attachx (if (> dir 0)
 281                       (- (cdr (ly:stencil-get-extent headgl X)) stemth)
 282                       0))
 283          (attachy (* dir 0.28))
 284          (stemgl (and (> log 0)
 285                       (ly:round-filled-box
 286                        (cons attachx (+ attachx  stemth))
 287                        (cons (min stemy attachy)
 288                              (max stemy attachy))
 289                        (/ stemth 3))))
 290          (dot (ly:find-glyph-by-name font "dots-dot"))
 291          (dotwid (interval-length (ly:stencil-get-extent dot X)))
 292          (dots (and (> dot-count 0)
 293                     (apply ly:stencil-add
 294                            (map (lambda (x)
 295                                   (ly:stencil-translate-axis
 296                                    dot  (* (+ 1 (* 2 x)) dotwid) X) )
 297                                 (iota dot-count 1)))))
 298          (flaggl (and (> log 2)
 299                       (ly:stencil-translate
 300                        (ly:find-glyph-by-name font
 301                                               (string-append "flags-"
 302                                                              (if (> dir 0) "u" "d")
 303                                                              (number->string log)))
 304                        (cons (+ attachx (/ stemth 2)) stemy)))))
 305     (if flaggl
 306         (set! stemgl (ly:stencil-add flaggl stemgl)))
 307     (if (ly:stencil? stemgl)
 308         (set! stemgl (ly:stencil-add stemgl headgl))
 309         (set! stemgl headgl))
 310     (if (ly:stencil? dots)
 311         (set! stemgl
 312               (ly:stencil-add
 313                (ly:stencil-translate-axis dots
 314                                            (+ (if (and (> dir 0) (> log 2))
 315                                                   (* 1.5 dotwid)
 316                                                   0)
 317                                               ;; huh ? why not necessary?
 318                                               ;;(cdr (ly:stencil-get-extent headgl X))
 319                                               dotwid)
 320                                            X)
 321                stemgl)))
 322     stemgl))
 323
 324 (use-modules (ice-9 regex))
 325
 326 (define-public log2
 327   (let ((divisor (log 2)))
 328     (lambda (z) (inexact->exact (/ (log z) divisor)))))
 329
 330 (define (parse-simple-duration duration-string)
 331   "Parse the `duration-string', eg ''4..'' or ''breve.'', and return a (log dots) list."
 332   (let ((match (regexp-exec (make-regexp "(breve|longa|maxima|[0-9]+)(\\.*)") duration-string)))
 333     (if (and match (string=? duration-string (match:substring match 0)))
 334         (let ((len  (match:substring match 1))
 335               (dots (match:substring match 2)))
 336           (list (cond ((string=? len "breve")  -1)
 337                       ((string=? len "longa")  -2)
 338                       ((string=? len "maxima") -3)
 339                       (else (log2 (string->number len))))
 340                 (if dots (string-length dots) 0)))
 341         (error "This is not a valid duration string:" duration-string))))
 342
 343 (def-markup-command (note paper props duration dir) (string? number?)
 344   "This produces a note with a stem pointing in @var{dir} direction, with
 345 the @var{duration} for the note head type and augmentation dots. For
 346 example, @code{\\note #\"4.\" #-0.75} creates a dotted quarter note, with
 347 a shortened down stem."
 348
 349   (let ((parsed (parse-simple-duration duration)))
 350     (note-by-number-markup paper props (car parsed) (cadr parsed) dir)))
 351
 352 (def-markup-command (normal-size-super paper props arg) (markup?)
 353   "A superscript which does not use a smaller font."
 354   (ly:stencil-translate-axis (interpret-markup
 355                                paper
 356                                props arg)
 357                               (* 0.5 (cdr (chain-assoc 'baseline-skip props)))
 358                               Y))
 359
 360 (def-markup-command (super paper props arg) (markup?)
 361   "
 362 @cindex raising text
 363 @cindex lowering text
 364 @cindex moving text
 365 @cindex translating text
 366
 367 @cindex @code{\\super}
 368
 369
 370 Raising and lowering texts can be done with @code{\\super} and
 371 @code{\\sub}:
 372
 373 @lilypond[verbatim,fragment,relative=1]
 374  c1^\\markup { E \"=\" mc \\super \"2\" }
 375 @end lilypond
 376
 377 "
 378
 379   (ly:stencil-translate-axis
 380    (interpret-markup
 381     paper
 382     (cons `((font-size . ,(- (chain-assoc-get 'font-size props 0) 3))) props)
 383     arg)
 384    (* 0.5 (cdr (chain-assoc 'baseline-skip props)))
 385    Y))
 386
 387 (def-markup-command (translate paper props offset arg) (number-pair? markup?)
 388   "This translates an object. Its first argument is a cons of numbers
 389 @example
 390 A \\translate #(cons 2 -3) @{ B C @} D
 391 @end example
 392 This moves `B C' 2 spaces to the right, and 3 down, relative to its
 393 surroundings. This command cannot be used to move isolated scripts
 394 vertically, for the same reason that @code{\\raise} cannot be used for
 395 that.
 396
 397 . "
 398   (ly:stencil-translate (interpret-markup  paper props arg)
 399                          offset))
 400
 401 (def-markup-command (sub paper props arg) (markup?)
 402   "Syntax: \\sub MARKUP."
 403   (ly:stencil-translate-axis
 404    (interpret-markup
 405     paper
 406     (cons `((font-size . ,(- (chain-assoc-get 'font-size props 0) 3))) props)
 407     arg)
 408    (* -0.5 (cdr (chain-assoc 'baseline-skip props)))
 409    Y))
 410
 411 (def-markup-command (normal-size-sub paper props arg) (markup?)
 412   (ly:stencil-translate-axis
 413    (interpret-markup paper props arg)
 414    (* -0.5 (cdr (chain-assoc 'baseline-skip props)))
 415    Y))
 416
 417 (def-markup-command (hbracket paper props arg) (markup?)
 418   "Horizontal brackets around @var{arg}."
 419   (let ((th 0.1) ;; todo: take from GROB.
 420         (m (interpret-markup paper props arg)))
 421     (bracketify-stencil m X th (* 2.5 th) th)))
 422
 423 (def-markup-command (bracket paper props arg) (markup?)
 424   "Vertical brackets around @var{arg}."
 425   (let ((th 0.1) ;; todo: take from GROB.
 426         (m (interpret-markup paper props arg)))
 427     (bracketify-stencil m Y th (* 2.5 th) th)))
 428
 429 ;; todo: fix negative space
 430 (def-markup-command (hspace paper props amount) (number?)
 431   "This produces a invisible object taking horizontal space.
 432 @example
 433 \\markup @{ A \\hspace #2.0 B @}
 434 @end example
 435 will put extra space between A and B, on top of the space that is
 436 normally inserted before elements on a line.
 437 "
 438   (if (> amount 0)
 439       (ly:make-stencil "" (cons 0 amount) '(-1 . 1) )
 440       (ly:make-stencil "" (cons amount amount) '(-1 . 1))))
 441
 442 (def-markup-command (override paper props new-prop arg) (pair? markup?)
 443   "Add the first argument in to the property list.  Properties may be
 444 any sort of property supported by @internalsref{font-interface} and
 445 @internalsref{text-interface}, for example
 446
 447 @verbatim
 448 \\override #'(font-family . married) \"bla\"
 449 @end verbatim
 450
 451 "
 452   (interpret-markup paper (cons (list new-prop) props) arg))
 453
 454 (def-markup-command (smaller paper props arg) (markup?)
 455   "Decrease the font size relative to current setting"
 456   (let* ((fs (chain-assoc-get 'font-size props 0))
 457          (entry (cons 'font-size (- fs 1))))
 458     (interpret-markup paper (cons (list entry) props) arg)))
 459
 460
 461 (def-markup-command (bigger paper props arg) (markup?)
 462   "Increase the font size relative to current setting"
 463   (let* ((fs (chain-assoc-get 'font-size props 0))
 464          (entry (cons 'font-size (+ fs 1))))
 465     (interpret-markup paper (cons (list entry) props) arg)))
 466
 467 (def-markup-command larger (markup?)
 468   bigger-markup)
 469
 470 (def-markup-command (box paper props arg) (markup?)
 471   "Draw a box round @var{arg}"
 472
 473   (let ((th 0.1)
 474         (pad 0.2)
 475         (m (interpret-markup paper props arg)))
 476     (box-stencil m th pad)))
 477
 478 (def-markup-command (strut paper props) ()
 479
 480   "Create a box of the same height as the space in the current font.
 481
 482 FIXME: is this working?
 483 "
 484
 485   (let ((m (Text_item::interpret_markup paper props " ")))
 486     (ly:stencil-set-extent! m X '(1000 . -1000))
 487     m))
 488
 489 (define number->mark-letter-vector (make-vector 25 #\A))
 490
 491 (do ((i 0 (1+ i))
 492      (j 0 (1+ j)))
 493     ((>= i 26))
 494   (if (= i (- (char->integer #\I) (char->integer #\A)))
 495       (set! i (1+ i)))
 496   (vector-set! number->mark-letter-vector j
 497                (integer->char (+ i (char->integer #\A)))))
 498
 499 (define (number->markletter-string n)
 500   "Double letters for big marks."
 501   (let*
 502       ((l (vector-length number->mark-letter-vector)))
 503
 504   (if (>= n l)
 505       (string-append (number->markletter-string (1- (quotient n l)))
 506                      (number->markletter-string (remainder n l)))
 507       (make-string 1 (vector-ref number->mark-letter-vector n)))))
 508
 509
 510 (def-markup-command (markletter paper props num) (integer?)
 511    "Make a markup letter for @var{num}.  The letters start with A to Z
 512  (skipping I), and continues with double letters."
 513
 514    (Text_item::interpret_markup paper props (number->markletter-string num)))