mf/feta-pendaal.mf

   1 % -*- Fundamental -*-  (emacs-20 mf mode mucks
   2 % feta-pendaal.mf -- piano pedal markings
   3 %
   4 % part of LilyPond's pretty-but-neat music font
   5 %
   6 % source file of the Feta (not the Font-En-Tja) music font
   7 %
   8 % (c) 2000--2004 Jan Nieuwenhuizen <janneke@gnu.org>
   9 %
  10 % Voor Cup
  11
  12 % Kerning
  13 %
  14 % Pe = -0.034 pedalh == -0.07 staff-space
  15 % ed = -0.27 pedalh == -0.53 staff-space
  16
  17
  18 fet_begingroup ("pedal");
  19
  20 pedalpha = 40;
  21 pedbeta = 25;
  22
  23 penh# = 0.7 linethickness#;
  24 penw# = 2 penh# + 0.14 staff_space#;
  25 define_pixels (penh, penw);
  26
  27 pedalh# = 2 staff_space#;
  28 pedalbh# = 4/7 pedalh#;
  29 define_pixels (pedalh, pedalbh);
  30
  31
  32 fet_beginchar ("Pedal asterisk", "*");
  33         save bulb, p, radius, thin, inner_r;
  34         path pat;
  35
  36         set_char_box (0, 7/9 pedalh#, 0, pedalh#);
  37
  38         z0 = (1/2 w, h - 1/2 w);
  39
  40         thin = 0.8 linethickness;
  41
  42         bulb + 2 radius = w;
  43         0.9 thin + bulb = (radius * pi * 2) / 8;
  44
  45         pickup pencircle scaled penh;
  46
  47         penpos 1 (bulb, 180);
  48         penpos 2 (bulb, 0);
  49         penpos 3 (thin, 0);
  50
  51         z1 = z0 + (0, radius);
  52         z2 = z1;
  53
  54         inner_r = .45 radius;
  55
  56         z4l = z0 + inner_r * dir (90 + 360/16);
  57         z4r = z0 + inner_r * dir (90 - 360/16);
  58
  59         z4 = .5 [z4l, z4r];
  60         z3 = .75 [z1, z4];
  61
  62         penlabels (0, 1, 2, 3, 4);
  63
  64         pat := z3r{up}
  65                .. z1l{up}
  66                .. z2l{down}
  67                .. z3l{down}
  68                .. z4l{dir (180 + 360/16)};
  69         for i = 1 upto 7:
  70                 pat := pat
  71                        .. ((z3r{up}
  72                            .. z1l{up}
  73                            .. z2l{down}
  74                            .. z3l{down}
  75                            .. z4l{dir (180 + 360/16)})
  76                                 rotatedaround (z0, 360/8 i));
  77         endfor;
  78
  79         pat := pat
  80                .. cycle;
  81
  82         % Uh, oh, there is a bug in metapost 0.641 which makes mf2pt1.mp's
  83         % redefinion of `fill' fail for this particular path, using a
  84         % wrong path orientation.
  85         %
  86         % Note that using `unfill' here makes the direct mpost output
  87         % wrong, but the `mf2pt1' script fixes it for the Type 1 output.
  88
  89         if known bp_per_pixel:
  90                 unfill pat;
  91         else:
  92                 fill pat;
  93         fi;
  94
  95         pickup pencircle scaled (7/8 inner_r);
  96
  97         undrawdot z0;
  98 fet_endchar;
  99
 100
 101 %% ugh. rounded corners!
 102
 103 fet_beginchar ("Pedal dash", "-");
 104         save dash_thickness;
 105
 106         dash_thickness# := penw#;
 107         define_whole_vertical_blacker_pixels (dash_thickness);
 108
 109         set_char_box (0, 3 penw#, 0, pedalbh#);
 110
 111         penpos1 (dash_thickness, 60);
 112         penpos2 (dash_thickness, 60);
 113
 114         z1l = (0, vround (2/3 h - 1/2 penw));
 115         z2r = (w, vround (y1l + 1.2 penw));
 116
 117         penlabels (1, 2, 3);
 118
 119         penstroke z1e{dir 40}
 120                   ..tension 1.2.. z2e{dir 40};
 121 fet_endchar;
 122
 123
 124 fet_beginchar ("Pedal dot", ".");
 125         set_char_box (0, penw#, 0, penw#);
 126
 127         pickup pencircle scaled penw;
 128
 129         drawdot (hround (1/2 penw), vround (1/2 penw));
 130 fet_endchar;
 131
 132
 133 def draw_pedal_P (expr show_labels) =
 134 begingroup;
 135         clearxy;
 136
 137         penpos1 (hround penh, 0);
 138         penpos2 (penw, 55);
 139         penpos3 (penw, pedalpha);
 140         penpos4 (1.2 penh, -pedalpha);
 141         penpos5 (penh, -pedalpha);
 142         penpos6 (penh, 180 - pedalpha);
 143         penpos7 (2 penh, 180 - pedalpha);
 144         penpos8 (penh, 90);
 145         penpos9 (4/3 penw, 50);
 146         penpos10 (1.4 penw, 50);
 147         penpos11 (penh, 90 + pedalpha);
 148
 149         z1r = (hround 0.6 w, h);
 150         x2l = hround (x1l - penw) + xpart feta_offset;
 151         y2 = vround (0.7 h) + ypart feta_offset;
 152         x3r = hround (x2l + 2 penw);
 153         y3r = 0.4 h;
 154         z4l = z5r + 1/4 (z3r - z5r);
 155         x5 = 1/4 w;
 156         y5r = 0;
 157         z6 = z5;
 158         z7 = z6r + 1/3 (z8r - z6r);
 159         z8r = z5r + 3/5 (z3r - z5r);
 160         x9l = x10l - penh;
 161         y9l = 1/4 penh;
 162         x10l = w - tand (90 - pedalpha) * y11l;
 163         y10l = 1/4 penh;
 164         x11l = w;
 165         y11 = 1/5 h;
 166
 167         z1' = round (0.9 [z2, z1]) + (xpart feta_offset, 0);
 168         penpos1' (penh, 0);
 169
 170         if show_labels = 1:
 171                 penlabels (range 1 thru 11);
 172                 penlabels (1');
 173         fi;
 174
 175         soft_penstroke z1'e
 176                        ..tension 2.5.. z2e
 177                        ..tension 1.5.. z3e
 178                        ..tension 2.5.. z4e
 179                        ..tension 1.5.. z5e
 180                        .. z6e
 181                        ..tension 1.5.. z7e
 182                        ..tension 1.5.. z8e{right}
 183                        ..tension 1.5.. z9e{dir - pedalpha}
 184                        .. z10e
 185                        ..tension 2.5.. z11e;
 186
 187         penpos12 (hround penh, 0);
 188         penpos13 (penw, -90 - pedbeta);
 189         penpos14 (vround penh, 90);
 190         penpos15 (penw, -90 + pedbeta);
 191         penpos16 (penh, 180 + pedbeta);
 192
 193         z12r = (hround (5/9 x1 + 1/2 hround penh), y2);
 194         z13l = (1/2 x12r, y15r);
 195         z14r = z1r;
 196         z15l = (1/2 [x16, w], y2l + 0.5 penw);
 197         x16 = 1/4 [x1, w];
 198         y16r = y2r;
 199
 200         if show_labels = 1:
 201                 penlabels (range 12 thru 16);
 202         fi;
 203
 204         soft_penstroke z12e{down}
 205                        ..tension 1.1.. z13e{dir (180 - pedbeta)}
 206                        ..tension 1.1.. z14e{right}
 207                        ..tension 1.1.. z15e{dir (180 + pedbeta)}
 208                        ..tension 1.1.. z16e{dir (90 + pedbeta)};
 209 endgroup;
 210 enddef;
 211
 212
 213 def draw_pedal_d (expr show_labels) =
 214 begingroup;
 215         clearxy;
 216
 217         penpos1 (vround penh, -10 - 90);
 218         penpos2 (hround penw, 190);
 219         penpos3 (vround (2 penh), 90);
 220         penpos4 (hround (3/4 penw), 0);
 221         penpos5 (penh, -70);
 222
 223         x1r = 0;
 224         y1l = h;
 225         z2 = (w - 1/2 hround penw, 1/2 pedalbh + penh);
 226         z4l = (hround (1/3 w), 1/2 pedalbh);
 227         z5l = (2/3 w, pedalbh);
 228         z3l = (hround x5l, 0);
 229
 230         if show_labels = 1:
 231                 penlabels (1, 2, 3, 4, 5);
 232         fi;
 233
 234         soft_penstroke z1e{dir (-10)}
 235                        ..tension 1.1.. z2e{dir (-90 + 10)}
 236                        ..tension 1.1.. z3e{left}
 237                        ..tension 1.1.. z4e{up}
 238                        ..tension 1.1.. z5e{dir (-70 + 90)};
 239 endgroup;
 240 enddef;
 241
 242
 243 def draw_pedal_e (expr show_labels) =
 244 begingroup;
 245         clearxy;
 246
 247         penpos1 (penh, pedalpha - 90);
 248         penpos2 (penh, pedalpha - 90);
 249         penpos3 (3/5 penw, pedalpha);
 250         penpos4 (1.2 penh, 90 + pedalpha);
 251         penpos5 (2/3 penw, 180);
 252         penpos6 (penw, 180 + pedalpha);
 253         penpos7 (2/3 penw, -90 - 20);
 254         penpos8 (penh, pedalpha - 90);
 255
 256         z1l = (0, 1/5 pedalh);
 257         % this helps to make the path go through z2 at low resolutions
 258         z2 = round (z1 + dir pedalpha * penw) + feta_offset;
 259         z3 = (3/5 w, 8/9 h);
 260         z4 = (2/9 w,  y3);
 261         x4r := hround x4r;
 262         x5r = 0;
 263         y5 = y2;
 264         x6 = 3/8 w;
 265         y6r = 1/2 penh;
 266         z7l = (x6l + penh, y6l);
 267         x8r = w;
 268         y8 = 1/5 pedalh;
 269
 270         soft_penstroke z1e
 271                        -- z2e{z2 - z1}
 272                        ..tension 1.1.. z3e
 273                        ..tension 1.05.. z4e
 274                        ..tension 1.1.. z5e
 275                        ..tension 1.5.. z6e{dir - pedalpha}
 276                        ..tension 1.1.. z7e
 277                        ..tension 2.5.. z8e;
 278
 279         if show_labels = 1:
 280                 penlabels (range 1 thru 8);
 281         fi;
 282 endgroup;
 283 enddef;
 284
 285
 286 fet_beginchar ("Pedal P", "P");
 287         set_char_box (0, 5/6 pedalh#, 0, pedalh#);
 288
 289         draw_pedal_P (1);
 290 fet_endchar;
 291
 292
 293 fet_beginchar ("Pedal d", "d");
 294         set_char_box (0, 2/3 pedalh#, 0, 7/8 pedalh#);
 295
 296         draw_pedal_d (1);
 297 fet_endchar;
 298
 299
 300 fet_beginchar ("Pedal e", "e");
 301         set_char_box (0, 2/5 pedalh#, 0, pedalbh#);
 302
 303         draw_pedal_e (1);
 304 fet_endchar;
 305
 306
 307 fet_beginchar ("Pedal Ped", "Ped");
 308         P_width# = 5/6 pedalh#;
 309         e_width# = 2/5 pedalh#;
 310         d_width# = 2/3 pedalh#;
 311         define_pixels (P_width, e_width, d_width);
 312
 313         e_height = pedalbh;
 314         d_height = 7/8 pedalh;
 315
 316         % Pe = -0.034 pedalh == -0.07 staff-space
 317         % ed = -0.27 pedalh == -0.53 staff-space
 318         Pe_kern# = -0.034 pedalh#;
 319         ed_kern# = -0.27 pedalh#;
 320         define_pixels (Pe_kern, ed_kern);
 321
 322         w := hround d_width;
 323         h := vround d_height;
 324         draw_pedal_d (0);
 325         currentpicture := currentpicture
 326                             shifted (hround (e_width + ed_kern), 0);
 327
 328         w := hround e_width;
 329         h := vround e_height;
 330         draw_pedal_e (0);
 331         currentpicture := currentpicture
 332                             shifted (hround (P_width + Pe_kern), 0);
 333
 334         w := hround P_width;
 335         h := vround pedalh;
 336         draw_pedal_P (0);
 337
 338         set_char_box (0, P_width# + Pe_kern# + e_width# + ed_kern# + d_width#,
 339                       0, pedalh#);
 340 fet_endchar;
 341
 342
 343 fet_endgroup ("pedal");