mf/parmesan-clefs.mf

   1 % -%-Fundamental-%- -*-Metafont-*-
   2 % parmesan-clefs.mf -- implement ancient clefs
   3 %
   4 % source file of LilyPond's pretty-but-neat music font
   5 %
   6 % (c)  2001--2003 Juergen Reuter <reuter@ipd.uka.de>
   7 %
   8
   9 fet_begingroup ("clefs")
  10
  11 %
  12 % character aligment:
  13 %
  14 %   Each clef is associated with a particular pitch: the treble clef
  15 %   with the 'g', the alto clef with the 'c', the bass clef with the
  16 %   'f', etc.  The shape of each clef character defines a vertical
  17 %   position that is assumed to represent this pitch.  For the treble
  18 %   clef, it is the vertical position of the center of the spiral
  19 %   ending that represents the 'g' pitch.  For the bass clef, it is
  20 %   the center between the two fat dots that define the vertical
  21 %   position of the 'f' pitch.  For the alto clef, it is the vertical
  22 %   center of the clef that is aligned with the 'c' pitch.  For each
  23 %   clef character, this center should be vertically aligned with the
  24 %   point (0, 0).  The horizontal alignment of each clef character
  25 %   should be such that the vertical line through the point (0, 0)
  26 %   touches the left-most edge of the clef.
  27 %
  28 %   TODO: document exact_center
  29 %
  30 % set_char_box() conventions:
  31 %
  32 % * breapth: Ignored (as far as I know).  Should be set to 0.
  33 %
  34 % * width: Should match the head's width.
  35 %
  36 % * depth: Should match the bottom edge of the head.  Affects vertical
  37 %   collision handling.
  38 %
  39 % * height: Should match the top edge of the head.  Affects vertical
  40 %   collision handling.
  41 %
  42
  43
  44 %%%%%%%%
  45 %
  46 %
  47 %
  48 % Editio Vaticana
  49 %
  50 %
  51 %
  52 def draw_vaticana_do_clef(expr exact_center, reduction) =
  53         save reduced_il;
  54
  55         reduced_il# = staff_space# * reduction;
  56
  57         set_char_box(0.0reduced_il#, 0.5reduced_il#,
  58                      0.8reduced_il#, 0.8reduced_il#);
  59
  60         define_pixels(reduced_il);
  61
  62         pickup pencircle xscaled 0.6stafflinethickness yscaled 0.6reduced_il;
  63
  64         save za, zb, zc, zd, ze, zf;
  65         pair za, zb, zc, zd, ze, zf;
  66
  67         rt  za = exact_center + (0.50reduced_il, -.45reduced_il);
  68             zb = exact_center + (0.25reduced_il, -.50reduced_il);
  69         lft zc = exact_center + (0.00reduced_il, -.25reduced_il);
  70         lft zd = exact_center + (0.00reduced_il, +.25reduced_il);
  71             ze = exact_center + (0.25reduced_il, +.50reduced_il);
  72         rt  zf = exact_center + (0.50reduced_il, +.45reduced_il);
  73         draw za .. zb .. zc --  % lower punctum
  74              zd .. ze .. zf;    % upper punctum
  75 enddef;
  76
  77
  78 fet_beginchar("Ed. Vat. do clef", "vaticana_do", "vatdoclef")
  79         if test = 1:
  80                 draw_staff(-1,3, 0.0);
  81         fi;
  82         draw_vaticana_do_clef((0,0), 1.0);
  83 fet_endchar;
  84 fet_beginchar("Ed. Vat. do clef", "vaticana_do_change", "vatcdoclef")
  85         draw_vaticana_do_clef((0,0), 1.0); % no reduction
  86 fet_endchar;
  87
  88
  89 def draw_vaticana_fa_clef(expr exact_center, reduction) =
  90
  91         save reduced_il, z;
  92         reduced_il# = staff_space# * reduction;
  93         define_pixels(reduced_il);
  94
  95         save za, zb, zc, zd, ze;
  96         pair za, zb, zc, zd, ze;
  97
  98         %left-handed punctum
  99         pickup pencircle xscaled 0.6stafflinethickness yscaled 0.5reduced_il;
 100         lft za = exact_center + (+0.00reduced_il, +0.00reduced_il);
 101             zb = exact_center + (+0.25reduced_il, +0.05reduced_il);
 102         rt  zc = exact_center + (+0.50reduced_il, -0.05reduced_il);
 103         draw za .. zb .. zc;
 104
 105         %stem
 106         pickup pencircle scaled 0.6stafflinethickness;
 107         xpart zc = xpart zd = xpart ze;
 108         ypart zd = ypart exact_center = bot ypart ze + 1.5reduced_il;
 109         draw zd -- ze;
 110
 111         %right-handed puncta as in do clef
 112         draw_vaticana_do_clef(exact_center + (0.55reduced_il, 0), reduction);
 113
 114         set_char_box(0.0reduced_il#, 1.05reduced_il#,
 115                      1.5reduced_il#, 0.8reduced_il#);
 116 enddef;
 117
 118
 119 fet_beginchar("Ed. Vat. fa clef", "vaticana_fa", "vatfaclef")
 120         if test = 1:
 121                 draw_staff(-1,3, 0.0);
 122         fi;
 123         draw_vaticana_fa_clef((0,0), 1.0);
 124 fet_endchar;
 125 fet_beginchar("Ed. Vat. fa clef", "vaticana_fa_change", "vatcfaclef")
 126         draw_vaticana_fa_clef((0,0), 1.0); % no reduction
 127 fet_endchar;
 128
 129 %%%%%%%%
 130 %
 131 %
 132 %
 133 % Editio Medicaea
 134 %
 135 %
 136 %
 137 def draw_medicaea_do_clef(expr exact_center, reduction) =
 138         save reduced_il, reduced_slt;
 139         reduced_il# = staff_space# * reduction;
 140         reduced_slt# = stafflinethickness# * reduction;
 141         define_pixels(reduced_il);
 142         define_pixels(reduced_slt);
 143
 144         save flag_height;
 145         flag_height# = 0.5 reduced_il#;
 146         define_pixels(flag_height);
 147
 148         %upper flag
 149         save za, zb;
 150         pair za, zb;
 151         pickup pencircle xscaled reduced_slt yscaled flag_height;
 152         xpart exact_center
 153                 = lft xpart za
 154                 = rt xpart zb - reduced_il;
 155         ypart za = ypart exact_center +
 156                 0.5 (reduced_il - flag_height - staff_space);
 157         ypart zb = ypart za - reduced_il + flag_height;
 158         draw za -- zb;
 159
 160         %lower flag
 161         save za, zb;
 162         pair za, zb;
 163         pickup pencircle xscaled reduced_slt yscaled flag_height;
 164         xpart exact_center
 165                 = lft xpart za
 166                 = rt xpart zb - reduced_il;
 167         ypart za = ypart exact_center +
 168                  0.5 (reduced_il - flag_height + staff_space);
 169         ypart zb = ypart za - reduced_il + flag_height;
 170         draw za -- zb;
 171
 172         %stem
 173         save za, zb;
 174         pair za, zb;
 175         pickup pencircle scaled reduced_slt;
 176         lft xpart za = lft xpart zb = xpart exact_center;
 177         ypart exact_center
 178                 = top ypart zb - 1.5 reduced_il
 179                 = bot ypart za + 1.5 reduced_il;
 180         draw za -- zb;
 181
 182         set_char_box(0, 1.0reduced_il#,
 183                      1.5reduced_il#, 1.5reduced_il#);
 184 enddef;
 185
 186
 187 fet_beginchar("Ed. Med. do clef", "medicaea_do", "meddoclef")
 188         if test = 1:
 189                 draw_staff(-1,3, 0.0);
 190         fi;
 191         draw_medicaea_do_clef((0,0), 1.0);
 192 fet_endchar;
 193 fet_beginchar("Ed. Med. do clef", "medicaea_do_change", "cmeddoclef")
 194         draw_medicaea_do_clef((0,0), .8);
 195 fet_endchar;
 196
 197
 198 def draw_medicaea_fa_clef(expr exact_center, reduction) =
 199         % inspired by Regensburger Edition of Medicaea (1885/86), in:
 200         % MGG, volume 2, col. 1327 ("Choralreform"), fig. 2.
 201
 202         save reduced_il, reduced_slt;
 203         reduced_il# = staff_space# * reduction;
 204         reduced_slt# = stafflinethickness# * reduction;
 205         define_pixels(reduced_il);
 206         define_pixels(reduced_slt);
 207
 208         save za, zb, zc, zd, ze;
 209         pair za, zb, zc, zd, ze;
 210
 211         %stem
 212         pickup pencircle scaled stafflinethickness;
 213         xpart za = xpart zb =
 214                 xpart exact_center + 0.4reduced_il;
 215         ypart za = ypart exact_center = bot ypart zb + 1.5reduced_il;
 216         draw za -- zb;
 217
 218         %left-handed punctum
 219         pickup pencircle xscaled reduced_slt yscaled reduced_il;
 220         lft zc = exact_center;
 221         zd = exact_center + (0.4reduced_il, 0);
 222         draw zc -- zd;
 223
 224         %right-handed puncta as in do clef
 225         draw_medicaea_do_clef(exact_center + (0.7reduced_il, 0), reduction);
 226
 227         set_char_box(0, 1.7reduced_il#, 1.5reduced_il#, 1.5reduced_il#);
 228 enddef;
 229
 230
 231 fet_beginchar("Ed. Med. fa clef", "medicaea_fa", "medfaclef")
 232         if test = 1:
 233                 draw_staff(-1,3, 0.0);
 234         fi;
 235         draw_medicaea_fa_clef((0,0), 1.0);
 236 fet_endchar;
 237 fet_beginchar("Ed. Med. fa clef", "medicaea_fa_change", "cmedfaclef")
 238         draw_medicaea_fa_clef((0,0), .8);
 239 fet_endchar;
 240
 241
 242 %%%%%%%%
 243 %
 244 %
 245 %
 246 % Mensural Notation
 247 %
 248 %
 249 %
 250 brevis_wid# := 2 staff_space#;
 251
 252 def draw_brevis(expr exact_center, reduction, small_width, small_height) =
 253         %
 254         % inspired by function draw_brevis of
 255         % feta-bolletjes.mf
 256         %
 257         save reduced_slt, reduced_nht;
 258         save stem_width, head_width;
 259         save serif_size, serif_protrude;
 260         save holeheight, beamheight;
 261
 262         reduced_slt# = stafflinethickness# * reduction;
 263         reduced_nht# = noteheight# * reduction;
 264         stem_width# = 1.4 reduced_slt#;
 265         if small_width:
 266                 head_width# = 0.5brevis_wid# * reduction;
 267         else:
 268                 head_width# = brevis_wid# * reduction;
 269         fi;
 270         if small_height:
 271                 serif_size# = 0.64 reduced_slt#;
 272                 serif_protrude# = 0.96 serif_size#;
 273                 holeheight# = 3 reduced_slt#;
 274                 beamheight# = 0.32(reduced_nht# - holeheight#);
 275         else:
 276                 serif_size# = 1.0 reduced_slt#;
 277                 serif_protrude# = 1.5 serif_size#;
 278                 holeheight# = 3 reduced_slt#;
 279                 beamheight# = 0.5(reduced_nht# - holeheight#);
 280         fi;
 281         define_pixels(reduced_slt);
 282         define_pixels(stem_width);
 283         define_pixels(head_width);
 284         define_pixels(serif_size);
 285         define_pixels(serif_protrude);
 286         define_pixels(beamheight);
 287
 288         penpos1(stem_width, 0);
 289         penpos2(stem_width, 0);
 290         penpos3(beamheight, 90);
 291         penpos4(beamheight, 90);
 292         penpos5(stem_width, 180);
 293
 294         z1l = exact_center;
 295         z2l = z1l + (0, -reduced_slt/2);
 296         z3r = z2r + serif_size*(1,-1);
 297         y4r = y3r;
 298         x4l = x1l + head_width/2;
 299         z5l = z3l + (-serif_size, -serif_protrude);
 300
 301         penlabels(1,2,3,4,5);
 302         fill z1r -- z1l -- z5r{down} .. z5l{up} .. z3l{right}
 303                 -- z4l -- z4r -- z3r{left} .. z2r{up} -- cycle;
 304 enddef;
 305
 306
 307 def draw_neo_mensural_c_clef(expr exact_center, reduction) =
 308         draw_brevis(exact_center, reduction, false, false);
 309
 310         save reduced_il, reduced_slt;
 311         save stem_width;
 312
 313         reduced_il# = staff_space# * reduction;
 314         reduced_slt# = stafflinethickness# * reduction;
 315         stem_width# = 1.4 reduced_slt#;
 316
 317         define_pixels(reduced_il);
 318         define_pixels(reduced_slt);
 319         define_pixels(stem_width);
 320
 321         pickup pencircle xscaled stem_width yscaled blot_diameter;
 322         z6 = exact_center + (stem_width/2, 0);
 323         z7 = z6 + (0, -2reduced_il);
 324         z8 = z6 + (-3reduced_slt, 0);
 325         z9 - z8 = z7 - z6;
 326         draw z6 .. z7;
 327         draw z8 .. z9;
 328
 329         addto currentpicture also currentpicture
 330                 yscaled -1 shifted (0, 2*(ypart exact_center));
 331         addto currentpicture also currentpicture
 332                 xscaled -1 shifted (2x4l,0);
 333
 334         set_char_box(3reduced_slt#, head_width# +3reduced_slt#,
 335                      2reduced_il#, 2reduced_il#);
 336 enddef;
 337
 338
 339 fet_beginchar("neo-mensural c clef", "neo_mensural_c", "neomenscclef")
 340         if test = 1:
 341                 draw_staff(-1,3, 0.0);
 342         fi;
 343         draw_neo_mensural_c_clef((0,0), 1.0);
 344 fet_endchar;
 345 fet_beginchar("neo-mensural c clef", "neo_mensural_c_change", "cneomenscclef")
 346         draw_neo_mensural_c_clef((1.3 staff_space#,0), .8);
 347 fet_endchar;
 348
 349
 350 def draw_petrucci_c_clef(expr exact_center, flare_align, reduction) =
 351         % inspired by Josquin Desprez, "Stabat Mater", Libro tertio,
 352         % 1519, printed by Petrucci, in: MGG, volume 7, Table 11.
 353         draw_brevis(exact_center, reduction, true, true);
 354
 355         save half_reduced_il, reduced_il, reduced_slt;
 356         save stem_width, interline;
 357         save left_depth, left_height;
 358
 359         half_reduced_il# = staff_space# * sqrt(reduction);
 360         reduced_il# = staff_space# * reduction;
 361         reduced_slt# = stafflinethickness# * reduction;
 362         stem_width# = 1.4 reduced_slt#;
 363         interline# = staff_space#;
 364
 365         left_height# = half_reduced_il# * min(3.2, 3.2 + 0.2 + flare_align);
 366         left_depth# = half_reduced_il# * min(3.2, 3.2 + 0.2 - flare_align);
 367
 368         define_pixels(half_reduced_il);
 369         define_pixels(reduced_il);
 370         define_pixels(reduced_slt);
 371         define_pixels(stem_width);
 372         define_pixels(interline);
 373         define_pixels(left_depth, left_height);
 374
 375         addto currentpicture also currentpicture
 376                 yscaled -1 shifted (0, 2*(ypart exact_center) - interline);
 377
 378         addto currentpicture also currentpicture
 379                 xscaled -1 shifted (reduction*2x4l,0);
 380
 381         addto currentpicture also currentpicture
 382                 yscaled -1 shifted (0, 4*(ypart exact_center));
 383
 384         pickup pencircle xscaled stem_width yscaled blot_diameter;
 385
 386         xpart z6 = xpart z7 = xpart exact_center + stem_width/2;
 387         ypart z6 = ypart exact_center + left_height;
 388         ypart z7 = ypart exact_center - left_depth;
 389         draw z6 .. z7;
 390
 391         xpart z8 = xpart z9 = reduction*2x4l - xpart exact_center - stem_width/2;
 392         ypart z8 = min(ypart z6 - 0.2*half_reduced_il,
 393                        xpart exact_center + 2.2half_reduced_il);
 394         ypart z9 = max(ypart z7 + 0.2*half_reduced_il,
 395                        xpart exact_center - 2.2half_reduced_il);
 396         draw z8 .. z9;
 397
 398         set_char_box(0, head_width#, left_depth#, left_height#);
 399 enddef;
 400
 401
 402 fet_beginchar("petrucci c1 clef", "petrucci_c1", "petruccic1clef")
 403         if test = 1:
 404                 draw_staff(-1,3, 0.0);
 405         fi;
 406         draw_petrucci_c_clef((0,0), +2, 1.0);
 407 fet_endchar;
 408 fet_beginchar("petrucci c1 clef", "petrucci_c1_change", "cpetruccic1clef")
 409         draw_petrucci_c_clef((1.3 staff_space#,0), +2, .8);
 410 fet_endchar;
 411
 412 fet_beginchar("petrucci c2 clef", "petrucci_c2", "petruccic2clef")
 413         if test = 1:
 414                 draw_staff(-1,3, 0.0);
 415         fi;
 416         draw_petrucci_c_clef((0,0), +1, 1.0);
 417 fet_endchar;
 418 fet_beginchar("petrucci c2 clef", "petrucci_c2_change", "cpetruccic2clef")
 419         draw_petrucci_c_clef((1.3 staff_space#,0), +1, .8);
 420 fet_endchar;
 421
 422 fet_beginchar("petrucci c3 clef", "petrucci_c3", "petruccic3clef")
 423         if test = 1:
 424                 draw_staff(-1,3, 0.0);
 425         fi;
 426         draw_petrucci_c_clef((0,0), 0, 1.0);
 427 fet_endchar;
 428 fet_beginchar("petrucci c3 clef", "petrucci_c3_change", "cpetruccic3clef")
 429         draw_petrucci_c_clef((1.3 staff_space#,0), 0, .8);
 430 fet_endchar;
 431
 432 fet_beginchar("petrucci c4 clef", "petrucci_c4", "petruccic4clef")
 433         if test = 1:
 434                 draw_staff(-1,3, 0.0);
 435         fi;
 436         draw_petrucci_c_clef((0,0), -1, 1.0);
 437 fet_endchar;
 438 fet_beginchar("petrucci c4 clef", "petrucci_c4_change", "cpetruccic4clef")
 439         draw_petrucci_c_clef((1.3 staff_space#,0), -1, .8);
 440 fet_endchar;
 441
 442 fet_beginchar("petrucci c5 clef", "petrucci_c5", "petruccic5clef")
 443         if test = 1:
 444                 draw_staff(-1,3, 0.0);
 445         fi;
 446         draw_petrucci_c_clef((0,0), -2, 1.0);
 447 fet_endchar;
 448 fet_beginchar("petrucci c5 clef", "petrucci_c5_change", "cpetruc5iceclef")
 449         draw_petrucci_c_clef((1.3 staff_space#,0), -2, .8);
 450 fet_endchar;
 451
 452
 453 def draw_mensural_c_clef(expr exact_center, reduction) =
 454         % inspired by Ockeghem, "Missa Prolationum", in: MGG, volume
 455         % 9, table 94.
 456         draw_petrucci_c_clef(exact_center, 0, reduction);
 457
 458         addto currentpicture also currentpicture
 459                 shifted (0, -interline);
 460
 461         save half_reduced_il;
 462         save left_depth, left_height;
 463
 464         half_reduced_il# = staff_space# * sqrt(reduction);
 465         left_height# = 3.2 * half_reduced_il#;
 466         left_depth# = left_height# + interline#;
 467
 468         set_char_box(0, head_width#, left_depth#, left_height#);
 469 enddef;
 470
 471
 472 fet_beginchar("mensural c clef", "mensural_c", "menscclef")
 473         if test = 1:
 474                 draw_staff(-1,3, 0.0);
 475         fi;
 476         draw_mensural_c_clef((0,0), 1.0);
 477 fet_endchar;
 478 fet_beginchar("mensural c clef", "mensural_c_change", "cmenscclef")
 479         draw_mensural_c_clef((0,0), .8);
 480 fet_endchar;
 481
 482 def draw_diamond(expr exact_center, reduction) =
 483         save stem_width, reduced_il, reduced_nht, holeheight, beamheight;
 484         save rh_height, rh_width;
 485
 486         stem_width# = 1.4 reduced_slt#;
 487         reduced_il# = staff_space# * reduction;
 488         reduced_nht# = noteheight# * reduction;
 489         holeheight# = 3 reduced_slt#;
 490         beamheight# = 0.4(reduced_nht# - holeheight#);
 491
 492         rh_height# = 1.2reduced_il#;
 493         rh_width# / rh_height# = tand(30);
 494
 495         define_pixels(beamheight);
 496         define_pixels(stem_width);
 497         define_pixels(rh_height);
 498         define_pixels(rh_width);
 499
 500         pickup pencircle
 501                 xscaled beamheight
 502                 yscaled stem_width
 503                 rotated 45;
 504
 505         draw
 506                 exact_center + (-rh_width/2, 0) --
 507                 exact_center + (0, rh_height/2) --
 508                 exact_center + (+rh_width/2, 0) --
 509                 exact_center + (0, -rh_height/2) --
 510                 cycle;
 511 enddef;
 512
 513 def draw_petrucci_f_clef(expr exact_center, reduction) =
 514         % inspired by L'homme arme super voces musicales in Misse
 515         % Josquin, 1502, Petrucci, in: MGG, volume 7, col. 200; also
 516         % inspired by Gaspar van Weerbeke, "Virgo Maria" (1502), in:
 517         % MGG, volume 9, col. 653 ("Motette"), fig. 3.; also by Andr'e
 518         % Campra, "Entr'ee des s'er'enades" (1710), in: MGG, volume 2,
 519         % col. 1649 ("Contredanse"), fig. 2.
 520         %
 521         draw_brevis(exact_center, reduction, true, false);
 522
 523         save reduced_il, reduced_slt;
 524         save stem_width, interline;
 525
 526         reduced_il# = staff_space# * reduction;
 527         reduced_slt# = stafflinethickness# * reduction;
 528         stem_width# = 1.4 reduced_slt#;
 529         interline# = staff_space#;
 530
 531         define_pixels(reduced_il);
 532         define_pixels(reduced_slt);
 533         define_pixels(stem_width);
 534         define_pixels(interline);
 535
 536         addto currentpicture also currentpicture
 537                 yscaled -1 shifted (0, 2*(ypart exact_center));
 538         addto currentpicture also currentpicture
 539                 xscaled -1 shifted (2x4l,0);
 540
 541
 542         % brevis stem
 543         pickup pencircle xscaled stem_width yscaled blot_diameter;
 544         z6 = exact_center + (2x4l - stem_width/2, 0);
 545         z7 = z6 + (0, -4reduced_il);
 546         draw z6 .. z7;
 547
 548         % upper diamond
 549         draw_diamond(exact_center + (1.6interline*reduction, interline/2),
 550                      reduction);
 551         pickup pencircle xscaled stem_width yscaled blot_diameter;
 552         z8 = exact_center +
 553              (1.6interline*reduction + stem_width/2, interline*reduction);
 554         z9 = z8 + (0, 1.5interline*reduction);
 555         draw z8 .. z9; % diamond stem
 556
 557         % lower diamond
 558         draw_diamond(exact_center + (1.6interline*reduction, -interline/2),
 559                      reduction);
 560         pickup pencircle xscaled stem_width yscaled blot_diameter;
 561         z10 = exact_center +
 562               (1.6interline*reduction - stem_width/2, -interline*reduction);
 563         z11 = z10 + (0, -3.5interline*reduction);
 564         draw z10 .. z11; % diamond stem
 565
 566         save reduced_il, rh_height, rh_width;
 567         reduced_il# = staff_space# * reduction;
 568         rh_height# = 1.2reduced_il#;
 569         rh_width# / rh_height# = tand(30);
 570         set_char_box(0, 1.6interline#*reduction + 0.5rh_width#,
 571                      4.5*interline#*reduction, 2.5*interline#*reduction);
 572 enddef;
 573
 574
 575 fet_beginchar("petrucci f clef", "petrucci_f", "petruccifclef")
 576         if test = 1:
 577                 draw_staff(-1,3, 0.0);
 578         fi;
 579         draw_petrucci_f_clef((0,0), 1.0);
 580 fet_endchar;
 581 fet_beginchar("petrucci f clef", "petrucci_f_change", "cpetruccifclef")
 582         draw_petrucci_f_clef((0,0), .8);
 583 fet_endchar;
 584
 585
 586 def draw_mensural_f_clef(expr exact_center, reduction) =
 587         %
 588         % inspired by Philippe le Duc, "Dite Signori" (1590), in: MGG,
 589         % volume 3, col. 848 ("Duc"); also by John Dowland, "The First
 590         % Booke of Songes" (1597), in: MGG, volume 3, col. 721
 591         % ("Dowland"), fig. 3.
 592
 593         save reduced_slt, stem_width, reduced_nht, holeheight, beamheight;
 594
 595         reduced_slt# = stafflinethickness# * reduction;
 596         stem_width# = 1.4 reduced_slt#;
 597         reduced_nht# = noteheight# * reduction;
 598         holeheight# = 3 reduced_slt#;
 599         beamheight# = 0.4(reduced_nht# - holeheight#);
 600
 601         define_pixels(beamheight, stem_width, staff_space);
 602
 603         pickup pencircle
 604                 xscaled beamheight
 605                 yscaled stem_width
 606                 rotated 45;
 607
 608         draw
 609                 exact_center + (1.0 staff_space, 0.55 staff_space) --
 610                 exact_center + (1.1 staff_space, 0.45 staff_space);
 611
 612         draw
 613                 exact_center + (1.1 staff_space, -0.55 staff_space) --
 614                 exact_center + (1.1 staff_space, -0.45 staff_space);
 615
 616         draw    halfcircle scaled 1.1 staff_space rotated -90
 617                 shifted (-exact_center + (+0.05 staff_space, 0));
 618
 619         set_char_box(0.5beamheight#, 1.1staff_space# + 0.5beamheight#,
 620                      0.55staff_space# + 0.5stem_width#,
 621                      0.55staff_space# + 0.5stem_width#);
 622 enddef;
 623
 624 fet_beginchar("mensural f clef", "mensural_f", "mensfclef")
 625         if test = 1:
 626                 draw_staff(-1,3, 0.0);
 627         fi;
 628         draw_mensural_f_clef((0,0), 1.0);
 629 fet_endchar;
 630 fet_beginchar("mensural f clef", "mensural_f_change", "cmensfclef")
 631         draw_mensural_f_clef((0,0), .8);
 632 fet_endchar;
 633
 634
 635 def draw_mensural_g_clef(expr exact_center, reduction) =
 636         %
 637         % TODO: Rewrite me!  This clef looks completely awful! --jr
 638         %
 639
 640         %
 641         % inspired by Francisco Guerrero, "Lib. 1.  Missarum" (1566),
 642         % in: MGG, volume 3, col. 858 ("Ducis"); also by Stefano
 643         % Fabri, "Quam speciosa veteranis" (1611), in: MGG, volume 3,
 644         % col. 1698 ("Fabri"); also by Philippus Dulichius,
 645         % "Fasciculus novus ..." (1598), in: MGG, volume 3, col. 919
 646         % ("Dulichius"), fig. 1; also by Noe Faignient, "Ic sal de
 647         % Heer myn God gebenedye" (1568), in: MGG, volume 3, col. 1735
 648         % ("Faignient").
 649         %
 650         % Metafont code partially inspired by Schwabacher 'G' of yswab
 651         % font.
 652
 653         save reduced_il, stem_width, height, width, apex_o, hair;
 654
 655         reduced_il#=staff_space#*reduction;
 656
 657         set_char_box(0.0reduced_il#, 1.2reduced_il#,
 658                      0.8reduced_il#, 1.5reduced_il#);
 659
 660         stem_width# = 0.17 reduced_il#;
 661         height# = 1.5 reduced_il#;
 662         width# = 1.13 reduced_il#;
 663         apex_o# = 0.02 reduced_il#;
 664         hair# =  3 stafflinethickness#;
 665         define_pixels(reduced_il, stem_width, height, width, apex_o, hair);
 666
 667         penpos1(2 stem_width, -142);
 668         z1l = (0.715 width, 0.742 height);
 669         penpos1'(hair, -90);
 670         z1'l = z1r;
 671         penpos2(1.179 stem_width, -142);
 672         z2l = (width, 0.466 height);
 673         penpos3(hair, 77);
 674         z3 = (0.764 width, 0.067 height);
 675         z4 = (0.59 width, -apex_o);
 676         penpos5(1.179 stem_width, 32);
 677         z5l=(0, 0.457 height);
 678         penpos6(hair, -56.5);
 679         z7 = (x4 - 0.843 stem_width, height + apex_o);
 680         z7 - z6l = whatever * dir33.5;
 681         penpos8(1.286 stem_width, -130);
 682         z8r = (0.715 width, 0.742 height) + (-apex_o, apex_o);
 683         z6r - z8r = whatever * (z7 - z8l);
 684         filldraw
 685                 z1'r{dir45} .. z2r{down} .. z3r{dir207} .. z5r{up} ..
 686                 z6r{z7-z6l} & z6r -- z8r -- z8l -- z7 --- z6l ...
 687                 z5l{down} .. z4{right} .. z3l{dir27} .. z2l{up} ..
 688                 z1l{1/3[z6l,z7]-z1l} & z1l -- z1r -- z1'r & cycle
 689                 shifted (-exact_center + (0, -0.75reduced_il));
 690
 691         penpos9(stem_width, 0);
 692         x9r = x4; y9 = 0.3 height;
 693
 694         pickup pencircle
 695                 scaled stem_width
 696                 rotated 45;
 697         draw    z9 -- (z9 + (0, -0.4reduced_il))
 698                 shifted (-exact_center + (0, -0.75reduced_il));
 699
 700         pickup pencircle
 701                 xscaled stem_width
 702                 yscaled hair
 703                 rotated 30;
 704
 705         draw halfcircle
 706                 scaled 0.5 reduced_il
 707                 rotated -90
 708                 shifted z8
 709                 shifted (0, 0.25reduced_il)
 710                 shifted (-exact_center + (0, -0.75reduced_il));
 711
 712         draw halfcircle
 713                 scaled 0.4 reduced_il
 714                 rotated 90
 715                 shifted (z8 + (0, 0.45 reduced_il))
 716                 shifted (0, 0.25reduced_il)
 717                 shifted (-exact_center + (0, -0.75reduced_il));
 718 enddef;
 719
 720
 721 fet_beginchar("mensural g clef", "mensural_g", "mensgclef")
 722         if test = 1:
 723                 draw_staff(-1,3, 0.0);
 724         fi;
 725         draw_mensural_g_clef((0,0), 1.0);
 726 fet_endchar;
 727 fet_beginchar("mensural g clef", "mensural_g_change", "cmensgclef")
 728         draw_mensural_g_clef((0,0), .8);
 729 fet_endchar;
 730
 731
 732
 733 def draw_petrucci_g_clef(expr exact_center, reduction) =
 734         % inspired by Josquin Desprez, "Stabat Mater", Libro tertio,
 735         % 1519, printed by Petrucci, in: MGG, volume 7, Table 11.
 736
 737         save reduced_il, reduced_slt;
 738
 739         reduced_il# = staff_space# * reduction;
 740         reduced_slt# = stafflinethickness# * reduction;
 741         define_pixels(reduced_il, reduced_slt);
 742
 743         set_char_box(0, 1.25 reduced_il#,
 744                      0.65 reduced_il#, 3.80 reduced_il#);
 745
 746         save za, zb, zc, zd, ze, zf, zg, zh, zi, zj;
 747         pair za, zb, zc, zd, ze, zf, zg, zh, zi, zj;
 748
 749         pickup pencircle
 750                 xscaled 0.50 reduced_slt
 751                 yscaled 0.22 reduced_il
 752                 rotated -35;
 753
 754         lft za = exact_center + (0.80 reduced_il, +0.00 reduced_il);
 755         lft zb = exact_center + (1.00 reduced_il, +1.20 reduced_il);
 756         lft zc = exact_center + (0.70 reduced_il, +2.00 reduced_il);
 757         lft zd = exact_center + (0.30 reduced_il, +3.00 reduced_il);
 758         lft ze = exact_center + (0.80 reduced_il, +3.70 reduced_il);
 759         lft zf = exact_center + (1.00 reduced_il, +3.00 reduced_il);
 760         lft zg = exact_center + (0.60 reduced_il, +2.00 reduced_il);
 761         lft zh = exact_center + (0.30 reduced_il, +1.70 reduced_il);
 762         lft zi = exact_center + (0.00 reduced_il, +0.75 reduced_il);
 763         lft zj = exact_center + (0.20 reduced_il, +0.60 reduced_il);
 764
 765         draw za{-1,2} .. zb .. zc .. zd .. ze .. zf .. zg .. zh .. zi .. zj;
 766
 767         save za, zb, zc, zd, ze, zf;
 768         pair za, zb, zc, zd, ze, zf;
 769
 770         pickup pencircle
 771                 xscaled 0.75 reduced_slt
 772                 yscaled 0.33 reduced_il
 773                 rotated -35;
 774
 775         lft za = exact_center + (1.05 reduced_il, +0.45 reduced_il);
 776         lft zb = exact_center + (0.55 reduced_il, +0.45 reduced_il);
 777         lft zc = exact_center + (0.55 reduced_il, -0.45 reduced_il);
 778         lft zd = exact_center + (1.05 reduced_il, -0.45 reduced_il);
 779         lft ze = exact_center + (1.10 reduced_il, +0.00 reduced_il);
 780         lft zf = exact_center + (0.80 reduced_il, +0.00 reduced_il);
 781
 782         draw za .. zb .. zc .. zd .. {up}ze -- zf;
 783 enddef;
 784
 785
 786 fet_beginchar("petrucci g clef", "petrucci_g", "petruccigclef")
 787         if test = 1:
 788                 draw_staff(-1,3, 0.0);
 789         fi;
 790         draw_petrucci_g_clef((0,0), 1.0);
 791 fet_endchar;
 792 fet_beginchar("petrucci g clef", "petrucci_g_change", "cpetruccigclef")
 793         draw_petrucci_g_clef((0,0), .8);
 794 fet_endchar;
 795
 796
 797
 798 %%%%%%%%
 799 %
 800 %
 801 %
 802 % Hufnagel
 803 %
 804 %
 805 %
 806 def draw_hufnagel_do_clef(expr exact_center, reduction) =
 807         %
 808         % inspired by Graduale of Friedrich Zollner (1442), in: MGG,
 809         % volume 9, col. 1413 ("Neustift"), fig. 1.
 810         %
 811         save reduced_il;
 812
 813         reduced_il# = staff_space# * reduction;
 814
 815         define_pixels(reduced_il);
 816
 817         pickup pencircle
 818                 xscaled (0.60reduced_il)
 819                 yscaled (0.10reduced_il)
 820                 rotated 40;
 821         save za, zb, zc, zd, ze, zf;
 822         pair za, zb, zc, zd, ze, zf;
 823
 824         za = exact_center + (+0.30reduced_il, +.45reduced_il);
 825         zb = exact_center + (+0.20reduced_il, +.45reduced_il);
 826         zc = exact_center + (-0.10reduced_il, +.60reduced_il);
 827         zd = exact_center + (-0.40reduced_il, +.45reduced_il);
 828         ze = exact_center + (-0.40reduced_il, -.45reduced_il);
 829         zf = exact_center + (-0.20reduced_il, -.55reduced_il);
 830         draw za .. zb .. zc -- zd -- ze -- zf;
 831
 832         set_char_box(0.60reduced_il#, 0.50reduced_il#,
 833                      0.70reduced_il#, 0.75reduced_il#);
 834 enddef;
 835
 836
 837 fet_beginchar("Hufnagel do clef", "hufnagel_do", "hufnageldoclef")
 838         if test = 1:
 839                 draw_staff(-1,3, 0.0);
 840         fi;
 841         draw_hufnagel_do_clef((0,0), 1.0);
 842 fet_endchar;
 843 fet_beginchar("Hufnagel do clef", "hufnagel_do_change", "chufnageldoclef")
 844         draw_hufnagel_do_clef((1.3 staff_space#,0), .8);
 845 fet_endchar;
 846
 847
 848 def draw_hufnagel_fa_clef(expr exact_center, reduction) =
 849         %
 850         % inspired by Bamberger Manuscript (15th century), in:
 851         % MGG, volume 2, table 59.
 852         %
 853         save reduced_il;
 854
 855         reduced_il# = staff_space# * reduction;
 856
 857         define_pixels(reduced_il);
 858
 859         pickup pencircle
 860                 xscaled (0.60reduced_il)
 861                 yscaled (0.10reduced_il)
 862                 rotated 40;
 863         save za, zb, zc, zd, ze, zf;
 864         pair za, zb, zc, zd, ze, zf;
 865
 866         za = exact_center + (+0.30reduced_il, +0.70reduced_il);
 867         zb = exact_center + (+0.20reduced_il, +0.70reduced_il);
 868         zc = exact_center + (-0.10reduced_il, +0.85reduced_il);
 869         zd = exact_center + (-0.40reduced_il, +0.70reduced_il);
 870         ze = exact_center + (-0.40reduced_il, -1.10reduced_il);
 871         draw za .. zb .. zc -- zd -- ze;
 872
 873         save zg, zh, zi, zj;
 874         pair zg, zh, zi, zj;
 875
 876         zg = exact_center + (+0.30reduced_il, -0.05reduced_il);
 877         zh = exact_center + (+0.20reduced_il, -0.05reduced_il);
 878         zi = exact_center + (-0.10reduced_il, +0.10reduced_il);
 879         zj = exact_center + (-0.40reduced_il, -0.05reduced_il);
 880         draw zg .. zh .. zi -- zj;
 881
 882         set_char_box(0.60reduced_il#, 0.60reduced_il#,
 883                      1.15reduced_il#, 1.00reduced_il#);
 884 enddef;
 885
 886
 887 fet_beginchar("Hufnagel fa clef", "hufnagel_fa", "hufnagelfaclef")
 888         if test = 1:
 889                 draw_staff(-1,3, 0.0);
 890         fi;
 891         draw_hufnagel_fa_clef((0,0), 1.0);
 892 fet_endchar;
 893 fet_beginchar("Hufnagel fa clef", "hufnagel_fa_change", "chufnagelfaclef")
 894         draw_hufnagel_fa_clef((0,0), .8);
 895 fet_endchar;
 896
 897
 898 def draw_hufnagel_do_fa_clef(expr exact_center, reduction) =
 899         draw_hufnagel_do_clef(exact_center, reduction);
 900         draw_hufnagel_fa_clef(exact_center + (0, -2staff_space), reduction);
 901         set_char_box(0.60reduced_il#, 0.60reduced_il#,
 902                      1.15reduced_il# + 2staff_space#, 0.75reduced_il#);
 903 enddef;
 904
 905
 906 fet_beginchar("Hufnagel do/fa clef", "hufnagel_do_fa", "hufnageldofaclef")
 907         if test = 1:
 908                 draw_staff(-1,3, 0.0);
 909         fi;
 910         draw_hufnagel_do_fa_clef((0,0), 1.0);
 911 fet_endchar;
 912 fet_beginchar("Hufnagel do/fa clef", "hufnagel_do_fa_change",
 913               "chufnageldofaclef")
 914         draw_hufnagel_do_fa_clef((0,0), .8);
 915 fet_endchar;
 916
 917
 918 fet_endgroup ("clefs")