mf/feta-nummer.mf

   1 % feta-nummer.mf -- implement bold Orator numerals
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997, 1998 Jan Nieuwenhuizen <janneke@gnu.org>
   8
   9 fet_begingroup("nummer")
  10 code := 47;
  11
  12 define_pixels(height,thick,thick,thin,hair,flare);
  13 define_pixels(foot_top,foot_width);
  14 define_pixels(kuulleke);
  15
  16 def calc_kuulleke(expr w,alpha) =
  17         begingroup;
  18         save beta; beta=(alpha-90)/2;
  19         save gamma; gamma=(90+alpha)/2;
  20
  21         penpos1(w/cosd(alpha),alpha);
  22         penpos2(hair,90+beta);
  23         z2=z1l+(1/2hair/tand((alpha+90)/2))*dir(beta);
  24
  25         penpos3(hair,gamma-90);
  26         z3=z1r-(1/2hair/tand((90-alpha)/2))*dir(gamma);
  27         z4=z1+kuulleke*dir(alpha-90);
  28         endgroup;
  29         enddef;
  30
  31 % should make generic macro?
  32 %
  33 def draw_foot(expr xpos) =
  34         begingroup;
  35         clearxy;
  36         penpos1(thick,0);
  37         z1=(xpos,foot_top);
  38         penpos2(foot_width,0);
  39         z2=(x1,0);
  40         penpos3(hair,-90);
  41         z3r=z2r;
  42         penpos4(hair,90);
  43         z4l=z2l;
  44         z5=(x1,kuulleke);
  45         penlabels(1,2,3,4);
  46         fill z1..{right}z1r{down}..{right}z3l..z3r{left}..z5
  47                 ..{left}z4l..z4r{right}..{up}z1l{right}..z1..cycle;
  48         endgroup;
  49         enddef;
  50
  51 def draw_six =
  52         set_char_box(0, 2/3height#*widen, 0, height#);
  53         message "w:"&decimal w;
  54         message "h:"&decimal h;
  55
  56         penpos1(thin,90);
  57         z1=(thick,h/2+thin-hair/2);
  58         penpos2(hair,90);
  59         z2=(w/2,y1);
  60         penpos3(7/8thick,0);
  61         % yup, should use the path fract [] "everywhere"
  62         z3r=(w,1/2[0,y1]);
  63         penpos4(hair,-90);
  64         z4r=(x2,0);
  65         penpos5(7/8thick,180);
  66         z5r=(0,y1);
  67         penpos6(hair,90);
  68         z6r=(w-flare,h);
  69         penpos7(7/8thick,180);
  70         z7r=(0,h/2);
  71         penpos10(7/8thick,180);
  72         z10r=(0,y3);
  73         penlabels(1,2,3,4,5,6,7,8,9,10,11);
  74         save t; t=tense;
  75         fill z5{right}..z2r{right}..tension t..z3r{down}
  76                 ..tension t..z4r{left}
  77                 ..tension t..z7r{up}..tension t..z6r{right}
  78                 ..z6l{left}..tension t..z7l{down}..z10l{up}..cycle;
  79         draw_flare(z6r,0,-90,hair,flare);
  80         unfill z2l{right}..tension t..z3l{down}..tension t
  81                 ..z4l{left}..tension t..z10l{up}..tension t..cycle;
  82         enddef;
  83
  84 fet_beginchar("Numeral 0", "0", "zero")
  85 %       set_char_box(0, 4/5height#*widen, 0, height#);
  86         set_char_box(0, 11/15height#*widen, 0, height#);
  87         message "w:"&decimal w;
  88         message "h:"&decimal h;
  89         penpos1(thin,90);
  90         z1r=(w/2,h);
  91         penpos2(thick,180);
  92         z2r=(0,h/2);
  93         penpos3(thin,-90);
  94         z3r=(w/2,0);
  95         penpos4(thick,0);
  96         z4r=(w,h/2);
  97         fill z1r..z2r..z3r..z4r..cycle;
  98         save t; t=1/tense;
  99         penlabels(1,2,3,4);
 100         unfill z1l..tension t..z2l..tension t..z3l
 101                 ..tension t..z4l..tension t..cycle;
 102 fet_endchar;
 103
 104 fet_beginchar("Numeral 1", "1", "one")
 105 %       set_char_box(0, 19/30height#*widen, 0, height#);
 106         set_char_box(0, 1/2foot_width#+3/2thick#+1/2hair#, 0, height#);
 107         message "w:"&decimal w;
 108         message "h:"&decimal h;
 109
 110         save alpha; alpha=0;
 111         calc_kuulleke(thick,alpha);
 112         z1=(3/2thick,height);
 113
 114         penpos5(thick,0);
 115         z5=(x1,foot_top);
 116
 117         z6=(0,h/2);
 118         save beta; beta=angle(z1l-z6);
 119         penpos7(thin,beta-90);
 120         z7l=z6;
 121         penpos8(thin/cosd(beta),-90);
 122         z8l=z1l;
 123         penpos9(thin,beta-90);
 124         z9r=z8r+(thin/cosd(beta))*(0,-1);
 125         penlabels(1,2,3,4,5,6,7,8,9);
 126         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 127         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l..z3r{down}
 128                 ..{down}z5r{left}..z5..{left}z5l{up}..{up}z2l..cycle;
 129         fill z7l{dir(beta)}..{dir(beta)}z1l..z2r..z9r{up}
 130                 ..z9l{dir(180+beta)}..{dir(180+beta)}z7r..cycle;
 131         penlabels(7,8,9);
 132
 133         draw_foot(x1);
 134 fet_endchar;
 135
 136 fet_beginchar("Numeral 2", "2", "two")
 137         set_char_box(0, 11/15height#*widen, 0, height#);
 138         message "w:"&decimal w;
 139         message "h:"&decimal h;
 140         clearxy;
 141         save alpha; alpha=-45*widen;
 142         save beta; beta=85;
 143         save gamma; gamma=beta-10;
 144         save theta; theta=20/widen;
 145         penpos1(hair,90+beta);
 146         z1=(0,0)+(1/2sqrt(2)*hair)*dir(45);
 147         penpos3(hair,90+gamma);
 148         z3=(w,thick)+(1/2sqrt(2)*hair)*dir(-135);
 149         penpos2(thick,90+alpha);
 150         x2-x1=x3-x2; y2=11/16thick/widen;
 151         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(gamma)}z3r
 152                 ..z3l{dir(180+gamma)}..{dir(180+alpha)}z2l
 153                 ..{dir(180+beta)}z1l..cycle;
 154
 155         penpos4(thick,0);
 156         z4r=(w-thin/2,.72h);
 157         penpos5(thin,90);
 158         z5r=(1/2hair+flare,h);
 159         penlabels(1,2,3,4);
 160         penlabels(5,6);
 161         save t; t=tense;
 162         fill z1l{dir(beta)}..tension t..z4r{up}
 163                 ..tension t..z5r{left}..z5l{right}
 164                 ..z4l{down}..tension t
 165                 ..{dir(180+beta)}z1r..cycle;
 166         draw_flare(z5r,180,90,thin,flare);
 167 fet_endchar;
 168
 169 fet_beginchar("Numeral 3", "3", "three")
 170         set_char_box(0, 2/3height#*widen, 0, height#);
 171         message "w:"&decimal w;
 172         message "h:"&decimal h;
 173         penpos1(hair,-90);
 174         z1l=(17/16thick,h);
 175         penpos2(7/8thick,180);
 176         z2l=(w-thick/8,3/4h+thick/16);
 177         penpos3(thin,90);
 178         z3=(w/2,h/2+1/8thick);
 179         penpos4(thin,90);
 180         z4=(5/8thick+1/2thin,y3);
 181         penpos5(thick,0);
 182         z5r=(w,1/4h+thick/16);
 183         penpos6(hair,-90);
 184         z6r=(9/8thick,0);
 185         penpos7(3/2thin,90);
 186         z7=(x5,y3);
 187         penlabels(1,2,3,4,5,6,7);
 188         save alpha; alpha=25;
 189         save t; t=tense;
 190         fill z1l{right}..tension t..z2l{down}..z7r{dir(180+alpha)}
 191                 ..z7l{dir(-alpha)}..z5r{down}..tension t..z6r{left}
 192                 ..z6l{right}..tension t..z5l{up}
 193                 ..tension t..z3l{left}..z4l{left}
 194                 ..z4r{right}..z3r{right}..tension t..z2r{up}
 195                 ..tension t..z1r{left}..cycle;
 196         draw_flare(z1l,180,90,hair,7/8flare);
 197         draw_flare(z6r,180,-90,hair,flare);
 198 fet_endchar;
 199
 200 fet_beginchar("Numeral 4", "4", "four")
 201         set_char_box(0, 4/5height#*widen, 0, height#);
 202         message "w:"&decimal w;
 203         message "h:"&decimal h;
 204
 205         save alpha; alpha=0;
 206         calc_kuulleke(3/2thick,alpha);
 207         z1r=(w-3/4thick,height);
 208
 209         z5=(thin,1/4height+thin);
 210         save beta; beta=angle(z3r-z5);
 211         penpos6(thin,-90);
 212         z6l=z5;
 213         penpos7(thin,-90);
 214         y7=y6; x7=w-1/2thin;
 215         penpos8(thin,-alpha);
 216         z8r=z5;
 217         penlabels(1,2,3,4,5,6,7);
 218         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 219         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 220                 ..z3r{dir(180+beta)}..{dir(180+beta)}z8r{right}
 221                 ..{right}z7l..z7r{left}..{left}z6r..z8l{dir(beta)}
 222                 ..{up}z2l..cycle;
 223
 224         clearxy;
 225
 226         save alpha; alpha=beta;
 227         calc_kuulleke(thick,alpha);
 228         z1r=(w-3/4thick,height-(3/2thin)/cosd(alpha));
 229
 230         penpos5(thick,0);
 231         z5=(x1,foot_top);
 232
 233         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 234         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 235                 ..z3r{down}..{down}z5r{left}..z5..{left}z5l{up}
 236                 ..{up}z2l..cycle;
 237         penlabels(1,2,3,4,5);
 238
 239         draw_foot(x5);
 240 fet_endchar;
 241
 242 fet_beginchar("Numeral 5", "5", "five")
 243         set_char_box(0, 7/10height#*widen, 0, height#);
 244         message "w:"&decimal w;
 245         message "h:"&decimal h;
 246         calc_kuulleke(w-thin,0);
 247         z1=(w/2+1/8thick,h);
 248         save alpha; alpha=0;
 249         penpos5(thin,0);
 250         z5l=(x1l,h-15/16thick);
 251         penpos6(hair,90-45);
 252         z6=z5r+1/2hair*dir(-45);
 253         penpos7(thin,0);
 254         z7l=(x1l,h/2+thin-hair);
 255         penlabels(1,2,3,4,5,6,7);
 256         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 257         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 258                 ..z3r{dir(-135)}..{left}z6r..z6l{down}..z7r{down}
 259                 ..z7l{up}..{up}z2l..cycle;
 260         penpos8(thin,90);
 261         z8l=(x7r,y7r-1/16thick);
 262         penpos9(thin,90);
 263         z9=(x11+3/16thick,10/16[y5,y7]);
 264         penpos10(thick,0);
 265         z10r=(w,1/2[y9r,y11r]);
 266         penpos11(hair,-90);
 267         z11r=(9/8thick,0);
 268         penlabels(8,9,10,11);
 269         save beta; beta=45;
 270         save t; t=tense;
 271         fill z8r{dir(beta)}..z9r{right}..tension t..z10r{down}
 272                 ..tension t..z11r{left}
 273                 ..z11l{right}..tension t..z10l{up}..tension t
 274                 ..z9l{left}..z8l{dir(180+beta+10)}..cycle;
 275         draw_flare(z11r,180,-90,hair,flare);
 276 fet_endchar;
 277
 278 fet_beginchar("Numeral 6", "6", "six")
 279         draw_six;
 280 fet_endchar;
 281
 282 fet_beginchar("Numeral 7", "7", "seven")
 283         set_char_box(0, 11/15height#*widen, 0, height#);
 284         message "w:"&decimal w;
 285         message "h:"&decimal h;
 286
 287         save alpha; alpha=-180;
 288 if true:
 289         penpos1(3/2thick,180+alpha);
 290         penpos2(hair,180+alpha-45);
 291         z2=z1l+(1/4sqrt(2)*hair)*dir(alpha-135);
 292         penpos3(hair,180+alpha+45);
 293         z3=z1r+(1/4sqrt(2)*hair)*dir(alpha-45);
 294         z4=z1+kuulleke*dir(alpha-90);
 295 else:
 296         % shit, does not work
 297         calc_kuulleke(3/2thick,-alpha);
 298 fi
 299         z1l=(thin,0);
 300
 301         save beta; beta=55;
 302         penpos5(thin,90+beta);
 303         z5=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 304
 305         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 306         save delta; delta=12;
 307         pickup pencircle;
 308         fill z3l{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z2r..
 309                 z2l{dir(beta+delta)}..{dir(beta)}z5r
 310                 ..z5l{dir(180+beta)}..{dir(delta-90)}z3r..cycle;
 311         penlabels(1,2,3,4,5);
 312
 313         clearxy;
 314         save alpha; alpha=-45*widen;
 315         penpos1(1/2thick,90);
 316         z1=(3/2thin,h-(thick+thin)/2);
 317         penpos3(thin,90+beta);
 318         z3=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 319         penpos2(thick,90+alpha);
 320         x2=1/2[x1,x3]-1/4thick; y2=h-15/16thick+thin*widen;
 321
 322         penpos4(thin,0);
 323         z4l=(0,h-thin/2);
 324         penpos5(thin,0);
 325         z5l=(0,h/2+thin/2);
 326
 327         penpos6(9/8thick,90);
 328         z6r=(thin,y1r+2/16thick);
 329
 330         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(beta)}z3r
 331                 ..z3l{dir(180+beta)}..{dir(180+alpha)}z2l
 332                 ..{dir(180+beta)}z1l..z6l{down}..{down}z5r
 333                 ..z5l{up}..{up}z4l..z4r{down}..{down}z6r..{right}cycle;
 334         penlabels(1,2,3,4,5,6);
 335 fet_endchar;
 336
 337 fet_beginchar("Numeral 8", "8", "eight")
 338         set_char_box(0, 11/15height#*widen, 0, height#);
 339         message "w:"&decimal w;
 340         message "h:"&decimal h;
 341         save alpha; alpha=60;
 342         save beta; beta=alpha-15;
 343         z1=(w/2,h/2+thick/8);
 344         penpos2(hair,90+180+beta);
 345         z2=(w/3,h/2+thin);
 346         penpos3(3/2thin,0);
 347         z3l=(0,h/4+thin/2);
 348         penpos4(hair,90);
 349         z4l=(x1,0);
 350         penpos5(thick,90+90+alpha);
 351         z5=z1+w/4*dir(alpha-90);
 352         penpos6(thick,90+90+alpha);
 353         z6=z1+(w/4-thin/2)*dir(90+alpha);
 354         penpos7(hair,90);
 355         z7r=(x1,h);
 356         penpos8(3/2thin,0);
 357         z8r=(w-thin/2,3/4h+thin/2);
 358         penpos9(hair,90+180+beta);
 359         z9=(2/3w,h/2);
 360         penlabels(1,2,3,4,5,6,7,8,9);
 361         save t; t=tense;
 362         fill z2r{dir(180+beta)}..z3r{down}..z4r{right}
 363                 ..z5r{dir(90+alpha)}..z6r{dir(90+alpha)}
 364                 ..tension t..z7r{right}..z8r{down}..z9r{dir(180+beta)}
 365                 ..z9l{dir(beta)}..z8l{up}..z7l{left}..z6l{dir(alpha-90)}
 366                 ..z5l{dir(alpha-90)}..tension t..z4l{left}..z3l{up}
 367                 ..z2l{dir(beta)}..cycle;
 368 fet_endchar;
 369
 370 fet_beginchar("Numeral 9", "9", "nine")
 371         draw_six;
 372 %       xy_mirror_char;
 373         currentpicture := currentpicture scaled -1;
 374         currentpicture := currentpicture shifted (w,h);
 375 fet_endchar;
 376
 377 fet_endgroup("nummer")
 378