mf/feta-nummer-code.mf

   1 % feta-nummer.mf -- implement bold Orator numerals
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997--2001 Jan Nieuwenhuizen <janneke@gnu.org>
   8
   9 fet_begingroup("number")
  10
  11 define_pixels(height,thick,thick,thin,hair,flare);
  12 define_pixels(foot_top,foot_width);
  13 define_pixels(kuulleke);
  14
  15 def calc_kuulleke(expr w,alpha) =
  16         begingroup;
  17         save beta; beta=(alpha-90)/2;
  18         save gamma; gamma=(90+alpha)/2;
  19
  20         penpos1(w/cosd(alpha),alpha);
  21         penpos2(hair,90+beta);
  22         z2=z1l+(1/2hair/tand((alpha+90)/2))*dir(beta);
  23
  24         penpos3(hair,gamma-90);
  25         z3=z1r-(1/2hair/tand((90-alpha)/2))*dir(gamma);
  26         z4=z1+kuulleke*dir(alpha-90);
  27         endgroup;
  28         enddef;
  29
  30 % should make generic macro?
  31 %
  32 def draw_foot(expr xpos) =
  33         begingroup;
  34         clearxy;
  35         penpos1(thick,0);
  36         z1=(xpos,foot_top);
  37         penpos2(foot_width,0);
  38         z2=(x1,0);
  39         penpos3(hair,-90);
  40         z3r=z2r;
  41         penpos4(hair,90);
  42         z4l=z2l;
  43         z5=(x1,kuulleke);
  44         penlabels(1,2,3,4);
  45         fill z1..{right}z1r{down}..{right}z3l..z3r{left}..z5
  46                 ..{left}z4l..z4r{right}..{up}z1l{right}..z1..cycle;
  47         endgroup;
  48         enddef;
  49
  50 def draw_six =
  51         set_char_box(0, 2/3height#*widen, 0, height#);
  52         message "w:"&decimal w;
  53         message "h:"&decimal h;
  54
  55         penpos1(thin,90);
  56         z1=(thick,h/2+thin-hair/2);
  57         penpos2(hair,90);
  58
  59         z2=(w/2,y1);
  60         penpos3(7/8thick,0);
  61         % yup, should use the path fract [] "everywhere"
  62         z3r=(w,1/2[0,y1]);
  63         penpos4(hair,-90);
  64         z4r=(x2,0);
  65         penpos5(7/8thick,180);
  66         z5r=(0,y1);
  67         penpos6(hair,90);
  68         z6r=(w-flare,h);
  69         penpos7(7/8thick,180);
  70         z7r=(0,h/2);
  71         penpos10(7/8thick,180);
  72         z10r=(0,y3);
  73         penlabels(1,2,3,4,5,6,7,8,9,10,11);
  74         save t; t=tense;
  75         fill z7{right}..z2r{right}..tension t..z3r{down}
  76                 ..tension t..z4r{left}
  77                 ..tension t..z7r{up}..tension t..z6r{right}
  78                 ..z6l{left}..tension t..z7l{down}..z10l{up}..cycle;
  79         draw_flare(z6r,0,-90,hair,flare);
  80         unfill z2l{right}..tension t..z3l{down}..tension t
  81                 ..z4l{left}..tension t..z10l{up}..tension t..cycle;
  82         enddef;
  83
  84 save dot_diam;
  85 dot_diam# = 7/8flare#;
  86 define_pixels(dot_diam);
  87
  88
  89 code := 43;  % , = 44
  90
  91 % urg
  92 fet_beginchar("Numeral comma", ",", "comma")
  93         set_char_box(0, dot_diam#, 3/2dot_diam#, dot_diam#);
  94         pickup pencircle scaled dot_diam;
  95         draw (dot_diam/2,dot_diam/2);
  96         z0=(w/3,0);
  97         alpha=65;
  98         penpos1(thin,alpha+90);
  99         z1l=(w/2,-1.5h+hair);
 100         z2=(w,h/2);
 101         pickup pencircle;
 102         filldraw z1l{dir(alpha)}..{up}z2..{z0-z2}z0{right}..{dir(180+alpha)}z1r..cycle;
 103         labels(0,1,2);
 104         penlabels(1);
 105 fet_endchar;
 106
 107 fet_beginchar("Numeral dash", "-", "dash")
 108         set_char_box(0, height#/3, 0, height#);
 109         pickup pencircle scaled thin;
 110         lft x1 = -b;
 111         rt x2 = w;
 112         y1 = y2 = h/3;
 113         draw z1 .. z2;
 114 fet_endchar;
 115
 116 fet_beginchar("Numeral dot", ".", "dot")
 117         set_char_box(0, dot_diam#, 0, dot_diam#);
 118         pickup pencircle scaled dot_diam;
 119         draw (dot_diam/2,dot_diam/2);
 120 fet_endchar;
 121
 122
 123 % skip slash
 124
 125 code := 47; % 0 = 48
 126
 127 fet_beginchar("Numeral 0", "0", "zero")
 128 %       set_char_box(0, 4/5height#*widen, 0, height#);
 129         set_char_box(0, 11/15height#*widen, 0, height#);
 130         message "w:"&decimal w;
 131         message "h:"&decimal h;
 132         penpos1(thin,90);
 133         z1r=(w/2,h);
 134         penpos2(thick,180);
 135         z2r=(0,h/2);
 136         penpos3(thin,-90);
 137         z3r=(w/2,0);
 138         penpos4(thick,0);
 139         z4r=(w,h/2);
 140         fill z1r..z2r..z3r..z4r..cycle;
 141         save t; t=1/tense;
 142         penlabels(1,2,3,4);
 143         unfill z1l..tension t..z2l..tension t..z3l
 144                 ..tension t..z4l..tension t..cycle;
 145 fet_endchar;
 146
 147 fet_beginchar("Numeral 1", "1", "one")
 148 %       set_char_box(0, 19/30height#*widen, 0, height#);
 149         set_char_box(0, 1/2foot_width#+3/2thick#+1/2hair#, 0, height#);
 150         message "w:"&decimal w;
 151         message "h:"&decimal h;
 152
 153         save alpha; alpha=0;
 154         calc_kuulleke(thick,alpha);
 155         z1=(3/2thick,height);
 156
 157         penpos5(thick,0);
 158         z5=(x1,foot_top);
 159
 160         z6=(0,h/2);
 161         save beta; beta=angle(z1l-z6);
 162         penpos7(thin,beta-90);
 163         z7l=z6;
 164         penpos8(thin/cosd(beta),-90);
 165         z8l=z1l;
 166         penpos9(thin,beta-90);
 167         z9r=z8r+(thin/cosd(beta))*(0,-1);
 168         penlabels(1,2,3,4,5,6,7,8,9);
 169         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 170         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l..z3r{down}
 171                 ..{down}z5r{left}..z5..{left}z5l{up}..{up}z2l..cycle;
 172         fill z7l{dir(beta)}..{dir(beta)}z1l..z2r..z9r{up}
 173                 ..z9l{dir(180+beta)}..{dir(180+beta)}z7r..cycle;
 174         penlabels(7,8,9);
 175
 176         draw_foot(x1);
 177 fet_endchar;
 178
 179 fet_beginchar("Numeral 2", "2", "two")
 180         set_char_box(0, 11/15height#*widen, 0, height#);
 181         message "w:"&decimal w;
 182         message "h:"&decimal h;
 183         clearxy;
 184         save alpha; alpha=-45*widen;
 185         save beta; beta=85;
 186         save gamma; gamma=beta-10;
 187         save theta; theta=20/widen;
 188         penpos1(hair,90+beta);
 189         z1=(0,0)+(1/2sqrt(2)*hair)*dir(45);
 190         penpos3(hair,90+gamma);
 191         z3=(w,thick)+(1/2sqrt(2)*hair)*dir(-135);
 192         penpos2(thick,90+alpha);
 193         x2-x1=x3-x2; y2=11/16thick/widen;
 194         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(gamma)}z3r
 195                 ..z3l{dir(180+gamma)}..{dir(180+alpha)}z2l
 196                 ..{dir(180+beta)}z1l..cycle;
 197
 198         penpos4(thick,0);
 199         z4r=(w-thin/2,.72h);
 200         penpos5(thin,90);
 201         z5r=(1/2hair+flare,h);
 202         penlabels(1,2,3,4);
 203         penlabels(5,6);
 204         save t; t=tense;
 205         fill z1l{dir(beta)}..tension t..z4r{up}
 206                 ..tension t..z5r{left}..z5l{right}
 207                 ..z4l{down}..tension t
 208                 ..{dir(180+beta)}z1r..cycle;
 209         draw_flare(z5r,180,90,thin,flare);
 210 fet_endchar;
 211
 212 fet_beginchar("Numeral 3", "3", "three")
 213         set_char_box(0, 2/3height#*widen, 0, height#);
 214         message "w:"&decimal w;
 215         message "h:"&decimal h;
 216         penpos1(hair,-90);
 217         z1l=(17/16thick,h);
 218         penpos2(7/8thick,180);
 219         z2l=(w-thick/8,3/4h+thick/16);
 220         penpos3(thin,90);
 221         z3=(w/2,h/2+1/8thick);
 222         penpos4(thin,90);
 223         z4=(5/8thick+1/2thin,y3);
 224         penpos5(thick,0);
 225         z5r=(w,1/4h+thick/16);
 226         penpos6(hair,-90);
 227         z6r=(9/8thick,0);
 228         penpos7(3/2thin,90);
 229         z7=(x5,y3);
 230         penlabels(1,2,3,4,5,6,7);
 231         save alpha; alpha=25;
 232         save t; t=tense;
 233         fill z1l{right}..tension t..z2l{down}..z7r{dir(180+alpha)}
 234                 ..z7l{dir(-alpha)}..z5r{down}..tension t..z6r{left}
 235                 ..z6l{right}..tension t..z5l{up}
 236                 ..tension t..z3l{left}..z4l{left}
 237                 ..z4r{right}..z3r{right}..tension t..z2r{up}
 238                 ..tension t..z1r{left}..cycle;
 239         draw_flare(z1l,180,90,hair,7/8flare);
 240         draw_flare(z6r,180,-90,hair,flare);
 241 fet_endchar;
 242
 243 fet_beginchar("Numeral 4", "4", "four")
 244         set_char_box(0, 4/5height#*widen, 0, height#);
 245         message "w:"&decimal w;
 246         message "h:"&decimal h;
 247
 248         save alpha; alpha=0;
 249         calc_kuulleke(3/2thick,alpha);
 250         z1r=(w-3/4thick,height);
 251
 252         z5=(thin,1/4height+thin);
 253         save beta; beta=angle(z3r-z5);
 254         penpos6(thin,-90);
 255         z6l=z5;
 256         penpos7(thin,-90);
 257         y7=y6; x7=w-1/2thin;
 258         penpos8(thin,-alpha);
 259         z8r=z5;
 260         penlabels(1,2,3,4,5,6,7);
 261         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 262         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 263                 ..z3r{dir(180+beta)}..{dir(180+beta)}z8r{right}
 264                 ..{right}z7l..z7r{left}..{left}z6r..z8l{dir(beta)}
 265                 ..{up}z2l..cycle;
 266
 267         clearxy;
 268
 269         save alpha; alpha=beta;
 270         calc_kuulleke(thick,alpha);
 271         z1r=(w-3/4thick,height-(3/2thin)/cosd(alpha));
 272
 273         penpos5(thick,0);
 274         z5=(x1,foot_top);
 275
 276         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 277         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 278                 ..z3r{down}..{down}z5r{left}..z5..{left}z5l{up}
 279                 ..{up}z2l..cycle;
 280         penlabels(1,2,3,4,5);
 281
 282         draw_foot(x5);
 283 fet_endchar;
 284
 285 fet_beginchar("Numeral 5", "5", "five")
 286         set_char_box(0, 7/10height#*widen, 0, height#);
 287         message "w:"&decimal w;
 288         message "h:"&decimal h;
 289         calc_kuulleke(w-thin,0);
 290         z1=(w/2+1/8thick,h);
 291         save alpha; alpha=0;
 292         penpos5(thin,0);
 293         z5l=(x1l,h-15/16thick);
 294         penpos6(hair,90-45);
 295         z6=z5r+1/2hair*dir(-45);
 296         penpos7(thin,0);
 297         z7l=(x1l,h/2+thin-hair);
 298         penlabels(1,2,3,4,5,6,7);
 299         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 300         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 301                 ..z3r{dir(-135)}..{left}z6r..z6l{down}..z7r{down}
 302                 ..z7l{up}..{up}z2l..cycle;
 303         penpos8(thin,90);
 304         z8l=(x7r,y7r-1/16thick);
 305         penpos9(thin,90);
 306         z9=(x11+3/16thick,10/16[y5,y7]);
 307         penpos10(thick,0);
 308         z10r=(w,1/2[y9r,y11r]);
 309         penpos11(hair,-90);
 310         z11r=(9/8thick,0);
 311         penlabels(8,9,10,11);
 312         save beta; beta=45;
 313         save t; t=tense;
 314         fill z8r{dir(beta)}..z9r{right}..tension t..z10r{down}
 315                 ..tension t..z11r{left}
 316                 ..z11l{right}..tension t..z10l{up}..tension t
 317                 ..z9l{left}..z8l{dir(180+beta+10)}..cycle;
 318         draw_flare(z11r,180,-90,hair,flare);
 319 fet_endchar;
 320
 321 fet_beginchar("Numeral 6", "6", "six")
 322         draw_six;
 323 fet_endchar;
 324
 325 fet_beginchar("Numeral 7", "7", "seven")
 326         set_char_box(0, 11/15height#*widen, 0, height#);
 327         message "w:"&decimal w;
 328         message "h:"&decimal h;
 329
 330         save alpha; alpha=-180;
 331 if true:
 332         penpos1(3/2thick,180+alpha);
 333         penpos2(hair,180+alpha-45);
 334         z2=z1l+(1/4sqrt(2)*hair)*dir(alpha-135);
 335         penpos3(hair,180+alpha+45);
 336         z3=z1r+(1/4sqrt(2)*hair)*dir(alpha-45);
 337         z4=z1+kuulleke*dir(alpha-90);
 338 else:
 339         % shit, does not work
 340         calc_kuulleke(3/2thick,-alpha);
 341 fi
 342         z1l=(thin,0);
 343
 344         save beta; beta=55;
 345         penpos5(thin,90+beta);
 346         z5=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 347
 348         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 349         save delta; delta=12;
 350         pickup pencircle;
 351         fill z3l{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z2r..
 352                 z2l{dir(beta+delta)}..{dir(beta)}z5r
 353                 ..z5l{dir(180+beta)}..{dir(delta-90)}z3r..cycle;
 354         penlabels(1,2,3,4,5);
 355
 356         clearxy;
 357         save alpha; alpha=-45*widen;
 358         penpos1(1/2thick,90);
 359         z1=(3/2thin,h-(thick+thin)/2);
 360         penpos3(thin,90+beta);
 361         z3=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 362         penpos2(thick,90+alpha);
 363         x2=1/2[x1,x3]-1/4thick; y2=h-15/16thick+thin*widen;
 364
 365         penpos4(thin,0);
 366         z4l=(0,h-thin/2);
 367         penpos5(thin,0);
 368         z5l=(0,h/2+thin/2);
 369
 370         penpos6(9/8thick,90);
 371         z6r=(thin,y1r+2/16thick);
 372
 373         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(beta)}z3r
 374                 ..z3l{dir(180+beta)}..{dir(180+alpha)}z2l
 375                 ..{dir(180+beta)}z1l..z6l{down}..{down}z5r
 376                 ..z5l{up}..{up}z4l..z4r{down}..{down}z6r..{right}cycle;
 377         penlabels(1,2,3,4,5,6);
 378 fet_endchar;
 379
 380 fet_beginchar("Numeral 8", "8", "eight")
 381         set_char_box(0, 11/15height#*widen, 0, height#);
 382         message "w:"&decimal w;
 383         message "h:"&decimal h;
 384         save alpha; alpha=60;
 385         save beta; beta=alpha-15;
 386         z1=(w/2,h/2+thick/8);
 387         penpos2(hair,90+180+beta);
 388         z2=(w/3,h/2+thin);
 389         penpos3(3/2thin,0);
 390         z3l=(0,h/4+thin/2);
 391         penpos4(hair,90);
 392         z4l=(x1,0);
 393         penpos5(thick,90+90+alpha);
 394         z5=z1+w/4*dir(alpha-90);
 395         penpos6(thick,90+90+alpha);
 396         z6=z1+(w/4-thin/2)*dir(90+alpha);
 397         penpos7(hair,90);
 398         z7r=(x1,h);
 399         penpos8(3/2thin,0);
 400         z8r=(w-thin/2,3/4h+thin/2);
 401         penpos9(hair,90+180+beta);
 402         z9=(2/3w,h/2);
 403         penlabels(1,2,3,4,5,6,7,8,9);
 404         save t; t=tense;
 405         fill z2r{dir(180+beta)}..z3r{down}..z4r{right}
 406                 ..z5r{dir(90+alpha)}..z6r{dir(90+alpha)}
 407                 ..tension t..z7r{right}..z8r{down}..z9r{dir(180+beta)}
 408                 ..z9l{dir(beta)}..z8l{up}..z7l{left}..z6l{dir(alpha-90)}
 409                 ..z5l{dir(alpha-90)}..tension t..z4l{left}..z3l{up}
 410                 ..z2l{dir(beta)}..cycle;
 411 fet_endchar;
 412
 413 fet_beginchar("Numeral 9", "9", "nine")
 414         draw_six;
 415 %       xy_mirror_char;
 416         currentpicture := currentpicture scaled -1;
 417         currentpicture := currentpicture shifted (w,h);
 418 fet_endchar;
 419
 420 fet_endgroup("number")
 421