mf/feta-nummer.mf

   1 % feta-nummer.mf
   2 % part of LilyPond's pretty-but-neat music font
   3
   4 fet_begingroup("nummer")
   5 code := 47;
   6
   7 define_pixels(height,thick,thick,thin,hair);
   8 foot_top#:=thick#;
   9 foot_width#:=9/4thick#;
  10 define_pixels(foot_top,foot_width);
  11 define_pixels(kuulleke);
  12
  13 def calc_kuulleke(expr w,alpha) =
  14         begingroup;
  15         save beta; beta=(alpha-90)/2;
  16         save gamma; gamma=(90+alpha)/2;
  17
  18         penpos1(w/cosd(alpha),alpha);
  19         penpos2(hair,90+beta);
  20         z2=z1l+(1/2hair/tand((alpha+90)/2))*dir(beta);
  21
  22         penpos3(hair,gamma-90);
  23         z3=z1r-(1/2hair/tand((90-alpha)/2))*dir(gamma);
  24         z4=z1+kuulleke*dir(alpha-90);
  25         endgroup;
  26         enddef;
  27
  28 % should make generic macro?
  29 %
  30 def draw_foot(expr xpos) =
  31         begingroup;
  32         clearxy;
  33         penpos1(thick,0);
  34         z1=(xpos,foot_top);
  35         penpos2(foot_width,0);
  36         z2=(x1,0);
  37         penpos3(hair,-90);
  38         z3r=z2r;
  39         penpos4(hair,90);
  40         z4l=z2l;
  41         z5=(x1,kuulleke);
  42         fill z1..{right}z1r{down}..{right}z3l..z3r{left}..z5
  43                 ..{left}z4l..z4r{right}..{up}z1l{right}..z1..cycle;
  44         endgroup;
  45         enddef;
  46
  47 def draw_six =
  48         set_char_box(0, 2/3height#*widen, 0, height#);
  49         message "w:"&decimal w;
  50         message "h:"&decimal h;
  51
  52         penpos1(thin,90);
  53         z1=(thick,h/2+thin-hair/2);
  54         penpos2(hair,90);
  55         z2=(w/2,y1);
  56         penpos3(7/8thick,0);
  57         % yup, should use the path fract [] "everywhere"
  58         z3r=(w,1/2[0,y1]);
  59         penpos4(hair,-90);
  60         z4r=(x2,0);
  61         penpos5(7/8thick,180);
  62         z5r=(0,y1);
  63         penpos6(hair,90);
  64         z6r=(w-9/8thick*flaren,h);
  65         penpos7(7/8thick,180);
  66         z7r=(0,h/2);
  67         penpos10(7/8thick,180);
  68         z10r=(0,y3);
  69         penlabels(1,2,3,4,5,6,7,8,9,10,11);
  70         save t; t=0.833;
  71         fill z5{right}..z2r{right}..tension t..z3r{down}
  72                 ..tension t..z4r{left}
  73                 ..tension t..z7r{up}..tension t..z6r{right}
  74                 ..z6l{left}..tension t..z7l{down}..z10l{up}..cycle;
  75         draw_flare(z6r,0,-90,hair,thick*flaren);
  76         unfill z2l{right}..tension t..z3l{down}..tension t
  77                 ..z4l{left}..tension t..z10l{up}..tension t..cycle;
  78         enddef;
  79
  80 fet_beginchar("Numeral 0", "0", "zero")
  81 %       set_char_box(0, 4/5height#*widen, 0, height#);
  82         set_char_box(0, 11/15height#*widen, 0, height#);
  83         message "w:"&decimal w;
  84         message "h:"&decimal h;
  85         penpos1(thin,90);
  86         z1r=(w/2,h);
  87         penpos2(thick,0);
  88         z2r=(w,h/2);
  89         penpos3(thin,-90);
  90         z3r=(w/2,0);
  91         penpos4(thick,180);
  92         z4r=(0,h/2);
  93         fill z1r..z2r..z3r..z4r..cycle;
  94         save t; t=1.2;
  95         unfill z1l..tension t..z2l..tension t..z3l
  96                 ..tension t..z4l..tension t..cycle;
  97 fet_endchar;
  98
  99 fet_beginchar("Numeral 1", "1", "one")
 100 %       set_char_box(0, 19/30height#*widen, 0, height#);
 101         set_char_box(0, 1/2foot_width#+3/2thick#+1/2hair#, 0, height#);
 102         message "w:"&decimal w;
 103         message "h:"&decimal h;
 104
 105         save alpha; alpha=0;
 106         calc_kuulleke(thick,alpha);
 107         z1=(3/2thick,height);
 108
 109         penpos5(thick,0);
 110         z5=(x1,foot_top);
 111
 112         z6=(0,h/2);
 113         save beta; beta=angle(z1l-z6);
 114         penpos7(thin,beta-90);
 115         z7l=z6;
 116         penpos8(thin/cosd(beta),-90);
 117         z8l=z1l;
 118         penpos9(thin,beta-90);
 119         z9r=z8r+(thin/cosd(beta))*(0,-1);
 120         penlabels(1,2,3,4,5,6,7,8,9);
 121         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 122         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l..z3r{down}
 123                 ..{down}z5r{left}..z5..{left}z5l{up}..{up}z2l..cycle;
 124         fill z7l{dir(beta)}..{dir(beta)}z1l..z2r..z9r{up}
 125                 ..z9l{dir(180+beta)}..{dir(180+beta)}z7r..cycle;
 126         penlabels(7,8,9);
 127
 128         draw_foot(x1);
 129 fet_endchar;
 130
 131 fet_beginchar("Numeral 2", "2", "two")
 132         set_char_box(0, 11/15height#*widen, 0, height#);
 133         message "w:"&decimal w;
 134         message "h:"&decimal h;
 135         clearxy;
 136         save alpha; alpha=-50;
 137         save beta; beta=75;
 138         penpos1(thin,90+beta);
 139         z1=(0,0)+(1/2sqrt(2)*thin)*dir(45);
 140         penpos3(hair,90+beta);
 141         z3=(w,thick)+(1/2sqrt(2)*hair)*dir(-135);
 142         penpos2(thick-hair,90+alpha);
 143         x2-x1=x3-x2; y2=5/8thick/fatten;
 144         penlabels(1,2,3);
 145         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(beta)}z3r
 146                 ..z3l{dir(180+beta)}..{dir(180+alpha)}z2l
 147                 ..{dir(180+beta)}z1l..cycle;
 148
 149         penpos4(thin,90);
 150         z4r=(thick,2/5h);
 151         penpos5(thick,0);
 152         z5r=(w-thin,.72h);
 153         penpos6(thin,90);
 154         z6r=(1/2hair+thick,h);
 155         penlabels(4,5,6);
 156         fill z1l{dir(beta)}..z4l{dir(15)}..z5r{up}..
 157                 tension 0.9 ..
 158                 z6r{left}
 159                 ..z6l{right}..z5l{down}..z4r{dir(180+15)}
 160                 ..{dir(180+beta)}z1r..cycle;
 161         % nice without flaren correction...
 162         draw_flare(z6r,180,90,thin,thick);
 163 fet_endchar;
 164
 165 fet_beginchar("Numeral 3", "3", "three")
 166         set_char_box(0, 2/3height#*widen, 0, height#);
 167         message "w:"&decimal w;
 168         message "h:"&decimal h;
 169         penpos1(hair,-90);
 170         z1l=(17/16thick,h);
 171         penpos2(thick-hair,180);
 172         z2l=(w-thick/8,3/4h+thick/16);
 173         penpos3(hair,90);
 174         z3=(w/2,h/2+1/8thick);
 175         penpos4(hair,90);
 176         z4=(1/2thick+hair,y3);
 177         penpos5(thick,0);
 178         z5r=(w,1/4h+thick/16);
 179         penpos6(hair,-90);
 180         z6r=(9/8thick,0);
 181         penpos7(thin+hair,90);
 182         z7=(x2,y3);
 183         penlabels(1,2,3,4,5,6,7);
 184         save alpha; alpha=25;
 185         save t; t=0.833;
 186         fill z1l{right}..tension t..z2l{down}..z7r{dir(180+alpha)}
 187                 ..z7l{dir(-alpha)}..z5r{down}..tension t..z6r{left}
 188                 ..z6l{right}..tension t..z5l{up}
 189                 ..tension t..z3l{left}..z4l{left}
 190                 ..z4r{right}..z3r{right}..tension t..z2r{up}
 191                 ..tension t..z1r{left}..cycle;
 192         draw_flare(z1l,180,90,hair,thick*flaren);
 193         draw_flare(z6r,180,-90,hair,9/8thick*flaren);
 194 fet_endchar;
 195
 196 fet_beginchar("Numeral 4", "4", "four")
 197         set_char_box(0, 4/5height#*widen, 0, height#);
 198         message "w:"&decimal w;
 199         message "h:"&decimal h;
 200
 201         save alpha; alpha=0;
 202         calc_kuulleke(3/2thick,alpha);
 203         z1r=(w-3thin,height);
 204
 205         z5=(thin,1/4height+thin);
 206         save beta; beta=angle(z3r-z5);
 207         penpos6(thin,-90);
 208         z6l=z5;
 209         penpos7(thin,-90);
 210         y7=y6; x7=w-1/2thin;
 211         penpos8(thin,-alpha);
 212         z8r=z5;
 213         penlabels(1,2,3,4,5,6,7);
 214         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 215         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 216                 ..z3r{dir(180+beta)}..{dir(180+beta)}z8r{right}
 217                 ..{right}z7l..z7r{left}..{left}z6r..z8l{dir(beta)}
 218                 ..{up}z2l..cycle;
 219
 220         clearxy;
 221
 222         save alpha; alpha=beta;
 223         calc_kuulleke(thick,alpha);
 224 %       z1r=(w-3thin,height-(thin+hair)/cosd(alpha));
 225         z1r=(w-3thin,height-(thin+1/2hair)/cosd(alpha));
 226
 227         penpos5(thick,0);
 228         z5=(x1,foot_top);
 229
 230         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 231         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 232                 ..z3r{down}..{down}z5r{left}..z5..{left}z5l{up}
 233                 ..{up}z2l..cycle;
 234         penlabels(1,2,3,4,5);
 235
 236         draw_foot(x5);
 237 fet_endchar;
 238
 239 fet_beginchar("Numeral 5", "5", "five")
 240         set_char_box(0, 7/10height#*widen, 0, height#);
 241         message "w:"&decimal w;
 242         message "h:"&decimal h;
 243         calc_kuulleke(w-thin,0);
 244         z1=(w/2+thin/2,h);
 245         save alpha; alpha=0;
 246         penpos5(thin,0);
 247         z5l=(x1l,h-15/16thick);
 248         penpos6(hair,90-45);
 249         z6=z5r+1/2hair*dir(-45);
 250         penpos7(thin,0);
 251         z7l=(x1l,h/2+thin-hair);
 252         penlabels(1,2,3,4,5,6,7);
 253         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 254         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 255                 ..z3r{dir(-135)}..{left}z6r..z6l{down}..z7r{down}
 256                 ..z7l{up}..{up}z2l..cycle;
 257         penpos8(thin,90);
 258         z8l=z7r;
 259         penpos9(hair,90);
 260         z9=(x11,1/2[y5,y7]);
 261         penpos10(thick,0);
 262         z10r=(w,1/2[y9r,y11r]);
 263         penpos11(hair,-90);
 264         z11r=(9/8thick,0);
 265         penlabels(8,9,10,11);
 266         save beta; beta=45;
 267         save t; t=0.833;
 268         fill z8r{dir(beta)}..z9r{right}..tension t..z10r{down}
 269                 ..tension t..z11r{left}
 270                 ..z11l{right}..tension t..z10l{up}..tension t
 271                 ..z9l{left}..z8l{dir(180+beta)}..cycle;
 272         draw_flare(z11r,180,-90,hair,9/8thick*flaren);
 273 fet_endchar;
 274
 275 fet_beginchar("Numeral 6", "6", "six")
 276         draw_six;
 277 fet_endchar;
 278
 279 fet_beginchar("Numeral 7", "7", "seven")
 280         set_char_box(0, 11/15height#*widen, 0, height#);
 281         message "w:"&decimal w;
 282         message "h:"&decimal h;
 283
 284         save alpha; alpha=-180;
 285 if true:
 286         penpos1(3/2thick,180+alpha);
 287         penpos2(hair,180+alpha-45);
 288         z2=z1l+(1/4sqrt(2)*hair)*dir(alpha-135);
 289         penpos3(hair,180+alpha+45);
 290         z3=z1r+(1/4sqrt(2)*hair)*dir(alpha-45);
 291         z4=z1+kuulleke*dir(alpha-90);
 292 else:
 293         % shit, does not work
 294         calc_kuulleke(3/2thick,-alpha);
 295 fi
 296         z1l=(thin,0);
 297
 298         save beta; beta=50;
 299         penpos5(thin,90+beta);
 300         z5=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 301
 302         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 303         save delta; delta=12;
 304         pickup pencircle;
 305         fill z3l{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z2r..
 306                 z2l{dir(beta+delta)}..{dir(beta)}z5r
 307                 ..z5l{dir(180+beta)}..{dir(delta-90)}z3r..cycle;
 308         penlabels(1,2,3,4,5);
 309
 310         clearxy;
 311         save alpha; alpha=-50;
 312         penpos1(2thin,90);
 313         z1=(3/2thin,h-(thick+thin)/2);
 314         penpos3(thin,90+beta);
 315         z3=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 316         penpos2(thick-hair,90+alpha);
 317         x2-x1=x3-x2; y2=h-5/8thick/fatten;
 318
 319         penpos4(thin,0);
 320         z4l=(0,h-thin/2);
 321         penpos5(thin,0);
 322         z5l=(0,h/2+thin/2);
 323
 324         penpos6(4thin,90);
 325         z6r=(thin,y1r+thin/2);
 326
 327         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(beta)}z3r
 328                 ..z3l{dir(180+beta)}..{dir(180+alpha)}z2l
 329                 ..{dir(180+beta)}z1l..z6l{down}..{down}z5r
 330                 ..z5l{up}..{up}z4l..z4r{down}..{down}z6r..{right}cycle;
 331         penlabels(1,2,3,4,5,6);
 332 fet_endchar;
 333
 334 fet_beginchar("Numeral 8", "8", "eight")
 335         set_char_box(0, 11/15height#*widen, 0, height#);
 336         message "w:"&decimal w;
 337         message "h:"&decimal h;
 338         save alpha; alpha=60;
 339         save beta; beta=alpha-15;
 340         z1=(w/2,h/2+thick/8);
 341         penpos2(hair,90+180+beta);
 342         z2=(w/3,h/2+thin);
 343         penpos3(3/2thin,0);
 344         z3l=(0,h/4+thin/2);
 345         penpos4(hair,90);
 346         z4l=(x1,0);
 347         penpos5(thick,90+90+alpha);
 348         z5=z1+w/4*dir(alpha-90);
 349         penpos6(thick,90+90+alpha);
 350         z6=z1+(w/4-thin/2)*dir(90+alpha);
 351         penpos7(hair,90);
 352         z7r=(x1,h);
 353         penpos8(3/2thin,0);
 354         z8r=(w-thin/2,3/4h+thin/2);
 355         penpos9(hair,90+180+beta);
 356         z9=(2/3w,h/2);
 357         penlabels(1,2,3,4,5,6,7,8,9);
 358         save t; t=0.85;
 359         fill z2r{dir(180+beta)}..z3r{down}..z4r{right}
 360                 ..z5r{dir(90+alpha)}..z6r{dir(90+alpha)}
 361                 ..tension t..z7r{right}..z8r{down}..z9r{dir(180+beta)}
 362                 ..z9l{dir(beta)}..z8l{up}..z7l{left}..z6l{dir(alpha-90)}
 363                 ..z5l{dir(alpha-90)}..tension t..z4l{left}..z3l{up}
 364                 ..z2l{dir(beta)}..cycle;
 365 fet_endchar;
 366
 367 fet_beginchar("Numeral 9", "9", "nine")
 368         draw_six;
 369 %       xy_mirror_char;
 370         currentpicture := currentpicture scaled -1;
 371         currentpicture := currentpicture shifted (w,h);
 372 fet_endchar;
 373
 374 fet_endgroup("nummer")
 375