scm/chord-entry.scm

   1 ;;;
   2 ;;; Generate chord names for the parser.
   3 ;;;
   4 ;;;
   5
   6 (define-public (construct-chord root duration modifications)
   7
   8   " Build a chord on root using modifiers in MODIFICATIONS. NoteEvent
   9 have duration DURATION..
  10
  11 Notes: natural 11 is left from chord if not explicitly specified.
  12
  13 Entry point for the parser.
  14
  15 "
  16   (let*
  17       ((flat-mods (flatten-list modifications))
  18        (base-chord (stack-thirds (ly:make-pitch 0 4 0) the-canonical-chord))
  19        (complete-chord '())
  20        (bass #f)
  21        (inversion #f)
  22        (lead-mod #f)
  23        (explicit-11 #f)
  24        (start-additions #t))
  25
  26     (define (interpret-inversion chord mods)
  27       "Read /FOO   part. Side effect: INVERSION is set."
  28
  29       (if (and (>  (length mods) 1) (eq? (car mods) 'chord-slash))
  30           (begin
  31             (set! inversion (cadr mods))
  32             (set! mods (cddr mods))))
  33
  34       (interpret-bass chord mods))
  35
  36     (define (interpret-bass chord mods)
  37       "Read /+FOO   part. Side effect: BASS is set."
  38
  39       (if (and (>  (length mods) 1) (eq? (car mods) 'chord-bass))
  40           (begin
  41             (set! bass (cadr mods))
  42             (set! mods (cddr mods))))
  43
  44       (if (pair? mods)
  45           (scm-error  'chord-format "construct-chord" "Spurious garbage following chord: ~A" mods #f)
  46           )
  47
  48       chord
  49       )
  50
  51     (define (interpret-removals  chord mods)
  52       (define (inner-interpret chord mods)
  53         (if (and (pair? mods) (ly:pitch? (car mods)))
  54             (inner-interpret
  55              (remove-step (+ 1  (ly:pitch-steps (car mods))) chord)
  56              (cdr mods))
  57             (interpret-inversion chord mods))
  58             )
  59
  60       (if (and (pair? mods) (eq? (car mods) 'chord-caret))
  61           (inner-interpret chord (cdr mods))
  62           (interpret-inversion chord mods))
  63
  64       )
  65
  66     (define (interpret-additions  chord mods)
  67       "Interpret additions. TODO: should restrict modifier use?"
  68
  69       (cond
  70        ((null? mods) chord)
  71        ((ly:pitch? (car mods))
  72         (if (= (pitch-step (car mods)) 11)
  73             (set! explicit-11 #t))
  74         (interpret-additions
  75          (cons (car mods) (remove-step (pitch-step (car mods)) chord))
  76          (cdr mods)))
  77        ((procedure? (car mods))
  78         (interpret-additions
  79          ((car mods)  chord)
  80          (cdr mods)))
  81        (else (interpret-removals  chord mods))
  82       ))
  83
  84     (define (pitch-octavated-strictly-below p root)
  85       "return P, but octavated, so it is below  ROOT"
  86       (ly:make-pitch
  87        (+
  88         (ly:pitch-octave root)
  89         (if (> (ly:pitch-notename root)
  90                 (ly:pitch-notename p))
  91             0 -1))
  92        (ly:pitch-notename p)
  93        (ly:pitch-alteration p)))
  94
  95     (define (process-inversion complete-chord)
  96       "Take out inversion from COMPLETE-CHORD, and put it at the bottom.
  97 Return (INVERSION . REST-OF-CHORD).
  98
  99 Side effect: put original pitch in INVERSION.
 100 If INVERSION is not in COMPLETE-CHORD, it will be set as a BASS, overriding
 101 the bass specified.
 102
 103 "
 104       (let*
 105           (
 106            (root (car complete-chord))
 107            (inv? (lambda (y)
 108                    (and (= (ly:pitch-notename y)
 109                            (ly:pitch-notename inversion))
 110                         (= (ly:pitch-alteration y)
 111                            (ly:pitch-alteration inversion))
 112                         )))
 113
 114            (rest-of-chord (remove inv? complete-chord))
 115            (inversion-candidates (filter inv? complete-chord))
 116            (down-inversion (pitch-octavated-strictly-below inversion root))
 117            )
 118
 119         (if (pair? inversion-candidates)
 120             (set! inversion (car inversion-candidates))
 121             (begin
 122               (set! bass inversion)
 123               (set! inversion #f))
 124             )
 125         (if inversion
 126             (cons down-inversion rest-of-chord)
 127             rest-of-chord
 128             )
 129       ))
 130
 131     ;; root is always one octave too low.
 132
 133     ; something weird happens when this is removed,
 134     ; every other chord is octavated. --hwn... hmmm.
 135     (set! root (ly:pitch-transpose root (ly:make-pitch 1 0 0)))
 136
 137     ;; skip the leading : , we need some of the stuff following it.
 138     (if (pair? flat-mods)
 139         (if (eq? (car flat-mods)  'chord-colon)
 140             (set! flat-mods (cdr flat-mods))
 141             (set! start-additions #f)
 142         ))
 143
 144     ;; remember modifier
 145     (if (and (pair? flat-mods) (procedure? (car flat-mods)))
 146         (begin
 147           (set! lead-mod (car flat-mods))
 148           (set! flat-mods (cdr flat-mods))
 149           ))
 150
 151
 152
 153     ;; extract first  number if present, and build pitch list.
 154     (if (and (pair? flat-mods)
 155              (ly:pitch?  (car flat-mods))
 156              (not (eq? lead-mod sus-modifier))
 157              )
 158
 159         (begin
 160           (if (=  (pitch-step (car flat-mods)) 11)
 161               (set! explicit-11 #t))
 162           (set! base-chord
 163                 (stack-thirds (car flat-mods) the-canonical-chord))
 164           (set! flat-mods (cdr flat-mods))
 165         ))
 166
 167     ;; apply modifier
 168     (if (procedure? lead-mod)
 169         (set! base-chord (lead-mod base-chord)))
 170
 171
 172     (set! complete-chord
 173           (if start-additions
 174            (interpret-additions base-chord flat-mods)
 175            (interpret-removals base-chord flat-mods)
 176            ))
 177
 178     (set! complete-chord (map (lambda (x) (ly:pitch-transpose x root))
 179                               (sort complete-chord ly:pitch<?)))
 180
 181     ;; If natural 11 + natural 3 is present, but not given explicitly,
 182     ;; we remove the 11.
 183     (if (and (not explicit-11)
 184              (get-step 11 complete-chord)
 185              (get-step 3 complete-chord)
 186              (= 0 (ly:pitch-alteration (get-step 11 complete-chord)))
 187              (= 0 (ly:pitch-alteration (get-step 3 complete-chord)))
 188              )
 189         (begin
 190           (set! complete-chord (remove-step 11  complete-chord))
 191           )
 192
 193         )
 194
 195     (if inversion
 196         (set! complete-chord (process-inversion complete-chord)))
 197     (if bass
 198         (set! bass (pitch-octavated-strictly-below bass root)))
 199
 200     (if #f
 201         (begin
 202           (write-me "\n*******\n" flat-mods)
 203           (write-me "root: " root)
 204           (write-me "base chord: " base-chord)
 205           (write-me "complete  chord: " complete-chord)
 206           (write-me "inversion: " inversion)
 207           (write-me "bass: " bass)))
 208
 209
 210
 211     (if inversion
 212         (make-chord (cdr complete-chord) bass duration (car complete-chord)
 213                     inversion)
 214         (make-chord complete-chord bass duration #f #f))
 215   ))
 216
 217
 218 (define (make-chord pitches bass duration inversion original-inv-pitch)
 219   "Make EventChord with notes corresponding to PITCHES, BASS and
 220 DURATION, and INVERSION."
 221   (define (make-note-ev pitch)
 222     (let*
 223         (
 224          (ev   (make-music-by-name 'NoteEvent))
 225          )
 226
 227       (ly:music-set-property! ev 'duration duration)
 228       (ly:music-set-property! ev 'pitch pitch)
 229       ev
 230       ))
 231
 232   (let*
 233       (
 234        (nots (map make-note-ev pitches))
 235        (bass-note (if bass (make-note-ev bass) #f))
 236        (inv-note (if inversion (make-note-ev inversion) #f))
 237        )
 238
 239
 240     (if bass-note
 241         (begin
 242           (ly:music-set-property! bass-note 'bass #t)
 243           (set! nots (cons bass-note nots))))
 244
 245
 246     (if inv-note
 247         (begin
 248           (ly:music-set-property! inv-note 'inversion #t)
 249           (ly:music-set-property! inv-note 'octavation
 250                                 (- (ly:pitch-octave inversion)
 251                                    (ly:pitch-octave original-inv-pitch))
 252                                 )
 253           (set! nots (cons inv-note nots))))
 254
 255     (make-event-chord nots)
 256   ))
 257
 258
 259 ;;;;;;;;;;;;;;;;
 260 ; chord modifiers change the pitch list.
 261
 262 (define (aug-modifier  pitches)
 263   (set! pitches  (replace-step (ly:make-pitch 0 4 SHARP) pitches))
 264   (replace-step (ly:make-pitch 0 2 0) pitches)
 265   )
 266
 267 (define (minor-modifier  pitches)
 268   (replace-step (ly:make-pitch 0 2 FLAT) pitches)
 269   )
 270
 271 (define (maj7-modifier  pitches)
 272   (set! pitches (remove-step 7 pitches))
 273   (cons  (ly:make-pitch 0 6 0) pitches)
 274   )
 275
 276 (define (dim-modifier  pitches)
 277   (set! pitches (replace-step (ly:make-pitch 0 2 FLAT) pitches))
 278   (set! pitches (replace-step (ly:make-pitch 0 4 FLAT) pitches))
 279   (set! pitches (replace-step (ly:make-pitch 0 6 DOUBLE-FLAT) pitches))
 280   pitches
 281   )
 282
 283 (define (sus-modifier  pitches)
 284    (remove-step (pitch-step (ly:make-pitch 0 2 0)) pitches)
 285   )
 286
 287 (define-public default-chord-modifier-list
 288   `((m . ,minor-modifier)
 289     (min . ,minor-modifier)
 290     (aug . , aug-modifier)
 291     (dim . , dim-modifier)
 292     (maj . , maj7-modifier)
 293     (sus . , sus-modifier)
 294     ))
 295
 296
 297 ;; canonical 13 chord.
 298 (define the-canonical-chord
 299   (map
 300    (lambda (n)
 301      (define (nca x)
 302        (if (= x 7) FLAT 0))
 303      (if (>= n 8)
 304          (ly:make-pitch 1 (- n 8) (nca n))
 305          (ly:make-pitch 0 (- n 1) (nca n))))
 306    '(1 3 5 7 9 11 13)))
 307
 308 (define (stack-thirds upper-step base)
 309   "Stack thirds listed in BASE until we reach UPPER-STEP. Add
 310 UPPER-STEP separately."
 311    (cond
 312     ((null? base) '())
 313     ((> (ly:pitch-steps upper-step) (ly:pitch-steps (car base)))
 314      (cons (car base) (stack-thirds upper-step  (cdr base))))
 315     ((<= (ly:pitch-steps upper-step) (ly:pitch-steps (car base)))
 316      (list upper-step))
 317     (else '())
 318     ))
 319