scm/chord-ignatzek-names.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 2000--2011  Han-Wen Nienhuys <hanwen@xs4all.nl>
   4 ;;;;
   5 ;;;; LilyPond is free software: you can redistribute it and/or modify
   6 ;;;; it under the terms of the GNU General Public License as published by
   7 ;;;; the Free Software Foundation, either version 3 of the License, or
   8 ;;;; (at your option) any later version.
   9 ;;;;
  10 ;;;; LilyPond is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;;;; GNU General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU General Public License
  16 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19
  20 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  22 ;;
  23 ;; jazz-part 2
  24 ;;
  25 ;; after Klaus Ignatzek,   Die Jazzmethode fuer Klavier 1.
  26 ;;
  27 ;; The idea is: split chords into
  28 ;;
  29 ;;  ROOT PREFIXES MAIN-NAME ALTERATIONS SUFFIXES ADDITIONS
  30 ;;
  31 ;; and put that through a layout routine.
  32 ;;
  33 ;; the split is a procedural process, with lots of set!.
  34 ;;
  35
  36
  37 ;; todo: naming is confusing: steps  (0 based) vs. steps (1 based).
  38 (define (pitch-step p)
  39   "Musicological notation for an interval. Eg. C to D is 2."
  40   (+ 1 (ly:pitch-steps p)))
  41
  42 (define (get-step x ps)
  43   "Does PS have the X step? Return that step if it does."
  44   (if (null? ps)
  45       #f
  46       (if (= (- x 1) (ly:pitch-steps (car ps)))
  47           (car ps)
  48           (get-step x (cdr ps)))))
  49
  50 (define (replace-step p ps)
  51   "Copy PS, but replace the step of P in PS."
  52   (if (null? ps)
  53       '()
  54       (let* ((t (replace-step p (cdr ps))))
  55         (if (= (ly:pitch-steps p) (ly:pitch-steps (car ps)))
  56             (cons p t)
  57             (cons (car ps) t)))))
  58
  59 (define (remove-step x ps)
  60   "Copy PS, but leave out the Xth step."
  61   (if (null? ps)
  62       '()
  63       (let* ((t (remove-step x (cdr ps))))
  64         (if (= (- x 1) (ly:pitch-steps (car ps)))
  65             t
  66             (cons (car ps) t)))))
  67
  68
  69 (define-public (ignatzek-chord-names
  70                 in-pitches bass inversion
  71                 context)
  72
  73   (define (remove-uptil-step x ps)
  74     "Copy PS, but leave out everything below the Xth step."
  75     (if (null? ps)
  76         '()
  77         (if (< (ly:pitch-steps (car ps)) (- x 1))
  78             (remove-uptil-step x (cdr ps))
  79             ps)))
  80
  81   (define name-root (ly:context-property context 'chordRootNamer))
  82   (define name-note
  83     (let ((nn (ly:context-property context 'chordNoteNamer)))
  84       (if (eq? nn '())
  85           ;; replacing the next line with name-root gives guile-error...? -rz
  86
  87           ;; apparently sequence of defines is equivalent to let, not let* ? -hwn
  88           (ly:context-property context 'chordRootNamer)
  89           ;; name-root
  90           nn)))
  91
  92   (define (is-natural-alteration? p)
  93     (= (natural-chord-alteration p) (ly:pitch-alteration p)))
  94
  95   (define (ignatzek-format-chord-name
  96            root
  97            prefix-modifiers
  98            main-name
  99            alteration-pitches
 100            addition-pitches
 101            suffix-modifiers
 102            bass-pitch
 103            lowercase-root?)
 104
 105     "Format for the given (lists of) pitches. This is actually more
 106 work than classifying the pitches."
 107
 108     (define (filter-main-name p)
 109       "The main name: don't print anything for natural 5 or 3."
 110       (if
 111        (or (not (ly:pitch? p))
 112            (and (is-natural-alteration? p)
 113                 (or (= (pitch-step p) 5)
 114                     (= (pitch-step p) 3))))
 115        '()
 116        (list (name-step p))))
 117
 118     (define (glue-word-to-step word x)
 119       (make-line-markup
 120        (list
 121         (make-simple-markup word)
 122         (name-step x))))
 123
 124     (define (suffix-modifier->markup mod)
 125       (if (or (= 4 (pitch-step mod))
 126               (= 2 (pitch-step mod)))
 127           (glue-word-to-step "sus" mod)
 128           (glue-word-to-step "huh" mod)))
 129
 130     (define (prefix-modifier->markup mod)
 131       (if (and (= 3 (pitch-step mod))
 132                (= FLAT (ly:pitch-alteration mod)))
 133           (make-simple-markup (if lowercase-root? "" "m"))
 134           (make-simple-markup "huh")))
 135
 136     (define (filter-alterations alters)
 137       "Filter out uninteresting (natural) pitches from ALTERS."
 138
 139       (define (altered? p)
 140         (not (is-natural-alteration? p)))
 141
 142       (if
 143        (null? alters)
 144        '()
 145        (let* ((lst (filter altered? alters))
 146               (lp (last-pair alters)))
 147
 148          ;; we want the highest also if unaltered
 149          (if (and (not (altered? (car lp)))
 150                   (> (pitch-step (car lp)) 5))
 151              (append lst (last-pair alters))
 152              lst))))
 153
 154     (define (name-step pitch)
 155       (define (step-alteration pitch)
 156         (- (ly:pitch-alteration pitch)
 157            (natural-chord-alteration pitch)))
 158
 159       (let* ((num-markup (make-simple-markup
 160                           (number->string (pitch-step pitch))))
 161              (args (list num-markup))
 162              (total (if (= (ly:pitch-alteration pitch) 0)
 163                         (if (= (pitch-step pitch) 7)
 164                             (list (ly:context-property context 'majorSevenSymbol))
 165                             args)
 166                         (cons (accidental->markup (step-alteration pitch)) args))))
 167
 168         (make-line-markup total)))
 169
 170     (let* ((sep (ly:context-property context 'chordNameSeparator))
 171            (root-markup (name-root root lowercase-root?))
 172            (add-markups (map (lambda (x) (glue-word-to-step "add" x))
 173                              addition-pitches))
 174            (filtered-alterations (filter-alterations alteration-pitches))
 175            (alterations (map name-step filtered-alterations))
 176            (suffixes (map suffix-modifier->markup suffix-modifiers))
 177            (prefixes (map prefix-modifier->markup prefix-modifiers))
 178            (main-markups (filter-main-name main-name))
 179            (to-be-raised-stuff (markup-join
 180                                 (append
 181                                  main-markups
 182                                  alterations
 183                                  suffixes
 184                                  add-markups) sep))
 185            (base-stuff (if (ly:pitch? bass-pitch)
 186                            (list sep (name-note bass-pitch #f))
 187                            '())))
 188
 189       (set! base-stuff
 190             (append
 191              (list root-markup
 192                    (conditional-kern-before (markup-join prefixes sep)
 193                                             (and (not (null? prefixes))
 194                                                  (= (ly:pitch-alteration root) NATURAL))
 195                                             (ly:context-property context 'chordPrefixSpacer))
 196                    (make-super-markup to-be-raised-stuff))
 197              base-stuff))
 198       (make-line-markup base-stuff)))
 199
 200   (define (ignatzek-format-exception
 201            root
 202            exception-markup
 203            bass-pitch
 204            lowercase-root?)
 205
 206     (make-line-markup
 207      `(
 208        ,(name-root root lowercase-root?)
 209        ,exception-markup
 210        .
 211        ,(if (ly:pitch? bass-pitch)
 212             (list (ly:context-property context 'chordNameSeparator)
 213                   (name-note bass-pitch #f))
 214             '()))))
 215
 216   (let* ((root (car in-pitches))
 217          (pitches (map (lambda (x) (ly:pitch-diff x root)) (cdr in-pitches)))
 218          (lowercase-root?
 219           (and (ly:context-property context 'chordNameLowercaseMinor)
 220        (let ((third (get-step 3 pitches)))
 221             (and third (= (ly:pitch-alteration third) FLAT)))))
 222          (exceptions (ly:context-property context 'chordNameExceptions))
 223          (exception (assoc-get pitches exceptions))
 224          (prefixes '())
 225          (suffixes '())
 226          (add-steps '())
 227          (main-name #f)
 228          (bass-note
 229           (if (ly:pitch? inversion)
 230               inversion
 231               bass))
 232          (alterations '()))
 233
 234     (if exception
 235         (ignatzek-format-exception root exception bass-note lowercase-root?)
 236
 237         (begin
 238           ;; no exception.
 239           ;; handle sus4 and sus2 suffix: if there is a 3 together with
 240           ;; sus2 or sus4, then we explicitly say add3.
 241           (map
 242            (lambda (j)
 243              (if (get-step j pitches)
 244                  (begin
 245                    (if (get-step 3 pitches)
 246                        (begin
 247                          (set! add-steps (cons (get-step 3 pitches) add-steps))
 248                          (set! pitches (remove-step 3 pitches))))
 249                    (set! suffixes (cons (get-step j pitches) suffixes)))))
 250            '(2 4))
 251
 252           ;; do minor-3rd modifier.
 253           (if (and (get-step 3 pitches)
 254                    (= (ly:pitch-alteration (get-step 3 pitches)) FLAT))
 255               (set! prefixes (cons (get-step 3 pitches) prefixes)))
 256
 257           ;; lazy bum. Should write loop.
 258           (cond
 259            ((get-step 7 pitches) (set! main-name (get-step 7 pitches)))
 260            ((get-step 6 pitches) (set! main-name (get-step 6 pitches)))
 261            ((get-step 5 pitches) (set! main-name (get-step 5 pitches)))
 262            ((get-step 4 pitches) (set! main-name (get-step 4 pitches)))
 263            ((get-step 3 pitches) (set! main-name (get-step 3 pitches))))
 264
 265           (let* ((3-diff? (lambda (x y)
 266                             (= (- (pitch-step y) (pitch-step x)) 2)))
 267                  (split (split-at-predicate
 268                          3-diff? (remove-uptil-step 5 pitches))))
 269             (set! alterations (append alterations (car split)))
 270             (set! add-steps (append add-steps (cdr split)))
 271             (set! alterations (delq main-name alterations))
 272             (set! add-steps (delq main-name add-steps))
 273
 274
 275             ;; chords with natural (5 7 9 11 13) or leading subsequence.
 276             ;; etc. are named by the top pitch, without any further
 277             ;; alterations.
 278             (if (and
 279                  (ly:pitch? main-name)
 280                  (= 7 (pitch-step main-name))
 281                  (is-natural-alteration? main-name)
 282                  (pair? (remove-uptil-step 7 alterations))
 283                  (reduce (lambda (x y) (and x y)) #t
 284                          (map is-natural-alteration? alterations)))
 285                 (begin
 286                   (set! main-name (last alterations))
 287                   (set! alterations '())))
 288
 289             (ignatzek-format-chord-name
 290              root prefixes main-name alterations add-steps suffixes bass-note
 291              lowercase-root?))))))