mf/feta-nummer-code.mf

   1 % feta-nummer.mf -- implement bold Orator numerals
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997--2002 Jan Nieuwenhuizen <janneke@gnu.org>
   8
   9
  10 %
  11 % TODO all the invocation of flare_path are weird --
  12 % the horizontal tangents should be more at the center of the
  13 % glyph.
  14 %
  15
  16 fet_begingroup("number")
  17
  18 define_pixels(height,thick,thick,thin,hair,flare);
  19 define_pixels(foot_top,foot_width);
  20 define_pixels(kuulleke);
  21
  22
  23
  24 %
  25 % Yet Another Bulb Routine with smooth inside curve.
  26 %
  27 % alpha = start direction.
  28 % beta = which side to turn to.
  29 % flare = diameter of the bulb
  30 % line = diameter of line attachment
  31 % direction = is ink on left or right side (1 or -1)
  32 %
  33
  34 def number_flare_path(expr pos,alpha,beta,line,flare,
  35
  36                         move_away_to,
  37                         turn_to,
  38                         away_from_start_pos, direction) =
  39         begingroup;
  40         clearxy;
  41
  42         z5 = z2 + 0.43* flare *dir (alpha - 1.5 beta);
  43
  44         save taille;
  45
  46         taille = 0.06;
  47         z4 = (0.75 - taille)  [z2r, z2l] + whatever* dir (alpha - beta) ;
  48         z4 = (0.00 + .4 taille) [z3l, z3r] + whatever* dir(alpha);
  49         penpos1(line,180+beta+alpha);
  50         z1r=pos;
  51
  52         z2r = z1r + move_away_to *dir (alpha) + (line + turn_to) * dir(alpha+beta);
  53         z3r = 0.5 [z2l,z2r] + 0.5 *flare *dir(alpha + beta);
  54
  55         penpos2(flare, alpha );
  56         penpos3(flare, alpha +  beta);
  57         penlabels(1, 2, 3, 4, 5);
  58         pickup pencircle;
  59
  60         save p;
  61         path p;
  62         p := z1r{dir(alpha)}
  63                 .. z2r{dir(180+alpha-beta)}
  64                 .. z3r{dir(alpha+180)}
  65                 .. z2l{dir(alpha-beta)}
  66
  67
  68 %%% Two versions of the curve: one with z4, the other with z5.
  69 %               .. z5{dir(alpha- beta/2 )}
  70                 ..z4{dir(180+alpha+beta)}
  71                 ..z1l{dir(alpha+180)};
  72 %       draw p ;
  73         if direction = 1:
  74                 p
  75         else:
  76                 reverse p
  77         fi
  78         endgroup
  79         enddef;
  80
  81
  82
  83 def calc_kuulleke(expr w,alpha) =
  84         begingroup;
  85         save beta; beta=(alpha-90)/2;
  86         save gamma; gamma=(90+alpha)/2;
  87
  88         penpos1(w/cosd(alpha),alpha);
  89         penpos2(hair,90+beta);
  90         z2=z1l+(1/2hair/tand((alpha+90)/2))*dir(beta);
  91
  92         penpos3(hair,gamma-90);
  93         z3=z1r-(1/2hair/tand((90-alpha)/2))*dir(gamma);
  94         z4=z1+kuulleke*dir(alpha-90);
  95         endgroup;
  96         enddef;
  97
  98 % should make generic macro?
  99 %
 100 def draw_foot(expr xpos) =
 101         begingroup;
 102         clearxy;
 103         penpos1(thick,0);
 104         z1=(xpos,foot_top);
 105         penpos2(foot_width,0);
 106         z2=(x1,0);
 107         penpos3(hair,-90);
 108         z3r=z2r;
 109         penpos4(hair,90);
 110         z4l=z2l;
 111         z5=(x1,kuulleke);
 112         penlabels(1,2,3,4);
 113         fill z1..{right}z1r{down}..{right}z3l..z3r{left}..z5
 114                 ..{left}z4l..z4r{right}..{up}z1l{right}..z1..cycle;
 115         endgroup;
 116         enddef;
 117
 118 def draw_six =
 119         set_char_box(0, 2/3height#*widen, 0, height#);
 120         message "w:"&decimal w;
 121         message "h:"&decimal h;
 122
 123         penpos1(thin,90);
 124         z1=(thick,h/2+thin-hair/2);
 125         penpos2(hair,90);
 126
 127         z2=(w/2,y1);
 128         penpos3(7/8thick,0);
 129         % yup, should use the path fract [] "everywhere"
 130         z3r=(w,1/2[0,y1]);
 131         penpos4(hair,-90);
 132         z4r=(x2,0);
 133         penpos6(hair,90);
 134         z6r=(w-flare,h);
 135         penpos7(7/8thick,180);
 136         z7r=(0,h/2);
 137         penpos10(7/8thick,180);
 138         z10r=(0,y3);
 139         penlabels(1,2,3,4,5,6,7,8,9,10,11);
 140
 141
 142         save t; t=tense;
 143         fill z7{right}..z2r{right}..tension t..z3r{down}
 144                 ..tension t..z4r{left}
 145                 ..tension t..z7r{up}
 146                 .. super_curvelet(z7r, z6r, 0.76, 1)
 147                 .. flare_path (z6r,0,-90,hair,flare, 1)
 148
 149                 ..tension t..z7l{down}..z10l{up}..cycle;
 150
 151         unfill z2l{right}..tension t..z3l{down}..tension t
 152                 ..z4l{left}..tension t..z10l{up}..tension t..cycle;
 153         enddef;
 154
 155 save dot_diam;
 156 dot_diam# = 7/8flare#;
 157 define_pixels(dot_diam);
 158
 159 code := 32;
 160 fet_beginchar("Space", "space", "space")
 161         set_char_box(0, space#,  0,height#);
 162 fet_endchar;
 163
 164 code := 43;  % , = 44
 165
 166 % urg
 167 fet_beginchar("Numeral comma", ",", "comma")
 168         set_char_box(0, dot_diam#, 3/2dot_diam#, dot_diam#);
 169         pickup pencircle scaled dot_diam;
 170         draw (dot_diam/2,dot_diam/2);
 171         z0=(w/3,0);
 172         alpha=65;
 173         penpos1(thin,alpha+90);
 174         z1l=(w/2,-1.5h+hair);
 175         z2=(w,h/2);
 176         pickup pencircle;
 177         filldraw z1l{dir(alpha)}..{up}z2..{z0-z2}z0{right}..{dir(180+alpha)}z1r..cycle;
 178         labels(0,1,2);
 179         penlabels(1);
 180 fet_endchar;
 181
 182 fet_beginchar("Numeral dash", "-", "dash")
 183         set_char_box(0, height#/3, 0, height#);
 184         pickup pencircle scaled thin;
 185         lft x1 = -b;
 186         rt x2 = w;
 187         y1 = y2 = h/3;
 188         draw z1 .. z2;
 189 fet_endchar;
 190
 191 fet_beginchar("Numeral dot", ".", "dot")
 192         set_char_box(0, dot_diam#, 0, dot_diam#);
 193         pickup pencircle scaled dot_diam;
 194         draw (dot_diam/2,dot_diam/2);
 195 fet_endchar;
 196
 197
 198 % skip slash
 199
 200 code := 47; % 0 = 48
 201
 202 fet_beginchar("Numeral 0", "0", "zero")
 203 %       set_char_box(0, 4/5height#*widen, 0, height#);
 204         set_char_box(0, 11/15height#*widen, 0, height#);
 205         message "w:"&decimal w;
 206         message "h:"&decimal h;
 207         penpos1(thin,90);
 208         z1r=(w/2,h);
 209         penpos2(thick,180);
 210         z2r=(0,h/2);
 211         penpos3(thin,-90);
 212         z3r=(w/2,0);
 213         penpos4(thick,0);
 214         z4r=(w,h/2);
 215         fill z1r..z2r..z3r..z4r..cycle;
 216         save t; t=1/tense;
 217         penlabels(1,2,3,4);
 218         unfill z1l..tension t..z2l..tension t..z3l
 219                 ..tension t..z4l..tension t..cycle;
 220 fet_endchar;
 221
 222 fet_beginchar("Numeral 1", "1", "one")
 223 %       set_char_box(0, 19/30height#*widen, 0, height#);
 224         set_char_box(0, 1/2foot_width#+3/2thick#+1/2hair#, 0, height#);
 225         message "w:"&decimal w;
 226         message "h:"&decimal h;
 227
 228         save alpha; alpha=0;
 229         calc_kuulleke(thick,alpha);
 230         z1=(3/2thick,height);
 231
 232         penpos5(thick,0);
 233         z5=(x1,foot_top);
 234
 235         z6=(0,h/2);
 236         save beta; beta=angle(z1l-z6);
 237         penpos7(thin,beta-90);
 238         z7l=z6;
 239         penpos8(thin/cosd(beta),-90);
 240         z8l=z1l;
 241         penpos9(thin,beta-90);
 242         z9r=z8r+(thin/cosd(beta))*(0,-1);
 243         penlabels(1,2,3,4,5,6,7,8,9);
 244         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 245         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l..z3r{down}
 246                 ..{down}z5r{left}..z5..{left}z5l{up}..{up}z2l..cycle;
 247         fill z7l{dir(beta)}..{dir(beta)}z1l..z2r..z9r{up}
 248                 ..z9l{dir(180+beta)}..{dir(180+beta)}z7r..cycle;
 249         penlabels(7,8,9);
 250
 251         draw_foot(x1);
 252 fet_endchar;
 253
 254 fet_beginchar("Numeral 2", "2", "two")
 255         set_char_box(0, 11/15height#*widen, 0, height#);
 256         message "w:"&decimal w;
 257         message "h:"&decimal h;
 258         clearxy;
 259         save alpha; alpha=-45*widen;
 260         save beta; beta=85;
 261         save gamma; gamma=beta-10;
 262         save flare_start_distance;
 263
 264         flare_start = 0.25 ;
 265         save theta; theta=20/widen;
 266         penpos1(hair,90+beta);
 267         z1=(0,0)+(1/2sqrt(2)*hair)*dir(45);
 268         penpos3(hair,90+gamma);
 269         z3=(w,thick)+(1/2sqrt(2)*hair)*dir(-135);
 270         penpos2(thick, 90+alpha -15);
 271         x2-x1=x3-x2;
 272         y2=10/16 thick/widen;
 273         fill z1r{dir(beta)}.. tension 0.9 .. {dir(alpha + 10)}z2r..{dir(gamma)}z3r
 274                 ..z3l{dir(180+gamma)}..{dir(180+alpha - 5)}z2l
 275                 ..{dir(180+beta)}z1l..cycle;
 276
 277         penpos4(0.85 thick,0);
 278         z4r=(w-thin/2, .71 h);
 279         penpos5(hair,90);
 280         y5r = h;
 281         x5r = 1/2 hair + 1.0 flare + flare_start* flare;
 282
 283         penlabels(1,2,3,4);
 284         penlabels(5,6);
 285         save t; t=tense;
 286
 287         save p;
 288         path p ;
 289         p := z1l{dir(beta)}..tension t..z4r{up}
 290                 .. number_flare_path(z5r,180,90,hair, flare,
 291                                 x5r  - 1/2 hair,
 292                                 .20 h,
 293                                 flare_start* flare, 1)
 294                 .. z4l{down}..tension t
 295                 ..{dir(180+beta)}z1r..cycle;
 296
 297         pickup pencircle scaled 1;
 298 %       draw p;
 299         fill p;
 300
 301 fet_endchar;
 302
 303 fet_beginchar("Numeral 3", "3", "three")
 304         set_char_box(0, 2/3height#*widen, 0, height#);
 305         message "w:"&decimal w;
 306         message "h:"&decimal h;
 307         penpos1(hair,-90);
 308         z1l=(17/16thick,h);
 309         penpos2(7/8thick,180);
 310         z2l=(w-thick/8,3/4h+thick/16);
 311         penpos3(thin,90);
 312         z3=(w/2,h/2+1/8thick);
 313         penpos4(thin,90);
 314         z4=(5/8thick+1/2thin,y3);
 315         penpos5(thick,0);
 316         z5r=(w,1/4h+thick/16);
 317         penpos6(hair,-90);
 318         z6r=(9/8thick,0);
 319         penpos7(3/2thin,90);
 320         z7=(x5,y3);
 321         penlabels(1,2,3,4,5,6,7);
 322         save alpha; alpha=25;
 323         save t; t=tense;
 324         pickup pencircle scaled 1;
 325 %       draw
 326         fill
 327                 flare_path (z1l, 180, 90, hair, 7/8 flare, -1)
 328                 .. super_curvelet(z1l, z2l, 0.76, -1)
 329                 .. z2l{down}..z7r{dir(180+alpha)}
 330                 ..z7l{dir(-alpha)}..z5r{down}..tension t..
 331
 332                 flare_path (z6r, 180, -90, hair, flare, 1) ..tension t..
 333
 334                 z5l{up}
 335                 ..tension t..z3l{left}..z4l{left}
 336                 ..z4r{right}..z3r{right}..tension t..z2r{up}
 337                 ..tension t.. cycle
 338 ;
 339 fet_endchar;
 340
 341
 342
 343 fet_beginchar("Numeral 4", "4", "four")
 344         set_char_box(0, 4/5height#*widen, 0, height#);
 345         message "w:"&decimal w;
 346         message "h:"&decimal h;
 347
 348         save alpha; alpha=0;
 349         calc_kuulleke(3/2thick,alpha);
 350         z1r=(w-3/4thick,height);
 351
 352         z5=(thin,1/4height+thin);
 353         save beta; beta=angle(z3r-z5);
 354         penpos6(thin,-90);
 355         z6l=z5;
 356         penpos7(thin,-90);
 357         y7=y6; x7=w-1/2thin;
 358         penpos8(thin,-alpha);
 359         z8r=z5;
 360         penlabels(1,2,3,4,5,6,7);
 361         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 362         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 363                 ..z3r{dir(180+beta)}..{dir(180+beta)}z8r{right}
 364                 ..{right}z7l..z7r{left}..{left}z6r..z8l{dir(beta)}
 365                 ..{up}z2l..cycle;
 366
 367         clearxy;
 368
 369         save alpha; alpha=beta;
 370         calc_kuulleke(thick,alpha);
 371         z1r=(w-3/4thick,height-(3/2thin)/cosd(alpha));
 372
 373         penpos5(thick,0);
 374         z5=(x1,foot_top);
 375
 376         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 377         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 378                 ..z3r{down}..{down}z5r{left}..z5..{left}z5l{up}
 379                 ..{up}z2l..cycle;
 380         penlabels(1,2,3,4,5);
 381
 382         draw_foot(x5);
 383 fet_endchar;
 384
 385 fet_beginchar("Numeral 5", "5", "five")
 386         set_char_box(0, 7/10height#*widen, 0, height#);
 387         message "w:"&decimal w;
 388         message "h:"&decimal h;
 389         calc_kuulleke(w-thin,0);
 390         z1=(w/2+1/8thick,h);
 391         save alpha; alpha=0;
 392         penpos5(thin,0);
 393         z5l=(x1l,h-15/16thick);
 394         penpos6(hair,90-45);
 395         z6=z5r+1/2hair*dir(-45);
 396         penpos7(thin,0);
 397         z7l=(x1l,h/2+thin-hair);
 398         penlabels(1,2,3,4,5,6,7);
 399         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 400         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 401                 ..z3r{dir(-135)}..{left}z6r..z6l{down}..z7r{down}
 402                 ..z7l{up}..{up}z2l..cycle;
 403         penpos8(thin,90);
 404         z8l=(x7r,y7r-1/16thick);
 405         penpos9(thin,90);
 406         z9=(x11+3/16thick,10/16[y5,y7]);
 407         penpos10(thick,0);
 408         z10r=(w,1/2[y9r,y11r]);
 409         penpos11(hair,-90);
 410         z11r=(9/8thick,0);
 411         penlabels(8,9,10,11);
 412         save beta; beta=45;
 413         save t; t=tense;
 414         fill z8r{dir(beta)}..z9r{right}..tension t..z10r{down}
 415                 .. super_curvelet(z10r, z11r, 0.76, 1)
 416                 .. flare_path(z11r,180,-90,hair,flare, 1)
 417                 ..z11l{right}..tension t..z10l{up}..tension t
 418                 ..z9l{left}..z8l{dir(180+beta+10)}..cycle;
 419
 420 fet_endchar;
 421
 422 fet_beginchar("Numeral 6", "6", "six")
 423         draw_six;
 424 fet_endchar;
 425
 426 fet_beginchar("Numeral 7", "7", "seven")
 427         set_char_box(0, 11/15height#*widen, 0, height#);
 428         message "w:"&decimal w;
 429         message "h:"&decimal h;
 430
 431         save alpha; alpha=-180;
 432 if true:
 433         penpos1(3/2thick,180+alpha);
 434         penpos2(hair,180+alpha-45);
 435         z2=z1l+(1/4sqrt(2)*hair)*dir(alpha-135);
 436         penpos3(hair,180+alpha+45);
 437         z3=z1r+(1/4sqrt(2)*hair)*dir(alpha-45);
 438         z4=z1+kuulleke*dir(alpha-90);
 439 else:
 440         % shit, does not work
 441         calc_kuulleke(3/2thick,-alpha);
 442 fi
 443         z1l=(thin,0);
 444
 445         save beta; beta=55;
 446         penpos5(thin,90+beta);
 447         z5=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 448
 449         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 450         save delta; delta=12;
 451         pickup pencircle;
 452         fill z3l{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z2r..
 453                 z2l{dir(beta+delta)}..{dir(beta)}z5r
 454                 ..z5l{dir(180+beta)}..{dir(delta-90)}z3r..cycle;
 455         penlabels(1,2,3,4,5);
 456
 457         clearxy;
 458         save alpha; alpha=-45*widen;
 459         penpos1(1/2thick,90);
 460         z1=(3/2thin,h-(thick+thin)/2);
 461         penpos3(thin,90+beta);
 462         z3=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 463         penpos2(thick,90+alpha);
 464         x2=1/2[x1,x3]-1/4thick; y2=h-15/16thick+thin*widen;
 465
 466         penpos4(thin,0);
 467         z4l=(0,h-thin/2);
 468         penpos5(thin,0);
 469         z5l=(0,h/2+thin/2);
 470
 471         penpos6(9/8thick,90);
 472         z6r=(thin,y1r+2/16thick);
 473
 474         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(beta)}z3r
 475                 ..z3l{dir(180+beta)}..{dir(180+alpha)}z2l
 476                 ..{dir(180+beta)}z1l..z6l{down}..{down}z5r
 477                 ..z5l{up}..{up}z4l..z4r{down}..{down}z6r..{right}cycle;
 478         penlabels(1,2,3,4,5,6);
 479 fet_endchar;
 480
 481 fet_beginchar("Numeral 8", "8", "eight")
 482         set_char_box(0, 11/15height#*widen, 0, height#);
 483         message "w:"&decimal w;
 484         message "h:"&decimal h;
 485         save alpha; alpha=60;
 486         save beta; beta=alpha-15;
 487         z1=(w/2,h/2+thick/8);
 488         penpos2(hair,90+180+beta);
 489         z2=(w/3,h/2+thin);
 490         penpos3(3/2thin,0);
 491         z3l=(0,h/4+thin/2);
 492         penpos4(hair,90);
 493         z4l=(x1,0);
 494         penpos5(thick,90+90+alpha);
 495         z5=z1+w/4*dir(alpha-90);
 496         penpos6(thick,90+90+alpha);
 497         z6=z1+(w/4-thin/2)*dir(90+alpha);
 498         penpos7(hair,90);
 499         z7r=(x1,h);
 500         penpos8(3/2thin,0);
 501         z8r=(w-thin/2,3/4h+thin/2);
 502         penpos9(hair,90+180+beta);
 503         z9=(2/3w,h/2);
 504         penlabels(1,2,3,4,5,6,7,8,9);
 505         save t; t=tense;
 506         fill z2r{dir(180+beta)}..z3r{down}..z4r{right}
 507                 ..z5r{dir(90+alpha)}..z6r{dir(90+alpha)}
 508                 ..tension t..z7r{right}..z8r{down}..z9r{dir(180+beta)}
 509                 ..z9l{dir(beta)}..z8l{up}..z7l{left}..z6l{dir(alpha-90)}
 510                 ..z5l{dir(alpha-90)}..tension t..z4l{left}..z3l{up}
 511                 ..z2l{dir(beta)}..cycle;
 512 fet_endchar;
 513
 514 fet_beginchar("Numeral 9", "9", "nine")
 515         draw_six;
 516 %       xy_mirror_char;
 517         currentpicture := currentpicture scaled -1;
 518         currentpicture := currentpicture shifted (w,h);
 519 fet_endchar;
 520
 521 fet_endgroup("number")
 522