mf/parmesan-clefs.mf

   1 % -%-Fundamental-%- -*-Metafont-*-
   2 % parmesan-clefs.mf -- implement ancient clefs
   3 %
   4 % source file of LilyPond's pretty-but-neat music font
   5 %
   6 % (c)  2001--2003 Juergen Reuter <reuter@ipd.uka.de>
   7 %
   8
   9 fet_begingroup ("clefs")
  10
  11 %
  12 % character aligment:
  13 %
  14 %   Each clef is associated with a particular pitch: the treble clef
  15 %   with the 'g', the alto clef with the 'c', the bass clef with the
  16 %   'f', etc.  The shape of each clef character defines a vertical
  17 %   position that is assumed to represent this pitch.  For the treble
  18 %   clef, it is the vertical position of the center of the spiral
  19 %   ending that represents the 'g' pitch.  For the bass clef, it is
  20 %   the center between the two fat dots that define the vertical
  21 %   position of the 'f' pitch.  For the alto clef, it is the vertical
  22 %   center of the clef that is aligned with the 'c' pitch.  For each
  23 %   clef character, this center should be vertically aligned with the
  24 %   point (0, 0).  The horizontal alignment of each clef character
  25 %   should be such that the vertical line through the point (0, 0)
  26 %   touches the left-most edge of the clef.
  27 %
  28 %   TODO: document exact_center
  29 %
  30 % set_char_box() conventions:
  31 %
  32 % * breapth: Ignored (as far as I know).  Should be set to 0.
  33 %
  34 % * width: Should match the head's width.
  35 %
  36 % * depth: Should match the bottom edge of the head.  Affects vertical
  37 %   collision handling.
  38 %
  39 % * height: Should match the top edge of the head.  Affects vertical
  40 %   collision handling.
  41 %
  42
  43
  44 %%%%%%%%
  45 %
  46 %
  47 %
  48 % Editio Vaticana
  49 %
  50 %
  51 %
  52 def draw_vaticana_do_clef(expr exact_center, reduction) =
  53         save reduced_il;
  54
  55         reduced_il# = staff_space# * reduction;
  56
  57         set_char_box(0 - xpart exact_center,
  58                      0.5reduced_il# + xpart exact_center,
  59                      0.8reduced_il# - ypart exact_center,
  60                      0.8reduced_il# + ypart exact_center);
  61
  62         define_pixels(reduced_il);
  63
  64         pickup pencircle xscaled 0.6linethickness yscaled 0.6 reduced_il;
  65
  66         save za, zb, zc, zd, ze, zf;
  67         pair za, zb, zc, zd, ze, zf;
  68
  69         rt  za = exact_center + (0.50reduced_il, -.45reduced_il);
  70             zb = exact_center + (0.25reduced_il, -.50reduced_il);
  71         lft zc = exact_center + (0.00reduced_il, -.25reduced_il);
  72         lft zd = exact_center + (0.00reduced_il, +.25reduced_il);
  73             ze = exact_center + (0.25reduced_il, +.50reduced_il);
  74         rt  zf = exact_center + (0.50reduced_il, +.45reduced_il);
  75         draw za .. zb .. zc --  % lower punctum
  76              zd .. ze .. zf;    % upper punctum
  77 enddef;
  78
  79
  80 fet_beginchar("Ed. Vat. do clef", "vaticana_do", "vatdoclef")
  81         if test = 1:
  82                 draw_staff(-1,3, 0.0);
  83         fi;
  84         draw_vaticana_do_clef((0,0), 1.0);
  85 fet_endchar;
  86 fet_beginchar("Ed. Vat. do clef", "vaticana_do_change", "vatcdoclef")
  87         draw_vaticana_do_clef((0,0), 1.0); % no reduction
  88 fet_endchar;
  89
  90
  91 def draw_vaticana_fa_clef(expr exact_center, reduction) =
  92
  93         save reduced_il, z;
  94         reduced_il# = staff_space# * reduction;
  95         define_pixels(reduced_il);
  96
  97         save za, zb, zc, zd, ze;
  98         pair za, zb, zc, zd, ze;
  99
 100         %left-handed punctum
 101         pickup pencircle xscaled 0.6linethickness yscaled 0.5reduced_il;
 102         lft za = exact_center + (+0.00reduced_il, +0.00reduced_il);
 103             zb = exact_center + (+0.25reduced_il, +0.05reduced_il);
 104         rt  zc = exact_center + (+0.50reduced_il, -0.05reduced_il);
 105         draw za .. zb .. zc;
 106
 107         %stem
 108         pickup pencircle scaled 0.6linethickness;
 109         xpart zc = xpart zd = xpart ze;
 110         ypart zd = ypart exact_center = bot ypart ze + 1.5reduced_il;
 111         draw zd -- ze;
 112
 113         %right-handed puncta as in do clef
 114         draw_vaticana_do_clef(exact_center + (0.55reduced_il#, 0), reduction);
 115
 116         set_char_box(0 - xpart exact_center,
 117                      1.05reduced_il# + xpart exact_center,
 118                      1.5reduced_il# - ypart exact_center,
 119                      0.8reduced_il# + ypart exact_center);
 120 enddef;
 121
 122
 123 fet_beginchar("Ed. Vat. fa clef", "vaticana_fa", "vatfaclef")
 124         if test = 1:
 125                 draw_staff(-1,3, 0.0);
 126         fi;
 127         draw_vaticana_fa_clef((0,0), 1.0);
 128 fet_endchar;
 129 fet_beginchar("Ed. Vat. fa clef", "vaticana_fa_change", "vatcfaclef")
 130         draw_vaticana_fa_clef((0,0), 1.0); % no reduction
 131 fet_endchar;
 132
 133 %%%%%%%%
 134 %
 135 %
 136 %
 137 % Editio Medicaea
 138 %
 139 %
 140 %
 141 def draw_medicaea_do_clef(expr exact_center, reduction) =
 142         save reduced_il, reduced_slt;
 143         reduced_il# = staff_space# * reduction;
 144         reduced_slt# = linethickness# * reduction;
 145         define_pixels(reduced_il);
 146         define_pixels(reduced_slt);
 147
 148         save flag_height;
 149         flag_height# = 0.5 reduced_il#;
 150         define_pixels(flag_height);
 151
 152         %upper flag
 153         save za, zb;
 154         pair za, zb;
 155         pickup pencircle xscaled reduced_slt yscaled flag_height;
 156         xpart exact_center
 157                 = lft xpart za
 158                 = rt xpart zb - reduced_il;
 159         ypart za = ypart exact_center +
 160                 0.5 (reduced_il - flag_height - staff_space);
 161         ypart zb = ypart za - reduced_il + flag_height;
 162         draw za -- zb;
 163
 164         %lower flag
 165         save za, zb;
 166         pair za, zb;
 167         pickup pencircle xscaled reduced_slt yscaled flag_height;
 168         xpart exact_center
 169                 = lft xpart za
 170                 = rt xpart zb - reduced_il;
 171         ypart za = ypart exact_center +
 172                  0.5 (reduced_il - flag_height + staff_space);
 173         ypart zb = ypart za - reduced_il + flag_height;
 174         draw za -- zb;
 175
 176         %stem
 177         save za, zb;
 178         pair za, zb;
 179         pickup pencircle scaled reduced_slt;
 180         lft xpart za = lft xpart zb = xpart exact_center;
 181         ypart exact_center
 182                 = top ypart zb - 1.5 reduced_il
 183                 = bot ypart za + 1.5 reduced_il;
 184         draw za -- zb;
 185
 186         set_char_box(0 - xpart exact_center,
 187                      1.0reduced_il# + xpart exact_center,
 188                      1.5reduced_il# - ypart exact_center,
 189                      1.5reduced_il# + ypart exact_center);
 190 enddef;
 191
 192
 193 fet_beginchar("Ed. Med. do clef", "medicaea_do", "meddoclef")
 194         if test = 1:
 195                 draw_staff(-1,3, 0.0);
 196         fi;
 197         draw_medicaea_do_clef((0,0), 1.0);
 198 fet_endchar;
 199 fet_beginchar("Ed. Med. do clef", "medicaea_do_change", "cmeddoclef")
 200         draw_medicaea_do_clef((0,0), .8);
 201 fet_endchar;
 202
 203
 204 def draw_medicaea_fa_clef(expr exact_center, reduction) =
 205         % inspired by Regensburger Edition of Medicaea (1885/86), in:
 206         % MGG, volume 2, col. 1327 ("Choralreform"), fig. 2.
 207
 208         save reduced_il, reduced_slt;
 209         reduced_il# = staff_space# * reduction;
 210         reduced_slt# = linethickness# * reduction;
 211         define_pixels(reduced_il);
 212         define_pixels(reduced_slt);
 213
 214         save za, zb, zc, zd, ze;
 215         pair za, zb, zc, zd, ze;
 216
 217         %stem
 218         pickup pencircle scaled linethickness;
 219         xpart za = xpart zb =
 220                 xpart exact_center + 0.4reduced_il;
 221         ypart za = ypart exact_center = bot ypart zb + 1.5reduced_il;
 222         draw za -- zb;
 223
 224         %left-handed punctum
 225         pickup pencircle xscaled reduced_slt yscaled reduced_il;
 226         lft zc = exact_center;
 227         zd = exact_center + (0.4reduced_il, 0);
 228         draw zc -- zd;
 229
 230         %right-handed puncta as in do clef
 231         draw_medicaea_do_clef(exact_center + (0.7reduced_il#, 0), reduction);
 232
 233         set_char_box(0 - xpart exact_center,
 234                      1.7reduced_il# + xpart exact_center,
 235                      1.5reduced_il# - ypart exact_center,
 236                      1.5reduced_il# + ypart exact_center);
 237 enddef;
 238
 239
 240 fet_beginchar("Ed. Med. fa clef", "medicaea_fa", "medfaclef")
 241         if test = 1:
 242                 draw_staff(-1,3, 0.0);
 243         fi;
 244         draw_medicaea_fa_clef((0,0), 1.0);
 245 fet_endchar;
 246 fet_beginchar("Ed. Med. fa clef", "medicaea_fa_change", "cmedfaclef")
 247         draw_medicaea_fa_clef((0,0), .8);
 248 fet_endchar;
 249
 250
 251 %%%%%%%%
 252 %
 253 %
 254 %
 255 % Mensural Notation
 256 %
 257 %
 258 %
 259
 260 %
 261 % width:        interval from left end to right end
 262 % height:       interval from bottom of lower beam to top of upper beam
 263 % exact_center: the coordinates of the vertical center point of the
 264 %               left edge.
 265 %
 266 def draw_brevis(expr exact_center, bwidth, bheight, blinethickness) =
 267
 268         save xoffs, yoffs, brevis_width, brevis_height, linethickness;
 269         xoffs# = xpart exact_center;
 270         yoffs# = ypart exact_center;
 271         brevis_width# = bwidth; brevis_height# = bheight;
 272         linethickness# = blinethickness;
 273
 274         save beam_width, beam_height, serif_size, serif_protrude, hole_height;
 275         beam_width# = 1.4 linethickness#;
 276         hole_height# = 3 linethickness#;
 277         2 beam_height# + hole_height# = brevis_height#;
 278         serif_size# = (hole_height# - linethickness#)/2;
 279         serif_protrude# = 1.5 serif_size#;
 280
 281         define_pixels(xoffs, yoffs, brevis_width, brevis_height, linethickness);
 282         define_pixels(beam_width, beam_height, serif_size, serif_protrude);
 283
 284         penpos1(beam_width, 0);
 285         penpos2(beam_width, 0);
 286         penpos3(beam_height, 90);
 287         penpos4(beam_height, 90);
 288         penpos5(beam_width, 180);
 289         z1l = (xoffs, yoffs);
 290         z2l = z1l + (0, -linethickness);
 291         z3r = z2r + serif_size*(1,-1);
 292         y4r = y3r;
 293         x4l = x1l + brevis_width/2;
 294         z5l = z3l + (-serif_size, -serif_protrude);
 295         fill z1r -- z1l -- z5r{down} .. z5l{up} .. z3l{right}
 296                 -- z4l -- z4r -- z3r{left} .. z2r{up} -- cycle;
 297
 298         addto currentpicture also currentpicture
 299                 yscaled -1 shifted (0, 2*yoffs);
 300
 301         pickup pencircle scaled linethickness;
 302         top y6 = yoffs + brevis_height/2;
 303         bot y7 = yoffs - brevis_height/2;
 304         lft x6 = lft x7 = xoffs;
 305         draw z6 -- z7;
 306
 307         addto currentpicture also currentpicture
 308                 xscaled -1 shifted (2xoffs + brevis_width, 0);
 309 enddef;
 310
 311
 312 def draw_neo_mensural_c_clef(expr exact_center, reduction) =
 313         save reduced_il, reduced_slt, stem_width;
 314         reduced_il# = staff_space# * reduction;
 315         reduced_slt# = linethickness# * reduction;
 316         stem_width# = 1.4 reduced_slt#;
 317         define_pixels(reduced_il, reduced_slt, stem_width);
 318
 319         draw_brevis(exact_center + (3reduced_slt#, 0),
 320                     2reduced_il#, reduced_il#, reduced_slt#);
 321
 322         save xoffs, yoffs;
 323         xoffs# = xpart exact_center;
 324         yoffs# = ypart exact_center;
 325         define_pixels(xoffs, yoffs);
 326
 327         pickup pencircle xscaled stem_width yscaled blot_diameter;
 328         lft x8  = lft x9  = xoffs;
 329         lft x10 = lft x11 = lft x8  + 3reduced_slt;
 330         rt  x12 = rt  x13 = lft x10 + 2reduced_il;
 331         rt  x14 = rt  x15 = rt  x12 + 3reduced_slt;
 332         top y9 - bot y8 = 4reduced_il;
 333         top y9 + bot y8 = 2yoffs;
 334         y12 = y14 = y10 = y8; y13 = y15 = y11 = y9;
 335         draw z8 -- z9;
 336         draw z10 -- z11;
 337         draw z12 -- z13;
 338         draw z14 -- z15;
 339
 340         set_char_box(0 - xpart exact_center,
 341                      2reduced_il# + 6reduced_slt# + xpart exact_center,
 342                      2reduced_il# - ypart exact_center,
 343                      2reduced_il# + ypart exact_center);
 344 enddef;
 345
 346
 347 fet_beginchar("neo-mensural c clef", "neo_mensural_c", "neomenscclef")
 348         if test = 1:
 349                 draw_staff(-1,3, 0.0);
 350         fi;
 351         draw_neo_mensural_c_clef((0,0), 1.0);
 352 fet_endchar;
 353 fet_beginchar("neo-mensural c clef", "neo_mensural_c_change", "cneomenscclef")
 354         draw_neo_mensural_c_clef((0,0), .8);
 355 fet_endchar;
 356
 357
 358 def draw_petrucci_c_clef(expr exact_center, flare_align, reduction) =
 359         % inspired by Josquin Desprez, "Stabat Mater", Libro tertio,
 360         % 1519, printed by Petrucci, in: MGG, volume 7, Table 11.
 361         % Also by Petrucci's Canti C, Venedig 1503.  In: MGG, volume
 362         % 9, p. 1681/1682.
 363
 364         save reduced_il, reduced_slt;
 365         reduced_il# = staff_space# * reduction;
 366         reduced_slt# = linethickness# * reduction;
 367         define_pixels(reduced_il);
 368
 369         draw_brevis(exact_center + (0, 0.5staff_space#),
 370                     reduced_il#, reduced_il#, reduced_slt#);
 371
 372         addto currentpicture also currentpicture shifted (0, -staff_space);
 373
 374         save half_reduced_il, left_depth, left_height;
 375         half_reduced_il# = staff_space# * sqrt(reduction);
 376         left_height# = half_reduced_il# * min(3.2, 3.2 + 0.2 + flare_align);
 377         left_depth# = half_reduced_il# * min(3.2, 3.2 + 0.2 - flare_align);
 378
 379         define_pixels(half_reduced_il);
 380         define_pixels(left_depth, left_height);
 381
 382         save xoffs, yoffs;
 383         xoffs# = xpart exact_center;
 384         yoffs# = ypart exact_center;
 385         define_pixels(xoffs, yoffs);
 386
 387         pickup pencircle xscaled 1.4 linethickness yscaled blot_diameter;
 388         lft x8 = lft x9 = xoffs;
 389         top y8 = yoffs + left_height;
 390         bot y9 = yoffs - left_depth;
 391         draw z8 .. z9;
 392
 393         rt x10 = rt x11 = xoffs + brevis_width;
 394         y10 = min(y8 - 0.2*half_reduced_il, yoffs + 2.2half_reduced_il);
 395         y11 = max(y9 + 0.2*half_reduced_il, yoffs - 2.2half_reduced_il);
 396         draw z10 .. z11;
 397
 398         set_char_box(0 - xpart exact_center,
 399                      reduced_il# + xpart exact_center,
 400                      left_depth# - ypart exact_center,
 401                      left_height# + ypart exact_center);
 402 enddef;
 403
 404
 405 fet_beginchar("petrucci c1 clef", "petrucci_c1", "petruccic1clef")
 406         if test = 1:
 407                 draw_staff(-1,3, 0.0);
 408         fi;
 409         draw_petrucci_c_clef((0,0), +2, 1.0);
 410 fet_endchar;
 411 fet_beginchar("petrucci c1 clef", "petrucci_c1_change", "cpetruccic1clef")
 412         draw_petrucci_c_clef((0,0), +2, .8);
 413 fet_endchar;
 414
 415 fet_beginchar("petrucci c2 clef", "petrucci_c2", "petruccic2clef")
 416         if test = 1:
 417                 draw_staff(-1,3, 0.0);
 418         fi;
 419         draw_petrucci_c_clef((0,0), +1, 1.0);
 420 fet_endchar;
 421 fet_beginchar("petrucci c2 clef", "petrucci_c2_change", "cpetruccic2clef")
 422         draw_petrucci_c_clef((0,0), +1, .8);
 423 fet_endchar;
 424
 425 fet_beginchar("petrucci c3 clef", "petrucci_c3", "petruccic3clef")
 426         if test = 1:
 427                 draw_staff(-1,3, 0.0);
 428         fi;
 429         draw_petrucci_c_clef((0,0), 0, 1.0);
 430 fet_endchar;
 431 fet_beginchar("petrucci c3 clef", "petrucci_c3_change", "cpetruccic3clef")
 432         draw_petrucci_c_clef((0,0), 0, .8);
 433 fet_endchar;
 434
 435 fet_beginchar("petrucci c4 clef", "petrucci_c4", "petruccic4clef")
 436         if test = 1:
 437                 draw_staff(-1,3, 0.0);
 438         fi;
 439         draw_petrucci_c_clef((0,0), -1, 1.0);
 440 fet_endchar;
 441 fet_beginchar("petrucci c4 clef", "petrucci_c4_change", "cpetruccic4clef")
 442         draw_petrucci_c_clef((0,0), -1, .8);
 443 fet_endchar;
 444
 445 fet_beginchar("petrucci c5 clef", "petrucci_c5", "petruccic5clef")
 446         if test = 1:
 447                 draw_staff(-1,3, 0.0);
 448         fi;
 449         draw_petrucci_c_clef((0,0), -2, 1.0);
 450 fet_endchar;
 451 fet_beginchar("petrucci c5 clef", "petrucci_c5_change", "cpetruc5iceclef")
 452         draw_petrucci_c_clef((0,0), -2, .8);
 453 fet_endchar;
 454
 455
 456 def draw_mensural_c_clef(expr exact_center, reduction) =
 457         % inspired by Ockeghem, "Missa Prolationum", in: MGG, volume
 458         % 9, table 94.
 459
 460         save reduced_il;
 461         reduced_il# = staff_space# * reduction;
 462         draw_brevis(exact_center + (0, 0.5staff_space#),
 463                     2reduced_il#, 0.8staff_space#, 0.8linethickness#);
 464         define_pixels(reduced_il);
 465         addto currentpicture also currentpicture shifted (0, -staff_space);
 466         addto currentpicture also currentpicture shifted (0, -staff_space);
 467
 468         save half_reduced_il;
 469         half_reduced_il# = staff_space# * sqrt(reduction);
 470         define_pixels(half_reduced_il);
 471
 472         save xoffs, yoffs;
 473         xoffs# = xpart exact_center;
 474         yoffs# = ypart exact_center;
 475         define_pixels(xoffs, yoffs);
 476
 477         pickup pencircle xscaled 1.4 linethickness yscaled blot_diameter;
 478         lft x8 = lft x9 = xoffs;
 479         top y8 = yoffs + 2.2 half_reduced_il;
 480         bot y9 = yoffs - 2.2 half_reduced_il - staff_space;
 481         draw z8 .. z9;
 482
 483         rt x10 = rt x11 = xoffs + brevis_width;
 484         y10 = yoffs + 1.4half_reduced_il;
 485         y11 = yoffs - 1.4half_reduced_il - staff_space;
 486         draw z10 .. z11;
 487
 488         set_char_box(0 - xpart exact_center,
 489                      2reduced_il# + xpart exact_center,
 490                      -yoffs# + 2.2 half_reduced_il# + staff_space# - ypart exact_center,
 491                      yoffs# + 2.2 half_reduced_il# + ypart exact_center);
 492 enddef;
 493
 494
 495 fet_beginchar("mensural c clef", "mensural_c", "menscclef")
 496         if test = 1:
 497                 draw_staff(-1,3, 0.0);
 498         fi;
 499         draw_mensural_c_clef((0,0), 1.0);
 500 fet_endchar;
 501 fet_beginchar("mensural c clef", "mensural_c_change", "cmenscclef")
 502         draw_mensural_c_clef((0,0), .8);
 503 fet_endchar;
 504
 505 def draw_diamond(expr exact_center, reduction) =
 506         save stem_width, reduced_il, reduced_nht, holeheight, beamheight;
 507         save rh_height, rh_width;
 508
 509         stem_width# = 1.4 reduced_slt#;
 510         reduced_il# = staff_space# * reduction;
 511         reduced_nht# = noteheight# * reduction;
 512         holeheight# = 3 reduced_slt#;
 513         beamheight# = 0.4(reduced_nht# - holeheight#);
 514
 515         rh_height# = 1.2reduced_il#;
 516         rh_width# / rh_height# = tand(30);
 517
 518         define_pixels(beamheight);
 519         define_pixels(stem_width);
 520         define_pixels(rh_height);
 521         define_pixels(rh_width);
 522
 523         pickup pencircle
 524                 xscaled beamheight
 525                 yscaled stem_width
 526                 rotated 45;
 527
 528         draw
 529                 exact_center + (-rh_width/2, 0) --
 530                 exact_center + (0, rh_height/2) --
 531                 exact_center + (+rh_width/2, 0) --
 532                 exact_center + (0, -rh_height/2) --
 533                 cycle;
 534 enddef;
 535
 536 def draw_petrucci_f_clef(expr exact_center, reduction) =
 537         % inspired by L'homme arme super voces musicales in Misse
 538         % Josquin, 1502, Petrucci, in: MGG, volume 7, col. 200; also
 539         % inspired by Gaspar van Weerbeke, "Virgo Maria" (1502), in:
 540         % MGG, volume 9, col. 653 ("Motette"), fig. 3.; also by Andr'e
 541         % Campra, "Entr'ee des s'er'enades" (1710), in: MGG, volume 2,
 542         % col. 1649 ("Contredanse"), fig. 2.
 543         %
 544
 545         save reduced_il, reduced_slt;
 546         reduced_il# = staff_space# * reduction;
 547         reduced_slt# = linethickness# * reduction;
 548         define_pixels(reduced_il);
 549         define_pixels(reduced_slt);
 550
 551         draw_brevis(exact_center, reduced_il#, reduced_il#, reduced_slt#);
 552
 553         save stem_width, interline;
 554         stem_width# = 1.4 reduced_slt#;
 555         interline# = staff_space#;
 556         define_pixels(stem_width);
 557         define_pixels(interline);
 558
 559         addto currentpicture also currentpicture
 560                 yscaled -1 shifted (0, 2*(ypart exact_center));
 561         addto currentpicture also currentpicture
 562                 xscaled -1 shifted (2x4l,0);
 563
 564
 565         % brevis stem
 566         pickup pencircle xscaled stem_width yscaled blot_diameter;
 567         rt z8 = exact_center + (reduced_il, 0);
 568         z9 = z8 + (0, -4reduced_il);
 569         draw z8 .. z9;
 570
 571         % upper diamond
 572         draw_diamond(exact_center + (1.6interline*reduction, interline/2),
 573                      reduction);
 574         pickup pencircle xscaled stem_width yscaled blot_diameter;
 575         z10 = exact_center +
 576              (1.6interline*reduction + stem_width/2, interline*reduction);
 577         top z11 = z10 + (0, 1.5interline*reduction);
 578         draw z10 .. z11; % diamond stem
 579
 580         % lower diamond
 581         draw_diamond(exact_center + (1.6interline*reduction, -interline/2),
 582                      reduction);
 583         pickup pencircle xscaled stem_width yscaled blot_diameter;
 584         z12 = exact_center +
 585               (1.6interline*reduction - stem_width/2, -interline*reduction);
 586         bot z13 = z12 + (0, -3.5interline*reduction);
 587         draw z12 .. z13; % diamond stem
 588
 589         save reduced_il, rh_height, rh_width;
 590         reduced_il# = staff_space# * reduction;
 591         rh_height# = 1.2reduced_il#;
 592         rh_width# / rh_height# = tand(30);
 593         set_char_box(0 - xpart exact_center,
 594                      1.6interline#*reduction + 0.5rh_width# + xpart exact_center,
 595                      4.5*interline#*reduction - ypart exact_center,
 596                      2.5*interline#*reduction + ypart exact_center);
 597 enddef;
 598
 599
 600 fet_beginchar("petrucci f clef", "petrucci_f", "petruccifclef")
 601         if test = 1:
 602                 draw_staff(-1,3, 0.0);
 603         fi;
 604         draw_petrucci_f_clef((0,0), 1.0);
 605 fet_endchar;
 606 fet_beginchar("petrucci f clef", "petrucci_f_change", "cpetruccifclef")
 607         draw_petrucci_f_clef((0,0), .8);
 608 fet_endchar;
 609
 610
 611 def draw_mensural_f_clef(expr exact_center, reduction) =
 612         %
 613         % inspired by Philippe le Duc, "Dite Signori" (1590), in: MGG,
 614         % volume 3, col. 848 ("Duc"); also by John Dowland, "The First
 615         % Booke of Songes" (1597), in: MGG, volume 3, col. 721
 616         % ("Dowland"), fig. 3.
 617
 618         save width, reduced_slt, stem_width, dot_diameter;
 619
 620         width# = 1.2staff_space# * reduction;
 621         reduced_slt# = linethickness# * reduction;
 622         stem_width# = 1.4 reduced_slt#;
 623         dot_diameter# = 0.1 reduction * staff_space#;
 624         define_pixels(width, stem_width, staff_space, dot_diameter);
 625
 626         pickup pencircle
 627                 xscaled 0.2width
 628                 yscaled stem_width
 629                 rotated 45;
 630
 631         % half circle
 632         lft z5 = (0, 0);
 633         draw    halfcircle scaled width rotated -90
 634                 shifted (z5-exact_center);
 635
 636
 637         % upper dot
 638         rt x2 = xpart exact_center + width;
 639         top y1 = ypart exact_center + 0.5width;
 640         z2 - z1 = (dot_diameter, -dot_diameter);
 641         draw z1 -- z2;
 642
 643         % lower dot
 644         x3 = x1;
 645         top y1 - bot y4 = width;
 646         z4 - z3 = (dot_diameter, -dot_diameter);
 647         draw z3 -- z4;
 648
 649         set_char_box(0 - xpart exact_center,
 650                      width# + xpart exact_center,
 651                      0.5width# - ypart exact_center,
 652                      0.5width# + ypart exact_center);
 653 enddef;
 654
 655 fet_beginchar("mensural f clef", "mensural_f", "mensfclef")
 656         if test = 1:
 657                 draw_staff(-1,3, 0.0);
 658         fi;
 659         draw_mensural_f_clef((0,0), 1.0);
 660 fet_endchar;
 661 fet_beginchar("mensural f clef", "mensural_f_change", "cmensfclef")
 662         draw_mensural_f_clef((0,0), .8);
 663 fet_endchar;
 664
 665
 666 def draw_mensural_g_clef(expr exact_center, reduction) =
 667         %
 668         % TODO: Rewrite me!  This clef looks completely awful! --jr
 669         %
 670
 671
 672   %
 673   % This code is completely undebuggable.
 674   %
 675   % the shift command is forbidden because (pen)labels come out
 676   % completely wrong
 677   %
 678
 679         %
 680         % inspired by Francisco Guerrero, "Lib. 1.  Missarum" (1566),
 681         % in: MGG, volume 3, col. 858 ("Ducis"); also by Stefano
 682         % Fabri, "Quam speciosa veteranis" (1611), in: MGG, volume 3,
 683         % col. 1698 ("Fabri"); also by Philippus Dulichius,
 684         % "Fasciculus novus ..." (1598), in: MGG, volume 3, col. 919
 685         % ("Dulichius"), fig. 1; also by Noe Faignient, "Ic sal de
 686         % Heer myn God gebenedye" (1568), in: MGG, volume 3, col. 1735
 687         % ("Faignient").
 688         %
 689         % Metafont code partially inspired by Schwabacher 'G' of yswab
 690         % font.
 691
 692         save reduced_il, stem_width, height, width, apex_o, hair;
 693
 694         reduced_il#=staff_space#*reduction;
 695
 696         set_char_box(0 - xpart exact_center,
 697                      1.2reduced_il# + xpart exact_center,
 698                      0.8reduced_il# - ypart exact_center,
 699                      1.5reduced_il# + ypart exact_center);
 700
 701         stem_width# = 0.17 reduced_il#;
 702         height# = 1.5 reduced_il#;
 703         width# = 1.13 reduced_il#;
 704         apex_o# = 0.02 reduced_il#;
 705         hair# =  3 linethickness#;
 706         define_pixels(reduced_il, stem_width, height, width, apex_o, hair);
 707
 708         penpos1(2 stem_width, -142);
 709         z1l = (0.715 width, 0.742 height);
 710         penpos1'(hair, -90);
 711         z1'l = z1r;
 712         penpos2(1.179 stem_width, -142);
 713         z2l = (width, 0.466 height);
 714         penpos3(hair, 77);
 715         z3 = (0.764 width, 0.067 height);
 716         z4 = (0.59 width, -apex_o);
 717         penpos5(1.179 stem_width, 32);
 718         z5l=(0, 0.457 height);
 719         penpos6(hair, -56.5);
 720         z7 = (x4 - 0.843 stem_width, height + apex_o);
 721         z7 - z6l = whatever * dir33.5;
 722         penpos8(1.286 stem_width, -130);
 723         z8r = (0.715 width, 0.742 height) + (-apex_o, apex_o);
 724         z6r - z8r = whatever * (z7 - z8l);
 725         filldraw
 726                 z1'r{dir45} .. z2r{down} .. z3r{dir207} .. z5r{up} ..
 727                 z6r{z7-z6l} & z6r -- z8r -- z8l -- z7 --- z6l ...
 728                 z5l{down} .. z4{right} .. z3l{dir27} .. z2l{up} ..
 729                 z1l{1/3[z6l,z7]-z1l} & z1l -- z1r -- z1'r & cycle
 730                 shifted (-exact_center + (0, -0.75reduced_il));
 731
 732         penpos9(stem_width, 0);
 733         x9r = x4; y9 = 0.3 height;
 734
 735         pickup pencircle
 736                 scaled stem_width
 737                 rotated 45;
 738         draw    z9 -- (z9 + (0, -0.4reduced_il))
 739                 shifted (-exact_center + (0, -0.75reduced_il));
 740
 741         pickup pencircle
 742                 xscaled stem_width
 743                 yscaled hair
 744                 rotated 30;
 745
 746         draw halfcircle
 747                 scaled 0.5 reduced_il
 748                 rotated -90
 749                 shifted z8
 750                 shifted (0, 0.25reduced_il)
 751                 shifted (-exact_center + (0, -0.75reduced_il));
 752
 753         draw halfcircle
 754                 scaled 0.4 reduced_il
 755                 rotated 90
 756                 shifted (z8 + (0, 0.45 reduced_il))
 757                 shifted (0, 0.25reduced_il)
 758                 shifted (-exact_center + (0, -0.75reduced_il));
 759 enddef;
 760
 761
 762 if 0 = 1:
 763   %
 764   % This clef is switched due to path problems  at smaller sizes.
 765   %
 766 fet_beginchar("mensural g clef", "mensural_g", "mensgclef")
 767         if test = 1:
 768                 draw_staff(-1,3, 0.0);
 769         fi;
 770         draw_mensural_g_clef((0,0), 1.0);
 771 fet_endchar;
 772 fet_beginchar("mensural g clef", "mensural_g_change", "cmensgclef")
 773         draw_mensural_g_clef((0,0), .8);
 774 fet_endchar;
 775
 776 fi;
 777
 778
 779 def draw_petrucci_g_clef(expr exact_center, reduction) =
 780         % inspired by Josquin Desprez, "Stabat Mater", Libro tertio,
 781         % 1519, printed by Petrucci, in: MGG, volume 7, Table 11.
 782
 783         save reduced_il, reduced_slt;
 784
 785         reduced_il# = staff_space# * reduction;
 786         reduced_slt# = linethickness# * reduction;
 787         define_pixels(reduced_il, reduced_slt);
 788
 789         set_char_box(0 - xpart exact_center,
 790                      1.25 reduced_il# + xpart exact_center,
 791                      0.65 reduced_il# - ypart exact_center,
 792                      3.80 reduced_il# + ypart exact_center);
 793
 794         save za, zb, zc, zd, ze, zf, zg, zh, zi, zj;
 795         pair za, zb, zc, zd, ze, zf, zg, zh, zi, zj;
 796
 797         pickup pencircle
 798                 xscaled 0.50 reduced_slt
 799                 yscaled 0.22 reduced_il
 800                 rotated -35;
 801
 802         lft za = exact_center + (0.80 reduced_il, +0.00 reduced_il);
 803         lft zb = exact_center + (1.00 reduced_il, +1.20 reduced_il);
 804         lft zc = exact_center + (0.70 reduced_il, +2.00 reduced_il);
 805         lft zd = exact_center + (0.30 reduced_il, +3.00 reduced_il);
 806         lft ze = exact_center + (0.80 reduced_il, +3.70 reduced_il);
 807         lft zf = exact_center + (1.00 reduced_il, +3.00 reduced_il);
 808         lft zg = exact_center + (0.60 reduced_il, +2.00 reduced_il);
 809         lft zh = exact_center + (0.30 reduced_il, +1.70 reduced_il);
 810         lft zi = exact_center + (0.00 reduced_il, +0.75 reduced_il);
 811         lft zj = exact_center + (0.20 reduced_il, +0.60 reduced_il);
 812
 813         draw za{-1,2} .. zb .. zc .. zd .. ze .. zf .. zg .. zh .. zi .. zj;
 814
 815         save za, zb, zc, zd, ze, zf;
 816         pair za, zb, zc, zd, ze, zf;
 817
 818         pickup pencircle
 819                 xscaled 0.75 reduced_slt
 820                 yscaled 0.33 reduced_il
 821                 rotated -35;
 822
 823         lft za = exact_center + (1.05 reduced_il, +0.45 reduced_il);
 824         lft zb = exact_center + (0.55 reduced_il, +0.45 reduced_il);
 825         lft zc = exact_center + (0.55 reduced_il, -0.45 reduced_il);
 826         lft zd = exact_center + (1.05 reduced_il, -0.45 reduced_il);
 827         lft ze = exact_center + (1.10 reduced_il, +0.00 reduced_il);
 828         lft zf = exact_center + (0.80 reduced_il, +0.00 reduced_il);
 829
 830         draw za .. zb .. zc .. zd .. {up}ze -- zf;
 831 enddef;
 832
 833
 834 fet_beginchar("petrucci g clef", "petrucci_g", "petruccigclef")
 835         if test = 1:
 836                 draw_staff(-1,3, 0.0);
 837         fi;
 838         draw_petrucci_g_clef((0,0), 1.0);
 839 fet_endchar;
 840 fet_beginchar("petrucci g clef", "petrucci_g_change", "cpetruccigclef")
 841         draw_petrucci_g_clef((0,0), .8);
 842 fet_endchar;
 843
 844
 845
 846 %%%%%%%%
 847 %
 848 %
 849 %
 850 % Hufnagel
 851 %
 852 %
 853 %
 854 def draw_hufnagel_do_clef(expr exact_center, reduction) =
 855         %
 856         % inspired by Graduale of Friedrich Zollner (1442), in: MGG,
 857         % volume 9, col. 1413 ("Neustift"), fig. 1.
 858         %
 859         save reduced_il;
 860
 861         reduced_il# = staff_space# * reduction;
 862
 863         define_pixels(reduced_il);
 864
 865         pickup pencircle
 866                 xscaled (0.60reduced_il)
 867                 yscaled (0.10reduced_il)
 868                 rotated 40;
 869         save za, zb, zc, zd, ze, zf;
 870         pair za, zb, zc, zd, ze, zf;
 871
 872         za = exact_center + (0.90reduced_il, +.45reduced_il);
 873         zb = exact_center + (0.80reduced_il, +.45reduced_il);
 874         zc = exact_center + (0.50reduced_il, +.60reduced_il);
 875         zd = exact_center + (0.20reduced_il, +.45reduced_il);
 876         ze = exact_center + (0.20reduced_il, -.45reduced_il);
 877         zf = exact_center + (0.40reduced_il, -.55reduced_il);
 878         draw za .. zb .. zc -- zd -- ze -- zf;
 879
 880         set_char_box(0 - xpart exact_center,
 881                      1.10reduced_il# + xpart exact_center,
 882                      0.70reduced_il# - ypart exact_center,
 883                      0.75reduced_il# + ypart exact_center);
 884 enddef;
 885
 886
 887 fet_beginchar("Hufnagel do clef", "hufnagel_do", "hufnageldoclef")
 888         if test = 1:
 889                 draw_staff(-1,3, 0.0);
 890         fi;
 891         draw_hufnagel_do_clef((0,0), 1.0);
 892 fet_endchar;
 893 fet_beginchar("Hufnagel do clef", "hufnagel_do_change", "chufnageldoclef")
 894         draw_hufnagel_do_clef((0,0), .8);
 895 fet_endchar;
 896
 897
 898 def draw_hufnagel_fa_clef(expr exact_center, reduction) =
 899         %
 900         % inspired by Bamberger Manuscript (15th century), in:
 901         % MGG, volume 2, table 59.
 902         %
 903         save reduced_il;
 904
 905         reduced_il# = staff_space# * reduction;
 906
 907         define_pixels(reduced_il);
 908
 909         pickup pencircle
 910                 xscaled (0.60reduced_il)
 911                 yscaled (0.10reduced_il)
 912                 rotated 40;
 913         save za, zb, zc, zd, ze, zf;
 914         pair za, zb, zc, zd, ze, zf;
 915
 916         za = exact_center + (0.90reduced_il, +0.70reduced_il);
 917         zb = exact_center + (0.80reduced_il, +0.70reduced_il);
 918         zc = exact_center + (0.50reduced_il, +0.85reduced_il);
 919         zd = exact_center + (0.20reduced_il, +0.70reduced_il);
 920         ze = exact_center + (0.20reduced_il, -1.10reduced_il);
 921         draw za .. zb .. zc -- zd -- ze;
 922
 923         save zg, zh, zi, zj;
 924         pair zg, zh, zi, zj;
 925
 926         zg = exact_center + (0.90reduced_il, -0.05reduced_il);
 927         zh = exact_center + (0.80reduced_il, -0.05reduced_il);
 928         zi = exact_center + (0.50reduced_il, +0.10reduced_il);
 929         zj = exact_center + (0.20reduced_il, -0.05reduced_il);
 930         draw zg .. zh .. zi -- zj;
 931
 932         set_char_box(0 - xpart exact_center,
 933                      1.20reduced_il# + xpart exact_center,
 934                      1.15reduced_il# - ypart exact_center,
 935                      1.00reduced_il# + ypart exact_center);
 936 enddef;
 937
 938
 939 fet_beginchar("Hufnagel fa clef", "hufnagel_fa", "hufnagelfaclef")
 940         if test = 1:
 941                 draw_staff(-1,3, 0.0);
 942         fi;
 943         draw_hufnagel_fa_clef((0,0), 1.0);
 944 fet_endchar;
 945 fet_beginchar("Hufnagel fa clef", "hufnagel_fa_change", "chufnagelfaclef")
 946         draw_hufnagel_fa_clef((0,0), .8);
 947 fet_endchar;
 948
 949
 950 def draw_hufnagel_do_fa_clef(expr exact_center, reduction) =
 951         draw_hufnagel_do_clef(exact_center, reduction);
 952         draw_hufnagel_fa_clef(exact_center + (0, -2staff_space#), reduction);
 953         set_char_box(0 - xpart exact_center,
 954                      1.20reduced_il# + xpart exact_center,
 955                      1.15reduced_il# + 2staff_space# - ypart exact_center,
 956                      0.75reduced_il# + ypart exact_center);
 957 enddef;
 958
 959
 960 fet_beginchar("Hufnagel do/fa clef", "hufnagel_do_fa", "hufnageldofaclef")
 961         if test = 1:
 962                 draw_staff(-1,3, 0.0);
 963         fi;
 964         draw_hufnagel_do_fa_clef((0,0), 1.0);
 965 fet_endchar;
 966 fet_beginchar("Hufnagel do/fa clef", "hufnagel_do_fa_change",
 967               "chufnageldofaclef")
 968         draw_hufnagel_do_fa_clef((0,0), .8);
 969 fet_endchar;
 970
 971
 972 fet_endgroup ("clefs")