mf/feta-pendaal.mf

   1 % -*- Fundamental -*-  (emacs-20 mf mode mucks
   2 % feta-pendaal.mf -- piano pedal markings
   3 %
   4 % part of LilyPond's pretty-but-neat music font
   5 %
   6 % source file of the Feta (not the Font-En-Tja) music font
   7 %
   8 % (c) 2000--2004 Jan Nieuwenhuizen <janneke@gnu.org>
   9 %
  10 % Voor Cup
  11
  12 % Kerning
  13 %
  14 % Pe = -0.034 pedalh == -0.07 staff-space
  15 % ed = -0.27 pedalh == -0.53 staff-space
  16
  17
  18 fet_begingroup ("pedal");
  19
  20 pedalpha = 40;
  21 pedbeta = 25;
  22
  23 penh# = 0.7 linethickness#;
  24 penw# = 2 penh# + 0.14 staff_space#;
  25 define_pixels (penh, penw);
  26
  27 pedalh# = 2 staff_space#;
  28 pedalbh# = 4/7 pedalh#;
  29 define_pixels (pedalh, pedalbh);
  30
  31
  32 fet_beginchar ("Pedal asterisk", "*");
  33         save bulb, p, radius, thin, inner_r;
  34         path p;
  35
  36         set_char_box (0, 7/9 pedalh#, 0, pedalh#);
  37
  38         z0 = (1/2 w, h - 1/2 w);
  39
  40         thin = 0.8 linethickness;
  41
  42         bulb + 2 radius = w;
  43         0.9 thin + bulb = (radius * pi * 2) / 8;
  44
  45         pickup pencircle scaled penh;
  46
  47         penpos 1 (bulb, 180);
  48         penpos 2 (bulb, 0);
  49         penpos 3 (thin, 0);
  50
  51         z1 = z0 + (0, radius);
  52         z2 = z1;
  53
  54         inner_r = .45 radius;
  55
  56         z4l = z0 + inner_r * dir (90 + 360/16);
  57         z4r = z0 + inner_r * dir (90 - 360/16);
  58
  59         z4 = .5 [z4l, z4r];
  60         z3 = .75 [z1, z4];
  61
  62         penlabels (0, 1, 2, 3, 4);
  63
  64         p := z3r{up}
  65              .. z1l{up}
  66              .. z2l{down}
  67              .. z3l{down}
  68              .. z4l{dir (180 + 360/16)};
  69         for i = 1 upto 7:
  70                 p := p
  71                      .. ((z3r{up}
  72                          .. z1l{up}
  73                          .. z2l{down}
  74                          .. z3l{down}
  75                          .. z4l{dir (180 + 360/16)}) rotatedaround (z0,
  76                                                                     360/8 i));
  77         endfor;
  78
  79         p := p
  80              .. cycle;
  81         fill p;
  82
  83         pickup pencircle scaled (7/8 inner_r);
  84
  85         undrawdot z0;
  86 fet_endchar;
  87
  88
  89 %% ugh. rounded corners!
  90
  91 fet_beginchar ("Pedal dash", "-");
  92         save dash_thickness;
  93
  94         dash_thickness# := penw#;
  95         define_whole_vertical_blacker_pixels (dash_thickness);
  96
  97         set_char_box (0, 3 penw#, 0, pedalbh#);
  98
  99         penpos1 (dash_thickness, 60);
 100         penpos2 (dash_thickness, 60);
 101
 102         z1l = (0, vround (2/3 h - 1/2 penw));
 103         z2r = (w, vround (y1l + 1.2 penw));
 104
 105         penlabels (1, 2, 3);
 106
 107         penstroke z1e{dir 40}
 108                   ..tension 1.2.. z2e{dir 40};
 109 fet_endchar;
 110
 111
 112 fet_beginchar ("Pedal dot", ".");
 113         set_char_box (0, penw#, 0, penw#);
 114
 115         pickup pencircle scaled penw;
 116
 117         drawdot (hround (1/2 penw), vround (1/2 penw));
 118 fet_endchar;
 119
 120
 121 def draw_pedal_P (expr show_labels) =
 122 begingroup;
 123         clearxy;
 124
 125         penpos1 (hround penh, 0);
 126         penpos2 (penw, 55);
 127         penpos3 (penw, pedalpha);
 128         penpos4 (1.2 penh, -pedalpha);
 129         penpos5 (penh, -pedalpha);
 130         penpos6 (penh, 180 - pedalpha);
 131         penpos7 (2 penh, 180 - pedalpha);
 132         penpos8 (penh, 90);
 133         penpos9 (4/3 penw, 50);
 134         penpos10 (1.4 penw, 50);
 135         penpos11 (penh, 90 + pedalpha);
 136
 137         z1r = (hround 0.6 w, h);
 138         x2l = hround (x1l - penw) + xpart feta_offset;
 139         y2 = vround (0.7 h) + ypart feta_offset;
 140         x3r = hround (x2l + 2 penw);
 141         y3r = 0.4 h;
 142         z4l = z5r + 1/4 (z3r - z5r);
 143         x5 = 1/4 w;
 144         y5r = 0;
 145         z6 = z5;
 146         z7 = z6r + 1/3 (z8r - z6r);
 147         z8r = z5r + 3/5 (z3r - z5r);
 148         x9l = x10l - penh;
 149         y9l = 1/4 penh;
 150         x10l = w - tand (90 - pedalpha) * y11l;
 151         y10l = 1/4 penh;
 152         x11l = w;
 153         y11 = 1/5 h;
 154
 155         z1' = round (0.9 [z2, z1]) + (xpart feta_offset, 0);
 156         penpos1' (penh, 0);
 157
 158         if show_labels = 1:
 159                 penlabels (range 1 thru 11);
 160                 penlabels (1');
 161         fi;
 162
 163         soft_penstroke z1'e
 164                        ..tension 2.5.. z2e
 165                        ..tension 1.5.. z3e
 166                        ..tension 2.5.. z4e
 167                        ..tension 1.5.. z5e
 168                        .. z6e
 169                        ..tension 1.5.. z7e
 170                        ..tension 1.5.. z8e{right}
 171                        ..tension 1.5.. z9e{dir - pedalpha}
 172                        .. z10e
 173                        ..tension 2.5.. z11e;
 174
 175         penpos12 (hround penh, 0);
 176         penpos13 (penw, -90 - pedbeta);
 177         penpos14 (vround penh, 90);
 178         penpos15 (penw, -90 + pedbeta);
 179         penpos16 (penh, 180 + pedbeta);
 180
 181         z12r = (hround (5/9 x1 + 1/2 hround penh), y2);
 182         z13l = (1/2 x12r, y15r);
 183         z14r = z1r;
 184         z15l = (1/2 [x16, w], y2l + 0.5 penw);
 185         x16 = 1/4 [x1, w];
 186         y16r = y2r;
 187
 188         if show_labels = 1:
 189                 penlabels (range 12 thru 16);
 190         fi;
 191
 192         soft_penstroke z12e{down}
 193                        ..tension 1.1.. z13e{dir (180 - pedbeta)}
 194                        ..tension 1.1.. z14e{right}
 195                        ..tension 1.1.. z15e{dir (180 + pedbeta)}
 196                        ..tension 1.1.. z16e{dir (90 + pedbeta)};
 197 endgroup;
 198 enddef;
 199
 200
 201 def draw_pedal_d (expr show_labels) =
 202 begingroup;
 203         clearxy;
 204
 205         penpos1 (vround penh, -10 - 90);
 206         penpos2 (hround penw, 190);
 207         penpos3 (vround (2 penh), 90);
 208         penpos4 (hround (3/4 penw), 0);
 209         penpos5 (penh, -70);
 210
 211         x1r = 0;
 212         y1l = h;
 213         z2 = (w - 1/2 hround penw, 1/2 pedalbh + penh);
 214         z4l = (hround (1/3 w), 1/2 pedalbh);
 215         z5l = (2/3 w, pedalbh);
 216         z3l = (hround x5l, 0);
 217
 218         if show_labels = 1:
 219                 penlabels (1, 2, 3, 4, 5);
 220         fi;
 221
 222         soft_penstroke z1e{dir (-10)}
 223                        ..tension 1.1.. z2e{dir (-90 + 10)}
 224                        ..tension 1.1.. z3e{left}
 225                        ..tension 1.1.. z4e{up}
 226                        ..tension 1.1.. z5e{dir (-70 + 90)};
 227 endgroup;
 228 enddef;
 229
 230
 231 def draw_pedal_e (expr show_labels) =
 232 begingroup;
 233         clearxy;
 234
 235         penpos1 (penh, pedalpha - 90);
 236         penpos2 (penh, pedalpha - 90);
 237         penpos3 (3/5 penw, pedalpha);
 238         penpos4 (1.2 penh, 90 + pedalpha);
 239         penpos5 (2/3 penw, 180);
 240         penpos6 (penw, 180 + pedalpha);
 241         penpos7 (2/3 penw, -90 - 20);
 242         penpos8 (penh, pedalpha - 90);
 243
 244         z1l = (0, 1/5 pedalh);
 245         % this helps to make the path go through z2 at low resolutions
 246         z2 = round (z1 + dir pedalpha * penw) + feta_offset;
 247         z3 = (3/5 w, 8/9 h);
 248         z4 = (2/9 w,  y3);
 249         x4r := hround x4r;
 250         x5r = 0;
 251         y5 = y2;
 252         x6 = 3/8 w;
 253         y6r = 1/2 penh;
 254         z7l = (x6l + penh, y6l);
 255         x8r = w;
 256         y8 = 1/5 pedalh;
 257
 258         soft_penstroke z1e
 259                        -- z2e{z2 - z1}
 260                        ..tension 1.1.. z3e
 261                        ..tension 1.05.. z4e
 262                        ..tension 1.1.. z5e
 263                        ..tension 1.5.. z6e{dir - pedalpha}
 264                        ..tension 1.1.. z7e
 265                        ..tension 2.5.. z8e;
 266
 267         if show_labels = 1:
 268                 penlabels (range 1 thru 8);
 269         fi;
 270 endgroup;
 271 enddef;
 272
 273
 274 fet_beginchar ("Pedal P", "P");
 275         set_char_box (0, 5/6 pedalh#, 0, pedalh#);
 276
 277         draw_pedal_P (1);
 278 fet_endchar;
 279
 280
 281 fet_beginchar ("Pedal d", "d");
 282         set_char_box (0, 2/3 pedalh#, 0, 7/8 pedalh#);
 283
 284         draw_pedal_d (1);
 285 fet_endchar;
 286
 287
 288 fet_beginchar ("Pedal e", "e");
 289         set_char_box (0, 2/5 pedalh#, 0, pedalbh#);
 290
 291         draw_pedal_e (1);
 292 fet_endchar;
 293
 294
 295 fet_beginchar ("Pedal Ped", "Ped");
 296         P_width# = 5/6 pedalh#;
 297         e_width# = 2/5 pedalh#;
 298         d_width# = 2/3 pedalh#;
 299         define_pixels (P_width, e_width, d_width);
 300
 301         e_height = pedalbh;
 302         d_height = 7/8 pedalh;
 303
 304         % Pe = -0.034 pedalh == -0.07 staff-space
 305         % ed = -0.27 pedalh == -0.53 staff-space
 306         Pe_kern# = -0.034 pedalh#;
 307         ed_kern# = -0.27 pedalh#;
 308         define_pixels (Pe_kern, ed_kern);
 309
 310         w := hround d_width;
 311         h := vround d_height;
 312         draw_pedal_d (0);
 313         currentpicture := currentpicture
 314                             shifted (hround (e_width + ed_kern), 0);
 315
 316         w := hround e_width;
 317         h := vround e_height;
 318         draw_pedal_e (0);
 319         currentpicture := currentpicture
 320                             shifted (hround (P_width + Pe_kern), 0);
 321
 322         w := hround P_width;
 323         h := vround pedalh;
 324         draw_pedal_P (0);
 325
 326         set_char_box (0, P_width# + Pe_kern# + e_width# + ed_kern# + d_width#,
 327                       0, pedalh#);
 328 fet_endchar;
 329
 330
 331 fet_endgroup ("pedal");