scm/backend-library.scm

   1 ;;;; backend-library.scm -- helpers for the backends.
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c)  2005 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;; Han-Wen Nienhuys <hanwen@cs.uu.nl>
   7
   8 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   9 ;; backend helpers.
  10
  11 (define-public (ly:system command)
  12   (let* ((status 0)
  13          (silenced
  14           (string-append command (if (ly:get-option 'verbose)
  15                                      ""
  16                                      " > /dev/null 2>&1 "))))
  17
  18     (if (ly:get-option 'verbose)
  19         (format (current-error-port) (_ "Invoking `~a'...") command))
  20
  21     (set! status (system silenced))
  22     (if (> status 0)
  23         (begin
  24           (format (current-error-port) (_ "`~a' failed (~a)") command status)
  25           (newline (current-error-port))
  26
  27           ;; hmmm.  what's the best failure option?
  28           (throw 'ly-file-failed)))))
  29
  30 (define-public (sanitize-command-option str)
  31   (string-append
  32    "\""
  33    (regexp-substitute/global #f "[^- 0-9,.a-zA-Z'\"\\]" str 'pre 'post)
  34    "\""))
  35
  36 (define-public (postscript->pdf papersizename name)
  37   (let* ((cmd (format #f "ps2pdf -sPAPERSIZE=~a '~a'"
  38                       (sanitize-command-option papersizename) name))
  39          (pdf-name (string-append (basename name ".ps") ".pdf" )))
  40
  41     (if (access? pdf-name W_OK)
  42         (delete-file pdf-name))
  43
  44     (format (current-error-port) (_ "Converting to `~a'...") pdf-name)
  45     (ly:system cmd)))
  46
  47 (define-public (postscript->png resolution papersizename name)
  48   (let* ((prefix (getenv "LILYPONDPREFIX"))
  49          (ps2png-source (if prefix
  50                            (format "~a/scripts/ps2png.py" prefix)
  51                            "ps2png"))
  52          (cmd (format #f
  53                       "~a --resolution=~S --papersize=~a~a '~a'"
  54                       (if (file-exists? ps2png-source)
  55                           (format "python ~a" ps2png-source)
  56                           "ps2png")
  57                       resolution
  58                       (sanitize-command-option papersizename)
  59                       (if (ly:get-option 'verbose) " --verbose " "")
  60                       name)))
  61     ;; Do not try to guess the name of the png file
  62     (format (current-error-port) (_ "Converting to `~a'...") "png")
  63     (ly:system cmd)))
  64
  65 (define-public (postprocess-output paper-book module filename formats)
  66   (for-each
  67    (lambda (f)
  68      ((eval (string->symbol (string-append "convert-to-" f))
  69             module)
  70       paper-book filename))
  71
  72    formats))
  73
  74 (define-public (completize-formats formats)
  75   (define new-fmts '())
  76
  77   (if (member "png" formats)
  78       (set! formats (cons "ps" formats)))
  79   (if (member "pdf" formats)
  80       (set! formats (cons "ps" formats)))
  81
  82   (for-each
  83    (lambda (x)
  84      (if (member x formats) (set! new-fmts (cons x new-fmts))))
  85    '("tex" "dvi" "ps" "pdf" "png"))
  86
  87   (reverse new-fmts))
  88
  89 (define (header-to-file file-name key value)
  90   (set! key (symbol->string key))
  91   (if (not (equal? "-" file-name))
  92       (set! file-name (string-append file-name "." key)))
  93   (format (current-error-port)
  94           (_ "Writing header field `~a' to `~a'...")
  95           key
  96           (if (equal? "-" file-name) "<stdout>" file-name))
  97   (if (equal? file-name "-")
  98       (display value)
  99       (display value (open-file file-name "w")))
 100   (newline (current-error-port))
 101   "")
 102
 103 (define-public (output-scopes scopes fields basename)
 104   (define (output-scope scope)
 105     (apply
 106      string-append
 107      (module-map
 108       (lambda (sym var)
 109         (let ((val (if (variable-bound? var) (variable-ref var) "")))
 110           (if (and (memq sym fields) (string? val))
 111               (header-to-file basename sym val))
 112           ""))
 113       scope)))
 114   (apply string-append (map output-scope scopes)))
 115