mf/feta-nummer-code.mf

   1 % feta-nummer.mf -- implement bold Orator numerals
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997--2002 Jan Nieuwenhuizen <janneke@gnu.org>
   8
   9 fet_begingroup("number")
  10
  11 define_pixels(height,thick,thick,thin,hair,flare);
  12 define_pixels(foot_top,foot_width);
  13 define_pixels(kuulleke);
  14
  15 def calc_kuulleke(expr w,alpha) =
  16         begingroup;
  17         save beta; beta=(alpha-90)/2;
  18         save gamma; gamma=(90+alpha)/2;
  19
  20         penpos1(w/cosd(alpha),alpha);
  21         penpos2(hair,90+beta);
  22         z2=z1l+(1/2hair/tand((alpha+90)/2))*dir(beta);
  23
  24         penpos3(hair,gamma-90);
  25         z3=z1r-(1/2hair/tand((90-alpha)/2))*dir(gamma);
  26         z4=z1+kuulleke*dir(alpha-90);
  27         endgroup;
  28         enddef;
  29
  30 % should make generic macro?
  31 %
  32 def draw_foot(expr xpos) =
  33         begingroup;
  34         clearxy;
  35         penpos1(thick,0);
  36         z1=(xpos,foot_top);
  37         penpos2(foot_width,0);
  38         z2=(x1,0);
  39         penpos3(hair,-90);
  40         z3r=z2r;
  41         penpos4(hair,90);
  42         z4l=z2l;
  43         z5=(x1,kuulleke);
  44         penlabels(1,2,3,4);
  45         fill z1..{right}z1r{down}..{right}z3l..z3r{left}..z5
  46                 ..{left}z4l..z4r{right}..{up}z1l{right}..z1..cycle;
  47         endgroup;
  48         enddef;
  49
  50 def draw_six =
  51         set_char_box(0, 2/3height#*widen, 0, height#);
  52         message "w:"&decimal w;
  53         message "h:"&decimal h;
  54
  55         penpos1(thin,90);
  56         z1=(thick,h/2+thin-hair/2);
  57         penpos2(hair,90);
  58
  59         z2=(w/2,y1);
  60         penpos3(7/8thick,0);
  61         % yup, should use the path fract [] "everywhere"
  62         z3r=(w,1/2[0,y1]);
  63         penpos4(hair,-90);
  64         z4r=(x2,0);
  65         penpos5(7/8thick,180);
  66         z5r=(0,y1);
  67         penpos6(hair,90);
  68         z6r=(w-flare,h);
  69         penpos7(7/8thick,180);
  70         z7r=(0,h/2);
  71         penpos10(7/8thick,180);
  72         z10r=(0,y3);
  73         penlabels(1,2,3,4,5,6,7,8,9,10,11);
  74         save t; t=tense;
  75         fill z7{right}..z2r{right}..tension t..z3r{down}
  76                 ..tension t..z4r{left}
  77                 ..tension t..z7r{up}..tension t..
  78                 flare_path (z6r,0,-90,hair,flare, 1)
  79                 ..tension t..z7l{down}..z10l{up}..cycle;
  80
  81         unfill z2l{right}..tension t..z3l{down}..tension t
  82                 ..z4l{left}..tension t..z10l{up}..tension t..cycle;
  83         enddef;
  84
  85 save dot_diam;
  86 dot_diam# = 7/8flare#;
  87 define_pixels(dot_diam);
  88
  89 code := 32;
  90 fet_beginchar("Space", "space", "space")
  91         set_char_box(0, space#,  0,height#);
  92 fet_endchar;
  93
  94 code := 43;  % , = 44
  95
  96 % urg
  97 fet_beginchar("Numeral comma", ",", "comma")
  98         set_char_box(0, dot_diam#, 3/2dot_diam#, dot_diam#);
  99         pickup pencircle scaled dot_diam;
 100         draw (dot_diam/2,dot_diam/2);
 101         z0=(w/3,0);
 102         alpha=65;
 103         penpos1(thin,alpha+90);
 104         z1l=(w/2,-1.5h+hair);
 105         z2=(w,h/2);
 106         pickup pencircle;
 107         filldraw z1l{dir(alpha)}..{up}z2..{z0-z2}z0{right}..{dir(180+alpha)}z1r..cycle;
 108         labels(0,1,2);
 109         penlabels(1);
 110 fet_endchar;
 111
 112 fet_beginchar("Numeral dash", "-", "dash")
 113         set_char_box(0, height#/3, 0, height#);
 114         pickup pencircle scaled thin;
 115         lft x1 = -b;
 116         rt x2 = w;
 117         y1 = y2 = h/3;
 118         draw z1 .. z2;
 119 fet_endchar;
 120
 121 fet_beginchar("Numeral dot", ".", "dot")
 122         set_char_box(0, dot_diam#, 0, dot_diam#);
 123         pickup pencircle scaled dot_diam;
 124         draw (dot_diam/2,dot_diam/2);
 125 fet_endchar;
 126
 127
 128 % skip slash
 129
 130 code := 47; % 0 = 48
 131
 132 fet_beginchar("Numeral 0", "0", "zero")
 133 %       set_char_box(0, 4/5height#*widen, 0, height#);
 134         set_char_box(0, 11/15height#*widen, 0, height#);
 135         message "w:"&decimal w;
 136         message "h:"&decimal h;
 137         penpos1(thin,90);
 138         z1r=(w/2,h);
 139         penpos2(thick,180);
 140         z2r=(0,h/2);
 141         penpos3(thin,-90);
 142         z3r=(w/2,0);
 143         penpos4(thick,0);
 144         z4r=(w,h/2);
 145         fill z1r..z2r..z3r..z4r..cycle;
 146         save t; t=1/tense;
 147         penlabels(1,2,3,4);
 148         unfill z1l..tension t..z2l..tension t..z3l
 149                 ..tension t..z4l..tension t..cycle;
 150 fet_endchar;
 151
 152 fet_beginchar("Numeral 1", "1", "one")
 153 %       set_char_box(0, 19/30height#*widen, 0, height#);
 154         set_char_box(0, 1/2foot_width#+3/2thick#+1/2hair#, 0, height#);
 155         message "w:"&decimal w;
 156         message "h:"&decimal h;
 157
 158         save alpha; alpha=0;
 159         calc_kuulleke(thick,alpha);
 160         z1=(3/2thick,height);
 161
 162         penpos5(thick,0);
 163         z5=(x1,foot_top);
 164
 165         z6=(0,h/2);
 166         save beta; beta=angle(z1l-z6);
 167         penpos7(thin,beta-90);
 168         z7l=z6;
 169         penpos8(thin/cosd(beta),-90);
 170         z8l=z1l;
 171         penpos9(thin,beta-90);
 172         z9r=z8r+(thin/cosd(beta))*(0,-1);
 173         penlabels(1,2,3,4,5,6,7,8,9);
 174         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 175         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l..z3r{down}
 176                 ..{down}z5r{left}..z5..{left}z5l{up}..{up}z2l..cycle;
 177         fill z7l{dir(beta)}..{dir(beta)}z1l..z2r..z9r{up}
 178                 ..z9l{dir(180+beta)}..{dir(180+beta)}z7r..cycle;
 179         penlabels(7,8,9);
 180
 181         draw_foot(x1);
 182 fet_endchar;
 183
 184 fet_beginchar("Numeral 2", "2", "two")
 185         set_char_box(0, 11/15height#*widen, 0, height#);
 186         message "w:"&decimal w;
 187         message "h:"&decimal h;
 188         clearxy;
 189         save alpha; alpha=-45*widen;
 190         save beta; beta=85;
 191         save gamma; gamma=beta-10;
 192         save theta; theta=20/widen;
 193         penpos1(hair,90+beta);
 194         z1=(0,0)+(1/2sqrt(2)*hair)*dir(45);
 195         penpos3(hair,90+gamma);
 196         z3=(w,thick)+(1/2sqrt(2)*hair)*dir(-135);
 197         penpos2(thick,90+alpha);
 198         x2-x1=x3-x2; y2=11/16thick/widen;
 199         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(gamma)}z3r
 200                 ..z3l{dir(180+gamma)}..{dir(180+alpha)}z2l
 201                 ..{dir(180+beta)}z1l..cycle;
 202
 203         penpos4(thick,0);
 204         z4r=(w-thin/2,.72h);
 205         penpos5(thin,90);
 206         z5r=(1/2hair+flare,h);
 207         penlabels(1,2,3,4);
 208         penlabels(5,6);
 209         save t; t=tense;
 210         fill z1l{dir(beta)}..tension t..z4r{up}
 211                 ..tension t..
 212                 flare_path(z5r,180,90,thin,flare,1)
 213                 ..z4l{down}..tension t
 214                 ..{dir(180+beta)}z1r..cycle;
 215 fet_endchar;
 216
 217 fet_beginchar("Numeral 3", "3", "three")
 218         set_char_box(0, 2/3height#*widen, 0, height#);
 219         message "w:"&decimal w;
 220         message "h:"&decimal h;
 221         penpos1(hair,-90);
 222         z1l=(17/16thick,h);
 223         penpos2(7/8thick,180);
 224         z2l=(w-thick/8,3/4h+thick/16);
 225         penpos3(thin,90);
 226         z3=(w/2,h/2+1/8thick);
 227         penpos4(thin,90);
 228         z4=(5/8thick+1/2thin,y3);
 229         penpos5(thick,0);
 230         z5r=(w,1/4h+thick/16);
 231         penpos6(hair,-90);
 232         z6r=(9/8thick,0);
 233         penpos7(3/2thin,90);
 234         z7=(x5,y3);
 235         penlabels(1,2,3,4,5,6,7);
 236         save alpha; alpha=25;
 237         save t; t=tense;
 238         pickup pencircle scaled 1;
 239 %       draw
 240         fill
 241                 flare_path (z1l, 180, 90, hair, 7/8 flare, -1) ..tension t..
 242                 z2l{down}..z7r{dir(180+alpha)}
 243                 ..z7l{dir(-alpha)}..z5r{down}..tension t..
 244
 245                 flare_path (z6r, 180, -90, hair, flare, 1) ..tension t..
 246
 247                 z5l{up}
 248                 ..tension t..z3l{left}..z4l{left}
 249                 ..z4r{right}..z3r{right}..tension t..z2r{up}
 250                 ..tension t.. cycle
 251 ;
 252 fet_endchar;
 253
 254
 255
 256 fet_beginchar("Numeral 4", "4", "four")
 257         set_char_box(0, 4/5height#*widen, 0, height#);
 258         message "w:"&decimal w;
 259         message "h:"&decimal h;
 260
 261         save alpha; alpha=0;
 262         calc_kuulleke(3/2thick,alpha);
 263         z1r=(w-3/4thick,height);
 264
 265         z5=(thin,1/4height+thin);
 266         save beta; beta=angle(z3r-z5);
 267         penpos6(thin,-90);
 268         z6l=z5;
 269         penpos7(thin,-90);
 270         y7=y6; x7=w-1/2thin;
 271         penpos8(thin,-alpha);
 272         z8r=z5;
 273         penlabels(1,2,3,4,5,6,7);
 274         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 275         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 276                 ..z3r{dir(180+beta)}..{dir(180+beta)}z8r{right}
 277                 ..{right}z7l..z7r{left}..{left}z6r..z8l{dir(beta)}
 278                 ..{up}z2l..cycle;
 279
 280         clearxy;
 281
 282         save alpha; alpha=beta;
 283         calc_kuulleke(thick,alpha);
 284         z1r=(w-3/4thick,height-(3/2thin)/cosd(alpha));
 285
 286         penpos5(thick,0);
 287         z5=(x1,foot_top);
 288
 289         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 290         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 291                 ..z3r{down}..{down}z5r{left}..z5..{left}z5l{up}
 292                 ..{up}z2l..cycle;
 293         penlabels(1,2,3,4,5);
 294
 295         draw_foot(x5);
 296 fet_endchar;
 297
 298 fet_beginchar("Numeral 5", "5", "five")
 299         set_char_box(0, 7/10height#*widen, 0, height#);
 300         message "w:"&decimal w;
 301         message "h:"&decimal h;
 302         calc_kuulleke(w-thin,0);
 303         z1=(w/2+1/8thick,h);
 304         save alpha; alpha=0;
 305         penpos5(thin,0);
 306         z5l=(x1l,h-15/16thick);
 307         penpos6(hair,90-45);
 308         z6=z5r+1/2hair*dir(-45);
 309         penpos7(thin,0);
 310         z7l=(x1l,h/2+thin-hair);
 311         penlabels(1,2,3,4,5,6,7);
 312         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 313         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 314                 ..z3r{dir(-135)}..{left}z6r..z6l{down}..z7r{down}
 315                 ..z7l{up}..{up}z2l..cycle;
 316         penpos8(thin,90);
 317         z8l=(x7r,y7r-1/16thick);
 318         penpos9(thin,90);
 319         z9=(x11+3/16thick,10/16[y5,y7]);
 320         penpos10(thick,0);
 321         z10r=(w,1/2[y9r,y11r]);
 322         penpos11(hair,-90);
 323         z11r=(9/8thick,0);
 324         penlabels(8,9,10,11);
 325         save beta; beta=45;
 326         save t; t=tense;
 327         fill z8r{dir(beta)}..z9r{right}..tension t..z10r{down}
 328                 ..tension t..
 329                 flare_path(z11r,180,-90,hair,flare, 1)
 330                 ..z11l{right}..tension t..z10l{up}..tension t
 331                 ..z9l{left}..z8l{dir(180+beta+10)}..cycle;
 332
 333 fet_endchar;
 334
 335 fet_beginchar("Numeral 6", "6", "six")
 336         draw_six;
 337 fet_endchar;
 338
 339 fet_beginchar("Numeral 7", "7", "seven")
 340         set_char_box(0, 11/15height#*widen, 0, height#);
 341         message "w:"&decimal w;
 342         message "h:"&decimal h;
 343
 344         save alpha; alpha=-180;
 345 if true:
 346         penpos1(3/2thick,180+alpha);
 347         penpos2(hair,180+alpha-45);
 348         z2=z1l+(1/4sqrt(2)*hair)*dir(alpha-135);
 349         penpos3(hair,180+alpha+45);
 350         z3=z1r+(1/4sqrt(2)*hair)*dir(alpha-45);
 351         z4=z1+kuulleke*dir(alpha-90);
 352 else:
 353         % shit, does not work
 354         calc_kuulleke(3/2thick,-alpha);
 355 fi
 356         z1l=(thin,0);
 357
 358         save beta; beta=55;
 359         penpos5(thin,90+beta);
 360         z5=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 361
 362         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 363         save delta; delta=12;
 364         pickup pencircle;
 365         fill z3l{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z2r..
 366                 z2l{dir(beta+delta)}..{dir(beta)}z5r
 367                 ..z5l{dir(180+beta)}..{dir(delta-90)}z3r..cycle;
 368         penlabels(1,2,3,4,5);
 369
 370         clearxy;
 371         save alpha; alpha=-45*widen;
 372         penpos1(1/2thick,90);
 373         z1=(3/2thin,h-(thick+thin)/2);
 374         penpos3(thin,90+beta);
 375         z3=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 376         penpos2(thick,90+alpha);
 377         x2=1/2[x1,x3]-1/4thick; y2=h-15/16thick+thin*widen;
 378
 379         penpos4(thin,0);
 380         z4l=(0,h-thin/2);
 381         penpos5(thin,0);
 382         z5l=(0,h/2+thin/2);
 383
 384         penpos6(9/8thick,90);
 385         z6r=(thin,y1r+2/16thick);
 386
 387         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(beta)}z3r
 388                 ..z3l{dir(180+beta)}..{dir(180+alpha)}z2l
 389                 ..{dir(180+beta)}z1l..z6l{down}..{down}z5r
 390                 ..z5l{up}..{up}z4l..z4r{down}..{down}z6r..{right}cycle;
 391         penlabels(1,2,3,4,5,6);
 392 fet_endchar;
 393
 394 fet_beginchar("Numeral 8", "8", "eight")
 395         set_char_box(0, 11/15height#*widen, 0, height#);
 396         message "w:"&decimal w;
 397         message "h:"&decimal h;
 398         save alpha; alpha=60;
 399         save beta; beta=alpha-15;
 400         z1=(w/2,h/2+thick/8);
 401         penpos2(hair,90+180+beta);
 402         z2=(w/3,h/2+thin);
 403         penpos3(3/2thin,0);
 404         z3l=(0,h/4+thin/2);
 405         penpos4(hair,90);
 406         z4l=(x1,0);
 407         penpos5(thick,90+90+alpha);
 408         z5=z1+w/4*dir(alpha-90);
 409         penpos6(thick,90+90+alpha);
 410         z6=z1+(w/4-thin/2)*dir(90+alpha);
 411         penpos7(hair,90);
 412         z7r=(x1,h);
 413         penpos8(3/2thin,0);
 414         z8r=(w-thin/2,3/4h+thin/2);
 415         penpos9(hair,90+180+beta);
 416         z9=(2/3w,h/2);
 417         penlabels(1,2,3,4,5,6,7,8,9);
 418         save t; t=tense;
 419         fill z2r{dir(180+beta)}..z3r{down}..z4r{right}
 420                 ..z5r{dir(90+alpha)}..z6r{dir(90+alpha)}
 421                 ..tension t..z7r{right}..z8r{down}..z9r{dir(180+beta)}
 422                 ..z9l{dir(beta)}..z8l{up}..z7l{left}..z6l{dir(alpha-90)}
 423                 ..z5l{dir(alpha-90)}..tension t..z4l{left}..z3l{up}
 424                 ..z2l{dir(beta)}..cycle;
 425 fet_endchar;
 426
 427 fet_beginchar("Numeral 9", "9", "nine")
 428         draw_six;
 429 %       xy_mirror_char;
 430         currentpicture := currentpicture scaled -1;
 431         currentpicture := currentpicture shifted (w,h);
 432 fet_endchar;
 433
 434 fet_endgroup("number")
 435