mf/parmesan-clefs.mf

   1 % -*-Fundamental-*-
   2 % parmesan-clefs.mf -- implement ancient clefs
   3 %
   4 % source file of LilyPond's pretty-but-neat music font
   5 %
   6 % (c) 2001--2002 Juergen Reuter <reuter@ipd.uka.de>
   7 %
   8
   9 fet_begingroup ("clefs")
  10
  11
  12 %%%%%%%%
  13 %
  14 %
  15 %
  16 % Editio Vaticana
  17 %
  18 %
  19 %
  20 def draw_vaticana_do_clef(expr exact_center, reduction) =
  21         save reduced_il;
  22
  23         reduced_il# = staff_space# * reduction;
  24
  25         set_char_box(0.4reduced_il#, 0.4reduced_il#, 0, reduced_il#);
  26
  27         define_pixels(reduced_il);
  28
  29         pickup pencircle xscaled stafflinethickness yscaled 0.6reduced_il;
  30
  31         save za, zb, zc, zd, ze, zf;
  32         pair za, zb, zc, zd, ze, zf;
  33
  34         za = exact_center + (-0.0reduced_il, -.45reduced_il);
  35         zb = exact_center + (-0.2reduced_il, -.50reduced_il);
  36         zc = exact_center + (-0.4reduced_il, -.25reduced_il);
  37         zd = exact_center + (-0.4reduced_il, +.25reduced_il);
  38         ze = exact_center + (-0.2reduced_il, +.50reduced_il);
  39         zf = exact_center + (-0.0reduced_il, +.45reduced_il);
  40         draw za .. zb .. zc --  % lower punctum
  41              zd .. ze .. zf;    % upper punctum
  42 enddef;
  43
  44
  45 fet_beginchar("Ed. Vat. do clef", "vaticana_do", "vatdoclef")
  46         if test = 1:
  47                 draw_staff(-1,3, 0.0);
  48         fi;
  49         draw_vaticana_do_clef((0,0), 1.0);
  50 fet_endchar;
  51 fet_beginchar("Ed. Vat. do clef", "vaticana_do_change", "vatcdoclef")
  52         draw_vaticana_do_clef((0,0), 1.0); % no reduction
  53 fet_endchar;
  54
  55
  56 def draw_vaticana_fa_clef(expr exact_center, reduction) =
  57
  58         save reduced_il, z;
  59         reduced_il# = staff_space# * reduction;
  60         define_pixels(reduced_il);
  61
  62         save za, zb, zc, zd, ze;
  63         pair za, zb, zc, zd, ze;
  64
  65         %stem
  66         pickup pencircle scaled stafflinethickness;
  67         xpart za = xpart zb =
  68                 xpart exact_center + 0.4reduced_il;
  69         ypart za = ypart exact_center = ypart zb + 1.5reduced_il;
  70         draw za .. zb;
  71
  72         %left-handed punctum
  73         pickup pencircle xscaled stafflinethickness yscaled 0.5reduced_il;
  74         zc = exact_center +
  75                 (+0.4reduced_il, -0.05reduced_il);
  76         zd = exact_center +
  77                 (+0.2reduced_il, +0.05reduced_il);
  78         ze = exact_center +
  79                 (+0.0reduced_il, +0.00reduced_il);
  80         draw zc .. zd .. ze;
  81
  82         %right-handed puncta as in do clef
  83         draw_vaticana_do_clef(
  84                 exact_center +
  85                 (+0.8reduced_il + 1.25stafflinethickness, 0),
  86                 reduction);
  87
  88         set_char_box(0.5reduced_il#, 1.5reduced_il#, 0, reduced_il#);
  89 enddef;
  90
  91
  92 fet_beginchar("Ed. Vat. fa clef", "vaticana_fa", "vatfaclef")
  93         if test = 1:
  94                 draw_staff(-1,3, 0.0);
  95         fi;
  96         draw_vaticana_fa_clef((0,0), 1.0);
  97 fet_endchar;
  98 fet_beginchar("Ed. Vat. fa clef", "vaticana_fa_change", "vatcfaclef")
  99         draw_vaticana_fa_clef((0,0), 1.0); % no reduction
 100 fet_endchar;
 101
 102 %%%%%%%%
 103 %
 104 %
 105 %
 106 % Editio Medicaea
 107 %
 108 %
 109 %
 110 def draw_medicaea_do_clef(expr exact_center, reduction) =
 111         save reduced_il, reduced_slt;
 112         reduced_il# = staff_space# * reduction;
 113         reduced_slt# = stafflinethickness# * reduction;
 114         define_pixels(reduced_il);
 115         define_pixels(reduced_slt);
 116
 117         save flag_height;
 118         flag_height# = 0.5 reduced_il#;
 119         define_pixels(flag_height);
 120
 121         %lower flag
 122         save za, zb;
 123         pair za, zb;
 124         pickup pencircle xscaled reduced_slt yscaled flag_height;
 125         xpart exact_center
 126                 = xpart za + 0.5 reduced_il
 127                 = xpart zb - 0.5 reduced_il;
 128         ypart za = ypart exact_center - 0.5 flag_height
 129                         - 0.5 (staff_space - reduced_il);
 130         ypart zb = ypart za - reduced_il + flag_height;
 131         draw za .. zb;
 132
 133         %upper flag
 134         save za, zb;
 135         pair za, zb;
 136         pickup pencircle xscaled reduced_slt yscaled flag_height;
 137         xpart exact_center
 138                 = xpart za + 0.5 reduced_il
 139                 = xpart zb - 0.5 reduced_il;
 140         ypart za = ypart exact_center - 0.5 flag_height
 141                         - 0.5 (staff_space - reduced_il)
 142                         + staff_space;
 143         ypart zb = ypart za - reduced_il + flag_height;
 144         draw za .. zb;
 145
 146         %stem
 147         save za, zb;
 148         pair za, zb;
 149         pickup pencircle scaled reduced_slt;
 150         xpart za = xpart zb = xpart exact_center - 0.5 reduced_il;
 151         ypart exact_center
 152                 = ypart za + 1.5 reduced_il
 153                 = ypart zb - 1.5 reduced_il;
 154         draw za .. zb;
 155
 156         set_char_box(0.5reduced_il#, 1.5reduced_il#,
 157                      1.5reduced_il#, 1.5reduced_il#);
 158 enddef;
 159
 160
 161 fet_beginchar("Ed. Med. do clef", "medicaea_do", "meddoclef")
 162         if test = 1:
 163                 draw_staff(-1,3, 0.0);
 164         fi;
 165         draw_medicaea_do_clef((0,0), 1.0);
 166 fet_endchar;
 167 fet_beginchar("Ed. Med. do clef", "medicaea_do_change", "cmeddoclef")
 168         draw_medicaea_do_clef((0,0), .8);
 169 fet_endchar;
 170
 171
 172 def draw_medicaea_fa_clef(expr exact_center, reduction) =
 173         % inspired by Regensburger Edition of Medicaea (1885/86), in:
 174         % MGG, volume 2, col. 1327 ("Choralreform"), fig. 2.
 175
 176         save reduced_il, reduced_slt;
 177         reduced_il# = staff_space# * reduction;
 178         reduced_slt# = stafflinethickness# * reduction;
 179         define_pixels(reduced_il);
 180         define_pixels(reduced_slt);
 181
 182         save za, zb, zc, zd, ze;
 183         pair za, zb, zc, zd, ze;
 184
 185         %stem
 186         pickup pencircle scaled stafflinethickness;
 187         xpart za = xpart zb =
 188                 xpart exact_center + 0.4reduced_il;
 189         ypart za = ypart exact_center = ypart zb + 1.5reduced_il;
 190         draw za -- zb;
 191
 192         %left-handed punctum
 193         pickup pencircle xscaled reduced_slt yscaled reduced_il;
 194         zc = exact_center +
 195                 (+0.4reduced_il, 0);
 196         zd = exact_center +
 197                 (+0.0reduced_il, 0);
 198         draw zc -- zd;
 199
 200         %right-handed puncta as in do clef
 201         draw_medicaea_do_clef(
 202                 exact_center +
 203                 (+1.1reduced_il + 1.25stafflinethickness, 0),
 204                 reduction);
 205
 206         set_char_box(reduced_il#/2, 2.6reduced_il#, 0, reduced_il#);
 207 enddef;
 208
 209
 210 fet_beginchar("Ed. Med. fa clef", "medicaea_fa", "medfaclef")
 211         if test = 1:
 212                 draw_staff(-1,3, 0.0);
 213         fi;
 214         draw_medicaea_fa_clef((0,0), 1.0);
 215 fet_endchar;
 216 fet_beginchar("Ed. Med. fa clef", "medicaea_fa_change", "cmedfaclef")
 217         draw_medicaea_fa_clef((0,0), .8);
 218 fet_endchar;
 219
 220
 221 %%%%%%%%
 222 %
 223 %
 224 %
 225 % Mensural Notation
 226 %
 227 %
 228 %
 229 brevis_wid# := 2 staff_space#;
 230
 231 def draw_brevis(expr exact_center, reduction, small_width, small_height) =
 232         %
 233         % inspired by function draw_brevis of
 234         % feta-bolletjes.mf
 235         %
 236         save reduced_slt, reduced_nht;
 237         save stem_width, head_width;
 238         save serif_size, serif_protrude;
 239         save holeheight, beamheight;
 240
 241         reduced_slt# = stafflinethickness# * reduction;
 242         reduced_nht# = noteheight# * reduction;
 243         stem_width# = 1.4 reduced_slt#;
 244         if small_width:
 245                 head_width# = 0.5brevis_wid# * reduction;
 246         else:
 247                 head_width# = brevis_wid# * reduction;
 248         fi;
 249         if small_height:
 250                 serif_size# = 0.64 reduced_slt#;
 251                 serif_protrude# = 0.96 serif_size#;
 252                 holeheight# = 3 reduced_slt#;
 253                 beamheight# = 0.32(reduced_nht# - holeheight#);
 254         else:
 255                 serif_size# = 1.0 reduced_slt#;
 256                 serif_protrude# = 1.5 serif_size#;
 257                 holeheight# = 3 reduced_slt#;
 258                 beamheight# = 0.5(reduced_nht# - holeheight#);
 259         fi;
 260         define_pixels(reduced_slt);
 261         define_pixels(stem_width);
 262         define_pixels(head_width);
 263         define_pixels(serif_size);
 264         define_pixels(serif_protrude);
 265         define_pixels(beamheight);
 266
 267         penpos1(stem_width, 0);
 268         penpos2(stem_width, 0);
 269         penpos3(beamheight, 90);
 270         penpos4(beamheight, 90);
 271         penpos5(stem_width, 180);
 272
 273         z1l = exact_center;
 274         z2l = z1l + (0, -reduced_slt/2);
 275         z3r = z2r + serif_size*(1,-1);
 276         y4r = y3r;
 277         x4l = x1l + head_width/2;
 278         z5l = z3l + (-serif_size, -serif_protrude);
 279
 280         penlabels(1,2,3,4,5);
 281         fill z1r -- z1l -- z5r{down} .. z5l{up} .. z3l{right}
 282                 -- z4l -- z4r -- z3r{left} .. z2r{up} -- cycle;
 283 enddef;
 284
 285
 286 def draw_neo_mensural_c_clef(expr exact_center, reduction) =
 287         draw_brevis(exact_center, reduction, false, false);
 288
 289         save reduced_il, reduced_slt;
 290         save stem_width;
 291
 292         reduced_il# = staff_space# * reduction;
 293         reduced_slt# = stafflinethickness# * reduction;
 294         stem_width# = 1.4 reduced_slt#;
 295
 296         define_pixels(reduced_il);
 297         define_pixels(reduced_slt);
 298         define_pixels(stem_width);
 299
 300         pickup pencircle xscaled stem_width yscaled blot_diameter;
 301         z6 = exact_center + (stem_width/2, 0);
 302         z7 = z6 + (0, -2reduced_il);
 303         z8 = z6 + (-3reduced_slt, 0);
 304         z9 - z8 = z7 - z6;
 305         draw z6 .. z7;
 306         draw z8 .. z9;
 307
 308         addto currentpicture also currentpicture
 309                 yscaled -1 shifted (0, 2*(ypart exact_center));
 310         addto currentpicture also currentpicture
 311                 xscaled -1 shifted (2x4l,0);
 312
 313         set_char_box(0, 2head_width#,
 314                      6reduced_slt#*reduction, 6reduced_slt#*reduction);
 315 enddef;
 316
 317
 318 fet_beginchar("neo-mensural c clef", "neo_mensural_c", "neomenscclef")
 319         if test = 1:
 320                 draw_staff(-1,3, 0.0);
 321         fi;
 322         draw_neo_mensural_c_clef((0,0), 1.0);
 323 fet_endchar;
 324 fet_beginchar("neo-mensural c clef", "neo_mensural_c_change", "cneomenscclef")
 325         draw_neo_mensural_c_clef((1.3 staff_space#,0), .8);
 326 fet_endchar;
 327
 328
 329 def draw_petrucci_c_clef(expr exact_center, flare_align, reduction) =
 330         % inspired by Josquin Desprez, "Stabat Mater", Libro tertio,
 331         % 1519, printed by Petrucci, in: MGG, volume 7, Table 11.
 332         draw_brevis(exact_center, reduction, true, true);
 333
 334         save half_reduced_il, reduced_il, reduced_slt;
 335         save stem_width, interline;
 336
 337         half_reduced_il# = staff_space# * sqrt(reduction);
 338         reduced_il# = staff_space# * reduction;
 339         reduced_slt# = stafflinethickness# * reduction;
 340         stem_width# = 1.4 reduced_slt#;
 341         interline# = staff_space#;
 342
 343         define_pixels(half_reduced_il);
 344         define_pixels(reduced_il);
 345         define_pixels(reduced_slt);
 346         define_pixels(stem_width);
 347         define_pixels(interline);
 348
 349         addto currentpicture also currentpicture
 350                 yscaled -1 shifted (0, 2*(ypart exact_center) - interline);
 351
 352         addto currentpicture also currentpicture
 353                 xscaled -1 shifted (reduction*2x4l,0);
 354
 355         addto currentpicture also currentpicture
 356                 yscaled -1 shifted (0, 4*(ypart exact_center));
 357
 358         pickup pencircle xscaled stem_width yscaled blot_diameter;
 359
 360         xpart z6 = xpart z7 = xpart exact_center + stem_width/2;
 361         ypart z6 = ypart exact_center +
 362                    min(3.2, 3.2 + 0.2 + flare_align)*half_reduced_il;
 363         ypart z7 = ypart exact_center -
 364                    min(3.2, 3.2 + 0.2 - flare_align)*half_reduced_il;
 365         draw z6 .. z7;
 366
 367         xpart z8 = xpart z9 = reduction*2x4l - xpart exact_center - stem_width/2;
 368         ypart z8 = min(ypart z6 - 0.2*half_reduced_il,
 369                        xpart exact_center + 2.2half_reduced_il);
 370         ypart z9 = max(ypart z7 + 0.2*half_reduced_il,
 371                        xpart exact_center - 2.2half_reduced_il);
 372         draw z8 .. z9;
 373
 374         set_char_box(0, 2head_width#,
 375                      noteheight#*4*reduction, noteheight#*4*reduction);
 376 enddef;
 377
 378
 379 fet_beginchar("petrucci c1 clef", "petrucci_c1", "petruccic1clef")
 380         if test = 1:
 381                 draw_staff(-1,3, 0.0);
 382         fi;
 383         draw_petrucci_c_clef((0,0), +2, 1.0);
 384 fet_endchar;
 385 fet_beginchar("petrucci c1 clef", "petrucci_c1_change", "cpetruccic1clef")
 386         draw_petrucci_c_clef((1.3 staff_space#,0), +2, .8);
 387 fet_endchar;
 388
 389 fet_beginchar("petrucci c2 clef", "petrucci_c2", "petruccic2clef")
 390         if test = 1:
 391                 draw_staff(-1,3, 0.0);
 392         fi;
 393         draw_petrucci_c_clef((0,0), +1, 1.0);
 394 fet_endchar;
 395 fet_beginchar("petrucci c2 clef", "petrucci_c2_change", "cpetruccic2clef")
 396         draw_petrucci_c_clef((1.3 staff_space#,0), +1, .8);
 397 fet_endchar;
 398
 399 fet_beginchar("petrucci c3 clef", "petrucci_c3", "petruccic3clef")
 400         if test = 1:
 401                 draw_staff(-1,3, 0.0);
 402         fi;
 403         draw_petrucci_c_clef((0,0), 0, 1.0);
 404 fet_endchar;
 405 fet_beginchar("petrucci c3 clef", "petrucci_c3_change", "cpetruccic3clef")
 406         draw_petrucci_c_clef((1.3 staff_space#,0), 0, .8);
 407 fet_endchar;
 408
 409 fet_beginchar("petrucci c4 clef", "petrucci_c4", "petruccic4clef")
 410         if test = 1:
 411                 draw_staff(-1,3, 0.0);
 412         fi;
 413         draw_petrucci_c_clef((0,0), -1, 1.0);
 414 fet_endchar;
 415 fet_beginchar("petrucci c4 clef", "petrucci_c4_change", "cpetruccic4clef")
 416         draw_petrucci_c_clef((1.3 staff_space#,0), -1, .8);
 417 fet_endchar;
 418
 419 fet_beginchar("petrucci c5 clef", "petrucci_c5", "petruccic5clef")
 420         if test = 1:
 421                 draw_staff(-1,3, 0.0);
 422         fi;
 423         draw_petrucci_c_clef((0,0), -2, 1.0);
 424 fet_endchar;
 425 fet_beginchar("petrucci c5 clef", "petrucci_c5_change", "cpetruc5iceclef")
 426         draw_petrucci_c_clef((1.3 staff_space#,0), -2, .8);
 427 fet_endchar;
 428
 429
 430 def draw_mensural_c_clef(expr exact_center, reduction) =
 431         % inspired by Ockeghem, "Missa Prolationum", in: MGG, volume
 432         % 9, table 94.
 433         draw_petrucci_c_clef(exact_center, 0, reduction);
 434
 435         addto currentpicture also currentpicture
 436                 shifted (0, -interline);
 437
 438         set_char_box(0, 2head_width#,
 439                      noteheight#*6*reduction, noteheight#*6*reduction);
 440 enddef;
 441
 442
 443 fet_beginchar("mensural c clef", "mensural_c", "menscclef")
 444         if test = 1:
 445                 draw_staff(-1,3, 0.0);
 446         fi;
 447         draw_mensural_c_clef((0,0), 1.0);
 448 fet_endchar;
 449 fet_beginchar("mensural c clef", "mensural_c_change", "cmenscclef")
 450         draw_mensural_c_clef((0,0), .8);
 451 fet_endchar;
 452
 453 def draw_diamond(expr exact_center, reduction) =
 454         save stem_width, reduced_il, reduced_nht, holeheight, beamheight;
 455         save rh_height, rh_width;
 456
 457         stem_width# = 1.4 reduced_slt#;
 458         reduced_il# = staff_space# * reduction;
 459         reduced_nht# = noteheight# * reduction;
 460         holeheight# = 3 reduced_slt#;
 461         beamheight# = 0.4(reduced_nht# - holeheight#);
 462
 463         rh_height# = 1.2reduced_il#;
 464         rh_width# / rh_height# = 0.58; % tan(30)
 465
 466         define_pixels(beamheight);
 467         define_pixels(stem_width);
 468         define_pixels(rh_height);
 469         define_pixels(rh_width);
 470
 471         pickup pencircle
 472                 xscaled beamheight
 473                 yscaled stem_width
 474                 rotated 45;
 475
 476         draw
 477                 exact_center + (-rh_width/2, 0) --
 478                 exact_center + (0, rh_height/2) --
 479                 exact_center + (+rh_width/2, 0) --
 480                 exact_center + (0, -rh_height/2) --
 481                 cycle;
 482 enddef;
 483
 484 def draw_petrucci_f_clef(expr exact_center, reduction) =
 485         % inspired by L'homme arme super voces musicales in Misse
 486         % Josquin, 1502, Petrucci, in: MGG, volume 7, col. 200; also
 487         % inspired by Gaspar van Weerbeke, "Virgo Maria" (1502), in:
 488         % MGG, volume 9, col. 653 ("Motette"), fig. 3.; also by Andr'e
 489         % Campra, "Entr'ee des s'er'enades" (1710), in: MGG, volume 2,
 490         % col. 1649 ("Contredanse"), fig. 2.
 491         %
 492         draw_brevis(exact_center, reduction, true, false);
 493
 494         save reduced_il, reduced_slt;
 495         save stem_width, interline;
 496
 497         reduced_il# = staff_space# * reduction;
 498         reduced_slt# = stafflinethickness# * reduction;
 499         stem_width# = 1.4 reduced_slt#;
 500         interline# = staff_space#;
 501
 502         define_pixels(reduced_il);
 503         define_pixels(reduced_slt);
 504         define_pixels(stem_width);
 505         define_pixels(interline);
 506
 507         addto currentpicture also currentpicture
 508                 yscaled -1 shifted (0, 2*(ypart exact_center));
 509         addto currentpicture also currentpicture
 510                 xscaled -1 shifted (2x4l,0);
 511
 512
 513         % brevis stem
 514         pickup pencircle xscaled stem_width yscaled blot_diameter;
 515         z6 = exact_center + (2x4l - stem_width/2, 0);
 516         z7 = z6 + (0, -4reduced_il);
 517         draw z6 .. z7;
 518
 519         % upper diamond
 520         draw_diamond(exact_center + (1.6interline*reduction, interline/2),
 521                      reduction);
 522         pickup pencircle xscaled stem_width yscaled blot_diameter;
 523         z8 = exact_center +
 524              (1.6interline*reduction + stem_width/2, interline*reduction);
 525         z9 = z8 + (0, 1.5interline*reduction);
 526         draw z8 .. z9; % diamond stem
 527
 528         % lower diamond
 529         draw_diamond(exact_center + (1.6interline*reduction, -interline/2),
 530                      reduction);
 531         pickup pencircle xscaled stem_width yscaled blot_diameter;
 532         z10 = exact_center +
 533               (1.6interline*reduction - stem_width/2, -interline*reduction);
 534         z11 = z10 + (0, -3.5interline*reduction);
 535         draw z10 .. z11; % diamond stem
 536
 537         set_char_box(0, 3head_width#,
 538                      3.5noteheight#*reduction, 1.5noteheight#*reduction);
 539 enddef;
 540
 541
 542 fet_beginchar("petrucci f clef", "petrucci_f", "petruccifclef")
 543         if test = 1:
 544                 draw_staff(-1,3, 0.0);
 545         fi;
 546         draw_petrucci_f_clef((0,0), 1.0);
 547 fet_endchar;
 548 fet_beginchar("petrucci f clef", "petrucci_f_change", "cpetruccifclef")
 549         draw_petrucci_f_clef((0,0), .8);
 550 fet_endchar;
 551
 552
 553 def draw_mensural_f_clef(expr exact_center, reduction) =
 554         %
 555         % inspired by Philippe le Duc, "Dite Signori" (1590), in: MGG,
 556         % volume 3, col. 848 ("Duc"); also by John Dowland, "The First
 557         % Booke of Songes" (1597), in: MGG, volume 3, col. 721
 558         % ("Dowland"), fig. 3.
 559
 560         save reduced_slt, stem_width, reduced_nht, holeheight, beamheight;
 561
 562         reduced_slt# = stafflinethickness# * reduction;
 563         stem_width# = 1.4 reduced_slt#;
 564         reduced_nht# = noteheight# * reduction;
 565         holeheight# = 3 reduced_slt#;
 566         beamheight# = 0.4(reduced_nht# - holeheight#);
 567
 568         define_pixels(beamheight, stem_width, staff_space);
 569
 570         pickup pencircle
 571                 xscaled beamheight
 572                 yscaled stem_width
 573                 rotated 45;
 574
 575         draw
 576                 exact_center + (1.0 staff_space, 0.6 staff_space) --
 577                 exact_center + (1.25 staff_space, 0.4 staff_space);
 578
 579         draw
 580                 exact_center + (1.0 staff_space, -0.4 staff_space) --
 581                 exact_center + (1.25 staff_space, -0.6 staff_space);
 582
 583         draw    halfcircle scaled 1.2 staff_space rotated -90
 584                 shifted (-exact_center + (+0.1 staff_space, 0));
 585
 586         set_char_box(0, 3staff_space#, 3staff_space#, 0);
 587 enddef;
 588
 589 fet_beginchar("mensural f clef", "mensural_f", "mensfclef")
 590         if test = 1:
 591                 draw_staff(-1,3, 0.0);
 592         fi;
 593         draw_mensural_f_clef((0,0), 1.0);
 594 fet_endchar;
 595 fet_beginchar("mensural f clef", "mensural_f_change", "cmensfclef")
 596         draw_mensural_f_clef((0,0), .8);
 597 fet_endchar;
 598
 599
 600 def draw_mensural_g_clef(expr exact_center, reduction) =
 601         %
 602         % inspired by Francisco Guerrero, "Lib. 1.  Missarum" (1566),
 603         % in: MGG, volume 3, col. 858 ("Ducis"); also by Stefano
 604         % Fabri, "Quam speciosa veteranis" (1611), in: MGG, volume 3,
 605         % col. 1698 ("Fabri"); also by Philippus Dulichius,
 606         % "Fasciculus novus ..." (1598), in: MGG, volume 3, col. 919
 607         % ("Dulichius"), fig. 1; also by Noe Faignient, "Ic sal de
 608         % Heer myn God gebenedye" (1568), in: MGG, volume 3, col. 1735
 609         % ("Faignient").
 610         %
 611         % Metafont code partially inspired by Schwabacher 'G' of yswab
 612         % font.
 613
 614         save reduced_il, stem_width, height, width, apex_o, hair;
 615
 616         reduced_il#=staff_space#*reduction;
 617
 618         set_char_box(0.5reduced_il#, 1.5reduced_il#,
 619                      1.5reduced_il#, 1.5reduced_il#);
 620
 621         stem_width# = 0.17 reduced_il#;
 622         height# = 1.5 reduced_il#;
 623         width# = 1.13 reduced_il#;
 624         apex_o# = 0.02 reduced_il#;
 625         hair# =  3 stafflinethickness#;
 626         define_pixels(reduced_il, stem_width, height, width, apex_o, hair);
 627
 628         penpos1(2 stem_width, -142);
 629         z1l = (0.715 width, 0.742 height);
 630         penpos1'(hair, -90);
 631         z1'l = z1r;
 632         penpos2(1.179 stem_width, -142);
 633         z2l = (width, 0.466 height);
 634         penpos3(hair, 77);
 635         z3 = (0.764 width, 0.067 height);
 636         z4 = (0.59 width, -apex_o);
 637         penpos5(1.179 stem_width, 32);
 638         z5l=(0, 0.457 height);
 639         penpos6(hair, -56.5);
 640         z7 = (x4 - 0.843 stem_width, height + apex_o);
 641         z7 - z6l = whatever * dir33.5;
 642         penpos8(1.286 stem_width, -130);
 643         z8r = (0.715 width, 0.742 height) + (-apex_o, apex_o);
 644         z6r - z8r = whatever * (z7 - z8l);
 645         filldraw
 646                 z1'r{dir45} .. z2r{down} .. z3r{dir207} .. z5r{up} ..
 647                 z6r{z7-z6l} & z6r -- z8r -- z8l -- z7 --- z6l ...
 648                 z5l{down} .. z4{right} .. z3l{dir27} .. z2l{up} ..
 649                 z1l{1/3[z6l,z7]-z1l} & z1l -- z1r -- z1'r & cycle
 650                 shifted (-exact_center + (0, -0.75reduced_il));
 651
 652         penpos9(stem_width, 0);
 653         x9r = x4; y9 = 0.3 height;
 654
 655         pickup pencircle
 656                 scaled stem_width
 657                 rotated 45;
 658         draw    z9 -- (z9 + (0, -0.4reduced_il))
 659                 shifted (-exact_center + (0, -0.75reduced_il));
 660
 661         pickup pencircle
 662                 xscaled stem_width
 663                 yscaled hair
 664                 rotated 30;
 665
 666         draw halfcircle
 667                 scaled 0.5 reduced_il
 668                 rotated -90
 669                 shifted z8
 670                 shifted (0, 0.25reduced_il)
 671                 shifted (-exact_center + (0, -0.75reduced_il));
 672
 673         draw halfcircle
 674                 scaled 0.4 reduced_il
 675                 rotated 90
 676                 shifted (z8 + (0, 0.45 reduced_il))
 677                 shifted (0, 0.25reduced_il)
 678                 shifted (-exact_center + (0, -0.75reduced_il));
 679 enddef;
 680
 681
 682 fet_beginchar("mensural g clef", "mensural_g", "mensgclef")
 683         if test = 1:
 684                 draw_staff(-1,3, 0.0);
 685         fi;
 686         draw_mensural_g_clef((0,0), 1.0);
 687 fet_endchar;
 688 fet_beginchar("mensural g clef", "mensural_g_change", "cmensgclef")
 689         draw_mensural_g_clef((0,0), .8);
 690 fet_endchar;
 691
 692
 693
 694 def draw_petrucci_g_clef(expr exact_center, reduction) =
 695         % inspired by Josquin Desprez, "Stabat Mater", Libro tertio,
 696         % 1519, printed by Petrucci, in: MGG, volume 7, Table 11.
 697
 698         set_char_box(0.6 staff_space#, 0.8 staff_space#, 0.6 staff_space#,
 699           4.0 staff_space#);
 700
 701         save reduced_il, reduced_slt;
 702
 703         reduced_il# = staff_space# * reduction;
 704         reduced_slt# = stafflinethickness# * reduction;
 705         define_pixels(reduced_il, reduced_slt);
 706
 707         save za, zb, zc, zd, ze, zf, zg, zh, zi, zj;
 708         pair za, zb, zc, zd, ze, zf, zg, zh, zi, zj;
 709
 710         pickup pencircle
 711                 xscaled 0.50 reduced_slt
 712                 yscaled 0.22 reduced_il
 713                 rotated -35;
 714
 715         za = exact_center + (+0.00 reduced_il, +0.00 reduced_il);
 716         zb = exact_center + (+0.20 reduced_il, +1.20 reduced_il);
 717         zc = exact_center + (-0.10 reduced_il, +2.00 reduced_il);
 718         zd = exact_center + (-0.50 reduced_il, +3.00 reduced_il);
 719         ze = exact_center + (+0.00 reduced_il, +3.70 reduced_il);
 720         zf = exact_center + (+0.20 reduced_il, +3.00 reduced_il);
 721         zg = exact_center + (-0.20 reduced_il, +2.00 reduced_il);
 722         zh = exact_center + (-0.50 reduced_il, +1.70 reduced_il);
 723         zi = exact_center + (-0.80 reduced_il, +0.75 reduced_il);
 724         zj = exact_center + (-0.60 reduced_il, +0.60 reduced_il);
 725
 726         draw za{-1,2} .. zb .. zc .. zd .. ze .. zf .. zg .. zh .. zi .. zj;
 727
 728         save za, zb, zc, zd, ze, zf;
 729         pair za, zb, zc, zd, ze, zf;
 730
 731         pickup pencircle
 732                 xscaled 0.75 reduced_slt
 733                 yscaled 0.33 reduced_il
 734                 rotated -35;
 735
 736         za = exact_center + (+0.25 reduced_il, +0.45 reduced_il);
 737         zb = exact_center + (-0.25 reduced_il, +0.45 reduced_il);
 738         zc = exact_center + (-0.25 reduced_il, -0.45 reduced_il);
 739         zd = exact_center + (+0.25 reduced_il, -0.45 reduced_il);
 740         ze = exact_center + (+0.30 reduced_il, +0.00 reduced_il);
 741         zf = exact_center + (+0.00 reduced_il, +0.00 reduced_il);
 742
 743         draw za .. zb .. zc .. zd .. {up}ze -- zf;
 744 enddef;
 745
 746
 747 fet_beginchar("petrucci g clef", "petrucci_g", "petruccigclef")
 748         if test = 1:
 749                 draw_staff(-1,3, 0.0);
 750         fi;
 751         draw_petrucci_g_clef((0,0), 1.0);
 752 fet_endchar;
 753 fet_beginchar("petrucci g clef", "petrucci_g_change", "cpetruccigclef")
 754         draw_petrucci_g_clef((0,0), .8);
 755 fet_endchar;
 756
 757
 758
 759 %%%%%%%%
 760 %
 761 %
 762 %
 763 % Hufnagel
 764 %
 765 %
 766 %
 767 def draw_hufnagel_do_clef(expr exact_center, reduction) =
 768         %
 769         % inspired by Graduale of Friedrich Zollner (1442), in: MGG,
 770         % volume 9, col. 1413 ("Neustift"), fig. 1.
 771         %
 772         save reduced_il;
 773
 774         reduced_il# = staff_space# * reduction;
 775
 776         define_pixels(reduced_il);
 777
 778         pickup pencircle
 779                 xscaled (0.60reduced_il)
 780                 yscaled (0.10reduced_il)
 781                 rotated 40;
 782         save za, zb, zc, zd, ze, zf;
 783         pair za, zb, zc, zd, ze, zf;
 784
 785         za = exact_center + (+0.30reduced_il, +.45reduced_il);
 786         zb = exact_center + (+0.20reduced_il, +.45reduced_il);
 787         zc = exact_center + (-0.10reduced_il, +.60reduced_il);
 788         zd = exact_center + (-0.40reduced_il, +.45reduced_il);
 789         ze = exact_center + (-0.40reduced_il, -.45reduced_il);
 790         zf = exact_center + (-0.20reduced_il, -.55reduced_il);
 791         draw za .. zb .. zc -- zd -- ze -- zf;
 792
 793         set_char_box(0.5reduced_il#, 0.5reduced_il#, 0, reduced_il#);
 794 enddef;
 795
 796
 797 fet_beginchar("Hufnagel do clef", "hufnagel_do", "hufnageldoclef")
 798         if test = 1:
 799                 draw_staff(-1,3, 0.0);
 800         fi;
 801         draw_hufnagel_do_clef((0,0), 1.0);
 802 fet_endchar;
 803 fet_beginchar("Hufnagel do clef", "hufnagel_do_change", "chufnageldoclef")
 804         draw_hufnagel_do_clef((1.3 staff_space#,0), .8);
 805 fet_endchar;
 806
 807
 808 def draw_hufnagel_fa_clef(expr exact_center, reduction) =
 809         %
 810         % inspired by Bamberger Manuscript (15th century), in:
 811         % MGG, volume 2, table 59.
 812         %
 813         save reduced_il;
 814
 815         reduced_il# = staff_space# * reduction;
 816
 817         define_pixels(reduced_il);
 818
 819         pickup pencircle
 820                 xscaled (0.60reduced_il)
 821                 yscaled (0.10reduced_il)
 822                 rotated 40;
 823         save za, zb, zc, zd, ze, zf;
 824         pair za, zb, zc, zd, ze, zf;
 825
 826         za = exact_center + (+0.30reduced_il, +0.70reduced_il);
 827         zb = exact_center + (+0.20reduced_il, +0.70reduced_il);
 828         zc = exact_center + (-0.10reduced_il, +0.85reduced_il);
 829         zd = exact_center + (-0.40reduced_il, +0.70reduced_il);
 830         ze = exact_center + (-0.40reduced_il, -1.10reduced_il);
 831         draw za .. zb .. zc -- zd -- ze;
 832
 833         save zg, zh, zi, zj;
 834         pair zg, zh, zi, zj;
 835
 836         zg = exact_center + (+0.30reduced_il, -0.05reduced_il);
 837         zh = exact_center + (+0.20reduced_il, -0.05reduced_il);
 838         zi = exact_center + (-0.10reduced_il, +0.10reduced_il);
 839         zj = exact_center + (-0.40reduced_il, -0.05reduced_il);
 840         draw zg .. zh .. zi -- zj;
 841
 842         set_char_box(0.5reduced_il#, 0.5reduced_il#, 0, reduced_il#);
 843 enddef;
 844
 845
 846 fet_beginchar("Hufnagel fa clef", "hufnagel_fa", "hufnagelfaclef")
 847         if test = 1:
 848                 draw_staff(-1,3, 0.0);
 849         fi;
 850         draw_hufnagel_fa_clef((0,0), 1.0);
 851 fet_endchar;
 852 fet_beginchar("Hufnagel fa clef", "hufnagel_fa_change", "chufnagelfaclef")
 853         draw_hufnagel_fa_clef((0,0), .8);
 854 fet_endchar;
 855
 856
 857 def draw_hufnagel_do_fa_clef(expr exact_center, reduction) =
 858         draw_hufnagel_do_clef(exact_center, reduction);
 859         draw_hufnagel_fa_clef(exact_center + (0, -2staff_space), reduction);
 860 enddef;
 861
 862
 863 fet_beginchar("Hufnagel do/fa clef", "hufnagel_do_fa", "hufnageldofaclef")
 864         if test = 1:
 865                 draw_staff(-1,3, 0.0);
 866         fi;
 867         draw_hufnagel_do_fa_clef((0,0), 1.0);
 868 fet_endchar;
 869 fet_beginchar("Hufnagel do/fa clef", "hufnagel_do_fa_change",
 870               "chufnageldofaclef")
 871         draw_hufnagel_do_fa_clef((0,0), .8);
 872 fet_endchar;
 873
 874
 875 fet_endgroup ("clefs")