scm/backend-library.scm

   1 ;;;; backend-library.scm -- helpers for the backends.
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2005--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;; Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   9 ;; backend helpers.
  10
  11 (define-public (ly:system command)
  12   (let* ((status 0)
  13          (dev-null "/dev/null")
  14          (silenced (if (or (ly:get-option 'verbose)
  15                            (not (access? dev-null W_OK)))
  16                        command
  17                        (format #f "~a > ~a 2>&1 " command dev-null))))
  18     (if (ly:get-option 'verbose)
  19         (ly:message (_ "Invoking `~a'...") command))
  20
  21     (set! status (system silenced))
  22     (if (> status 0)
  23         (begin
  24           (ly:message (_ "`~a' failed (~a)") command status)
  25           (ly:progress "\n")
  26           ;; hmmm.  what's the best failure option?
  27           (throw 'ly-file-failed)))))
  28
  29 (define-public (sanitize-command-option str)
  30   "Kill dubious shell quoting"
  31
  32   (string-append
  33    "\""
  34    (regexp-substitute/global #f "[^-_ 0-9,.a-zA-Z'\"\\]" str 'pre 'post)
  35    "\""))
  36
  37 (define-public (search-executable names)
  38   (define (helper path lst)
  39     (if (null? (cdr lst))
  40         (car lst)
  41         (if (search-path path (car lst)) (car lst)
  42             (helper path (cdr lst)))))
  43
  44   (let ((path (parse-path (getenv "PATH"))))
  45     (helper path names)))
  46
  47 (define-public (search-gs)
  48
  49   ;; must be sure that we don't catch stuff from old GUBs.
  50   (search-executable '("gs")))
  51
  52 (define-public (postscript->pdf paper-width paper-height name)
  53   (let* ((pdf-name (string-append
  54                     (basename (basename name ".ps") ".eps")
  55                     ".pdf"))
  56          (is-eps (string-match "\\.eps$" name))
  57          (paper-size-string (if is-eps
  58                                 " -dEPSCrop "
  59                                 (format "-dDEVICEWIDTHPOINTS=~,2f \
  60 -dDEVICEHEIGHTPOINTS=~,2f "
  61                                         paper-width paper-height )))
  62
  63          (cmd (format #f
  64                       "~a\
  65  ~a\
  66  ~a\
  67  ~a\
  68  -dCompatibilityLevel=1.4 \
  69  -dNOPAUSE\
  70  -dBATCH\
  71  -r1200 \
  72  -sDEVICE=pdfwrite\
  73  -sOutputFile=~S\
  74  -c .setpdfwrite\
  75  -f ~S\
  76 "
  77                       (search-gs)
  78                       (if (ly:get-option 'verbose) "" "-q")
  79                       (if (ly:get-option 'gs-load-fonts)
  80                           " -dNOSAFER "
  81                           " -dSAFER ")
  82                       paper-size-string
  83                       pdf-name
  84                       name)))
  85     ;; The wrapper on windows cannot handle `=' signs,
  86     ;; gs has a workaround with #.
  87     (if (eq? PLATFORM 'windows)
  88         (begin
  89           (set! cmd (string-regexp-substitute "=" "#" cmd))
  90           (set! cmd (string-regexp-substitute "-dSAFER " "" cmd))))
  91
  92     (if (access? pdf-name W_OK)
  93         (delete-file pdf-name))
  94
  95     (ly:message (_ "Converting to `~a'...") pdf-name)
  96     (ly:progress "\n")
  97     (ly:system cmd)
  98     ))
  99
 100 (use-modules (scm ps-to-png))
 101
 102 (define-public (postscript->png resolution paper-width paper-height name)
 103     ;; Do not try to guess the name of the png file,
 104     ;; GS produces PNG files like BASE-page%d.png.
 105     ;;(ly:message (_ "Converting to `~a'...")
 106     ;;      (string-append (basename name ".ps") "-page1.png" )))
 107   (let ((verbose (ly:get-option 'verbose))
 108         (rename-page-1 #f))
 109
 110     (ly:message (_ "Converting to ~a...") "PNG")
 111
 112     (make-ps-images name
 113                     #:resolution resolution
 114                     #:page-width  paper-width
 115                     #:page-height paper-height
 116                     #:rename-page-1 rename-page-1
 117                     #:be-verbose verbose
 118                     #:anti-alias-factor (ly:get-option 'anti-alias-factor)
 119                     #:pixmap-format (ly:get-option 'pixmap-format)
 120                     )
 121
 122     (ly:progress "\n")))
 123
 124 (define-public (postprocess-output paper-book module filename formats)
 125   (let*
 126       ((completed (completize-formats formats))
 127        (base (string-regexp-substitute "\\.[a-z]+$" "" filename))
 128        (intermediate (remove
 129                       (lambda (x)
 130                         (member x formats))
 131                       completed)))
 132
 133     (for-each
 134      (lambda (f)
 135        ((eval (string->symbol (format "convert-to-~a" f)) module)
 136         paper-book filename))
 137      completed)
 138
 139     (if (ly:get-option 'delete-intermediate-files)
 140         (for-each
 141          (lambda (f)
 142            (delete-file (string-append base "." f)))
 143          intermediate))
 144     ))
 145
 146 (define-public (completize-formats formats)
 147   (define new-fmts '())
 148
 149   (if (member "png" formats)
 150       (set! formats (cons "ps" formats)))
 151   (if (member "pdf" formats)
 152       (set! formats (cons "ps" formats)))
 153
 154   (for-each
 155    (lambda (x)
 156      (if (member x formats) (set! new-fmts (cons x new-fmts))))
 157    '("tex" "dvi" "ps" "pdf" "png"))
 158
 159   (uniq-list (reverse new-fmts)))
 160
 161 (define (header-to-file file-name key value)
 162   (set! key (symbol->string key))
 163   (if (not (equal? "-" file-name))
 164       (set! file-name (string-append file-name "." key)))
 165   (ly:message (_ "Writing header field `~a' to `~a'...")
 166               key
 167               (if (equal? "-" file-name) "<stdout>" file-name))
 168   (if (equal? file-name "-")
 169       (display value)
 170       (let ((port (open-file file-name "w")))
 171         (display value port)
 172         (close-port port)))
 173
 174   (ly:progress "\n")
 175   "")
 176
 177 (define-public (output-scopes scopes fields basename)
 178   (define (output-scope scope)
 179     (apply
 180      string-append
 181      (module-map
 182       (lambda (sym var)
 183         (let ((val (if (variable-bound? var) (variable-ref var) "")))
 184           (if (and (memq sym fields) (string? val))
 185               (header-to-file basename sym val))
 186           ""))
 187       scope)))
 188   (apply string-append (map output-scope scopes)))
 189