mf/parmesan-heads.mf

   1 % -%-Fundamental-%- -*-Metafont-*-
   2 % parmesan-heads.mf -- implement ancient note heads
   3 %
   4 % source file of LilyPond's pretty-but-neat music font
   5 %
   6 % (c)  2001--2003 Juergen Reuter <reuter@ipd.uka.de>
   7 %
   8 % Neo-mensural heads originally by
   9 % Christian Mondrup and Mats Bengtsson
  10 %
  11
  12 save black_notehead_width;
  13 numeric black_notehead_width;
  14
  15 fet_begingroup ("noteheads")
  16
  17 %
  18 % character aligment:
  19 %
  20 %   The head is assumed to be vertically centered around (0, 0).
  21 %   The left-most edge of the head should touch the vertical line
  22 %   that goes though the point (0, 0).
  23 %
  24 % set_char_box() conventions:
  25 %
  26 % * breapth: Ignored (as far as I know).  Should be set to 0.
  27 %
  28 % * width: Should match the head's width.
  29 %
  30 % * depth: Should match the bottom edge of the head.  Affects vertical
  31 %   collision handling.
  32 %
  33 % * height: Should match the top edge of the head.  Affects vertical
  34 %   collision handling.
  35 %
  36
  37 overdone_heads = 0;
  38 noteheight# := staff_space# + (1 + overdone_heads)*stafflinethickness#;
  39 define_pixels(noteheight);
  40
  41
  42 %%%%%%%%
  43 %
  44 %
  45 %
  46 % MENSURAL NOTATION
  47 %
  48 %
  49 %
  50
  51 def draw_neo_brevis(expr brevwid) =
  52         save beamheight, head_width;
  53         save holeheight, stem_width;
  54         save serif_size, serif_protrude;
  55
  56         head_width# = brevwid;
  57         holeheight = 3 stafflinethickness;
  58         stem_width = 1.4 stafflinethickness;
  59
  60
  61         define_pixels(head_width);
  62         set_char_box(0, head_width#, noteheight#/2, noteheight#/2);
  63
  64         2 beamheight + holeheight = noteheight;
  65         serif_size = (holeheight - stafflinethickness)/2;
  66         serif_protrude = 1.5 serif_size;
  67         penpos1(stem_width, 0);
  68         penpos2(stem_width, 0);
  69         penpos3(beamheight, 90);
  70         penpos4(beamheight, 90);
  71         penpos5(stem_width, 180);
  72
  73         z1l = (0, 0);
  74         z2l = (0, -stafflinethickness/2);
  75         z3r = z2r + serif_size *(1,-1);
  76         y4r = y3r;
  77         x4r = head_width/2;
  78         z5l = z3l + (-serif_size, -serif_protrude);
  79
  80         penlabels(1,2,3,4, 5);
  81         fill z1r -- z1l -- z5r{down} .. z5l{up} .. z3l{right}
  82                 -- z4l -- z4r -- z3r{left} .. z2r{up} -- cycle;
  83
  84         addto currentpicture also currentpicture yscaled -1;
  85         show z4r; show z4l;
  86         addto currentpicture also currentpicture
  87                 shifted (-x4r,0) xscaled -1 shifted (x4l,0);
  88
  89 enddef;
  90
  91
  92 def draw_neo_left_stemmed_head (expr wid) =
  93         draw_neo_brevis(wid);
  94
  95         x6 = x7 = head_width - stem_width/2;
  96         y6 = y5;
  97         y7 = y5 - 2.25 staff_space;
  98         pickup pencircle scaled stem_width;
  99         draw z6 .. z7;
 100 enddef;
 101
 102 fet_beginchar("Left stemmed notehead", "lneo_mensural", "mensuralleftstemmedhead");
 103         draw_neo_left_stemmed_head (2 staff_space#);
 104 fet_endchar;
 105
 106 %
 107 % Some sources (eg Musix/OpusTeX think that the appendage should be on
 108 % the left, some say right. Right wins democratically.
 109 %
 110 def draw_neo_longa (expr wid) =
 111         draw_neo_brevis(wid);
 112         save theta;
 113
 114         x7r = head_width;
 115         y7 = y5;
 116 %       z7 = z5;
 117         z6 - z7 = (stem_width/2, -staff_space);
 118         theta = angle(z6-z7)+ 90;
 119         penpos7(stem_width, theta);
 120         penpos6(1.2 stem_width, theta);
 121
 122         fill z7r .. z6r{z6-z7} .. {z7-z6} z6l -- z7l -- cycle;
 123         penlabels(6,7);
 124 enddef;
 125
 126 %
 127 % En wij presenteren U: de opvolgster van Emily
 128 %
 129 % (ze is wel breed)
 130 %
 131 fet_beginchar("Maxima notehead", "-3neo_mensural", "mensuralmaximahead");
 132         draw_neo_longa (2.6 staff_space#)
 133 fet_endchar;
 134
 135 fet_beginchar("Longa notehead", "-2neo_mensural", "mensurallongahead");
 136         draw_neo_longa (2 staff_space#)
 137 fet_endchar;
 138
 139 fet_beginchar("Brevis notehead", "-1neo_mensural", "mensuralbrevishead")
 140         draw_neo_brevis(2 staff_space#);
 141 fet_endchar;
 142
 143 def draw_neo_mensural_black_head (expr wid) =
 144         save head_width;
 145         head_width# = wid;
 146         set_char_box (0, head_width#, noteheight#/2, noteheight#/2);
 147         charwx := head_width# / 2;
 148         charwy := noteheight# / 2;
 149
 150         y3 = y1 =0;
 151         x2 = x4 = (x1 + x3) /2;
 152         define_pixels (head_width);
 153         pickup pencircle scaled blot_diameter;
 154         top y2 = h;
 155         bot y4 = -d;
 156         lft x1 = 0;
 157         rt x3 = w;
 158
 159         filldraw z1 -- z2 -- z3 -- z4 -- cycle;
 160 enddef;
 161
 162 def draw_neo_mensural_open_head (expr wid)=
 163         draw_neo_mensural_black_head (wid);
 164         save diamNW, diamSW;
 165         diamNW = length (z2 - z1) + blot_diameter;
 166         diamSW = length (z4 - z1) + blot_diameter;
 167
 168         save hole_widthNW, hole_widthSW;
 169         hole_widthNW = 0.34 diamNW ;
 170         hole_widthSW + 2.6 stafflinethickness = diamSW;
 171
 172         (z7 + z5)/2 = (w/2, 0);
 173         (z8 + z6)/2 = (w/2, 0);
 174         (z6 - z5) = hole_widthNW * unitvector (z2 - z1);
 175         (z7 - z6) = hole_widthSW * unitvector (z4 - z1);
 176
 177         labels (1,2,3,4,5,6,7,8);
 178
 179         unfill z5 -- z6 -- z7 -- z8 --cycle;
 180 enddef;
 181
 182 fet_beginchar("Neo-mensural open head","0neo_mensural","neomensuralsemibrevishead")
 183       draw_neo_mensural_open_head (staff_space#);
 184 fet_endchar;
 185
 186 fet_beginchar("Neo-mensural open head","1neo_mensural","neomensuralminimahead")
 187       draw_neo_mensural_open_head (staff_space#);
 188 fet_endchar;
 189
 190 fet_beginchar("Neo-mensural black head","2neo_mensural","neomensuralsemiminimahead")
 191       draw_neo_mensural_black_head (staff_space#);
 192 fet_endchar;
 193
 194
 195
 196 def draw_brevis (expr wid) =
 197         % TODO.  For the moment, fall back to draw_neo_brevis.
 198         draw_neo_brevis(wid);
 199 enddef;
 200
 201 def draw_left_stemmed_head (expr wid) =
 202         draw_brevis(wid);
 203         save theta;
 204
 205         x6 = x7 = stem_width/2;
 206         y6 = y5;
 207         y7 = y5 - 2.25staff_space;
 208         pickup pencircle scaled stem_width;
 209         draw z6 .. z7;
 210 enddef;
 211
 212 fet_beginchar("Left stemmed notehead", "lmensural", "mensuralleftstemmedhead");
 213         draw_left_stemmed_head (staff_space#)
 214 fet_endchar;
 215
 216 def draw_longa (expr wid) =
 217         draw_brevis(wid);
 218
 219         x6 = x7 = head_width - stem_width/2;
 220         y6 = y5;
 221         y7 = y5 - 2.25staff_space;
 222         pickup pencircle scaled stem_width;
 223         draw z6 .. z7;
 224 enddef;
 225
 226 fet_beginchar("Maxima notehead", "-3mensural", "mensuralmaximahead");
 227         draw_longa (2.0 staff_space#)
 228 fet_endchar;
 229
 230 fet_beginchar("Longa notehead", "-2mensural", "mensurallongahead");
 231         draw_longa (staff_space#)
 232 fet_endchar;
 233
 234 fet_beginchar("Brevis notehead", "-1mensural", "mensuralbrevishead")
 235         draw_brevis(staff_space#);
 236 fet_endchar;
 237
 238 def draw_diamond_head (expr head_h, pen_w, pen_h, angle, open) =
 239       save head_width, head_height;
 240       head_height# = head_h;
 241       head_width# / head_height# = tand(angle);
 242       define_pixels(head_width, head_height);
 243
 244       set_char_box (0, head_width#,
 245         head_height#/2, head_height#/2);
 246
 247       charwx := head_width# / 2;
 248       charwy := head_height# / 2 - stafflinethickness#;
 249
 250       pickup pencircle
 251              xscaled (min(blot_diameter, pen_w * head_width))
 252              yscaled (min(blot_diameter, pen_h * head_width))
 253              rotated -angle;
 254
 255       %% FIXME: replace "xpart (top z2)" (and, analogously,
 256       %% "ypart (rt z3)") with an expression that really delivers the
 257       %% x coordinate of the uppermost pixel that is drawn with respect
 258       %% to the pencircle (this requires some elliptical computations).
 259       %% MF obviously interprets "xpart (top z2)" as "top (xpart z2)",
 260       %% i.e. "top x2", which is not what we want.
 261
 262       xpart (top z2) = ypart (rt z3) = 0;
 263       top y2 = head_height/2;
 264       rt x3 = head_width/2;
 265       z2 = - z4;
 266       z3 = - z1;
 267
 268       if open:
 269               draw z1 -- z2 -- z3 -- z4 -- cycle;
 270       else:
 271               filldraw z1 -- z2 -- z3 -- z4 -- cycle;
 272       fi;
 273
 274       currentpicture := currentpicture shifted (head_width/2, 0);
 275
 276 enddef;
 277
 278
 279 fet_beginchar("Mensural open head","0mensural","mensuralsemibrevishead")
 280         draw_diamond_head (staff_space#, 0.15, 0.30, 30, true);
 281 fet_endchar;
 282
 283 fet_beginchar("Mensural open head","1mensural","mensuralminimahead")
 284         draw_diamond_head (staff_space#, 0.15, 0.30, 30, true);
 285 fet_endchar;
 286
 287 fet_beginchar("Mensural black head","2mensural","mensuralsemiminimahead")
 288         draw_diamond_head (staff_space#, 0.15, 0.30, 30, false);
 289 fet_endchar;
 290
 291
 292 %%%%%%%%
 293 %
 294 %
 295 %
 296 % EDITIO VATICANA (including solesmes extensions)
 297 %
 298 %
 299 %
 300
 301 % parameterized punctum
 302 def punctum_char (expr verbose_name, internal_name, ly_name,
 303                   left_stem, right_stem, linea, cavum,
 304                   straight, auctum, direction_up, excentric, up_shift, down_shift, mag) =
 305
 306         fet_beginchar(verbose_name, internal_name, ly_name)
 307                 save b_h, a_w;
 308                 a_b := 1.54; % b_h*a_b/a_w = wd/ht
 309                 b_h := 0.85;
 310                 a_w := 1.09;
 311
 312                 save a, beta, ht, wd;
 313                 ht# = noteheight# * mag;
 314                 2beta# = ht# * b_h;
 315                 a# = beta# * a_b;
 316                 wd# = 2a# / a_w;
 317                 black_notehead_width# := wd#;
 318
 319                 % direction
 320                 save direction, direction_sign;
 321                 pair direction;
 322                 if direction_up:
 323                         direction = up;
 324                         direction_sign# = 1;
 325                 else:
 326                         direction = down;
 327                         direction_sign# = -1;
 328                 fi;
 329
 330                 % convexity and excentricity
 331                 save u_convexity, u_excentricity;
 332                 if straight:
 333                         u_convexity# = -0.01ht#;
 334                         u_excentricity# = 0.0ht#; % dummy
 335                 elseif auctum:
 336                         u_convexity# = -0.03ht#;
 337                         u_excentricity# = +0.25ht#;
 338                 else:
 339                         u_convexity# = -0.05ht#;
 340                         u_excentricity# = 0.0ht#; % dummy
 341                 fi;
 342                 save convexity, excentricity;
 343                 convexity# = direction_sign# * u_convexity#;
 344                 excentricity# = direction_sign# * u_excentricity#;
 345
 346                 % y shift offset
 347                 save yoffs;
 348                 if up_shift:
 349                         yoffs# = 0.08ht#;
 350                 elseif down_shift:
 351                         yoffs# = -0.11ht#;
 352                 else:
 353                         yoffs# = 0.00ht#;
 354                 fi
 355
 356                 define_pixels(convexity, excentricity, yoffs, ht, wd);
 357                 pickup pencircle scaled stafflinethickness;
 358
 359                 path p;
 360                 save height, yoffs_bt;
 361                 define_pixels (height, yoffs_bt);
 362                 height# = 0.47ht#;
 363                 yoffs_bt# = yoffs# - 0.5*height# - 0.25*convexity#;
 364                 xpart z1a = xpart z1b;
 365                 xpart z2a = xpart z2b;
 366                 xpart z3a = xpart z3b;
 367                 ypart z1a + height = ypart z1b;
 368                 ypart z2a + height = ypart z2b;
 369                 ypart z3a + height = ypart z3b;
 370
 371                 save box_top, box_bt;
 372
 373                 if auctum:
 374                         z1a = (0.00wd + stafflinethickness/2, yoffs_bt);
 375                         z2a = (0.21wd, yoffs_bt + 1.0*convexity);
 376                         z3a = (0.42wd - stafflinethickness/2,
 377                                yoffs_bt + 1.0*excentricity);
 378                         box_top# = height# + yoffs_bt# +
 379                                 max(0, 1.0*convexity#, 1.0*excentricity#);
 380                         box_bt# = yoffs_bt# +
 381                                 min(0, 1.0*convexity#, 1.0*excentricity#);
 382                         p = z1a .. {right}z2a .. {direction}z3a --
 383                             z3b{-direction} .. z2b{left} .. z1b -- cycle;
 384                 elseif excentric:
 385                         z1a = (0.00wd + stafflinethickness/2,
 386                                yoffs_bt - 1.0*convexity);
 387                         z2a = (0.08wd, yoffs_bt + 1.4*convexity);
 388                         z3a = (0.42wd - stafflinethickness/2,
 389                                yoffs_bt - 1.0*convexity);
 390                         box_top# = height# + yoffs_bt# +
 391                                 max(-1.0*convexity#, 1.4*convexity#, 0);
 392                         box_bt# = yoffs_bt# +
 393                                 min(-1.0*convexity#, 1.4*convexity#, 0);
 394                         p = z1a{direction} .. z2a{right} .. z3a --
 395                             z3b .. {left}z2b .. {-direction}z1b -- cycle;
 396                 else:
 397                         z1a = (0.00wd + stafflinethickness/2, yoffs_bt);
 398                         z2a = (0.21wd, yoffs_bt + 1.0*convexity);
 399                         z3a = (0.42wd - stafflinethickness/2, yoffs_bt);
 400                         box_top# = height# + yoffs_bt# +
 401                                 max(0, 1.0*convexity#);
 402                         box_bt# = yoffs_bt# +
 403                                 min(0, 1.0*convexity#);
 404                         p = z1a .. z2a .. z3a --
 405                             z3b .. z2b .. z1b -- cycle;
 406                 fi;
 407
 408                 if cavum:
 409                         draw p;
 410                 else:
 411                         filldraw p;
 412                 fi;
 413
 414                 pickup pencircle scaled 0.6stafflinethickness;
 415
 416                 save stem_bt;
 417
 418                 if left_stem:
 419                         z5=(0.00wd + 0.6stafflinethickness/2, yoffs);
 420                         z6=(0.00wd + 0.6stafflinethickness/2, yoffs - 1.1ht);
 421                         draw z5 -- z6;
 422                         stem_bt# = yoffs# - 1.1ht#;
 423                 elseif right_stem:
 424                         z5=(0.42wd - 0.6stafflinethickness/2, yoffs);
 425                         z6=(0.42wd - 0.6stafflinethickness/2, yoffs - 1.5ht);
 426                         draw z5 -- z6;
 427                         stem_bt# = yoffs# - 1.5ht#;
 428                 else:
 429                         stem_bt# = 0;
 430                 fi;
 431
 432                 set_char_box(0.00wd#, 0.42wd#,
 433                              max(0, -box_bt#, -stem_bt#) + stafflinethickness#/2,
 434                              max(0, box_top#) + stafflinethickness#/2);
 435
 436                 if linea:
 437                         save linea_width, linea_height;
 438                         linea_width# = 0.6 stafflinethickness#;
 439                         linea_height# = 0.7 ht#;
 440                         define_pixels (linea_width, linea_height);
 441                         draw_block ((-0.10wd - linea_width/2,
 442                                      -linea_height/2),
 443                                     (-0.10wd + linea_width/2,
 444                                      +linea_height/2));
 445                         draw_block ((+0.52wd - linea_width/2,
 446                                      -linea_height/2),
 447                                     (+0.52wd + linea_width/2,
 448                                      +linea_height/2));
 449                         set_char_box(0,
 450                                      0.62wd# + linea_width#,
 451                                      linea_height#/2,
 452                                      linea_height#/2);
 453                         currentpicture := currentpicture
 454                                 shifted (0.10wd + linea_width/2, 0);
 455                 fi;
 456         fet_endchar;
 457 enddef;
 458
 459 % parameterized punctum inclinatum
 460 def inclinatum_char(expr verbose_name, internal_name, ly_name,
 461                     small, stropha, auctum) =
 462
 463         fet_beginchar(verbose_name, internal_name, ly_name)
 464                 save ht, alpha;
 465                 alpha# = 35;
 466                 if small:
 467                         ht# = 0.50 noteheight#;
 468                 else:
 469                         ht# = 0.80 noteheight#;
 470                 fi;
 471
 472                 draw_diamond_head (ht#, 0, 0, alpha#, false);
 473
 474                 if stropha:
 475                         pickup pencircle
 476                                 xscaled (0.25*head_height)
 477                                 yscaled (0.55*head_height)
 478                                 rotated alpha#;
 479                         save za, off_angle; pair za;
 480                         off_angle := 15;
 481                         za = (0, -0.25*head_height)
 482                                 rotated -(alpha# + off_angle)
 483                                 shifted (0.48 head_width, -0.02 head_width);
 484                         undraw za;
 485                 fi;
 486
 487                 if auctum:
 488                         pickup pencircle scaled stafflinethickness;
 489                         save za, zb, zc;
 490                         pair za, zb, zc;
 491                         za = (0, -0.5 head_height + stafflinethickness);
 492                         zb = 0.6 (za + zc);
 493                         zc = za + (0.52 head_width, 0);
 494                         draw za{(0,-1) rotated alpha#} .. {right}zb{right} ..
 495                              {(0,1) rotated -alpha#}zc;
 496                 fi;
 497         fet_endchar;
 498 enddef;
 499
 500 % punctum
 501 punctum_char("Ed. Vat. punctum", "vaticana_punctum", "vatpunctumhead",
 502              false, false, false, false, false,
 503              false, false, false, false, false, 1.0);
 504
 505 % punctum cavum (for OpusTeX compatibility)
 506 punctum_char("Ed. Vat. punctum cavum", "vaticana_punctum_cavum",
 507              "vatpunctumcavumhead",
 508              false, false, false, true, false,
 509              false, false, false, false, false, 1.0);
 510
 511 % linea punctum (for OpusTeX compatibility)
 512 punctum_char("Ed. Vat. linea punctum", "vaticana_linea_punctum",
 513              "vatlineapunctumhead",
 514              false, false, true, false, false,
 515              false, false, false, false, false, 1.0);
 516
 517 % linea punctum cavum (for OpusTeX compatibility)
 518 punctum_char("Ed. Vat. linea punctum cavum", "vaticana_linea_punctum_cavum",
 519              "vatlineapunctumcavumhead",
 520              false, false, true, true, false,
 521              false, false, false, false, false, 1.0);
 522
 523 % punctum inclinatum
 524 inclinatum_char("Ed. Vat. inclinatum", "vaticana_inclinatum",
 525                 "vatinclinatumhead",
 526                 false, false, false);
 527
 528 % pes lower punctum
 529 punctum_char("Ed. Vat. pes lower punctum", "vaticana_lpes", "vatlpeshead",
 530              false, false, false, false, true,
 531              false, true, false, false, false, 1.0);
 532
 533 % pes lower punctum
 534 punctum_char("Ed. Vat. pes var lower punctum", "vaticana_vlpes", "vatvlpeshead",
 535              false, false, false, false, true,
 536              false, true, false, false, true, 1.0);
 537
 538 % pes upper punctum
 539 punctum_char("Ed. Vat. pes upper punctum", "vaticana_upes", "vatupeshead",
 540              false, false, false, false, true,
 541              false, false, false, false, false, 1.0);
 542
 543 % pes upper punctum (shifted variation)
 544 %
 545 % This note head is used instead of the regular pes upper punctum to
 546 % avoid collision with the lower punctum note of the pes when the upper
 547 % punctum sits directly on top of the lower punctum.
 548 %
 549 punctum_char("Ed. Vat. var pes upper punctum", "vaticana_vupes",
 550              "vatvupeshead",
 551              false, false, false, false, true,
 552              false, false, false, true, false, 1.0);
 553
 554 % small punctum as used in epiphonus
 555 punctum_char("Ed. Vat. plica", "vaticana_plica", "vatplicahead",
 556              false, false, false, false, false,
 557              false, false, false, false, false, 0.6);
 558
 559 % excentric punctum as used in epiphonus
 560 punctum_char("Ed. Vat. epiphonus", "vaticana_epiphonus", "vatepiphonushead",
 561              false, false, false, false, false,
 562              false, true, true, false, false, 1.0);
 563
 564 % excentric punctum as used in epiphonus (shifted variation)
 565 %
 566 % This note head is used instead of the regular epiphonus punctum to
 567 % avoid collision with the plica head when the plica sits directly on
 568 % top of the lower head.
 569 %
 570 punctum_char("Ed. Vat. var epiphonus", "vaticana_vepiphonus", "vatvepiphonushead",
 571              false, false, false, false, false,
 572              false, true, true, false, true, 1.0);
 573
 574 % small punctum as used in cephalicus
 575 punctum_char("Ed. Vat. rev. plica", "vaticana_reverse_plica", "vatrplicahead",
 576              false, false, false, false, false,
 577              false, true, false, false, false, 0.6);
 578
 579 % excentric punctum as used in cephalicus; without left stem
 580 punctum_char("Ed. Vat. cephalicus", "vaticana_inner_cephalicus",
 581              "vatinnercephalicushead",
 582              false, false, false, false, false,
 583              false, false, true, false, false, 1.0);
 584
 585 % excentric punctum as used in cephalicus; with left stem
 586 punctum_char("Ed. Vat. cephalicus", "vaticana_cephalicus",
 587              "vatcephalicushead",
 588              true, false, false, false, false,
 589              false, false, true, false, false, 1.0);
 590
 591 % quilisma
 592 fet_beginchar("Ed. Vat. quilisma", "vaticana_quilisma", "vatquilismahead")
 593         save b_h,a_w;
 594         a_b:=1.54; % b_h*a_b/a_w = wd/ht
 595         b_h:=0.85;
 596         a_w:=1.09;
 597
 598         save a, beta, ht, wd;
 599         ht# = noteheight#;
 600         2beta# = ht#*b_h;
 601         a# = beta#*a_b;
 602         wd# = 2a# / a_w;
 603         set_char_box(0, 0.42wd#, 0.28 ht#, 0.36 ht#);
 604         black_notehead_width# := wd#;
 605
 606         define_pixels(ht, wd);
 607         pickup pencircle xscaled stafflinethickness yscaled 0.44ht;
 608         lft x1 = 0.00wd; bot y1 = -0.28ht;
 609         x2 = 0.11wd;     y2 = -0.14ht;
 610         x3 = 0.12wd;     y3 = +0.03ht;
 611         x4 = 0.25wd;     y4 = -0.09ht;
 612         x5 = 0.26wd;     y5 = +0.08ht;
 613         x6 = 0.40wd;     y6 = -0.04ht;
 614         rt x7 = 0.42wd;  top y7 = +0.36ht;
 615         draw z1 .. z2 -- z3 .. z4 -- z5 .. z6 -- z7;
 616 fet_endchar;
 617
 618 % solesmes punctum inclinatum parvum
 619 inclinatum_char("Solesmes punctum inclinatum parvum", "solesmes_incl_parvum",
 620                 "solinclparvumhead",
 621                 true, false, false);
 622
 623 % solesmes punctum auctum ascendens
 624 punctum_char("Solesmes punctum auctum ascendens", "solesmes_auct_asc",
 625              "solauctaschead",
 626              false, false, false, false, false,
 627              true, true, false, false, false, 1.0);
 628
 629 % solesmes punctum auctum descendens
 630 punctum_char("Solesmes punctum auctum descendens", "solesmes_auct_desc",
 631              "solauctdeschead",
 632              false, false, false, false, false,
 633              true, false, false, false, false, 1.0);
 634
 635 % solesmes punctum inclinatum auctum
 636 inclinatum_char("Solesmes punctum incl. auctum", "solesmes_incl_auctum",
 637                 "solpunctuminclinatumauctumhead",
 638                 false, false, true);
 639
 640 % solesmes stropha
 641 inclinatum_char("Solesmes stropha", "solesmes_stropha",
 642                 "solstrophahead",
 643                 false, true, false);
 644
 645 % solesmes stropha aucta
 646 inclinatum_char("Solesmes stropha aucta", "solesmes_stropha_aucta",
 647                 "solstrophaauctahead",
 648                 false, true, true);
 649
 650 % solesmes oriscus
 651 fet_beginchar("Solesmes oriscus", "solesmes_oriscus",
 652         "soloriscushead")
 653         save b_h, a_w;
 654         a_b := 1.54; % b_h*a_b/a_w = wd/ht
 655         b_h := 0.85;
 656         a_w := 1.09;
 657
 658         save a, beta, ht, wd;
 659         ht# = noteheight#;
 660         2beta# = ht# * b_h;
 661         a# = beta# * a_b;
 662         wd# = 2a# / a_w;
 663         black_notehead_width# := wd#;
 664
 665         save convexity;
 666         convexity# = +0.05ht#;
 667
 668         define_pixels(ht, wd, convexity);
 669         pickup pencircle xscaled blot_diameter yscaled 0.50ht;
 670         lft x1 = 0.00wd; y1 = -convexity;
 671         x2 = 0.16wd;     y2 = +convexity;
 672         x3 = 0.33wd;     y3 = -convexity;
 673         rt x4 = 0.50wd;  y4 = +convexity;
 674         draw z1 .. z2 .. z3 .. z4;
 675         set_char_box(0.00wd#, 0.50wd#,
 676                      0.25ht# + convexity#, 0.25ht# + convexity#);
 677 fet_endchar;
 678
 679 %%%%%%%%
 680 %
 681 %
 682 %
 683 % EDITIO MEDICAEA
 684 %
 685 %
 686 %
 687
 688 % inclinatum
 689 fet_beginchar("Ed. Med. inclinatum", "medicaea_inclinatum",
 690         "medinclinatumhead")
 691         draw_diamond_head (1.2staff_space#, 0, 0, 35, false);
 692 fet_endchar;
 693
 694 % parametrized punctum
 695 def punctum_char (expr verbose_name, internal_name, ly_name,
 696         left_up_stem, left_down_stem) =
 697
 698         fet_beginchar(verbose_name, internal_name, ly_name)
 699
 700                 save a, beta, ht, wd;
 701                 ht# = 2 staff_space#;
 702                 wd# = ht#;
 703                 black_notehead_width# := wd#;
 704
 705                 define_pixels(ht, wd);
 706                 pickup pencircle
 707                         xscaled blot_diameter
 708                         yscaled 0.50ht;
 709                 z1 = (0.00wd + blot_diameter/2, 0);
 710                 z2 = (0.4wd - blot_diameter/2, 0);
 711                 draw z1 .. z2;
 712
 713                 pickup pencircle
 714                         xscaled stafflinethickness
 715                         yscaled blot_diameter;
 716
 717                 if left_down_stem:
 718                         z4=(0.00wd + stafflinethickness/2, blot_diameter/2);
 719                         z5=(0.00wd + stafflinethickness/2, - 1.25ht);
 720                         draw z4 .. z5;
 721                         set_char_box(0.0, 0.4wd#, 1.25ht#, 0.25ht#);
 722                 elseif left_up_stem:
 723                         z4=(0.00wd + stafflinethickness/2, blot_diameter/2);
 724                         z5=(0.00wd + stafflinethickness/2, + 1.25ht);
 725                         draw z4 .. z5;
 726                         set_char_box(0.0, 0.4wd#, 0.25ht#, 1.25ht#);
 727                 else:
 728                         set_char_box(0.0, 0.4wd#, 0.25ht#, 0.25ht#);
 729                 fi;
 730
 731         fet_endchar;
 732 enddef;
 733
 734 % punctum
 735 punctum_char("Ed. Med. punctum", "medicaea_punctum", "medpunctumhead",
 736         false, false);
 737
 738 % left up-stemmed punctum
 739 punctum_char("Ed. Med. reverse virga", "medicaea_rvirga", "medrvirgahead",
 740         true, false);
 741
 742 % virga (i.e. left down-stemmed punctum)
 743 punctum_char("Ed. Med. virga", "medicaea_virga", "medvirgahead",
 744         false, true);
 745
 746 %%%%%%%%
 747 %
 748 %
 749 %
 750 % HUFNAGEL
 751 %
 752 %
 753 %
 754
 755 % punctum
 756 % parametrized punctum
 757 def punctum_char (expr verbose_name, internal_name, ly_name,
 758         down_stem) =
 759         fet_beginchar(verbose_name, internal_name, ly_name)
 760                 save alpha;
 761                 alpha# = 55;
 762                 draw_diamond_head (staff_space#, 0, 0, alpha#, false);
 763                 if down_stem:
 764                         pickup pencircle
 765                                 xscaled blot_diameter
 766                                 yscaled (0.7*staff_space)
 767                                 rotated -alpha#;
 768                         save za, zb; pair za, zb;
 769                         za = (head_width/2, 0);
 770                         bot zb = (head_width/2, -1.5staff_space);
 771                         draw za -- zb;
 772                         set_char_box (0, head_width#,
 773                                       1.5staff_space#, head_height#/2);
 774                 fi;
 775         fet_endchar;
 776 enddef;
 777
 778 % punctum
 779 punctum_char("Hufnagel punctum", "hufnagel_punctum", "hufpunctumhead", false)
 780
 781 % virga
 782 punctum_char("Hufnagel virga", "hufnagel_virga", "hufvirgahead", true)
 783
 784 % pes lower punctum
 785 fet_beginchar("Hufnagel pes lower punctum", "hufnagel_lpes", "huflpeshead")
 786         save width, height, alpha;
 787         width# = 2*staff_space#;
 788         height# = 0.7*staff_space#;
 789         alpha# = 35;
 790
 791         set_char_box(0, width#, height#/2, height#/2);
 792
 793         pickup pencircle scaled stafflinethickness;
 794         define_pixels(width, height);
 795
 796         rt x3 = -lft x1 = width/2;
 797         y2 = y3 = height/2;
 798         y1 = y4 = -height/2;
 799         tand(alpha#) * (y2 - y1) = x2 - x1 = x3 - x4;
 800
 801         filldraw z1 -- z2 -- z3 -- z4 -- cycle;
 802
 803         currentpicture := currentpicture shifted (width/2, 0);
 804 fet_endchar;
 805
 806 fet_endgroup ("noteheads")