mf/feta-nummer-code.mf

   1 % feta-nummer.mf -- implement bold Orator numerals
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997--2002 Jan Nieuwenhuizen <janneke@gnu.org>
   8
   9 %
  10 % These numbers were taken from a part that that the EJE violas played
  11 % 1997 -- Probably Mendelssohn's ouverture Heimkehr aus der Fremde.
  12 %
  13
  14 %
  15 % TODO all the invocation of flare_path are weird --
  16 % the horizontal tangents should be more at the center of the
  17 % glyph.
  18 %
  19
  20 fet_begingroup("number")
  21
  22 define_pixels(height,thick,thick,thin,hair,flare);
  23 define_pixels(foot_top,foot_width);
  24 define_pixels(kuulleke);
  25
  26
  27
  28 %
  29 % Yet Another Bulb Routine with smooth inside curve.
  30 %
  31 % alpha = start direction.
  32 % beta = which side to turn to.
  33 % flare = diameter of the bulb
  34 % line = diameter of line attachment
  35 % direction = is ink on left or right side (1 or -1)
  36 %
  37
  38 def number_flare_path(expr pos,alpha,beta,line,flare,
  39
  40                         move_away_to,
  41                         turn_to,
  42                         away_from_start_pos, direction) =
  43         begingroup;
  44         clearxy;
  45
  46         z5 = z2 + 0.43* flare *dir (alpha - 1.5 beta);
  47
  48         save taille;
  49
  50         taille = 0.06;
  51         z4 = (0.75 - taille)  [z2r, z2l] + whatever* dir (alpha - beta) ;
  52         z4 = (0.00 + .4 taille) [z3l, z3r] + whatever* dir(alpha);
  53         penpos1(line,180+beta+alpha);
  54         z1r=pos;
  55
  56         z2r = z1r + move_away_to *dir (alpha) + (line + turn_to) * dir(alpha+beta);
  57         z3r = 0.5 [z2l,z2r] + 0.5 *flare *dir(alpha + beta);
  58
  59         penpos2(flare, alpha );
  60         penpos3(flare, alpha +  beta);
  61         penlabels(1, 2, 3, 4, 5);
  62         pickup pencircle;
  63
  64         save p;
  65         path p;
  66         p := z1r{dir(alpha)}
  67                 .. z2r{dir(180+alpha-beta)}
  68                 .. z3r{dir(alpha+180)}
  69                 .. z2l{dir(alpha-beta)}
  70
  71
  72 %%% Two versions of the curve: one with z4, the other with z5.
  73 %               .. z5{dir(alpha- beta/2 )}
  74                 ..z4{dir(180+alpha+beta)}
  75                 ..z1l{dir(alpha+180)};
  76 %       draw p ;
  77         if direction = 1:
  78                 p
  79         else:
  80                 reverse p
  81         fi
  82         endgroup
  83         enddef;
  84
  85
  86
  87 def calc_kuulleke(expr w,alpha) =
  88         begingroup;
  89         save beta; beta=(alpha-90)/2;
  90         save gamma; gamma=(90+alpha)/2;
  91
  92         penpos1(w/cosd(alpha),alpha);
  93         penpos2(hair,90+beta);
  94         z2=z1l+(1/2hair/tand((alpha+90)/2))*dir(beta);
  95
  96         penpos3(hair,gamma-90);
  97         z3=z1r-(1/2hair/tand((90-alpha)/2))*dir(gamma);
  98         z4=z1+kuulleke*dir(alpha-90);
  99         endgroup;
 100         enddef;
 101
 102 % should make generic macro?
 103 %
 104 def draw_foot(expr xpos) =
 105         begingroup;
 106         clearxy;
 107         penpos1(thick,0);
 108         z1=(xpos,foot_top);
 109         penpos2(foot_width,0);
 110         z2=(x1,0);
 111         penpos3(hair,-90);
 112         z3r=z2r;
 113         penpos4(hair,90);
 114         z4l=z2l;
 115         z5=(x1,kuulleke);
 116         penlabels(1,2,3,4);
 117         fill z1..{right}z1r{down}..{right}z3l..z3r{left}..z5
 118                 ..{left}z4l..z4r{right}..{up}z1l{right}..z1..cycle;
 119         endgroup;
 120         enddef;
 121
 122 def draw_six =
 123         set_char_box(0, 2/3height#*widen, 0, height#);
 124         message "w:"&decimal w;
 125         message "h:"&decimal h;
 126
 127         penpos1(thin,90);
 128         z1=(thick,h/2+thin-hair/2);
 129         penpos2(hair,90);
 130
 131         z2=(w/2,y1);
 132         penpos3(7/8thick,0);
 133         % yup, should use the path fract [] "everywhere"
 134         z3r=(w,1/2[0,y1]);
 135         penpos4(hair,-90);
 136         z4r=(x2,0);
 137         penpos6(hair,90);
 138         z6r=(w-flare,h);
 139         penpos7(7/8thick,180);
 140         z7r=(0,h/2);
 141         penpos10(7/8thick,180);
 142         z10r=(0,y3);
 143         penlabels(1,2,3,4,5,6,7,8,9,10,11);
 144
 145
 146         save t; t=tense;
 147         fill z7{right}..z2r{right}..tension t..z3r{down}
 148                 ..tension t..z4r{left}
 149                 ..tension t..z7r{up}
 150                 .. super_curvelet(z7r, z6r, 0.76, 1)
 151                 .. flare_path (z6r,0,-90,hair,flare, 1)
 152
 153                 ..tension t..z7l{down}..z10l{up}..cycle;
 154
 155         unfill z2l{right}..tension t..z3l{down}..tension t
 156                 ..z4l{left}..tension t..z10l{up}..tension t..cycle;
 157         enddef;
 158
 159 save dot_diam;
 160 dot_diam# = 7/8flare#;
 161 define_pixels(dot_diam);
 162
 163 code := 32;
 164 fet_beginchar("Space", "space", "space")
 165         set_char_box(0, space#,  0,height#);
 166 fet_endchar;
 167
 168 code := 43;  % , = 44
 169
 170 % urg
 171 fet_beginchar("Numeral comma", ",", "comma")
 172         set_char_box(0, dot_diam#, 3/2dot_diam#, dot_diam#);
 173         pickup pencircle scaled dot_diam;
 174         draw (dot_diam/2,dot_diam/2);
 175         z0=(w/3,0);
 176         alpha=65;
 177         penpos1(thin,alpha+90);
 178         z1l=(w/2,-1.5h+hair);
 179         z2=(w,h/2);
 180         pickup pencircle;
 181         filldraw z1l{dir(alpha)}..{up}z2..{z0-z2}z0{right}..{dir(180+alpha)}z1r..cycle;
 182         labels(0,1,2);
 183         penlabels(1);
 184 fet_endchar;
 185
 186 fet_beginchar("Numeral dash", "-", "dash")
 187         set_char_box(0, height#/3, 0, height#);
 188         pickup pencircle scaled thin;
 189         lft x1 = -b;
 190         rt x2 = w;
 191         y1 = y2 = h/3;
 192         draw z1 .. z2;
 193 fet_endchar;
 194
 195 fet_beginchar("Numeral dot", ".", "dot")
 196         set_char_box(0, dot_diam#, 0, dot_diam#);
 197         pickup pencircle scaled dot_diam;
 198         draw (dot_diam/2,dot_diam/2);
 199 fet_endchar;
 200
 201
 202 % skip slash
 203
 204 code := 47; % 0 = 48
 205
 206 fet_beginchar("Numeral 0", "0", "zero")
 207 %       set_char_box(0, 4/5height#*widen, 0, height#);
 208         set_char_box(0, 11/15height#*widen, 0, height#);
 209         message "w:"&decimal w;
 210         message "h:"&decimal h;
 211         penpos1(thin,90);
 212         z1r=(w/2,h);
 213         penpos2(thick,180);
 214         z2r=(0,h/2);
 215         penpos3(thin,-90);
 216         z3r=(w/2,0);
 217         penpos4(thick,0);
 218         z4r=(w,h/2);
 219         fill z1r..z2r..z3r..z4r..cycle;
 220         save t; t=1/tense;
 221         penlabels(1,2,3,4);
 222         unfill z1l..tension t..z2l..tension t..z3l
 223                 ..tension t..z4l..tension t..cycle;
 224 fet_endchar;
 225
 226 fet_beginchar("Numeral 1", "1", "one")
 227 %       set_char_box(0, 19/30height#*widen, 0, height#);
 228         set_char_box(0, 1/2foot_width#+3/2thick#+1/2hair#, 0, height#);
 229         message "w:"&decimal w;
 230         message "h:"&decimal h;
 231
 232         save alpha; alpha=0;
 233         calc_kuulleke(thick,alpha);
 234         z1=(3/2thick,height);
 235
 236         penpos5(thick,0);
 237         z5=(x1,foot_top);
 238
 239         z6=(0,h/2);
 240         save beta; beta=angle(z1l-z6);
 241         penpos7(thin,beta-90);
 242         z7l=z6;
 243         penpos8(thin/cosd(beta),-90);
 244         z8l=z1l;
 245         penpos9(thin,beta-90);
 246         z9r=z8r+(thin/cosd(beta))*(0,-1);
 247         penlabels(1,2,3,4,5,6,7,8,9);
 248         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 249         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l..z3r{down}
 250                 ..{down}z5r{left}..z5..{left}z5l{up}..{up}z2l..cycle;
 251         fill z7l{dir(beta)}..{dir(beta)}z1l..z2r..z9r{up}
 252                 ..z9l{dir(180+beta)}..{dir(180+beta)}z7r..cycle;
 253         penlabels(7,8,9);
 254
 255         draw_foot(x1);
 256 fet_endchar;
 257
 258 fet_beginchar("Numeral 2", "2", "two")
 259         set_char_box(0, 11/15height#*widen, 0, height#);
 260         message "w:"&decimal w;
 261         message "h:"&decimal h;
 262         clearxy;
 263         save alpha; alpha=-45*widen;
 264         save beta; beta=85;
 265         save gamma; gamma=beta-10;
 266         save flare_start_distance;
 267
 268         flare_start = 0.25 ;
 269         save theta; theta=20/widen;
 270         penpos1(hair,90+beta);
 271         z1=(0,0)+(1/2sqrt(2)*hair)*dir(45);
 272         penpos3(hair,90+gamma);
 273         z3=(w,thick)+(1/2sqrt(2)*hair)*dir(-135);
 274         penpos2(thick, 90+alpha -15);
 275         x2-x1=x3-x2;
 276         y2=10/16 thick/widen;
 277         fill z1r{dir(beta)}.. tension 0.9 .. {dir(alpha + 10)}z2r..{dir(gamma)}z3r
 278                 ..z3l{dir(180+gamma)}..{dir(180+alpha - 5)}z2l
 279                 ..{dir(180+beta)}z1l..cycle;
 280
 281         penpos4(0.85 thick,0);
 282         z4r=(w-thin/2, .71 h);
 283         penpos5(hair,90);
 284         y5r = h;
 285         x5r = 1/2 hair + 1.0 flare + flare_start* flare;
 286
 287         penlabels(1,2,3,4);
 288         penlabels(5,6);
 289         save t; t=tense;
 290
 291         save p;
 292         path p ;
 293         p := z1l{dir(beta)}..tension t..z4r{up}
 294                 .. number_flare_path(z5r,180,90,hair, flare,
 295                                 x5r  - 1/2 hair,
 296                                 .20 h,
 297                                 flare_start* flare, 1)
 298                 .. z4l{down}..tension t
 299                 ..{dir(180+beta)}z1r..cycle;
 300
 301         pickup pencircle scaled 1;
 302 %       draw p;
 303         fill p;
 304
 305 fet_endchar;
 306
 307 fet_beginchar("Numeral 3", "3", "three")
 308         set_char_box(0, 2/3height#*widen, 0, height#);
 309         message "w:"&decimal w;
 310         message "h:"&decimal h;
 311         penpos1(hair,-90);
 312         z1l=(17/16thick,h);
 313         penpos2(7/8thick,180);
 314         z2l=(w-thick/8,3/4h+thick/16);
 315         penpos3(thin,90);
 316         z3=(w/2,h/2+1/8thick);
 317         penpos4(thin,90);
 318         z4=(5/8thick+1/2thin,y3);
 319         penpos5(thick,0);
 320         z5r=(w,1/4h+thick/16);
 321         penpos6(hair,-90);
 322         z6r=(9/8thick,0);
 323         penpos7(3/2thin,90);
 324         z7=(x5,y3);
 325         penlabels(1,2,3,4,5,6,7);
 326         save alpha; alpha=25;
 327         save t; t=tense;
 328         pickup pencircle scaled 1;
 329 %       draw
 330         fill
 331                 flare_path (z1l, 180, 90, hair, 7/8 flare, -1)
 332                 .. super_curvelet(z1l, z2l, 0.76, -1)
 333                 .. z2l{down}..z7r{dir(180+alpha)}
 334                 ..z7l{dir(-alpha)}..z5r{down}..tension t..
 335
 336                 flare_path (z6r, 180, -90, hair, flare, 1) ..tension t..
 337
 338                 z5l{up}
 339                 ..tension t..z3l{left}..z4l{left}
 340                 ..z4r{right}..z3r{right}..tension t..z2r{up}
 341                 ..tension t.. cycle
 342 ;
 343 fet_endchar;
 344
 345
 346
 347 fet_beginchar("Numeral 4", "4", "four")
 348         set_char_box(0, 4/5height#*widen, 0, height#);
 349         message "w:"&decimal w;
 350         message "h:"&decimal h;
 351
 352         save alpha; alpha=0;
 353         calc_kuulleke(3/2thick,alpha);
 354         z1r=(w-3/4thick,height);
 355
 356         z5=(thin,1/4height+thin);
 357         save beta; beta=angle(z3r-z5);
 358         penpos6(thin,-90);
 359         z6l=z5;
 360         penpos7(thin,-90);
 361         y7=y6; x7=w-1/2thin;
 362         penpos8(thin,-alpha);
 363         z8r=z5;
 364         penlabels(1,2,3,4,5,6,7);
 365         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 366         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 367                 ..z3r{dir(180+beta)}..{dir(180+beta)}z8r{right}
 368                 ..{right}z7l..z7r{left}..{left}z6r..z8l{dir(beta)}
 369                 ..{up}z2l..cycle;
 370
 371         clearxy;
 372
 373         save alpha; alpha=beta;
 374         calc_kuulleke(thick,alpha);
 375         z1r=(w-3/4thick,height-(3/2thin)/cosd(alpha));
 376
 377         penpos5(thick,0);
 378         z5=(x1,foot_top);
 379
 380         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 381         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 382                 ..z3r{down}..{down}z5r{left}..z5..{left}z5l{up}
 383                 ..{up}z2l..cycle;
 384         penlabels(1,2,3,4,5);
 385
 386         draw_foot(x5);
 387 fet_endchar;
 388
 389 fet_beginchar("Numeral 5", "5", "five")
 390         set_char_box(0, 7/10height#*widen, 0, height#);
 391         message "w:"&decimal w;
 392         message "h:"&decimal h;
 393         calc_kuulleke(w-thin,0);
 394         z1=(w/2+1/8thick,h);
 395         save alpha; alpha=0;
 396         penpos5(thin,0);
 397         z5l=(x1l,h-15/16thick);
 398         penpos6(hair,90-45);
 399         z6=z5r+1/2hair*dir(-45);
 400         penpos7(thin,0);
 401         z7l=(x1l,h/2+thin-hair);
 402         penlabels(1,2,3,4,5,6,7);
 403         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 404         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 405                 ..z3r{dir(-135)}..{left}z6r..z6l{down}..z7r{down}
 406                 ..z7l{up}..{up}z2l..cycle;
 407         penpos8(thin,90);
 408         z8l=(x7r,y7r-1/16thick);
 409         penpos9(thin,90);
 410         z9=(x11+3/16thick,10/16[y5,y7]);
 411         penpos10(thick,0);
 412         z10r=(w,1/2[y9r,y11r]);
 413         penpos11(hair,-90);
 414         z11r=(9/8thick,0);
 415         penlabels(8,9,10,11);
 416         save beta; beta=45;
 417         save t; t=tense;
 418         fill z8r{dir(beta)}..z9r{right}..tension t..z10r{down}
 419                 .. super_curvelet(z10r, z11r, 0.76, 1)
 420                 .. flare_path(z11r,180,-90,hair,flare, 1)
 421                 ..z11l{right}..tension t..z10l{up}..tension t
 422                 ..z9l{left}..z8l{dir(180+beta+10)}..cycle;
 423
 424 fet_endchar;
 425
 426 fet_beginchar("Numeral 6", "6", "six")
 427         draw_six;
 428 fet_endchar;
 429
 430 fet_beginchar("Numeral 7", "7", "seven")
 431         set_char_box(0, 11/15height#*widen, 0, height#);
 432         message "w:"&decimal w;
 433         message "h:"&decimal h;
 434
 435         save alpha; alpha=-180;
 436 if true:
 437         penpos1(3/2thick,180+alpha);
 438         penpos2(hair,180+alpha-45);
 439         z2=z1l+(1/4sqrt(2)*hair)*dir(alpha-135);
 440         penpos3(hair,180+alpha+45);
 441         z3=z1r+(1/4sqrt(2)*hair)*dir(alpha-45);
 442         z4=z1+kuulleke*dir(alpha-90);
 443 else:
 444         % shit, does not work
 445         calc_kuulleke(3/2thick,-alpha);
 446 fi
 447         z1l=(thin,0);
 448
 449         save beta; beta=55;
 450         penpos5(thin,90+beta);
 451         z5=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 452
 453         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 454         save delta; delta=12;
 455         pickup pencircle;
 456         fill z3l{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z2r..
 457                 z2l{dir(beta+delta)}..{dir(beta)}z5r
 458                 ..z5l{dir(180+beta)}..{dir(delta-90)}z3r..cycle;
 459         penlabels(1,2,3,4,5);
 460
 461         clearxy;
 462         save alpha; alpha=-45*widen;
 463         penpos1(1/2thick,90);
 464         z1=(3/2thin,h-(thick+thin)/2);
 465         penpos3(thin,90+beta);
 466         z3=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 467         penpos2(thick,90+alpha);
 468         x2=1/2[x1,x3]-1/4thick; y2=h-15/16thick+thin*widen;
 469
 470         penpos4(thin,0);
 471         z4l=(0,h-thin/2);
 472         penpos5(thin,0);
 473         z5l=(0,h/2+thin/2);
 474
 475         penpos6(9/8thick,90);
 476         z6r=(thin,y1r+2/16thick);
 477
 478         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(beta)}z3r
 479                 ..z3l{dir(180+beta)}..{dir(180+alpha)}z2l
 480                 ..{dir(180+beta)}z1l..z6l{down}..{down}z5r
 481                 ..z5l{up}..{up}z4l..z4r{down}..{down}z6r..{right}cycle;
 482         penlabels(1,2,3,4,5,6);
 483 fet_endchar;
 484
 485 fet_beginchar("Numeral 8", "8", "eight")
 486         set_char_box(0, 11/15height#*widen, 0, height#);
 487         message "w:"&decimal w;
 488         message "h:"&decimal h;
 489         save alpha; alpha=60;
 490         save beta; beta=alpha-15;
 491         z1=(w/2,h/2+thick/8);
 492         penpos2(hair,90+180+beta);
 493         z2=(w/3,h/2+thin);
 494         penpos3(3/2thin,0);
 495         z3l=(0,h/4+thin/2);
 496         penpos4(hair,90);
 497         z4l=(x1,0);
 498         penpos5(thick,90+90+alpha);
 499         z5=z1+w/4*dir(alpha-90);
 500         penpos6(thick,90+90+alpha);
 501         z6=z1+(w/4-thin/2)*dir(90+alpha);
 502         penpos7(hair,90);
 503         z7r=(x1,h);
 504         penpos8(3/2thin,0);
 505         z8r=(w-thin/2,3/4h+thin/2);
 506         penpos9(hair,90+180+beta);
 507         z9=(2/3w,h/2);
 508         penlabels(1,2,3,4,5,6,7,8,9);
 509         save t; t=tense;
 510         fill z2r{dir(180+beta)}..z3r{down}..z4r{right}
 511                 ..z5r{dir(90+alpha)}..z6r{dir(90+alpha)}
 512                 ..tension t..z7r{right}..z8r{down}..z9r{dir(180+beta)}
 513                 ..z9l{dir(beta)}..z8l{up}..z7l{left}..z6l{dir(alpha-90)}
 514                 ..z5l{dir(alpha-90)}..tension t..z4l{left}..z3l{up}
 515                 ..z2l{dir(beta)}..cycle;
 516 fet_endchar;
 517
 518 fet_beginchar("Numeral 9", "9", "nine")
 519         draw_six;
 520 %       xy_mirror_char;
 521         currentpicture := currentpicture scaled -1;
 522         currentpicture := currentpicture shifted (w,h);
 523 fet_endchar;
 524
 525 fet_endgroup("number")
 526