mf/feta-nummer-code.mf

   1 % feta-nummer.mf -- implement bold Orator numerals
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997--2002 Jan Nieuwenhuizen <janneke@gnu.org>
   8
   9 fet_begingroup("number")
  10
  11 define_pixels(height,thick,thick,thin,hair,flare);
  12 define_pixels(foot_top,foot_width);
  13 define_pixels(kuulleke);
  14
  15 def calc_kuulleke(expr w,alpha) =
  16         begingroup;
  17         save beta; beta=(alpha-90)/2;
  18         save gamma; gamma=(90+alpha)/2;
  19
  20         penpos1(w/cosd(alpha),alpha);
  21         penpos2(hair,90+beta);
  22         z2=z1l+(1/2hair/tand((alpha+90)/2))*dir(beta);
  23
  24         penpos3(hair,gamma-90);
  25         z3=z1r-(1/2hair/tand((90-alpha)/2))*dir(gamma);
  26         z4=z1+kuulleke*dir(alpha-90);
  27         endgroup;
  28         enddef;
  29
  30 % should make generic macro?
  31 %
  32 def draw_foot(expr xpos) =
  33         begingroup;
  34         clearxy;
  35         penpos1(thick,0);
  36         z1=(xpos,foot_top);
  37         penpos2(foot_width,0);
  38         z2=(x1,0);
  39         penpos3(hair,-90);
  40         z3r=z2r;
  41         penpos4(hair,90);
  42         z4l=z2l;
  43         z5=(x1,kuulleke);
  44         penlabels(1,2,3,4);
  45         fill z1..{right}z1r{down}..{right}z3l..z3r{left}..z5
  46                 ..{left}z4l..z4r{right}..{up}z1l{right}..z1..cycle;
  47         endgroup;
  48         enddef;
  49
  50 def draw_six =
  51         set_char_box(0, 2/3height#*widen, 0, height#);
  52         message "w:"&decimal w;
  53         message "h:"&decimal h;
  54
  55         penpos1(thin,90);
  56         z1=(thick,h/2+thin-hair/2);
  57         penpos2(hair,90);
  58
  59         z2=(w/2,y1);
  60         penpos3(7/8thick,0);
  61         % yup, should use the path fract [] "everywhere"
  62         z3r=(w,1/2[0,y1]);
  63         penpos4(hair,-90);
  64         z4r=(x2,0);
  65         penpos5(7/8thick,180);
  66         z5r=(0,y1);
  67         penpos6(hair,90);
  68         z6r=(w-flare,h);
  69         penpos7(7/8thick,180);
  70         z7r=(0,h/2);
  71         penpos10(7/8thick,180);
  72         z10r=(0,y3);
  73         penlabels(1,2,3,4,5,6,7,8,9,10,11);
  74         save t; t=tense;
  75         fill z7{right}..z2r{right}..tension t..z3r{down}
  76                 ..tension t..z4r{left}
  77                 ..tension t..z7r{up}..tension t..
  78                 flare_path (z6r,0,-90,hair,flare, 1)
  79                 ..tension t..z7l{down}..z10l{up}..cycle;
  80
  81         unfill z2l{right}..tension t..z3l{down}..tension t
  82                 ..z4l{left}..tension t..z10l{up}..tension t..cycle;
  83         enddef;
  84
  85 save dot_diam;
  86 dot_diam# = 7/8flare#;
  87 define_pixels(dot_diam);
  88
  89
  90 code := 43;  % , = 44
  91
  92 % urg
  93 fet_beginchar("Numeral comma", ",", "comma")
  94         set_char_box(0, dot_diam#, 3/2dot_diam#, dot_diam#);
  95         pickup pencircle scaled dot_diam;
  96         draw (dot_diam/2,dot_diam/2);
  97         z0=(w/3,0);
  98         alpha=65;
  99         penpos1(thin,alpha+90);
 100         z1l=(w/2,-1.5h+hair);
 101         z2=(w,h/2);
 102         pickup pencircle;
 103         filldraw z1l{dir(alpha)}..{up}z2..{z0-z2}z0{right}..{dir(180+alpha)}z1r..cycle;
 104         labels(0,1,2);
 105         penlabels(1);
 106 fet_endchar;
 107
 108 fet_beginchar("Numeral dash", "-", "dash")
 109         set_char_box(0, height#/3, 0, height#);
 110         pickup pencircle scaled thin;
 111         lft x1 = -b;
 112         rt x2 = w;
 113         y1 = y2 = h/3;
 114         draw z1 .. z2;
 115 fet_endchar;
 116
 117 fet_beginchar("Numeral dot", ".", "dot")
 118         set_char_box(0, dot_diam#, 0, dot_diam#);
 119         pickup pencircle scaled dot_diam;
 120         draw (dot_diam/2,dot_diam/2);
 121 fet_endchar;
 122
 123
 124 % skip slash
 125
 126 code := 47; % 0 = 48
 127
 128 fet_beginchar("Numeral 0", "0", "zero")
 129 %       set_char_box(0, 4/5height#*widen, 0, height#);
 130         set_char_box(0, 11/15height#*widen, 0, height#);
 131         message "w:"&decimal w;
 132         message "h:"&decimal h;
 133         penpos1(thin,90);
 134         z1r=(w/2,h);
 135         penpos2(thick,180);
 136         z2r=(0,h/2);
 137         penpos3(thin,-90);
 138         z3r=(w/2,0);
 139         penpos4(thick,0);
 140         z4r=(w,h/2);
 141         fill z1r..z2r..z3r..z4r..cycle;
 142         save t; t=1/tense;
 143         penlabels(1,2,3,4);
 144         unfill z1l..tension t..z2l..tension t..z3l
 145                 ..tension t..z4l..tension t..cycle;
 146 fet_endchar;
 147
 148 fet_beginchar("Numeral 1", "1", "one")
 149 %       set_char_box(0, 19/30height#*widen, 0, height#);
 150         set_char_box(0, 1/2foot_width#+3/2thick#+1/2hair#, 0, height#);
 151         message "w:"&decimal w;
 152         message "h:"&decimal h;
 153
 154         save alpha; alpha=0;
 155         calc_kuulleke(thick,alpha);
 156         z1=(3/2thick,height);
 157
 158         penpos5(thick,0);
 159         z5=(x1,foot_top);
 160
 161         z6=(0,h/2);
 162         save beta; beta=angle(z1l-z6);
 163         penpos7(thin,beta-90);
 164         z7l=z6;
 165         penpos8(thin/cosd(beta),-90);
 166         z8l=z1l;
 167         penpos9(thin,beta-90);
 168         z9r=z8r+(thin/cosd(beta))*(0,-1);
 169         penlabels(1,2,3,4,5,6,7,8,9);
 170         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 171         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l..z3r{down}
 172                 ..{down}z5r{left}..z5..{left}z5l{up}..{up}z2l..cycle;
 173         fill z7l{dir(beta)}..{dir(beta)}z1l..z2r..z9r{up}
 174                 ..z9l{dir(180+beta)}..{dir(180+beta)}z7r..cycle;
 175         penlabels(7,8,9);
 176
 177         draw_foot(x1);
 178 fet_endchar;
 179
 180 fet_beginchar("Numeral 2", "2", "two")
 181         set_char_box(0, 11/15height#*widen, 0, height#);
 182         message "w:"&decimal w;
 183         message "h:"&decimal h;
 184         clearxy;
 185         save alpha; alpha=-45*widen;
 186         save beta; beta=85;
 187         save gamma; gamma=beta-10;
 188         save theta; theta=20/widen;
 189         penpos1(hair,90+beta);
 190         z1=(0,0)+(1/2sqrt(2)*hair)*dir(45);
 191         penpos3(hair,90+gamma);
 192         z3=(w,thick)+(1/2sqrt(2)*hair)*dir(-135);
 193         penpos2(thick,90+alpha);
 194         x2-x1=x3-x2; y2=11/16thick/widen;
 195         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(gamma)}z3r
 196                 ..z3l{dir(180+gamma)}..{dir(180+alpha)}z2l
 197                 ..{dir(180+beta)}z1l..cycle;
 198
 199         penpos4(thick,0);
 200         z4r=(w-thin/2,.72h);
 201         penpos5(thin,90);
 202         z5r=(1/2hair+flare,h);
 203         penlabels(1,2,3,4);
 204         penlabels(5,6);
 205         save t; t=tense;
 206         fill z1l{dir(beta)}..tension t..z4r{up}
 207                 ..tension t..
 208                 flare_path(z5r,180,90,thin,flare,1)
 209                 ..z4l{down}..tension t
 210                 ..{dir(180+beta)}z1r..cycle;
 211 fet_endchar;
 212
 213 fet_beginchar("Numeral 3", "3", "three")
 214         set_char_box(0, 2/3height#*widen, 0, height#);
 215         message "w:"&decimal w;
 216         message "h:"&decimal h;
 217         penpos1(hair,-90);
 218         z1l=(17/16thick,h);
 219         penpos2(7/8thick,180);
 220         z2l=(w-thick/8,3/4h+thick/16);
 221         penpos3(thin,90);
 222         z3=(w/2,h/2+1/8thick);
 223         penpos4(thin,90);
 224         z4=(5/8thick+1/2thin,y3);
 225         penpos5(thick,0);
 226         z5r=(w,1/4h+thick/16);
 227         penpos6(hair,-90);
 228         z6r=(9/8thick,0);
 229         penpos7(3/2thin,90);
 230         z7=(x5,y3);
 231         penlabels(1,2,3,4,5,6,7);
 232         save alpha; alpha=25;
 233         save t; t=tense;
 234         pickup pencircle scaled 1;
 235 %       draw
 236         fill
 237                 flare_path (z1l, 180, 90, hair, 7/8 flare, -1) ..tension t..
 238                 z2l{down}..z7r{dir(180+alpha)}
 239                 ..z7l{dir(-alpha)}..z5r{down}..tension t..
 240
 241                 flare_path (z6r, 180, -90, hair, flare, 1) ..tension t..
 242
 243                 z5l{up}
 244                 ..tension t..z3l{left}..z4l{left}
 245                 ..z4r{right}..z3r{right}..tension t..z2r{up}
 246                 ..tension t.. cycle
 247 ;
 248 fet_endchar;
 249
 250
 251
 252 fet_beginchar("Numeral 4", "4", "four")
 253         set_char_box(0, 4/5height#*widen, 0, height#);
 254         message "w:"&decimal w;
 255         message "h:"&decimal h;
 256
 257         save alpha; alpha=0;
 258         calc_kuulleke(3/2thick,alpha);
 259         z1r=(w-3/4thick,height);
 260
 261         z5=(thin,1/4height+thin);
 262         save beta; beta=angle(z3r-z5);
 263         penpos6(thin,-90);
 264         z6l=z5;
 265         penpos7(thin,-90);
 266         y7=y6; x7=w-1/2thin;
 267         penpos8(thin,-alpha);
 268         z8r=z5;
 269         penlabels(1,2,3,4,5,6,7);
 270         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 271         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 272                 ..z3r{dir(180+beta)}..{dir(180+beta)}z8r{right}
 273                 ..{right}z7l..z7r{left}..{left}z6r..z8l{dir(beta)}
 274                 ..{up}z2l..cycle;
 275
 276         clearxy;
 277
 278         save alpha; alpha=beta;
 279         calc_kuulleke(thick,alpha);
 280         z1r=(w-3/4thick,height-(3/2thin)/cosd(alpha));
 281
 282         penpos5(thick,0);
 283         z5=(x1,foot_top);
 284
 285         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 286         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 287                 ..z3r{down}..{down}z5r{left}..z5..{left}z5l{up}
 288                 ..{up}z2l..cycle;
 289         penlabels(1,2,3,4,5);
 290
 291         draw_foot(x5);
 292 fet_endchar;
 293
 294 fet_beginchar("Numeral 5", "5", "five")
 295         set_char_box(0, 7/10height#*widen, 0, height#);
 296         message "w:"&decimal w;
 297         message "h:"&decimal h;
 298         calc_kuulleke(w-thin,0);
 299         z1=(w/2+1/8thick,h);
 300         save alpha; alpha=0;
 301         penpos5(thin,0);
 302         z5l=(x1l,h-15/16thick);
 303         penpos6(hair,90-45);
 304         z6=z5r+1/2hair*dir(-45);
 305         penpos7(thin,0);
 306         z7l=(x1l,h/2+thin-hair);
 307         penlabels(1,2,3,4,5,6,7);
 308         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 309         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 310                 ..z3r{dir(-135)}..{left}z6r..z6l{down}..z7r{down}
 311                 ..z7l{up}..{up}z2l..cycle;
 312         penpos8(thin,90);
 313         z8l=(x7r,y7r-1/16thick);
 314         penpos9(thin,90);
 315         z9=(x11+3/16thick,10/16[y5,y7]);
 316         penpos10(thick,0);
 317         z10r=(w,1/2[y9r,y11r]);
 318         penpos11(hair,-90);
 319         z11r=(9/8thick,0);
 320         penlabels(8,9,10,11);
 321         save beta; beta=45;
 322         save t; t=tense;
 323         fill z8r{dir(beta)}..z9r{right}..tension t..z10r{down}
 324                 ..tension t..
 325                 flare_path(z11r,180,-90,hair,flare, 1)
 326                 ..z11l{right}..tension t..z10l{up}..tension t
 327                 ..z9l{left}..z8l{dir(180+beta+10)}..cycle;
 328
 329 fet_endchar;
 330
 331 fet_beginchar("Numeral 6", "6", "six")
 332         draw_six;
 333 fet_endchar;
 334
 335 fet_beginchar("Numeral 7", "7", "seven")
 336         set_char_box(0, 11/15height#*widen, 0, height#);
 337         message "w:"&decimal w;
 338         message "h:"&decimal h;
 339
 340         save alpha; alpha=-180;
 341 if true:
 342         penpos1(3/2thick,180+alpha);
 343         penpos2(hair,180+alpha-45);
 344         z2=z1l+(1/4sqrt(2)*hair)*dir(alpha-135);
 345         penpos3(hair,180+alpha+45);
 346         z3=z1r+(1/4sqrt(2)*hair)*dir(alpha-45);
 347         z4=z1+kuulleke*dir(alpha-90);
 348 else:
 349         % shit, does not work
 350         calc_kuulleke(3/2thick,-alpha);
 351 fi
 352         z1l=(thin,0);
 353
 354         save beta; beta=55;
 355         penpos5(thin,90+beta);
 356         z5=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 357
 358         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 359         save delta; delta=12;
 360         pickup pencircle;
 361         fill z3l{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z2r..
 362                 z2l{dir(beta+delta)}..{dir(beta)}z5r
 363                 ..z5l{dir(180+beta)}..{dir(delta-90)}z3r..cycle;
 364         penlabels(1,2,3,4,5);
 365
 366         clearxy;
 367         save alpha; alpha=-45*widen;
 368         penpos1(1/2thick,90);
 369         z1=(3/2thin,h-(thick+thin)/2);
 370         penpos3(thin,90+beta);
 371         z3=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 372         penpos2(thick,90+alpha);
 373         x2=1/2[x1,x3]-1/4thick; y2=h-15/16thick+thin*widen;
 374
 375         penpos4(thin,0);
 376         z4l=(0,h-thin/2);
 377         penpos5(thin,0);
 378         z5l=(0,h/2+thin/2);
 379
 380         penpos6(9/8thick,90);
 381         z6r=(thin,y1r+2/16thick);
 382
 383         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(beta)}z3r
 384                 ..z3l{dir(180+beta)}..{dir(180+alpha)}z2l
 385                 ..{dir(180+beta)}z1l..z6l{down}..{down}z5r
 386                 ..z5l{up}..{up}z4l..z4r{down}..{down}z6r..{right}cycle;
 387         penlabels(1,2,3,4,5,6);
 388 fet_endchar;
 389
 390 fet_beginchar("Numeral 8", "8", "eight")
 391         set_char_box(0, 11/15height#*widen, 0, height#);
 392         message "w:"&decimal w;
 393         message "h:"&decimal h;
 394         save alpha; alpha=60;
 395         save beta; beta=alpha-15;
 396         z1=(w/2,h/2+thick/8);
 397         penpos2(hair,90+180+beta);
 398         z2=(w/3,h/2+thin);
 399         penpos3(3/2thin,0);
 400         z3l=(0,h/4+thin/2);
 401         penpos4(hair,90);
 402         z4l=(x1,0);
 403         penpos5(thick,90+90+alpha);
 404         z5=z1+w/4*dir(alpha-90);
 405         penpos6(thick,90+90+alpha);
 406         z6=z1+(w/4-thin/2)*dir(90+alpha);
 407         penpos7(hair,90);
 408         z7r=(x1,h);
 409         penpos8(3/2thin,0);
 410         z8r=(w-thin/2,3/4h+thin/2);
 411         penpos9(hair,90+180+beta);
 412         z9=(2/3w,h/2);
 413         penlabels(1,2,3,4,5,6,7,8,9);
 414         save t; t=tense;
 415         fill z2r{dir(180+beta)}..z3r{down}..z4r{right}
 416                 ..z5r{dir(90+alpha)}..z6r{dir(90+alpha)}
 417                 ..tension t..z7r{right}..z8r{down}..z9r{dir(180+beta)}
 418                 ..z9l{dir(beta)}..z8l{up}..z7l{left}..z6l{dir(alpha-90)}
 419                 ..z5l{dir(alpha-90)}..tension t..z4l{left}..z3l{up}
 420                 ..z2l{dir(beta)}..cycle;
 421 fet_endchar;
 422
 423 fet_beginchar("Numeral 9", "9", "nine")
 424         draw_six;
 425 %       xy_mirror_char;
 426         currentpicture := currentpicture scaled -1;
 427         currentpicture := currentpicture shifted (w,h);
 428 fet_endchar;
 429
 430 fet_endgroup("number")
 431