mf/parmesan-heads.mf

   1 % -%-Fundamental-%- -*-Metafont-*-
   2 % parmesan-heads.mf -- implement ancient note heads
   3 %
   4 % source file of LilyPond's pretty-but-neat music font
   5 %
   6 % (c)  2001--2003 Juergen Reuter <reuter@ipd.uka.de>
   7 %
   8 % Neo-mensural heads originally by
   9 % Christian Mondrup and Mats Bengtsson
  10 %
  11
  12 save black_notehead_width;
  13 numeric black_notehead_width;
  14
  15 fet_begingroup ("noteheads")
  16
  17 %
  18 % character aligment:
  19 %
  20 %   The head is assumed to be vertically centered around (0, 0).
  21 %   The left-most edge of the head should touch the vertical line
  22 %   that goes though the point (0, 0).
  23 %
  24 % set_char_box() conventions:
  25 %
  26 % * breapth: Ignored (as far as I know).  Should be set to 0.
  27 %
  28 % * width: Should match the head's width.
  29 %
  30 % * depth: Should match the bottom edge of the head.  Affects vertical
  31 %   collision handling.
  32 %
  33 % * height: Should match the top edge of the head.  Affects vertical
  34 %   collision handling.
  35 %
  36
  37 noteheight#:=staff_space# + (1 + overdone_heads)*stafflinethickness#;
  38 define_pixels(noteheight);
  39
  40
  41 %%%%%%%%
  42 %
  43 %
  44 %
  45 % MENSURAL NOTATION
  46 %
  47 %
  48 %
  49 brevis_wid# := 2 staff_space#;
  50
  51 def draw_neo_brevis(expr brevwid) =
  52         save beamheight, head_width;
  53         save holeheight, stem_width;
  54         save serif_size, serif_protrude;
  55
  56         head_width# = brevwid;
  57         holeheight = 3 stafflinethickness;
  58         stem_width = 1.4 stafflinethickness;
  59
  60
  61         define_pixels(head_width);
  62         set_char_box(0, head_width#, noteheight#/2, noteheight#/2);
  63
  64         2 beamheight + holeheight = noteheight;
  65         serif_size = (holeheight - stafflinethickness)/2;
  66         serif_protrude = 1.5 serif_size;
  67         penpos1(stem_width, 0);
  68         penpos2(stem_width, 0);
  69         penpos3(beamheight, 90);
  70         penpos4(beamheight, 90);
  71         penpos5(stem_width, 180);
  72
  73         z1l = (0, 0);
  74         z2l = (0, -stafflinethickness/2);
  75         z3r = z2r + serif_size *(1,-1);
  76         y4r = y3r;
  77         x4r = head_width/2;
  78         z5l = z3l + (-serif_size, -serif_protrude);
  79
  80         penlabels(1,2,3,4, 5);
  81         fill z1r -- z1l -- z5r{down} .. z5l{up} .. z3l{right}
  82                 -- z4l -- z4r -- z3r{left} .. z2r{up} -- cycle;
  83
  84         addto currentpicture also currentpicture yscaled -1;
  85         show z4r; show z4l;
  86         addto currentpicture also currentpicture
  87                 shifted (-x4r,0) xscaled -1 shifted (x4l,0);
  88
  89 enddef;
  90
  91
  92 def draw_neo_left_stemmed_head (expr wid) =
  93         draw_neo_brevis(wid);
  94
  95         x6 = x7 = head_width - stem_width/2;
  96         y6 = y5;
  97         y7 = y5 - 2.25staff_space;
  98         pickup pencircle scaled stem_width;
  99         draw z6 .. z7;
 100 enddef;
 101
 102 fet_beginchar("Left stemmed notehead", "lneo_mensural", "mensuralleftstemmedhead");
 103         draw_neo_left_stemmed_head (brevis_wid#)
 104 fet_endchar;
 105
 106 %
 107 % Some sources (eg Musix/OpusTeX think that the appendage should be on
 108 % the left, some say right. Right wins democratically.
 109 %
 110 def draw_neo_longa (expr wid) =
 111         draw_neo_brevis(wid);
 112         save theta;
 113
 114         x7r = head_width;
 115         y7 = y5;
 116 %       z7 = z5;
 117         z6 - z7 = (stem_width/2, -staff_space);
 118         theta = angle(z6-z7)+ 90;
 119         penpos7(stem_width, theta);
 120         penpos6(1.2 stem_width, theta);
 121
 122         fill z7r .. z6r{z6-z7} .. {z7-z6} z6l -- z7l -- cycle;
 123         penlabels(6,7);
 124 enddef;
 125
 126 %
 127 % En wij presenteren U: de opvolgster van Emily
 128 %
 129 % (ze is wel breed)
 130 %
 131 fet_beginchar("Maxima notehead", "-3neo_mensural", "mensuralmaximahead");
 132         draw_neo_longa (1.3 brevis_wid#)
 133 fet_endchar;
 134
 135 fet_beginchar("Longa notehead", "-2neo_mensural", "mensurallongahead");
 136         draw_neo_longa (brevis_wid#)
 137 fet_endchar;
 138
 139 fet_beginchar("Brevis notehead", "-1neo_mensural", "mensuralbrevishead")
 140         draw_neo_brevis(brevis_wid#);
 141 fet_endchar;
 142
 143 def draw_neo_mensural_black_head (expr wid) =
 144         save head_width;
 145         head_width# = wid;
 146         set_char_box (0, head_width#, noteheight#/2, noteheight#/2);
 147         charwx := head_width# / 2;
 148         charwy := noteheight# / 2;
 149
 150         y3 = y1 =0;
 151         x2 = x4 = (x1 + x3) /2;
 152         define_pixels (head_width);
 153         pickup pencircle scaled blot_diameter;
 154         top y2 = h;
 155         bot y4 = -d;
 156         lft x1 = 0;
 157         rt x3 = w;
 158
 159         filldraw z1 -- z2 -- z3 -- z4 -- cycle;
 160 enddef;
 161
 162 def draw_neo_mensural_open_head (expr wid)=
 163         draw_neo_mensural_black_head (wid);
 164         save diamNW, diamSW;
 165         diamNW = length (z2 - z1) + blot_diameter;
 166         diamSW = length (z4 - z1) + blot_diameter;
 167
 168         save hole_widthNW, hole_widthSW;
 169         hole_widthNW = 0.34 diamNW ;
 170         hole_widthSW + 2.6 stafflinethickness = diamSW;
 171
 172         (z7 + z5)/2 = (w/2, 0);
 173         (z8 + z6)/2 = (w/2, 0);
 174         (z6 - z5) = hole_widthNW * unitvector (z2 - z1);
 175         (z7 - z6) = hole_widthSW * unitvector (z4 - z1);
 176
 177         labels (1,2,3,4,5,6,7,8);
 178
 179         unfill z5 -- z6 -- z7 -- z8 --cycle;
 180 enddef;
 181
 182 fet_beginchar("Neo-mensural open head","0neo_mensural","neomensuralsemibrevishead")
 183       draw_neo_mensural_open_head (staff_space#);
 184 fet_endchar;
 185
 186 fet_beginchar("Neo-mensural open head","1neo_mensural","neomensuralminimahead")
 187       draw_neo_mensural_open_head (staff_space#);
 188 fet_endchar;
 189
 190 fet_beginchar("Neo-mensural black head","2neo_mensural","neomensuralsemiminimahead")
 191       draw_neo_mensural_black_head (staff_space#);
 192 fet_endchar;
 193
 194
 195 brevis_wid# := 1 staff_space#;
 196
 197 def draw_brevis (expr wid) =
 198         % TODO.  For the moment, fall back to draw_neo_brevis.
 199         draw_neo_brevis(wid);
 200 enddef;
 201
 202 def draw_left_stemmed_head (expr wid) =
 203         draw_brevis(wid);
 204         save theta;
 205
 206         x6 = x7 = stem_width/2;
 207         y6 = y5;
 208         y7 = y5 - 2.25staff_space;
 209         pickup pencircle scaled stem_width;
 210         draw z6 .. z7;
 211 enddef;
 212
 213 fet_beginchar("Left stemmed notehead", "lmensural", "mensuralleftstemmedhead");
 214         draw_left_stemmed_head (brevis_wid#)
 215 fet_endchar;
 216
 217 def draw_longa (expr wid) =
 218         draw_brevis(wid);
 219
 220         x6 = x7 = head_width - stem_width/2;
 221         y6 = y5;
 222         y7 = y5 - 2.25staff_space;
 223         pickup pencircle scaled stem_width;
 224         draw z6 .. z7;
 225 enddef;
 226
 227 fet_beginchar("Maxima notehead", "-3mensural", "mensuralmaximahead");
 228         draw_longa (2.0 brevis_wid#)
 229 fet_endchar;
 230
 231 fet_beginchar("Longa notehead", "-2mensural", "mensurallongahead");
 232         draw_longa (brevis_wid#)
 233 fet_endchar;
 234
 235 fet_beginchar("Brevis notehead", "-1mensural", "mensuralbrevishead")
 236         draw_brevis(brevis_wid#);
 237 fet_endchar;
 238
 239 def draw_diamond_head (expr head_h, pen_w, pen_h, angle, open) =
 240       save head_width, head_height;
 241       head_height# = head_h;
 242       head_width# / head_height# = tand(angle);
 243       define_pixels(head_width, head_height);
 244
 245       set_char_box (0, head_width#,
 246         head_height#/2, head_height#/2);
 247
 248       charwx := head_width# / 2;
 249       charwy := head_height# / 2 - stafflinethickness#;
 250
 251       pickup pencircle
 252              xscaled (min(blot_diameter, pen_w * head_width))
 253              yscaled (min(blot_diameter, pen_h * head_width))
 254              rotated -angle;
 255
 256       %% FIXME: replace "xpart (top z2)" (and, analogously,
 257       %% "ypart (rt z3)") with an expression that really delivers the
 258       %% x coordinate of the uppermost pixel that is drawn with respect
 259       %% to the pencircle (this requires some elliptical computations).
 260       %% MF obviously interprets "xpart (top z2)" as "top (xpart z2)",
 261       %% i.e. "top x2", which is not what we want.
 262
 263       xpart (top z2) = ypart (rt z3) = 0;
 264       top y2 = head_height/2;
 265       rt x3 = head_width/2;
 266       z2 = - z4;
 267       z3 = - z1;
 268
 269       if open:
 270               draw z1 -- z2 -- z3 -- z4 -- cycle;
 271       else:
 272               filldraw z1 -- z2 -- z3 -- z4 -- cycle;
 273       fi;
 274
 275       currentpicture := currentpicture shifted (head_width/2, 0);
 276
 277 enddef;
 278
 279
 280 fet_beginchar("Mensural open head","0mensural","mensuralsemibrevishead")
 281         draw_diamond_head (staff_space#, 0.15, 0.30, 30, true);
 282 fet_endchar;
 283
 284 fet_beginchar("Mensural open head","1mensural","mensuralminimahead")
 285         draw_diamond_head (staff_space#, 0.15, 0.30, 30, true);
 286 fet_endchar;
 287
 288 fet_beginchar("Mensural black head","2mensural","mensuralsemiminimahead")
 289         draw_diamond_head (staff_space#, 0.15, 0.30, 30, false);
 290 fet_endchar;
 291
 292
 293 %%%%%%%%
 294 %
 295 %
 296 %
 297 % EDITIO VATICANA (including solesmes extensions)
 298 %
 299 %
 300 %
 301
 302 % parameterized punctum
 303 def punctum_char (expr verbose_name, internal_name, ly_name,
 304                   left_stem, right_stem, linea, cavum,
 305                   straight, auctum, direction_up, excentric, up_shift, down_shift, mag) =
 306
 307         fet_beginchar(verbose_name, internal_name, ly_name)
 308                 save b_h, a_w;
 309                 a_b := 1.54; % b_h*a_b/a_w = wd/ht
 310                 b_h := 0.85;
 311                 a_w := 1.09;
 312
 313                 save a, beta, ht, wd;
 314                 ht# = noteheight# * mag;
 315                 2beta# = ht# * b_h;
 316                 a# = beta# * a_b;
 317                 wd# = 2a# / a_w;
 318                 black_notehead_width# := wd#;
 319
 320                 % direction
 321                 save direction, direction_sign;
 322                 pair direction;
 323                 if direction_up:
 324                         direction = up;
 325                         direction_sign# = 1;
 326                 else:
 327                         direction = down;
 328                         direction_sign# = -1;
 329                 fi;
 330
 331                 % convexity and excentricity
 332                 save u_convexity, u_excentricity;
 333                 if straight:
 334                         u_convexity# = -0.01ht#;
 335                         u_excentricity# = 0.0ht#; % dummy
 336                 elseif auctum:
 337                         u_convexity# = -0.03ht#;
 338                         u_excentricity# = +0.25ht#;
 339                 else:
 340                         u_convexity# = -0.05ht#;
 341                         u_excentricity# = 0.0ht#; % dummy
 342                 fi;
 343                 save convexity, excentricity;
 344                 convexity# = direction_sign# * u_convexity#;
 345                 excentricity# = direction_sign# * u_excentricity#;
 346
 347                 % y shift offset
 348                 save yoffs;
 349                 if up_shift:
 350                         yoffs# = 0.08ht#;
 351                 elseif down_shift:
 352                         yoffs# = -0.11ht#;
 353                 else:
 354                         yoffs# = 0.00ht#;
 355                 fi
 356
 357                 define_pixels(convexity, excentricity, yoffs, ht, wd);
 358                 pickup pencircle scaled stafflinethickness;
 359
 360                 path p;
 361                 save height, yoffs_bt;
 362                 define_pixels (height, yoffs_bt);
 363                 height# = 0.47ht#;
 364                 yoffs_bt# = yoffs# - 0.5*height# - 0.25*convexity#;
 365                 xpart z1a = xpart z1b;
 366                 xpart z2a = xpart z2b;
 367                 xpart z3a = xpart z3b;
 368                 ypart z1a + height = ypart z1b;
 369                 ypart z2a + height = ypart z2b;
 370                 ypart z3a + height = ypart z3b;
 371
 372                 save box_top, box_bt;
 373
 374                 if auctum:
 375                         z1a = (0.00wd + stafflinethickness/2, yoffs_bt);
 376                         z2a = (0.21wd, yoffs_bt + 1.0*convexity);
 377                         z3a = (0.42wd - stafflinethickness/2,
 378                                yoffs_bt + 1.0*excentricity);
 379                         box_top# = height# + yoffs_bt# +
 380                                 max(0, 1.0*convexity#, 1.0*excentricity#);
 381                         box_bt# = yoffs_bt# +
 382                                 min(0, 1.0*convexity#, 1.0*excentricity#);
 383                         p = z1a .. {right}z2a .. {direction}z3a --
 384                             z3b{-direction} .. z2b{left} .. z1b -- cycle;
 385                 elseif excentric:
 386                         z1a = (0.00wd + stafflinethickness/2,
 387                                yoffs_bt - 1.0*convexity);
 388                         z2a = (0.08wd, yoffs_bt + 1.4*convexity);
 389                         z3a = (0.42wd - stafflinethickness/2,
 390                                yoffs_bt - 1.0*convexity);
 391                         box_top# = height# + yoffs_bt# +
 392                                 max(-1.0*convexity#, 1.4*convexity#, 0);
 393                         box_bt# = yoffs_bt# +
 394                                 min(-1.0*convexity#, 1.4*convexity#, 0);
 395                         p = z1a{direction} .. z2a{right} .. z3a --
 396                             z3b .. {left}z2b .. {-direction}z1b -- cycle;
 397                 else:
 398                         z1a = (0.00wd + stafflinethickness/2, yoffs_bt);
 399                         z2a = (0.21wd, yoffs_bt + 1.0*convexity);
 400                         z3a = (0.42wd - stafflinethickness/2, yoffs_bt);
 401                         box_top# = height# + yoffs_bt# +
 402                                 max(0, 1.0*convexity#);
 403                         box_bt# = yoffs_bt# +
 404                                 min(0, 1.0*convexity#);
 405                         p = z1a .. z2a .. z3a --
 406                             z3b .. z2b .. z1b -- cycle;
 407                 fi;
 408
 409                 if cavum:
 410                         draw p;
 411                 else:
 412                         filldraw p;
 413                 fi;
 414
 415                 pickup pencircle scaled 0.6stafflinethickness;
 416
 417                 save stem_bt;
 418
 419                 if left_stem:
 420                         z5=(0.00wd + 0.6stafflinethickness/2, yoffs);
 421                         z6=(0.00wd + 0.6stafflinethickness/2, yoffs - 1.1ht);
 422                         draw z5 -- z6;
 423                         stem_bt# = yoffs# - 1.1ht#;
 424                 elseif right_stem:
 425                         z5=(0.42wd - 0.6stafflinethickness/2, yoffs);
 426                         z6=(0.42wd - 0.6stafflinethickness/2, yoffs - 1.5ht);
 427                         draw z5 -- z6;
 428                         stem_bt# = yoffs# - 1.5ht#;
 429                 else:
 430                         stem_bt# = 0;
 431                 fi;
 432
 433                 set_char_box(0.00wd#, 0.42wd#,
 434                              max(0, -box_bt#, -stem_bt#) + stafflinethickness#/2,
 435                              max(0, box_top#) + stafflinethickness#/2);
 436
 437                 if linea:
 438                         save linea_width, linea_height;
 439                         linea_width# = 0.6 stafflinethickness#;
 440                         linea_height# = 0.7 ht#;
 441                         define_pixels (linea_width, linea_height);
 442                         draw_block ((-0.10wd - linea_width/2,
 443                                      -linea_height/2),
 444                                     (-0.10wd + linea_width/2,
 445                                      +linea_height/2));
 446                         draw_block ((+0.52wd - linea_width/2,
 447                                      -linea_height/2),
 448                                     (+0.52wd + linea_width/2,
 449                                      +linea_height/2));
 450                         set_char_box(0,
 451                                      0.62wd# + linea_width#,
 452                                      linea_height#/2,
 453                                      linea_height#/2);
 454                         currentpicture := currentpicture
 455                                 shifted (0.10wd + linea_width/2, 0);
 456                 fi;
 457         fet_endchar;
 458 enddef;
 459
 460 % parameterized punctum inclinatum
 461 def inclinatum_char(expr verbose_name, internal_name, ly_name,
 462                     small, stropha, auctum) =
 463
 464         fet_beginchar(verbose_name, internal_name, ly_name)
 465                 save ht, alpha;
 466                 alpha# = 35;
 467                 if small:
 468                         ht# = 0.50 noteheight#;
 469                 else:
 470                         ht# = 0.80 noteheight#;
 471                 fi;
 472
 473                 draw_diamond_head (ht#, 0, 0, alpha#, false);
 474
 475                 if stropha:
 476                         pickup pencircle
 477                                 xscaled (0.25*head_height)
 478                                 yscaled (0.55*head_height)
 479                                 rotated alpha#;
 480                         save za, off_angle; pair za;
 481                         off_angle := 15;
 482                         za = (0, -0.25*head_height)
 483                                 rotated -(alpha# + off_angle)
 484                                 shifted (0.48 head_width, -0.02 head_width);
 485                         undraw za;
 486                 fi;
 487
 488                 if auctum:
 489                         pickup pencircle scaled stafflinethickness;
 490                         save za, zb, zc;
 491                         pair za, zb, zc;
 492                         za = (0, -0.5 head_height + stafflinethickness);
 493                         zb = 0.6 (za + zc);
 494                         zc = za + (0.52 head_width, 0);
 495                         draw za{(0,-1) rotated alpha#} .. {right}zb{right} ..
 496                              {(0,1) rotated -alpha#}zc;
 497                 fi;
 498         fet_endchar;
 499 enddef;
 500
 501 % punctum
 502 punctum_char("Ed. Vat. punctum", "vaticana_punctum", "vatpunctumhead",
 503              false, false, false, false, false,
 504              false, false, false, false, false, 1.0);
 505
 506 % punctum cavum (for OpusTeX compatibility)
 507 punctum_char("Ed. Vat. punctum cavum", "vaticana_punctum_cavum",
 508              "vatpunctumcavumhead",
 509              false, false, false, true, false,
 510              false, false, false, false, false, 1.0);
 511
 512 % linea punctum (for OpusTeX compatibility)
 513 punctum_char("Ed. Vat. linea punctum", "vaticana_linea_punctum",
 514              "vatlineapunctumhead",
 515              false, false, true, false, false,
 516              false, false, false, false, false, 1.0);
 517
 518 % linea punctum cavum (for OpusTeX compatibility)
 519 punctum_char("Ed. Vat. linea punctum cavum", "vaticana_linea_punctum_cavum",
 520              "vatlineapunctumcavumhead",
 521              false, false, true, true, false,
 522              false, false, false, false, false, 1.0);
 523
 524 % punctum inclinatum
 525 inclinatum_char("Ed. Vat. inclinatum", "vaticana_inclinatum",
 526                 "vatinclinatumhead",
 527                 false, false, false);
 528
 529 % pes lower punctum
 530 punctum_char("Ed. Vat. pes lower punctum", "vaticana_lpes", "vatlpeshead",
 531              false, false, false, false, true,
 532              false, true, false, false, false, 1.0);
 533
 534 % pes lower punctum
 535 punctum_char("Ed. Vat. pes var lower punctum", "vaticana_vlpes", "vatvlpeshead",
 536              false, false, false, false, true,
 537              false, true, false, false, true, 1.0);
 538
 539 % pes upper punctum
 540 punctum_char("Ed. Vat. pes upper punctum", "vaticana_upes", "vatupeshead",
 541              false, false, false, false, true,
 542              false, false, false, false, false, 1.0);
 543
 544 % pes upper punctum (shifted variation)
 545 %
 546 % This note head is used instead of the regular pes upper punctum to
 547 % avoid collision with the lower punctum note of the pes when the upper
 548 % punctum sits directly on top of the lower punctum.
 549 %
 550 punctum_char("Ed. Vat. var pes upper punctum", "vaticana_vupes",
 551              "vatvupeshead",
 552              false, false, false, false, true,
 553              false, false, false, true, false, 1.0);
 554
 555 % small punctum as used in epiphonus
 556 punctum_char("Ed. Vat. plica", "vaticana_plica", "vatplicahead",
 557              false, false, false, false, false,
 558              false, false, false, false, false, 0.6);
 559
 560 % excentric punctum as used in epiphonus
 561 punctum_char("Ed. Vat. epiphonus", "vaticana_epiphonus", "vatepiphonushead",
 562              false, false, false, false, false,
 563              false, true, true, false, false, 1.0);
 564
 565 % excentric punctum as used in epiphonus (shifted variation)
 566 %
 567 % This note head is used instead of the regular epiphonus punctum to
 568 % avoid collision with the plica head when the plica sits directly on
 569 % top of the lower head.
 570 %
 571 punctum_char("Ed. Vat. var epiphonus", "vaticana_vepiphonus", "vatvepiphonushead",
 572              false, false, false, false, false,
 573              false, true, true, false, true, 1.0);
 574
 575 % small punctum as used in cephalicus
 576 punctum_char("Ed. Vat. rev. plica", "vaticana_reverse_plica", "vatrplicahead",
 577              false, false, false, false, false,
 578              false, true, false, false, false, 0.6);
 579
 580 % excentric punctum as used in cephalicus; without left stem
 581 punctum_char("Ed. Vat. cephalicus", "vaticana_inner_cephalicus",
 582              "vatinnercephalicushead",
 583              false, false, false, false, false,
 584              false, false, true, false, false, 1.0);
 585
 586 % excentric punctum as used in cephalicus; with left stem
 587 punctum_char("Ed. Vat. cephalicus", "vaticana_cephalicus",
 588              "vatcephalicushead",
 589              true, false, false, false, false,
 590              false, false, true, false, false, 1.0);
 591
 592 % quilisma
 593 fet_beginchar("Ed. Vat. quilisma", "vaticana_quilisma", "vatquilismahead")
 594         save b_h,a_w;
 595         a_b:=1.54; % b_h*a_b/a_w = wd/ht
 596         b_h:=0.85;
 597         a_w:=1.09;
 598
 599         save a, beta, ht, wd;
 600         ht# = noteheight#;
 601         2beta# = ht#*b_h;
 602         a# = beta#*a_b;
 603         wd# = 2a# / a_w;
 604         set_char_box(0, 0.42wd#, 0.28 ht#, 0.36 ht#);
 605         black_notehead_width# := wd#;
 606
 607         define_pixels(ht, wd);
 608         pickup pencircle xscaled stafflinethickness yscaled 0.44ht;
 609         lft x1 = 0.00wd; bot y1 = -0.28ht;
 610         x2 = 0.11wd;     y2 = -0.14ht;
 611         x3 = 0.12wd;     y3 = +0.03ht;
 612         x4 = 0.25wd;     y4 = -0.09ht;
 613         x5 = 0.26wd;     y5 = +0.08ht;
 614         x6 = 0.40wd;     y6 = -0.04ht;
 615         rt x7 = 0.42wd;  top y7 = +0.36ht;
 616         draw z1 .. z2 -- z3 .. z4 -- z5 .. z6 -- z7;
 617 fet_endchar;
 618
 619 % solesmes punctum inclinatum parvum
 620 inclinatum_char("Solesmes punctum inclinatum parvum", "solesmes_incl_parvum",
 621                 "solinclparvumhead",
 622                 true, false, false);
 623
 624 % solesmes punctum auctum ascendens
 625 punctum_char("Solesmes punctum auctum ascendens", "solesmes_auct_asc",
 626              "solauctaschead",
 627              false, false, false, false, false,
 628              true, true, false, false, false, 1.0);
 629
 630 % solesmes punctum auctum descendens
 631 punctum_char("Solesmes punctum auctum descendens", "solesmes_auct_desc",
 632              "solauctdeschead",
 633              false, false, false, false, false,
 634              true, false, false, false, false, 1.0);
 635
 636 % solesmes punctum inclinatum auctum
 637 inclinatum_char("Solesmes punctum incl. auctum", "solesmes_incl_auctum",
 638                 "solpunctuminclinatumauctumhead",
 639                 false, false, true);
 640
 641 % solesmes stropha
 642 inclinatum_char("Solesmes stropha", "solesmes_stropha",
 643                 "solstrophahead",
 644                 false, true, false);
 645
 646 % solesmes stropha aucta
 647 inclinatum_char("Solesmes stropha aucta", "solesmes_stropha_aucta",
 648                 "solstrophaauctahead",
 649                 false, true, true);
 650
 651 % solesmes oriscus
 652 fet_beginchar("Solesmes oriscus", "solesmes_oriscus",
 653         "soloriscushead")
 654         save b_h, a_w;
 655         a_b := 1.54; % b_h*a_b/a_w = wd/ht
 656         b_h := 0.85;
 657         a_w := 1.09;
 658
 659         save a, beta, ht, wd;
 660         ht# = noteheight#;
 661         2beta# = ht# * b_h;
 662         a# = beta# * a_b;
 663         wd# = 2a# / a_w;
 664         black_notehead_width# := wd#;
 665
 666         save convexity;
 667         convexity# = +0.05ht#;
 668
 669         define_pixels(ht, wd, convexity);
 670         pickup pencircle xscaled blot_diameter yscaled 0.50ht;
 671         lft x1 = 0.00wd; y1 = -convexity;
 672         x2 = 0.16wd;     y2 = +convexity;
 673         x3 = 0.33wd;     y3 = -convexity;
 674         rt x4 = 0.50wd;  y4 = +convexity;
 675         draw z1 .. z2 .. z3 .. z4;
 676         set_char_box(0.00wd#, 0.50wd#,
 677                      0.25ht# + convexity#, 0.25ht# + convexity#);
 678 fet_endchar;
 679
 680 %%%%%%%%
 681 %
 682 %
 683 %
 684 % EDITIO MEDICAEA
 685 %
 686 %
 687 %
 688
 689 % inclinatum
 690 fet_beginchar("Ed. Med. inclinatum", "medicaea_inclinatum",
 691         "medinclinatumhead")
 692         draw_diamond_head (1.2staff_space#, 0, 0, 35, false);
 693 fet_endchar;
 694
 695 % parametrized punctum
 696 def punctum_char (expr verbose_name, internal_name, ly_name,
 697         left_up_stem, left_down_stem) =
 698
 699         fet_beginchar(verbose_name, internal_name, ly_name)
 700
 701                 save a, beta, ht, wd;
 702                 ht# = 2 staff_space#;
 703                 wd# = ht#;
 704                 black_notehead_width# := wd#;
 705
 706                 define_pixels(ht, wd);
 707                 pickup pencircle
 708                         xscaled blot_diameter
 709                         yscaled 0.50ht;
 710                 z1 = (0.00wd + blot_diameter/2, 0);
 711                 z2 = (0.4wd - blot_diameter/2, 0);
 712                 draw z1 .. z2;
 713
 714                 pickup pencircle
 715                         xscaled stafflinethickness
 716                         yscaled blot_diameter;
 717
 718                 if left_down_stem:
 719                         z4=(0.00wd + stafflinethickness/2, blot_diameter/2);
 720                         z5=(0.00wd + stafflinethickness/2, - 1.25ht);
 721                         draw z4 .. z5;
 722                         set_char_box(0.0, 0.4wd#, 1.25ht#, 0.25ht#);
 723                 elseif left_up_stem:
 724                         z4=(0.00wd + stafflinethickness/2, blot_diameter/2);
 725                         z5=(0.00wd + stafflinethickness/2, + 1.25ht);
 726                         draw z4 .. z5;
 727                         set_char_box(0.0, 0.4wd#, 0.25ht#, 1.25ht#);
 728                 else:
 729                         set_char_box(0.0, 0.4wd#, 0.25ht#, 0.25ht#);
 730                 fi;
 731
 732         fet_endchar;
 733 enddef;
 734
 735 % punctum
 736 punctum_char("Ed. Med. punctum", "medicaea_punctum", "medpunctumhead",
 737         false, false);
 738
 739 % left up-stemmed punctum
 740 punctum_char("Ed. Med. reverse virga", "medicaea_rvirga", "medrvirgahead",
 741         true, false);
 742
 743 % virga (i.e. left down-stemmed punctum)
 744 punctum_char("Ed. Med. virga", "medicaea_virga", "medvirgahead",
 745         false, true);
 746
 747 %%%%%%%%
 748 %
 749 %
 750 %
 751 % HUFNAGEL
 752 %
 753 %
 754 %
 755
 756 % punctum
 757 % parametrized punctum
 758 def punctum_char (expr verbose_name, internal_name, ly_name,
 759         down_stem) =
 760         fet_beginchar(verbose_name, internal_name, ly_name)
 761                 save alpha;
 762                 alpha# = 55;
 763                 draw_diamond_head (staff_space#, 0, 0, alpha#, false);
 764                 if down_stem:
 765                         pickup pencircle
 766                                 xscaled blot_diameter
 767                                 yscaled (0.7*staff_space)
 768                                 rotated -alpha#;
 769                         save za, zb; pair za, zb;
 770                         za = (head_width/2, 0);
 771                         bot zb = (head_width/2, -1.5staff_space);
 772                         draw za -- zb;
 773                         set_char_box (0, head_width#,
 774                                       1.5staff_space#, head_height#/2);
 775                 fi;
 776         fet_endchar;
 777 enddef;
 778
 779 % punctum
 780 punctum_char("Hufnagel punctum", "hufnagel_punctum", "hufpunctumhead", false)
 781
 782 % virga
 783 punctum_char("Hufnagel virga", "hufnagel_virga", "hufvirgahead", true)
 784
 785 % pes lower punctum
 786 fet_beginchar("Hufnagel pes lower punctum", "hufnagel_lpes", "huflpeshead")
 787         save width, height, alpha;
 788         width# = 2*staff_space#;
 789         height# = 0.7*staff_space#;
 790         alpha# = 35;
 791
 792         set_char_box(0, width#, height#/2, height#/2);
 793
 794         pickup pencircle scaled stafflinethickness;
 795         define_pixels(width, height);
 796
 797         rt x3 = -lft x1 = width/2;
 798         y2 = y3 = height/2;
 799         y1 = y4 = -height/2;
 800         tand(alpha#) * (y2 - y1) = x2 - x1 = x3 - x4;
 801
 802         filldraw z1 -- z2 -- z3 -- z4 -- cycle;
 803
 804         currentpicture := currentpicture shifted (width/2, 0);
 805 fet_endchar;
 806
 807 fet_endgroup ("noteheads")