mf/feta-nummer-code.mf

   1 % feta-nummer.mf -- implement bold Orator numerals
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997--2002 Jan Nieuwenhuizen <janneke@gnu.org>
   8
   9 %
  10 % These numbers were taken from a part that that the EJE violas played
  11 % 1997 -- Probably Mendelssohn's ouverture Heimkehr aus der Fremde.
  12 %
  13
  14 %
  15 % TODO all the invocation of flare_path are weird --
  16 % the horizontal tangents should be more at the center of the
  17 % glyph.
  18 %
  19
  20 fet_begingroup("number")
  21
  22 define_pixels(height,thick,thick,thin,hair,flare);
  23 define_pixels(foot_top,foot_width);
  24 define_pixels(kuulleke);
  25
  26
  27
  28 %
  29 % Yet Another Bulb Routine with smooth inside curve.
  30 %
  31 % alpha = start direction.
  32 % beta = which side to turn to.
  33 % flare = diameter of the bulb
  34 % line = diameter of line attachment
  35 % direction = is ink on left or right side (1 or -1)
  36 %
  37
  38 %
  39 % move_away_to = amount left (for 2)
  40 % turn_to  = amount down (for  2 )
  41 %
  42 def number_flare_path(expr pos,alpha,beta,line,flare,
  43
  44                         move_away_to,
  45                         turn_to, taille, taille_ratio,
  46                         direction) =
  47         begingroup;
  48         clearxy;
  49
  50 %       z5 = z2 + 0.43* flare *dir (alpha - 1.5 beta);
  51
  52         z4 = (0.75 - taille)  [z2r, z2l] + whatever* dir (alpha - beta) ;
  53         z4 = (taille_ratio * taille) [z3l, z3r] + whatever* dir(alpha);
  54         penpos1(line,180+beta+alpha);
  55         z1r=pos;
  56
  57         z2r = z1r + move_away_to *dir (alpha) + (line + turn_to) * dir(alpha+beta);
  58         z3r = 0.5 [z2l,z2r] + 0.5 *flare *dir(alpha + beta);
  59
  60         penpos2(flare, alpha );
  61         penpos3(flare, alpha +  beta);
  62         penlabels(1, 2, 3, 4, 5);
  63         pickup pencircle;
  64
  65         save p;
  66         path p;
  67         p := z1r{dir(alpha)}
  68                 .. z2r{dir(180+alpha-beta)}
  69                 .. z3r{dir(alpha+180)}
  70                 .. z2l{dir(alpha-beta)}
  71
  72
  73 %%% Two versions of the curve: one with z4, the other with z5.
  74 %               .. z5{dir(alpha- beta/2 )}
  75                 ..z4{dir(180+alpha+beta)}
  76                 ..z1l{dir(alpha+180)};
  77 %       draw p ;
  78         if direction = 1:
  79                 p
  80         else:
  81                 reverse p
  82         fi
  83         endgroup
  84         enddef;
  85
  86
  87
  88 def calc_kuulleke(expr w,alpha) =
  89         begingroup;
  90         save beta; beta=(alpha-90)/2;
  91         save gamma; gamma=(90+alpha)/2;
  92
  93         penpos1(w/cosd(alpha),alpha);
  94         penpos2(hair,90+beta);
  95         z2=z1l+(1/2hair/tand((alpha+90)/2))*dir(beta);
  96
  97         penpos3(hair,gamma-90);
  98         z3=z1r-(1/2hair/tand((90-alpha)/2))*dir(gamma);
  99         z4=z1+kuulleke*dir(alpha-90);
 100         endgroup;
 101         enddef;
 102
 103 % should make generic macro?
 104 %
 105 def draw_foot(expr xpos) =
 106         begingroup;
 107         clearxy;
 108         penpos1(thick,0);
 109         z1=(xpos,foot_top);
 110         penpos2(foot_width,0);
 111         z2=(x1,0);
 112         penpos3(hair,-90);
 113         z3r=z2r;
 114         penpos4(hair,90);
 115         z4l=z2l;
 116         z5=(x1,kuulleke);
 117         penlabels(1,2,3,4);
 118         fill z1..{right}z1r{down}..{right}z3l..z3r{left}..z5
 119                 ..{left}z4l..z4r{right}..{up}z1l{right}..z1..cycle;
 120         endgroup;
 121         enddef;
 122
 123 def draw_six =
 124         set_char_box(0, 2/3height#*widen, 0, height#);
 125         message "w:"&decimal w;
 126         message "h:"&decimal h;
 127
 128         penpos1(thin,90);
 129         z1=(thick,h/2+thin-hair/2);
 130         penpos2(hair,90);
 131
 132         z2=(w/2,y1);
 133         penpos3(7/8thick,0);
 134         % yup, should use the path fract [] "everywhere"
 135         z3r=(w,1/2[0,y1]);
 136         penpos4(hair,-90);
 137         z4r=(x2,0);
 138         penpos6(hair,90);
 139         z6r=(w-flare,h);
 140         penpos7(7/8thick,180);
 141         z7r=(0,h/2);
 142         penpos10(7/8thick,180);
 143         z10r=(0,y3);
 144         penlabels(1,2,3,4,5,6,7,8,9,10,11);
 145
 146
 147         save t; t=tense;
 148         fill z7{right}..z2r{right}..tension t..z3r{down}
 149                 ..tension t..z4r{left}
 150                 ..tension t..z7r{up}
 151                 .. super_curvelet(z7r, z6r, 0.76, 1)
 152                 .. flare_path (z6r,0,-90,hair,flare, 1)
 153
 154                 ..tension t..z7l{down}..z10l{up}..cycle;
 155
 156         unfill z2l{right}..tension t..z3l{down}..tension t
 157                 ..z4l{left}..tension t..z10l{up}..tension t..cycle;
 158         enddef;
 159
 160 save dot_diam;
 161 dot_diam# = 7/8flare#;
 162 define_pixels(dot_diam);
 163
 164 code := 32;
 165 fet_beginchar("Space", "space", "space")
 166         set_char_box(0, space#,  0,height#);
 167 fet_endchar;
 168
 169 code := 43;  % , = 44
 170
 171 % urg
 172 fet_beginchar("Numeral comma", ",", "comma")
 173         set_char_box(0, dot_diam#, 3/2dot_diam#, dot_diam#);
 174         pickup pencircle scaled dot_diam;
 175         draw (dot_diam/2,dot_diam/2);
 176         z0=(w/3,0);
 177         alpha=65;
 178         penpos1(thin,alpha+90);
 179         z1l=(w/2,-1.5h+hair);
 180         z2=(w,h/2);
 181         pickup pencircle;
 182         filldraw z1l{dir(alpha)}..{up}z2..{z0-z2}z0{right}..{dir(180+alpha)}z1r..cycle;
 183         labels(0,1,2);
 184         penlabels(1);
 185 fet_endchar;
 186
 187 fet_beginchar("Numeral dash", "-", "dash")
 188         set_char_box(0, height#/3, 0, height#);
 189         pickup pencircle scaled thin;
 190         lft x1 = -b;
 191         rt x2 = w;
 192         y1 = y2 = h/3;
 193         draw z1 .. z2;
 194 fet_endchar;
 195
 196 fet_beginchar("Numeral dot", ".", "dot")
 197         set_char_box(0, dot_diam#, 0, dot_diam#);
 198         pickup pencircle scaled dot_diam;
 199         draw (dot_diam/2,dot_diam/2);
 200 fet_endchar;
 201
 202
 203 % skip slash
 204
 205 code := 47; % 0 = 48
 206
 207 fet_beginchar("Numeral 0", "0", "zero")
 208         set_char_box(0, 11/15height# * widen, 0, height#);
 209         message "w:"&decimal w;
 210         message "h:"&decimal h;
 211         penpos1(thin,90);
 212         z1r=(w/2,h);
 213         penpos2(thick,180);
 214         z2r=(0,h/2);
 215         penpos3(thin,-90);
 216         z3r=(w/2,0);
 217         penpos4(thick,0);
 218         z4r=(w,h/2);
 219         fill z1r..z2r..z3r..z4r..cycle;
 220         save t; t=1/tense;
 221         penlabels(1,2,3,4);
 222         unfill z1l..tension t..z2l..tension t..z3l
 223                 ..tension t..z4l..tension t..cycle;
 224 fet_endchar;
 225
 226 fet_beginchar("Numeral 1", "1", "one")
 227 %       set_char_box(0, 19/30height#*widen, 0, height#);
 228         set_char_box(0, 1/2foot_width#+3/2thick#+1/2hair#, 0, height#);
 229         message "w:"&decimal w;
 230         message "h:"&decimal h;
 231
 232         save alpha; alpha=0;
 233         calc_kuulleke(thick,alpha);
 234         z1=(3/2thick,height);
 235
 236         penpos5(thick,0);
 237         z5=(x1,foot_top);
 238
 239         z6=(0,h/2);
 240         save beta; beta=angle(z1l-z6);
 241         penpos7(thin,beta-90);
 242         z7l=z6;
 243         penpos8(thin/cosd(beta),-90);
 244         z8l=z1l;
 245         penpos9(thin,beta-90);
 246         z9r=z8r+(thin/cosd(beta))*(0,-1);
 247         penlabels(1,2,3,4,5,6,7,8,9);
 248         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 249         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l..z3r{down}
 250                 ..{down}z5r{left}..z5..{left}z5l{up}..{up}z2l..cycle;
 251         fill z7l{dir(beta)}..{dir(beta)}z1l..z2r..z9r{up}
 252                 ..z9l{dir(180+beta)}..{dir(180+beta)}z7r..cycle;
 253         penlabels(7,8,9);
 254
 255         draw_foot(x1);
 256 fet_endchar;
 257
 258 fet_beginchar("Numeral 2", "2", "two")
 259         set_char_box(0, 23/30 height#*widen, 0, height#);
 260         message "w:"&decimal w;
 261         message "h:"&decimal h;
 262         clearxy;
 263         save alpha; alpha=-45*widen;
 264         save beta; beta=85;
 265         save gamma; gamma=beta-10;
 266         save flare_start_distance;
 267
 268         flare_start = 0.25 ;
 269         save theta; theta=20/widen;
 270         penpos1(hair,90+beta);
 271         z1=(0,0)+(1/2sqrt(2)*hair)*dir(45);
 272         penpos3(hair,90+gamma);
 273         z3=(w,thick)+(1/2sqrt(2)*hair)*dir(-135);
 274         penpos2(thick, 90+alpha -15);
 275         x2-x1=x3-x2;
 276         y2=10/16 thick/widen;
 277         fill z1r{dir(beta)}.. tension 0.9 .. {dir(alpha + 10)}z2r..{dir(gamma)}z3r
 278                 ..z3l{dir(180+gamma)}..{dir(180+alpha - 5)}z2l
 279                 ..{dir(180+beta)}z1l..cycle;
 280
 281         penpos4(thick,0);
 282         z4r=(w-thin/2, .71 h);
 283         penpos5(hair,90);
 284         y5r = h;
 285         x5r = 9/20 w ;
 286
 287         penlabels(1,2,3,4);
 288         penlabels(5,6);
 289         save t; t=tense;
 290
 291         save p;
 292         path p ;
 293         p := z1l{dir(beta)}..tension t..z4r{up}
 294                 .. number_flare_path(z5r,180,90,hair, 1.05 flare,
 295                                 x5r  - 1/2 hair,
 296                                 .21 h, 0.006, 0.4, 1)
 297                 .. z4l{down}..tension t
 298                 ..{dir(180+beta)}z1r..cycle;
 299
 300         pickup pencircle scaled 1;
 301 %       draw p;
 302         fill p;
 303
 304 fet_endchar;
 305
 306 fet_beginchar("Numeral 3", "3", "three")
 307         set_char_box(0, 2/3height#*widen, 0, height#);
 308         message "w:"&decimal w;
 309         message "h:"&decimal h;
 310         penpos1(hair,-90);
 311
 312 %       flare_start = 0.25 ;
 313         x1l = 17/40 w;
 314         y1l = h;
 315
 316 %       z1l=(17/16thick,h);
 317         penpos2(7/8thick,180);
 318         z2l=(w-thick/8,3/4h+thick/16);
 319         penpos3(thin,90);
 320         z3=(w/2,h/2+1/8thick);
 321         penpos4(thin,90);
 322         z4=(5/8thick+1/2thin,y3);
 323         penpos5(thick,0);
 324         z5r=(w,1/4h+thick/16);
 325         penpos6(hair,-90);
 326
 327         x6r= 18/40 w;
 328         y6r = 0;
 329         penpos7(3/2thin,90);
 330         z7=(x5,y3);
 331         penlabels(1,2,3,4,5,6,7);
 332         save alpha; alpha=25;
 333         save t; t=tense;
 334         pickup pencircle scaled 1;
 335
 336         %.. number_flare_path(z5r,180,90,hair, 1.05 flare, x5r  - 1/2 hair, .21 h, 1)
 337
 338 %       draw
 339         fill
 340                 number_flare_path (z1l, 180, 90, hair,  flare, x1l, .15 h, 0.05, 2,  -1)
 341 %               flare_path (z1l, 180, 90, hair, 7/8 flare,  -1)
 342 %               .. super_curvelet(z1l, z2l, 0.76, -1)
 343                 .. z2l{down}..z7r{dir(180+alpha)}
 344                 ..z7l{dir(-alpha)}..z5r{down}..
 345                 number_flare_path (z6r, 180, -90, hair,  flare, x6l, .17 h, 0.05, 2,  1)
 346 %               flare_path (z6r, 180, -90, hair, flare, 1) ..tension t..
 347                 .. z5l{up}
 348                 ..tension t..z3l{left}..z4l{left}
 349                 ..z4r{right}..z3r{right}..tension t..z2r{up}
 350                 ..tension t.. cycle
 351 ;
 352 fet_endchar;
 353
 354
 355
 356 fet_beginchar("Numeral 4", "4", "four")
 357         set_char_box(0, 4/5height#*widen, 0, height#);
 358         message "w:"&decimal w;
 359         message "h:"&decimal h;
 360
 361         save alpha; alpha=0;
 362         calc_kuulleke(3/2thick,alpha);
 363         z1r=(w-3/4thick,height);
 364
 365         z5=(thin,1/4height+thin);
 366         save beta; beta=angle(z3r-z5);
 367         penpos6(thin,-90);
 368         z6l=z5;
 369         penpos7(thin,-90);
 370         y7=y6; x7=w-1/2thin;
 371         penpos8(thin,-alpha);
 372         z8r=z5;
 373         penlabels(1,2,3,4,5,6,7);
 374         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 375         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 376                 ..z3r{dir(180+beta)}..{dir(180+beta)}z8r{right}
 377                 ..{right}z7l..z7r{left}..{left}z6r..z8l{dir(beta)}
 378                 ..{up}z2l..cycle;
 379
 380         clearxy;
 381
 382         save alpha; alpha=beta;
 383         calc_kuulleke(thick,alpha);
 384         z1r=(w-3/4thick,height-(3/2thin)/cosd(alpha));
 385
 386         penpos5(thick,0);
 387         z5=(x1,foot_top);
 388
 389         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 390         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 391                 ..z3r{down}..{down}z5r{left}..z5..{left}z5l{up}
 392                 ..{up}z2l..cycle;
 393         penlabels(1,2,3,4,5);
 394
 395         draw_foot(x5);
 396 fet_endchar;
 397
 398 fet_beginchar("Numeral 5", "5", "five")
 399         set_char_box(0, 7/10height#*widen, 0, height#);
 400         message "w:"&decimal w;
 401         message "h:"&decimal h;
 402         calc_kuulleke(w-thin,0);
 403         z1=(w/2+1/8thick,h);
 404         save alpha; alpha=0;
 405         penpos5(thin,0);
 406         z5l=(x1l,h-15/16thick);
 407         penpos6(hair,90-45);
 408         z6=z5r+1/2hair*dir(-45);
 409         penpos7(thin,0);
 410         z7l=(x1l,h/2+thin-hair);
 411         penlabels(1,2,3,4,5,6,7);
 412         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 413         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 414                 ..z3r{dir(-135)}..{left}z6r..z6l{down}..z7r{down}
 415                 ..z7l{up}..{up}z2l..cycle;
 416         penpos8(thin,90);
 417         z8l=(x7r,y7r-1/16thick);
 418         penpos9(thin,90);
 419         z9=(x11+3/16thick,10/16[y5,y7]);
 420         penpos10(thick,0);
 421         z10r=(w,1/2[y9r,y11r]);
 422         penpos11(hair,-90);
 423         z11r=(9/8thick,0);
 424         penlabels(8,9,10,11);
 425         save beta; beta=45;
 426         save t; t=tense;
 427         fill z8r{dir(beta)}..z9r{right}..tension t..z10r{down}
 428                 .. super_curvelet(z10r, z11r, 0.76, 1)
 429                 .. flare_path(z11r,180,-90,hair,flare, 1)
 430                 ..z11l{right}..tension t..z10l{up}..tension t
 431                 ..z9l{left}..z8l{dir(180+beta+10)}..cycle;
 432
 433 fet_endchar;
 434
 435 fet_beginchar("Numeral 6", "6", "six")
 436         draw_six;
 437 fet_endchar;
 438
 439 fet_beginchar("Numeral 7", "7", "seven")
 440         set_char_box(0, 11/15height#*widen, 0, height#);
 441         message "w:"&decimal w;
 442         message "h:"&decimal h;
 443
 444         save alpha; alpha=-180;
 445 if true:
 446         penpos1(3/2thick,180+alpha);
 447         penpos2(hair,180+alpha-45);
 448         z2=z1l+(1/4sqrt(2)*hair)*dir(alpha-135);
 449         penpos3(hair,180+alpha+45);
 450         z3=z1r+(1/4sqrt(2)*hair)*dir(alpha-45);
 451         z4=z1+kuulleke*dir(alpha-90);
 452 else:
 453         % shit, does not work
 454         calc_kuulleke(3/2thick,-alpha);
 455 fi
 456         z1l=(thin,0);
 457
 458         save beta; beta=55;
 459         penpos5(thin,90+beta);
 460         z5=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 461
 462         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 463         save delta; delta=12;
 464         pickup pencircle;
 465         fill z3l{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z2r..
 466                 z2l{dir(beta+delta)}..{dir(beta)}z5r
 467                 ..z5l{dir(180+beta)}..{dir(delta-90)}z3r..cycle;
 468         penlabels(1,2,3,4,5);
 469
 470         clearxy;
 471         save alpha; alpha=-45*widen;
 472         penpos1(1/2thick,90);
 473         z1=(3/2thin,h-(thick+thin)/2);
 474         penpos3(thin,90+beta);
 475         z3=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 476         penpos2(thick,90+alpha);
 477         x2=1/2[x1,x3]-1/4thick; y2=h-15/16thick+thin*widen;
 478
 479         penpos4(thin,0);
 480         z4l=(0,h-thin/2);
 481         penpos5(thin,0);
 482         z5l=(0,h/2+thin/2);
 483
 484         penpos6(9/8thick,90);
 485         z6r=(thin,y1r+2/16thick);
 486
 487         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(beta)}z3r
 488                 ..z3l{dir(180+beta)}..{dir(180+alpha)}z2l
 489                 ..{dir(180+beta)}z1l..z6l{down}..{down}z5r
 490                 ..z5l{up}..{up}z4l..z4r{down}..{down}z6r..{right}cycle;
 491         penlabels(1,2,3,4,5,6);
 492 fet_endchar;
 493
 494 fet_beginchar("Numeral 8", "8", "eight")
 495         set_char_box(0, 11/15height#*widen, 0, height#);
 496         message "w:"&decimal w;
 497         message "h:"&decimal h;
 498         save alpha; alpha=60;
 499         save beta; beta=alpha-15;
 500         z1=(w/2,h/2+thick/8);
 501         penpos2(hair,90+180+beta);
 502         z2=(w/3,h/2+thin);
 503         penpos3(3/2thin,0);
 504         z3l=(0,h/4+thin/2);
 505         penpos4(hair,90);
 506         z4l=(x1,0);
 507         penpos5(thick,90+90+alpha);
 508         z5=z1+w/4*dir(alpha-90);
 509         penpos6(thick,90+90+alpha);
 510         z6=z1+(w/4-thin/2)*dir(90+alpha);
 511         penpos7(hair,90);
 512         z7r=(x1,h);
 513         penpos8(3/2thin,0);
 514         z8r=(w-thin/2,3/4h+thin/2);
 515         penpos9(hair,90+180+beta);
 516         z9=(2/3w,h/2);
 517         penlabels(1,2,3,4,5,6,7,8,9);
 518         save t; t=tense;
 519         fill z2r{dir(180+beta)}..z3r{down}..z4r{right}
 520                 ..z5r{dir(90+alpha)}..z6r{dir(90+alpha)}
 521                 ..tension t..z7r{right}..z8r{down}..z9r{dir(180+beta)}
 522                 ..z9l{dir(beta)}..z8l{up}..z7l{left}..z6l{dir(alpha-90)}
 523                 ..z5l{dir(alpha-90)}..tension t..z4l{left}..z3l{up}
 524                 ..z2l{dir(beta)}..cycle;
 525 fet_endchar;
 526
 527 fet_beginchar("Numeral 9", "9", "nine")
 528         draw_six;
 529 %       xy_mirror_char;
 530         currentpicture := currentpicture scaled -1;
 531         currentpicture := currentpicture shifted (w,h);
 532 fet_endchar;
 533
 534 fet_endgroup("number")
 535