mf/parmesan-clefs.mf

   1 % feta-klef.mf --  implement Clefs -*-Fundamental-*-
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997--2002 Han-Wen Nienhuys <hanwen@cs.uu.nl>,
   8 % Jan Nieuwenhuizen <janneke@gnu.org>,
   9 % Juergen Reuter <reuter@ipd.uka.de>
  10
  11
  12 fet_begingroup("clefs");
  13
  14 %%%%%%%%
  15 %
  16 %
  17 %
  18 % Editio Vaticana
  19 %
  20 %
  21 %
  22 def draw_vaticana_do_clef(expr exact_center, reduction) =
  23         save reduced_il;
  24
  25         reduced_il# = staff_space# * reduction;
  26
  27         set_char_box(0.4reduced_il#, 0.4reduced_il#, 0, reduced_il#);
  28
  29         define_pixels(reduced_il);
  30
  31         pickup pencircle xscaled stafflinethickness yscaled 0.6reduced_il;
  32
  33         save za, zb, zc, zd, ze, zf;
  34         pair za, zb, zc, zd, ze, zf;
  35
  36         za = exact_center + (-0.0reduced_il, -.45reduced_il);
  37         zb = exact_center + (-0.2reduced_il, -.50reduced_il);
  38         zc = exact_center + (-0.4reduced_il, -.25reduced_il);
  39         zd = exact_center + (-0.4reduced_il, +.25reduced_il);
  40         ze = exact_center + (-0.2reduced_il, +.50reduced_il);
  41         zf = exact_center + (-0.0reduced_il, +.45reduced_il);
  42         draw za .. zb .. zc --  % lower punctum
  43              zd .. ze .. zf;    % upper punctum
  44 enddef;
  45
  46
  47 fet_beginchar("Ed. Vat. do clef", "vaticana_do", "vatdoclef")
  48         if test = 1:
  49                 draw_staff(-1,3, 0.0);
  50         fi;
  51         draw_vaticana_do_clef((0,0), 1.0);
  52 fet_endchar;
  53 fet_beginchar("Ed. Vat. do clef", "vaticana_do_change", "vatcdoclef")
  54         draw_vaticana_do_clef((0,0), 1.0); % no reduction
  55 fet_endchar;
  56
  57
  58 def draw_vaticana_fa_clef(expr exact_center, reduction) =
  59
  60         save reduced_il, z;
  61         reduced_il# = staff_space# * reduction;
  62         define_pixels(reduced_il);
  63
  64         save za, zb, zc, zd, ze;
  65         pair za, zb, zc, zd, ze;
  66
  67         %stem
  68         pickup pencircle scaled stafflinethickness;
  69         xpart za = xpart zb =
  70                 xpart exact_center + 0.4reduced_il;
  71         ypart za = ypart exact_center = ypart zb + 1.5reduced_il;
  72         draw za .. zb;
  73
  74         %left-handed punctum
  75         pickup pencircle xscaled stafflinethickness yscaled 0.5reduced_il;
  76         zc = exact_center +
  77                 (+0.4reduced_il, -0.05reduced_il);
  78         zd = exact_center +
  79                 (+0.2reduced_il, +0.05reduced_il);
  80         ze = exact_center +
  81                 (+0.0reduced_il, +0.00reduced_il);
  82         draw zc .. zd .. ze;
  83
  84         %right-handed puncta as in do clef
  85         draw_vaticana_do_clef(
  86                 exact_center +
  87                 (+0.8reduced_il + 1.25stafflinethickness, 0),
  88                 reduction);
  89
  90         set_char_box(0.5reduced_il#, 1.5reduced_il#, 0, reduced_il#);
  91 enddef;
  92
  93
  94 fet_beginchar("Ed. Vat. fa clef", "vaticana_fa", "vatfaclef")
  95         if test = 1:
  96                 draw_staff(-1,3, 0.0);
  97         fi;
  98         draw_vaticana_fa_clef((0,0), 1.0);
  99 fet_endchar;
 100 fet_beginchar("Ed. Vat. fa clef", "vaticana_fa_change", "vatcfaclef")
 101         draw_vaticana_fa_clef((0,0), 1.0); % no reduction
 102 fet_endchar;
 103
 104 %%%%%%%%
 105 %
 106 %
 107 %
 108 % Editio Medicaea
 109 %
 110 %
 111 %
 112 def draw_medicaea_do_clef(expr exact_center, reduction) =
 113         save reduced_il, reduced_slt;
 114         reduced_il# = staff_space# * reduction;
 115         reduced_slt# = stafflinethickness# * reduction;
 116         define_pixels(reduced_il);
 117         define_pixels(reduced_slt);
 118
 119         save flag_height;
 120         flag_height# = 0.5 reduced_il#;
 121         define_pixels(flag_height);
 122
 123         %lower flag
 124         save za, zb;
 125         pair za, zb;
 126         pickup pencircle xscaled reduced_slt yscaled flag_height;
 127         xpart exact_center
 128                 = xpart za + 0.5 reduced_il
 129                 = xpart zb - 0.5 reduced_il;
 130         ypart za = ypart exact_center - 0.5 flag_height
 131                         - 0.5 (staff_space - reduced_il);
 132         ypart zb = ypart za - reduced_il + flag_height;
 133         draw za .. zb;
 134
 135         %upper flag
 136         save za, zb;
 137         pair za, zb;
 138         pickup pencircle xscaled reduced_slt yscaled flag_height;
 139         xpart exact_center
 140                 = xpart za + 0.5 reduced_il
 141                 = xpart zb - 0.5 reduced_il;
 142         ypart za = ypart exact_center - 0.5 flag_height
 143                         - 0.5 (staff_space - reduced_il)
 144                         + staff_space;
 145         ypart zb = ypart za - reduced_il + flag_height;
 146         draw za .. zb;
 147
 148         %stem
 149         save za, zb;
 150         pair za, zb;
 151         pickup pencircle scaled reduced_slt;
 152         xpart za = xpart zb = xpart exact_center - 0.5 reduced_il;
 153         ypart exact_center
 154                 = ypart za + 1.5 reduced_il
 155                 = ypart zb - 1.5 reduced_il;
 156         draw za .. zb;
 157
 158         set_char_box(0.5reduced_il#, 1.5reduced_il#,
 159                      1.5reduced_il#, 1.5reduced_il#);
 160 enddef;
 161
 162
 163 fet_beginchar("Ed. Med. do clef", "medicaea_do", "meddoclef")
 164         if test = 1:
 165                 draw_staff(-1,3, 0.0);
 166         fi;
 167         draw_medicaea_do_clef((0,0), 1.0);
 168 fet_endchar;
 169 fet_beginchar("Ed. Med. do clef", "medicaea_do_change", "cmeddoclef")
 170         draw_medicaea_do_clef((0,0), .8);
 171 fet_endchar;
 172
 173
 174 def draw_medicaea_fa_clef(expr exact_center, reduction) =
 175         % inspired by Regensburger Edition of Medicaea (1885/86), in:
 176         % MGG, volume 2, col. 1327 ("Choralreform"), fig. 2.
 177
 178         save reduced_il, reduced_slt;
 179         reduced_il# = staff_space# * reduction;
 180         reduced_slt# = stafflinethickness# * reduction;
 181         define_pixels(reduced_il);
 182         define_pixels(reduced_slt);
 183
 184         save za, zb, zc, zd, ze;
 185         pair za, zb, zc, zd, ze;
 186
 187         %stem
 188         pickup pencircle scaled stafflinethickness;
 189         xpart za = xpart zb =
 190                 xpart exact_center + 0.4reduced_il;
 191         ypart za = ypart exact_center = ypart zb + 1.5reduced_il;
 192         draw za -- zb;
 193
 194         %left-handed punctum
 195         pickup pencircle xscaled reduced_slt yscaled reduced_il;
 196         zc = exact_center +
 197                 (+0.4reduced_il, 0);
 198         zd = exact_center +
 199                 (+0.0reduced_il, 0);
 200         draw zc -- zd;
 201
 202         %right-handed puncta as in do clef
 203         draw_medicaea_do_clef(
 204                 exact_center +
 205                 (+1.1reduced_il + 1.25stafflinethickness, 0),
 206                 reduction);
 207
 208         set_char_box(reduced_il#/2, 2.6reduced_il#, 0, reduced_il#);
 209 enddef;
 210
 211
 212 fet_beginchar("Ed. Med. fa clef", "medicaea_fa", "medfaclef")
 213         if test = 1:
 214                 draw_staff(-1,3, 0.0);
 215         fi;
 216         draw_medicaea_fa_clef((0,0), 1.0);
 217 fet_endchar;
 218 fet_beginchar("Ed. Med. fa clef", "medicaea_fa_change", "cmedfaclef")
 219         draw_medicaea_fa_clef((0,0), .8);
 220 fet_endchar;
 221
 222
 223 %%%%%%%%
 224 %
 225 %
 226 %
 227 % Mensural Notation
 228 %
 229 %
 230 %
 231 brevis_wid# := 2 staff_space#;
 232
 233 def draw_brevis(expr exact_center, reduction, small_width, small_height) =
 234         %
 235         % inspired by function draw_brevis of
 236         % feta-bolletjes.mf
 237         %
 238         save reduced_slt, reduced_nht;
 239         save stem_width, head_width;
 240         save serif_size, serif_protrude;
 241         save holeheight, beamheight;
 242
 243         reduced_slt# = stafflinethickness# * reduction;
 244         reduced_nht# = noteheight# * reduction;
 245         stem_width# = 1.4 reduced_slt#;
 246         if small_width:
 247                 head_width# = 0.5brevis_wid# * reduction;
 248         else:
 249                 head_width# = brevis_wid# * reduction;
 250         fi;
 251         if small_height:
 252                 serif_size# = 0.64 reduced_slt#;
 253                 serif_protrude# = 0.96 serif_size#;
 254                 holeheight# = 3 reduced_slt#;
 255                 beamheight# = 0.32(reduced_nht# - holeheight#);
 256         else:
 257                 serif_size# = 1.0 reduced_slt#;
 258                 serif_protrude# = 1.5 serif_size#;
 259                 holeheight# = 3 reduced_slt#;
 260                 beamheight# = 0.5(reduced_nht# - holeheight#);
 261         fi;
 262         define_pixels(reduced_slt);
 263         define_pixels(stem_width);
 264         define_pixels(head_width);
 265         define_pixels(serif_size);
 266         define_pixels(serif_protrude);
 267         define_pixels(beamheight);
 268
 269         penpos1(stem_width, 0);
 270         penpos2(stem_width, 0);
 271         penpos3(beamheight, 90);
 272         penpos4(beamheight, 90);
 273         penpos5(stem_width, 180);
 274
 275         z1l = exact_center;
 276         z2l = z1l + (0, -reduced_slt/2);
 277         z3r = z2r + serif_size*(1,-1);
 278         y4r = y3r;
 279         x4l = x1l + head_width/2;
 280         z5l = z3l + (-serif_size, -serif_protrude);
 281
 282         penlabels(1,2,3,4,5);
 283         fill z1r -- z1l -- z5r{down} .. z5l{up} .. z3l{right}
 284                 -- z4l -- z4r -- z3r{left} .. z2r{up} -- cycle;
 285 enddef;
 286
 287
 288 def draw_neo_mensural_c_clef(expr exact_center, reduction) =
 289         draw_brevis(exact_center, reduction, false, false);
 290
 291         save reduced_il, reduced_slt;
 292         save stem_width;
 293
 294         reduced_il# = staff_space# * reduction;
 295         reduced_slt# = stafflinethickness# * reduction;
 296         stem_width# = 1.4 reduced_slt#;
 297
 298         define_pixels(reduced_il);
 299         define_pixels(reduced_slt);
 300         define_pixels(stem_width);
 301
 302         pickup pencircle xscaled stem_width yscaled blot_diameter;
 303         z6 = exact_center + (stem_width/2, 0);
 304         z7 = z6 + (0, -2reduced_il);
 305         z8 = z6 + (-3reduced_slt, 0);
 306         z9 - z8 = z7 - z6;
 307         draw z6 .. z7;
 308         draw z8 .. z9;
 309
 310         addto currentpicture also currentpicture
 311                 yscaled -1 shifted (0, 2*(ypart exact_center));
 312         addto currentpicture also currentpicture
 313                 xscaled -1 shifted (2x4l,0);
 314
 315         set_char_box(0, 2head_width#,
 316                      6reduced_slt#*reduction, 6reduced_slt#*reduction);
 317 enddef;
 318
 319
 320 fet_beginchar("neo-mensural c clef", "neo_mensural_c", "neomenscclef")
 321         if test = 1:
 322                 draw_staff(-1,3, 0.0);
 323         fi;
 324         draw_neo_mensural_c_clef((0,0), 1.0);
 325 fet_endchar;
 326 fet_beginchar("neo-mensural c clef", "neo_mensural_c_change", "cneomenscclef")
 327         draw_neo_mensural_c_clef((1.3 staff_space#,0), .8);
 328 fet_endchar;
 329
 330
 331 def draw_petrucci_c_clef(expr exact_center, reduction) =
 332         % inspired by Josquin Desprez, "Stabat Mater", Libro tertio,
 333         % 1519, printed by Petrucci, in: MGG, volume 7, Table 11.
 334         draw_brevis(exact_center, reduction, true, true);
 335
 336         save reduced_il, reduced_slt;
 337         save stem_width, interline;
 338
 339         reduced_il# = staff_space# * reduction;
 340         reduced_slt# = stafflinethickness# * reduction;
 341         stem_width# = 1.4 reduced_slt#;
 342         interline# = staff_space#;
 343
 344         define_pixels(reduced_il);
 345         define_pixels(reduced_slt);
 346         define_pixels(stem_width);
 347         define_pixels(interline);
 348
 349         addto currentpicture also currentpicture
 350                 yscaled -1 shifted (0, 2*(ypart exact_center) - interline);
 351
 352         pickup pencircle xscaled stem_width yscaled blot_diameter;
 353         z6 = exact_center + (stem_width/2, 0);
 354         z7 = z6 + (0, -2.2reduced_il);
 355         draw z6 .. z7;
 356
 357         addto currentpicture also currentpicture
 358                 xscaled -1 shifted (2x4l,0);
 359
 360         z8 = exact_center + (stem_width/2, 0);
 361         z9 = z8 + (0, -3.2reduced_il);
 362         draw z8 .. z9;
 363
 364         addto currentpicture also currentpicture
 365                 yscaled -1 shifted (0, 4*(ypart exact_center));
 366
 367         set_char_box(0, 2head_width#,
 368                      noteheight#*4*reduction, noteheight#*4*reduction);
 369 enddef;
 370
 371
 372 fet_beginchar("petrucci c clef", "petrucci_c", "petruccicclef")
 373         if test = 1:
 374                 draw_staff(-1,3, 0.0);
 375         fi;
 376         draw_petrucci_c_clef((0,0), 1.0);
 377 fet_endchar;
 378 fet_beginchar("petrucci c clef", "petrucci_c_change", "cpetruccicclef")
 379         draw_petrucci_c_clef((1.3 staff_space#,0), .8);
 380 fet_endchar;
 381
 382
 383 def draw_mensural_c_clef(expr exact_center, reduction) =
 384         % inspired by Ockeghem, "Missa Prolationum", in: MGG, volume
 385         % 9, table 94.
 386         draw_petrucci_c_clef(exact_center, reduction);
 387
 388         addto currentpicture also currentpicture
 389                 shifted (0, -interline);
 390
 391         set_char_box(0, 2head_width#,
 392                      noteheight#*6*reduction, noteheight#*6*reduction);
 393 enddef;
 394
 395
 396 fet_beginchar("mensural c clef", "mensural_c", "menscclef")
 397         if test = 1:
 398                 draw_staff(-1,3, 0.0);
 399         fi;
 400         draw_mensural_c_clef((0,0), 1.0);
 401 fet_endchar;
 402 fet_beginchar("mensural c clef", "mensural_c_change", "cmenscclef")
 403         draw_mensural_c_clef((0,0), .8);
 404 fet_endchar;
 405
 406 def draw_diamond(expr exact_center, reduction) =
 407         save stem_width, reduced_il, reduced_nht, holeheight, beamheight;
 408         save rh_height, rh_width;
 409
 410         stem_width# = 1.4 reduced_slt#;
 411         reduced_il# = staff_space# * reduction;
 412         reduced_nht# = noteheight# * reduction;
 413         holeheight# = 3 reduced_slt#;
 414         beamheight# = 0.4(reduced_nht# - holeheight#);
 415
 416         rh_height# = 1.2reduced_il#;
 417         rh_width# / rh_height# = 0.58; % tan(30)
 418
 419         define_pixels(beamheight);
 420         define_pixels(stem_width);
 421         define_pixels(rh_height);
 422         define_pixels(rh_width);
 423
 424         pickup pencircle
 425                 xscaled beamheight
 426                 yscaled stem_width
 427                 rotated 45;
 428
 429         draw
 430                 exact_center + (-rh_width/2, 0) --
 431                 exact_center + (0, rh_height/2) --
 432                 exact_center + (+rh_width/2, 0) --
 433                 exact_center + (0, -rh_height/2) --
 434                 cycle;
 435 enddef;
 436
 437 def draw_petrucci_f_clef(expr exact_center, reduction) =
 438         % inspired by L'homme arme super voces musicales in Misse
 439         % Josquin, 1502, Petrucci, in: MGG, volume 7, col. 200; also
 440         % inspired by Gaspar van Weerbeke, "Virgo Maria" (1502), in:
 441         % MGG, volume 9, col. 653 ("Motette"), fig. 3.; also by Andr'e
 442         % Campra, "Entr'ee des s'er'enades" (1710), in: MGG, volume 2,
 443         % col. 1649 ("Contredanse"), fig. 2.
 444         %
 445         draw_brevis(exact_center, reduction, true, false);
 446
 447         save reduced_il, reduced_slt;
 448         save stem_width, interline;
 449
 450         reduced_il# = staff_space# * reduction;
 451         reduced_slt# = stafflinethickness# * reduction;
 452         stem_width# = 1.4 reduced_slt#;
 453         interline# = staff_space#;
 454
 455         define_pixels(reduced_il);
 456         define_pixels(reduced_slt);
 457         define_pixels(stem_width);
 458         define_pixels(interline);
 459
 460         addto currentpicture also currentpicture
 461                 yscaled -1 shifted (0, 2*(ypart exact_center));
 462         addto currentpicture also currentpicture
 463                 xscaled -1 shifted (2x4l,0);
 464
 465
 466         % brevis stem
 467         pickup pencircle xscaled stem_width yscaled blot_diameter;
 468         z6 = exact_center + (2x4l - stem_width/2, 0);
 469         z7 = z6 + (0, -4reduced_il);
 470         draw z6 .. z7;
 471
 472         % upper diamond
 473         draw_diamond(exact_center + (1.6interline*reduction, interline/2),
 474                      reduction);
 475         pickup pencircle xscaled stem_width yscaled blot_diameter;
 476         z8 = exact_center +
 477              (1.6interline*reduction + stem_width/2, interline*reduction);
 478         z9 = z8 + (0, 1.5interline*reduction);
 479         draw z8 .. z9; % diamond stem
 480
 481         % lower diamond
 482         draw_diamond(exact_center + (1.6interline*reduction, -interline/2),
 483                      reduction);
 484         pickup pencircle xscaled stem_width yscaled blot_diameter;
 485         z10 = exact_center +
 486               (1.6interline*reduction - stem_width/2, -interline*reduction);
 487         z11 = z10 + (0, -3.5interline*reduction);
 488         draw z10 .. z11; % diamond stem
 489
 490         set_char_box(0, 3head_width#,
 491                      3.5noteheight#*reduction, 1.5noteheight#*reduction);
 492 enddef;
 493
 494
 495 fet_beginchar("petrucci f clef", "petrucci_f", "petruccifclef")
 496         if test = 1:
 497                 draw_staff(-1,3, 0.0);
 498         fi;
 499         draw_petrucci_f_clef((0,0), 1.0);
 500 fet_endchar;
 501 fet_beginchar("petrucci f clef", "petrucci_f_change", "cpetruccifclef")
 502         draw_petrucci_f_clef((0,0), .8);
 503 fet_endchar;
 504
 505
 506 def draw_mensural_f_clef(expr exact_center, reduction) =
 507         %
 508         % inspired by Philippe le Duc, "Dite Signori" (1590), in: MGG,
 509         % volume 3, col. 848 ("Duc"); also by John Dowland, "The First
 510         % Booke of Songes" (1597), in: MGG, volume 3, col. 721
 511         % ("Dowland"), fig. 3.
 512
 513         save reduced_slt, stem_width, reduced_nht, holeheight, beamheight;
 514
 515         reduced_slt# = stafflinethickness# * reduction;
 516         stem_width# = 1.4 reduced_slt#;
 517         reduced_nht# = noteheight# * reduction;
 518         holeheight# = 3 reduced_slt#;
 519         beamheight# = 0.4(reduced_nht# - holeheight#);
 520
 521         define_pixels(beamheight, stem_width, staff_space);
 522
 523         pickup pencircle
 524                 xscaled beamheight
 525                 yscaled stem_width
 526                 rotated 45;
 527
 528         draw
 529                 exact_center + (1.0 staff_space, 0.6 staff_space) --
 530                 exact_center + (1.25 staff_space, 0.4 staff_space);
 531
 532         draw
 533                 exact_center + (1.0 staff_space, -0.4 staff_space) --
 534                 exact_center + (1.25 staff_space, -0.6 staff_space);
 535
 536         draw    halfcircle scaled 1.2 staff_space rotated -90
 537                 shifted (-exact_center + (+0.1 staff_space, 0));
 538
 539         set_char_box(0, 3staff_space#, 3staff_space#, 0);
 540 enddef;
 541
 542 fet_beginchar("mensural f clef", "mensural_f", "mensfclef")
 543         if test = 1:
 544                 draw_staff(-1,3, 0.0);
 545         fi;
 546         draw_mensural_f_clef((0,0), 1.0);
 547 fet_endchar;
 548 fet_beginchar("mensural f clef", "mensural_f_change", "cmensfclef")
 549         draw_mensural_f_clef((0,0), .8);
 550 fet_endchar;
 551
 552
 553 def draw_mensural_g_clef(expr exact_center, reduction) =
 554         %
 555         % inspired by Francisco Guerrero, "Lib. 1.  Missarum" (1566),
 556         % in: MGG, volume 3, col. 858 ("Ducis"); also by Stefano
 557         % Fabri, "Quam speciosa veteranis" (1611), in: MGG, volume 3,
 558         % col. 1698 ("Fabri"); also by Philippus Dulichius,
 559         % "Fasciculus novus ..." (1598), in: MGG, volume 3, col. 919
 560         % ("Dulichius"), fig. 1; also by Noe Faignient, "Ic sal de
 561         % Heer myn God gebenedye" (1568), in: MGG, volume 3, col. 1735
 562         % ("Faignient").
 563         %
 564         % Metafont code partially inspired by Schwabacher 'G' of yswab
 565         % font.
 566
 567         save reduced_il, stem_width, height, width, apex_o, hair;
 568
 569         reduced_il#=staff_space#*reduction;
 570
 571         set_char_box(0.5reduced_il#, 1.5reduced_il#,
 572                      1.5reduced_il#, 1.5reduced_il#);
 573
 574         stem_width# = 0.17 reduced_il#;
 575         height# = 1.5 reduced_il#;
 576         width# = 1.13 reduced_il#;
 577         apex_o# = 0.02 reduced_il#;
 578         hair# =  3 stafflinethickness#;
 579         define_pixels(reduced_il, stem_width, height, width, apex_o, hair);
 580
 581         penpos1(2 stem_width, -142);
 582         z1l = (0.715 width, 0.742 height);
 583         penpos1'(hair, -90);
 584         z1'l = z1r;
 585         penpos2(1.179 stem_width, -142);
 586         z2l = (width, 0.466 height);
 587         penpos3(hair, 77);
 588         z3 = (0.764 width, 0.067 height);
 589         z4 = (0.59 width, -apex_o);
 590         penpos5(1.179 stem_width, 32);
 591         z5l=(0, 0.457 height);
 592         penpos6(hair, -56.5);
 593         z7 = (x4 - 0.843 stem_width, height + apex_o);
 594         z7 - z6l = whatever * dir33.5;
 595         penpos8(1.286 stem_width, -130);
 596         z8r = (0.715 width, 0.742 height) + (-apex_o, apex_o);
 597         z6r - z8r = whatever * (z7 - z8l);
 598         filldraw
 599                 z1'r{dir45} .. z2r{down} .. z3r{dir207} .. z5r{up} ..
 600                 z6r{z7-z6l} & z6r -- z8r -- z8l -- z7 --- z6l ...
 601                 z5l{down} .. z4{right} .. z3l{dir27} .. z2l{up} ..
 602                 z1l{1/3[z6l,z7]-z1l} & z1l -- z1r -- z1'r & cycle
 603                 shifted (-exact_center + (0, -0.75reduced_il));
 604
 605         penpos9(stem_width, 0);
 606         x9r = x4; y9 = 0.3 height;
 607
 608         pickup pencircle
 609                 scaled stem_width
 610                 rotated 45;
 611         draw    z9 -- (z9 + (0, -0.4reduced_il))
 612                 shifted (-exact_center + (0, -0.75reduced_il));
 613
 614         pickup pencircle
 615                 xscaled stem_width
 616                 yscaled hair
 617                 rotated 30;
 618
 619         draw halfcircle
 620                 scaled 0.5 reduced_il
 621                 rotated -90
 622                 shifted z8
 623                 shifted (0, 0.25reduced_il)
 624                 shifted (-exact_center + (0, -0.75reduced_il));
 625
 626         draw halfcircle
 627                 scaled 0.4 reduced_il
 628                 rotated 90
 629                 shifted (z8 + (0, 0.45 reduced_il))
 630                 shifted (0, 0.25reduced_il)
 631                 shifted (-exact_center + (0, -0.75reduced_il));
 632 enddef;
 633
 634
 635 fet_beginchar("mensural g clef", "mensural_g", "mensgclef")
 636         if test = 1:
 637                 draw_staff(-1,3, 0.0);
 638         fi;
 639         draw_mensural_g_clef((0,0), 1.0);
 640 fet_endchar;
 641 fet_beginchar("mensural g clef", "mensural_g_change", "cmensgclef")
 642         draw_mensural_g_clef((0,0), .8);
 643 fet_endchar;
 644
 645
 646
 647 def draw_petrucci_g_clef(expr exact_center, reduction) =
 648         % inspired by Josquin Desprez, "Stabat Mater", Libro tertio,
 649         % 1519, printed by Petrucci, in: MGG, volume 7, Table 11.
 650
 651         set_char_box(0.6 staff_space#, 0.8 staff_space#, 0.6 staff_space#,
 652           4.0 staff_space#);
 653
 654         save reduced_il, reduced_slt;
 655
 656         reduced_il# = staff_space# * reduction;
 657         reduced_slt# = stafflinethickness# * reduction;
 658         define_pixels(reduced_il, reduced_slt);
 659
 660         save za, zb, zc, zd, ze, zf, zg, zh, zi, zj;
 661         pair za, zb, zc, zd, ze, zf, zg, zh, zi, zj;
 662
 663         pickup pencircle
 664                 xscaled 0.50 reduced_slt
 665                 yscaled 0.22 reduced_il
 666                 rotated -35;
 667
 668         za = exact_center + (+0.00 reduced_il, +0.00 reduced_il);
 669         zb = exact_center + (+0.20 reduced_il, +1.20 reduced_il);
 670         zc = exact_center + (-0.10 reduced_il, +2.00 reduced_il);
 671         zd = exact_center + (-0.50 reduced_il, +3.00 reduced_il);
 672         ze = exact_center + (+0.00 reduced_il, +3.70 reduced_il);
 673         zf = exact_center + (+0.20 reduced_il, +3.00 reduced_il);
 674         zg = exact_center + (-0.20 reduced_il, +2.00 reduced_il);
 675         zh = exact_center + (-0.50 reduced_il, +1.70 reduced_il);
 676         zi = exact_center + (-0.80 reduced_il, +0.75 reduced_il);
 677         zj = exact_center + (-0.60 reduced_il, +0.60 reduced_il);
 678
 679         draw za{-1,2} .. zb .. zc .. zd .. ze .. zf .. zg .. zh .. zi .. zj;
 680
 681         save za, zb, zc, zd, ze, zf;
 682         pair za, zb, zc, zd, ze, zf;
 683
 684         pickup pencircle
 685                 xscaled 0.75 reduced_slt
 686                 yscaled 0.33 reduced_il
 687                 rotated -35;
 688
 689         za = exact_center + (+0.25 reduced_il, +0.45 reduced_il);
 690         zb = exact_center + (-0.25 reduced_il, +0.45 reduced_il);
 691         zc = exact_center + (-0.25 reduced_il, -0.45 reduced_il);
 692         zd = exact_center + (+0.25 reduced_il, -0.45 reduced_il);
 693         ze = exact_center + (+0.30 reduced_il, +0.00 reduced_il);
 694         zf = exact_center + (+0.00 reduced_il, +0.00 reduced_il);
 695
 696         draw za .. zb .. zc .. zd .. {up}ze -- zf;
 697 enddef;
 698
 699
 700 fet_beginchar("petrucci g clef", "petrucci_g", "petruccigclef")
 701         if test = 1:
 702                 draw_staff(-1,3, 0.0);
 703         fi;
 704         draw_petrucci_g_clef((0,0), 1.0);
 705 fet_endchar;
 706 fet_beginchar("petrucci g clef", "petrucci_g_change", "cpetruccigclef")
 707         draw_petrucci_g_clef((0,0), .8);
 708 fet_endchar;
 709
 710
 711
 712 %%%%%%%%
 713 %
 714 %
 715 %
 716 % Hufnagel
 717 %
 718 %
 719 %
 720 def draw_hufnagel_do_clef(expr exact_center, reduction) =
 721         %
 722         % inspired by Graduale of Friedrich Zollner (1442), in: MGG,
 723         % volume 9, col. 1413 ("Neustift"), fig. 1.
 724         %
 725         save reduced_il;
 726
 727         reduced_il# = staff_space# * reduction;
 728
 729         define_pixels(reduced_il);
 730
 731         pickup pencircle
 732                 xscaled (0.60reduced_il)
 733                 yscaled (0.10reduced_il)
 734                 rotated 40;
 735         save za, zb, zc, zd, ze, zf;
 736         pair za, zb, zc, zd, ze, zf;
 737
 738         za = exact_center + (+0.30reduced_il, +.45reduced_il);
 739         zb = exact_center + (+0.20reduced_il, +.45reduced_il);
 740         zc = exact_center + (-0.10reduced_il, +.60reduced_il);
 741         zd = exact_center + (-0.40reduced_il, +.45reduced_il);
 742         ze = exact_center + (-0.40reduced_il, -.45reduced_il);
 743         zf = exact_center + (-0.20reduced_il, -.55reduced_il);
 744         draw za .. zb .. zc -- zd -- ze -- zf;
 745
 746         set_char_box(0.5reduced_il#, 0.5reduced_il#, 0, reduced_il#);
 747 enddef;
 748
 749
 750 fet_beginchar("Hufnagel do clef", "hufnagel_do", "hufnageldoclef")
 751         if test = 1:
 752                 draw_staff(-1,3, 0.0);
 753         fi;
 754         draw_hufnagel_do_clef((0,0), 1.0);
 755 fet_endchar;
 756 fet_beginchar("Hufnagel do clef", "hufnagel_do_change", "chufnageldoclef")
 757         draw_hufnagel_do_clef((1.3 staff_space#,0), .8);
 758 fet_endchar;
 759
 760
 761 def draw_hufnagel_fa_clef(expr exact_center, reduction) =
 762         %
 763         % inspired by Bamberger Manuscript (15th century), in:
 764         % MGG, volume 2, table 59.
 765         %
 766         save reduced_il;
 767
 768         reduced_il# = staff_space# * reduction;
 769
 770         define_pixels(reduced_il);
 771
 772         pickup pencircle
 773                 xscaled (0.60reduced_il)
 774                 yscaled (0.10reduced_il)
 775                 rotated 40;
 776         save za, zb, zc, zd, ze, zf;
 777         pair za, zb, zc, zd, ze, zf;
 778
 779         za = exact_center + (+0.30reduced_il, +0.70reduced_il);
 780         zb = exact_center + (+0.20reduced_il, +0.70reduced_il);
 781         zc = exact_center + (-0.10reduced_il, +0.85reduced_il);
 782         zd = exact_center + (-0.40reduced_il, +0.70reduced_il);
 783         ze = exact_center + (-0.40reduced_il, -1.10reduced_il);
 784         draw za .. zb .. zc -- zd -- ze;
 785
 786         save zg, zh, zi, zj;
 787         pair zg, zh, zi, zj;
 788
 789         zg = exact_center + (+0.30reduced_il, -0.05reduced_il);
 790         zh = exact_center + (+0.20reduced_il, -0.05reduced_il);
 791         zi = exact_center + (-0.10reduced_il, +0.10reduced_il);
 792         zj = exact_center + (-0.40reduced_il, -0.05reduced_il);
 793         draw zg .. zh .. zi -- zj;
 794
 795         set_char_box(0.5reduced_il#, 0.5reduced_il#, 0, reduced_il#);
 796 enddef;
 797
 798
 799 fet_beginchar("Hufnagel fa clef", "hufnagel_fa", "hufnagelfaclef")
 800         if test = 1:
 801                 draw_staff(-1,3, 0.0);
 802         fi;
 803         draw_hufnagel_fa_clef((0,0), 1.0);
 804 fet_endchar;
 805 fet_beginchar("Hufnagel fa clef", "hufnagel_fa_change", "chufnagelfaclef")
 806         draw_hufnagel_fa_clef((0,0), .8);
 807 fet_endchar;
 808
 809
 810 def draw_hufnagel_do_fa_clef(expr exact_center, reduction) =
 811         draw_hufnagel_do_clef(exact_center, reduction);
 812         draw_hufnagel_fa_clef(exact_center + (0, -2staff_space), reduction);
 813 enddef;
 814
 815
 816 fet_beginchar("Hufnagel do/fa clef", "hufnagel_do_fa", "hufnageldofaclef")
 817         if test = 1:
 818                 draw_staff(-1,3, 0.0);
 819         fi;
 820         draw_hufnagel_do_fa_clef((0,0), 1.0);
 821 fet_endchar;
 822 fet_beginchar("Hufnagel do/fa clef", "hufnagel_do_fa_change",
 823               "chufnageldofaclef")
 824         draw_hufnagel_do_fa_clef((0,0), .8);
 825 fet_endchar;
 826
 827
 828 fet_endgroup("clefs");