scm/backend-library.scm

   1 ;;;; backend-library.scm -- helpers for the backends.
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c)  2005 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;; Han-Wen Nienhuys <hanwen@cs.uu.nl>
   7
   8 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   9 ;; backend helpers.
  10
  11 (define-public (ly:system command)
  12   (let* ((status 0)
  13          (dev-null "/dev/null")
  14          (silenced (if (or (ly:get-option 'verbose)
  15                            (not (access? dev-null W_OK)))
  16                        command
  17                        (format #f "~a > ~a 2>&1 " command dev-null))))
  18     (if (ly:get-option 'verbose)
  19         (ly:message (_ "Invoking `~a'...") command))
  20
  21     (set! status (system silenced))
  22     (if (> status 0)
  23         (begin
  24           (ly:message (_ "`~a' failed (~a)") command status)
  25           (ly:progress "\n")
  26           ;; hmmm.  what's the best failure option?
  27           (throw 'ly-file-failed)))))
  28
  29 (define-public (sanitize-command-option str)
  30   (string-append
  31    "\""
  32    (regexp-substitute/global #f "[^- 0-9,.a-zA-Z'\"\\]" str 'pre 'post)
  33    "\""))
  34
  35 (define-public (search-executable names)
  36   (define (helper path lst)
  37     (if (null? (cdr lst))
  38         (car lst)
  39         (if (search-path path (car lst)) (car lst)
  40             (helper path (cdr lst)))))
  41
  42   (let ((path (parse-path (getenv "PATH"))))
  43     (helper path names)))
  44
  45 (define-public (search-gs)
  46   (search-executable '("gs-nox" "gs-8.15" "gs")))
  47
  48 (define-public (postscript->pdf papersizename name)
  49   (let* ((pdf-name (string-append (basename name ".ps") ".pdf"))
  50          (cmd (format #f
  51                       "~a\
  52  ~a\
  53  ~a\
  54  -dCompatibilityLevel=1.4 \
  55  -sPAPERSIZE=~a\
  56  -dNOPAUSE\
  57  -dBATCH\
  58  -r1200 \
  59  -sDEVICE=pdfwrite\
  60  -sOutputFile=~S\
  61  -c .setpdfwrite\
  62  -f ~S\
  63 "
  64                       (search-gs)
  65                       (if (ly:get-option 'verbose) "" "-q")
  66                       (if (ly:get-option 'gs-font-load)
  67                           " -dNOSAFER "
  68                           " -dSAFER ")
  69                       (sanitize-command-option papersizename)
  70                       pdf-name
  71                       name)))
  72     ;; The wrapper on windows cannot handle `=' signs,
  73     ;; gs has a workaround with #.
  74     (if (eq? PLATFORM 'windows)
  75         (begin
  76           (set! cmd (string-regexp-substitute "=" "#" cmd))
  77           (set! cmd (string-regexp-substitute "-dSAFER " "" cmd))))
  78
  79     (if (access? pdf-name W_OK)
  80         (delete-file pdf-name))
  81
  82     (ly:message (_ "Converting to `~a'...") pdf-name)
  83     (ly:progress "\n")
  84     (ly:system cmd)
  85     ))
  86
  87 (use-modules (scm ps-to-png))
  88 (define-public (postscript->png resolution paper-size-name name)
  89     ;; Do not try to guess the name of the png file,
  90     ;; GS produces PNG files like BASE-page%d.png.
  91     ;;(ly:message (_ "Converting to `~a'...")
  92     ;;      (string-append (basename name ".ps") "-page1.png" )))
  93   (let ((paper-size (sanitize-command-option paper-size-name))
  94         (verbose (ly:get-option 'verbose))
  95         (rename-page-1 #f))
  96     (ly:message (_ "Converting to ~a...") "PNG")
  97     (make-ps-images name resolution paper-size rename-page-1 verbose)
  98     (ly:progress "\n")))
  99
 100 (define-public (postprocess-output paper-book module filename formats)
 101   (let*
 102       ((completed (completize-formats formats))
 103        (base (string-regexp-substitute "\\.[a-z]+$" "" filename))
 104        (intermediate (remove
 105                       (lambda (x)
 106                         (member x formats))
 107                       completed)))
 108     (for-each
 109      (lambda (f)
 110        ((eval (string->symbol (string-append "convert-to-" f)) module)
 111         paper-book filename))
 112      completed)
 113
 114     (if (ly:get-option 'delete-intermediate-files)
 115         (for-each
 116          (lambda (f)
 117            (delete-file (string-append base "." f)))
 118          intermediate))
 119     ))
 120
 121 (define-public (completize-formats formats)
 122   (define new-fmts '())
 123
 124   (if (member "png" formats)
 125       (set! formats (cons "ps" formats)))
 126   (if (member "pdf" formats)
 127       (set! formats (cons "ps" formats)))
 128
 129   (for-each
 130    (lambda (x)
 131      (if (member x formats) (set! new-fmts (cons x new-fmts))))
 132    '("tex" "dvi" "ps" "pdf" "png"))
 133
 134   (uniq-list (reverse new-fmts)))
 135
 136 (define (header-to-file file-name key value)
 137   (set! key (symbol->string key))
 138   (if (not (equal? "-" file-name))
 139       (set! file-name (string-append file-name "." key)))
 140   (ly:message (_ "Writing header field `~a' to `~a'...")
 141               key
 142               (if (equal? "-" file-name) "<stdout>" file-name))
 143   (if (equal? file-name "-")
 144       (display value)
 145       (display value (open-file file-name "w")))
 146   (ly:progress "\n")
 147   "")
 148
 149 (define-public (output-scopes scopes fields basename)
 150   (define (output-scope scope)
 151     (apply
 152      string-append
 153      (module-map
 154       (lambda (sym var)
 155         (let ((val (if (variable-bound? var) (variable-ref var) "")))
 156           (if (and (memq sym fields) (string? val))
 157               (header-to-file basename sym val))
 158           ""))
 159       scope)))
 160   (apply string-append (map output-scope scopes)))
 161