mf/feta-nummer-code.mf

   1 % feta-nummer.mf -- implement bold Orator numerals
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997--2002 Jan Nieuwenhuizen <janneke@gnu.org>
   8
   9 fet_begingroup("number")
  10
  11 define_pixels(height,thick,thick,thin,hair,flare);
  12 define_pixels(foot_top,foot_width);
  13 define_pixels(kuulleke);
  14
  15 def calc_kuulleke(expr w,alpha) =
  16         begingroup;
  17         save beta; beta=(alpha-90)/2;
  18         save gamma; gamma=(90+alpha)/2;
  19
  20         penpos1(w/cosd(alpha),alpha);
  21         penpos2(hair,90+beta);
  22         z2=z1l+(1/2hair/tand((alpha+90)/2))*dir(beta);
  23
  24         penpos3(hair,gamma-90);
  25         z3=z1r-(1/2hair/tand((90-alpha)/2))*dir(gamma);
  26         z4=z1+kuulleke*dir(alpha-90);
  27         endgroup;
  28         enddef;
  29
  30 % should make generic macro?
  31 %
  32 def draw_foot(expr xpos) =
  33         begingroup;
  34         clearxy;
  35         penpos1(thick,0);
  36         z1=(xpos,foot_top);
  37         penpos2(foot_width,0);
  38         z2=(x1,0);
  39         penpos3(hair,-90);
  40         z3r=z2r;
  41         penpos4(hair,90);
  42         z4l=z2l;
  43         z5=(x1,kuulleke);
  44         penlabels(1,2,3,4);
  45         fill z1..{right}z1r{down}..{right}z3l..z3r{left}..z5
  46                 ..{left}z4l..z4r{right}..{up}z1l{right}..z1..cycle;
  47         endgroup;
  48         enddef;
  49
  50 def draw_six =
  51         set_char_box(0, 2/3height#*widen, 0, height#);
  52         message "w:"&decimal w;
  53         message "h:"&decimal h;
  54
  55         penpos1(thin,90);
  56         z1=(thick,h/2+thin-hair/2);
  57         penpos2(hair,90);
  58
  59         z2=(w/2,y1);
  60         penpos3(7/8thick,0);
  61         % yup, should use the path fract [] "everywhere"
  62         z3r=(w,1/2[0,y1]);
  63         penpos4(hair,-90);
  64         z4r=(x2,0);
  65         penpos5(7/8thick,180);
  66         z5r=(0,y1);
  67         penpos6(hair,90);
  68         z6r=(w-flare,h);
  69         penpos7(7/8thick,180);
  70         z7r=(0,h/2);
  71         penpos10(7/8thick,180);
  72         z10r=(0,y3);
  73         penlabels(1,2,3,4,5,6,7,8,9,10,11);
  74
  75
  76         % TODO: use super_curvelet for stuff connected to flare_path.
  77
  78         save t; t=tense;
  79         fill z7{right}..z2r{right}..tension t..z3r{down}
  80                 ..tension t..z4r{left}
  81                 ..tension t..z7r{up}..tension t..
  82                 flare_path (z6r,0,-90,hair,flare, 1)
  83                 ..tension t..z7l{down}..z10l{up}..cycle;
  84
  85         unfill z2l{right}..tension t..z3l{down}..tension t
  86                 ..z4l{left}..tension t..z10l{up}..tension t..cycle;
  87         enddef;
  88
  89 save dot_diam;
  90 dot_diam# = 7/8flare#;
  91 define_pixels(dot_diam);
  92
  93 code := 32;
  94 fet_beginchar("Space", "space", "space")
  95         set_char_box(0, space#,  0,height#);
  96 fet_endchar;
  97
  98 code := 43;  % , = 44
  99
 100 % urg
 101 fet_beginchar("Numeral comma", ",", "comma")
 102         set_char_box(0, dot_diam#, 3/2dot_diam#, dot_diam#);
 103         pickup pencircle scaled dot_diam;
 104         draw (dot_diam/2,dot_diam/2);
 105         z0=(w/3,0);
 106         alpha=65;
 107         penpos1(thin,alpha+90);
 108         z1l=(w/2,-1.5h+hair);
 109         z2=(w,h/2);
 110         pickup pencircle;
 111         filldraw z1l{dir(alpha)}..{up}z2..{z0-z2}z0{right}..{dir(180+alpha)}z1r..cycle;
 112         labels(0,1,2);
 113         penlabels(1);
 114 fet_endchar;
 115
 116 fet_beginchar("Numeral dash", "-", "dash")
 117         set_char_box(0, height#/3, 0, height#);
 118         pickup pencircle scaled thin;
 119         lft x1 = -b;
 120         rt x2 = w;
 121         y1 = y2 = h/3;
 122         draw z1 .. z2;
 123 fet_endchar;
 124
 125 fet_beginchar("Numeral dot", ".", "dot")
 126         set_char_box(0, dot_diam#, 0, dot_diam#);
 127         pickup pencircle scaled dot_diam;
 128         draw (dot_diam/2,dot_diam/2);
 129 fet_endchar;
 130
 131
 132 % skip slash
 133
 134 code := 47; % 0 = 48
 135
 136 fet_beginchar("Numeral 0", "0", "zero")
 137 %       set_char_box(0, 4/5height#*widen, 0, height#);
 138         set_char_box(0, 11/15height#*widen, 0, height#);
 139         message "w:"&decimal w;
 140         message "h:"&decimal h;
 141         penpos1(thin,90);
 142         z1r=(w/2,h);
 143         penpos2(thick,180);
 144         z2r=(0,h/2);
 145         penpos3(thin,-90);
 146         z3r=(w/2,0);
 147         penpos4(thick,0);
 148         z4r=(w,h/2);
 149         fill z1r..z2r..z3r..z4r..cycle;
 150         save t; t=1/tense;
 151         penlabels(1,2,3,4);
 152         unfill z1l..tension t..z2l..tension t..z3l
 153                 ..tension t..z4l..tension t..cycle;
 154 fet_endchar;
 155
 156 fet_beginchar("Numeral 1", "1", "one")
 157 %       set_char_box(0, 19/30height#*widen, 0, height#);
 158         set_char_box(0, 1/2foot_width#+3/2thick#+1/2hair#, 0, height#);
 159         message "w:"&decimal w;
 160         message "h:"&decimal h;
 161
 162         save alpha; alpha=0;
 163         calc_kuulleke(thick,alpha);
 164         z1=(3/2thick,height);
 165
 166         penpos5(thick,0);
 167         z5=(x1,foot_top);
 168
 169         z6=(0,h/2);
 170         save beta; beta=angle(z1l-z6);
 171         penpos7(thin,beta-90);
 172         z7l=z6;
 173         penpos8(thin/cosd(beta),-90);
 174         z8l=z1l;
 175         penpos9(thin,beta-90);
 176         z9r=z8r+(thin/cosd(beta))*(0,-1);
 177         penlabels(1,2,3,4,5,6,7,8,9);
 178         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 179         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l..z3r{down}
 180                 ..{down}z5r{left}..z5..{left}z5l{up}..{up}z2l..cycle;
 181         fill z7l{dir(beta)}..{dir(beta)}z1l..z2r..z9r{up}
 182                 ..z9l{dir(180+beta)}..{dir(180+beta)}z7r..cycle;
 183         penlabels(7,8,9);
 184
 185         draw_foot(x1);
 186 fet_endchar;
 187
 188 fet_beginchar("Numeral 2", "2", "two")
 189         set_char_box(0, 11/15height#*widen, 0, height#);
 190         message "w:"&decimal w;
 191         message "h:"&decimal h;
 192         clearxy;
 193         save alpha; alpha=-45*widen;
 194         save beta; beta=85;
 195         save gamma; gamma=beta-10;
 196         save theta; theta=20/widen;
 197         penpos1(hair,90+beta);
 198         z1=(0,0)+(1/2sqrt(2)*hair)*dir(45);
 199         penpos3(hair,90+gamma);
 200         z3=(w,thick)+(1/2sqrt(2)*hair)*dir(-135);
 201         penpos2(thick,90+alpha);
 202         x2-x1=x3-x2; y2=11/16thick/widen;
 203         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(gamma)}z3r
 204                 ..z3l{dir(180+gamma)}..{dir(180+alpha)}z2l
 205                 ..{dir(180+beta)}z1l..cycle;
 206
 207         penpos4(thick,0);
 208         z4r=(w-thin/2,.72h);
 209         penpos5(thin,90);
 210         z5r=(1/2hair+flare,h);
 211         penlabels(1,2,3,4);
 212         penlabels(5,6);
 213         save t; t=tense;
 214         fill z1l{dir(beta)}..tension t..z4r{up}
 215                 ..tension t..
 216                 flare_path(z5r,180,90,thin,flare,1)
 217                 ..z4l{down}..tension t
 218                 ..{dir(180+beta)}z1r..cycle;
 219 fet_endchar;
 220
 221 fet_beginchar("Numeral 3", "3", "three")
 222         set_char_box(0, 2/3height#*widen, 0, height#);
 223         message "w:"&decimal w;
 224         message "h:"&decimal h;
 225         penpos1(hair,-90);
 226         z1l=(17/16thick,h);
 227         penpos2(7/8thick,180);
 228         z2l=(w-thick/8,3/4h+thick/16);
 229         penpos3(thin,90);
 230         z3=(w/2,h/2+1/8thick);
 231         penpos4(thin,90);
 232         z4=(5/8thick+1/2thin,y3);
 233         penpos5(thick,0);
 234         z5r=(w,1/4h+thick/16);
 235         penpos6(hair,-90);
 236         z6r=(9/8thick,0);
 237         penpos7(3/2thin,90);
 238         z7=(x5,y3);
 239         penlabels(1,2,3,4,5,6,7);
 240         save alpha; alpha=25;
 241         save t; t=tense;
 242         pickup pencircle scaled 1;
 243 %       draw
 244         fill
 245                 flare_path (z1l, 180, 90, hair, 7/8 flare, -1) ..tension t..
 246                 z2l{down}..z7r{dir(180+alpha)}
 247                 ..z7l{dir(-alpha)}..z5r{down}..tension t..
 248
 249                 flare_path (z6r, 180, -90, hair, flare, 1) ..tension t..
 250
 251                 z5l{up}
 252                 ..tension t..z3l{left}..z4l{left}
 253                 ..z4r{right}..z3r{right}..tension t..z2r{up}
 254                 ..tension t.. cycle
 255 ;
 256 fet_endchar;
 257
 258
 259
 260 fet_beginchar("Numeral 4", "4", "four")
 261         set_char_box(0, 4/5height#*widen, 0, height#);
 262         message "w:"&decimal w;
 263         message "h:"&decimal h;
 264
 265         save alpha; alpha=0;
 266         calc_kuulleke(3/2thick,alpha);
 267         z1r=(w-3/4thick,height);
 268
 269         z5=(thin,1/4height+thin);
 270         save beta; beta=angle(z3r-z5);
 271         penpos6(thin,-90);
 272         z6l=z5;
 273         penpos7(thin,-90);
 274         y7=y6; x7=w-1/2thin;
 275         penpos8(thin,-alpha);
 276         z8r=z5;
 277         penlabels(1,2,3,4,5,6,7);
 278         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 279         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 280                 ..z3r{dir(180+beta)}..{dir(180+beta)}z8r{right}
 281                 ..{right}z7l..z7r{left}..{left}z6r..z8l{dir(beta)}
 282                 ..{up}z2l..cycle;
 283
 284         clearxy;
 285
 286         save alpha; alpha=beta;
 287         calc_kuulleke(thick,alpha);
 288         z1r=(w-3/4thick,height-(3/2thin)/cosd(alpha));
 289
 290         penpos5(thick,0);
 291         z5=(x1,foot_top);
 292
 293         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 294         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 295                 ..z3r{down}..{down}z5r{left}..z5..{left}z5l{up}
 296                 ..{up}z2l..cycle;
 297         penlabels(1,2,3,4,5);
 298
 299         draw_foot(x5);
 300 fet_endchar;
 301
 302 fet_beginchar("Numeral 5", "5", "five")
 303         set_char_box(0, 7/10height#*widen, 0, height#);
 304         message "w:"&decimal w;
 305         message "h:"&decimal h;
 306         calc_kuulleke(w-thin,0);
 307         z1=(w/2+1/8thick,h);
 308         save alpha; alpha=0;
 309         penpos5(thin,0);
 310         z5l=(x1l,h-15/16thick);
 311         penpos6(hair,90-45);
 312         z6=z5r+1/2hair*dir(-45);
 313         penpos7(thin,0);
 314         z7l=(x1l,h/2+thin-hair);
 315         penlabels(1,2,3,4,5,6,7);
 316         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 317         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 318                 ..z3r{dir(-135)}..{left}z6r..z6l{down}..z7r{down}
 319                 ..z7l{up}..{up}z2l..cycle;
 320         penpos8(thin,90);
 321         z8l=(x7r,y7r-1/16thick);
 322         penpos9(thin,90);
 323         z9=(x11+3/16thick,10/16[y5,y7]);
 324         penpos10(thick,0);
 325         z10r=(w,1/2[y9r,y11r]);
 326         penpos11(hair,-90);
 327         z11r=(9/8thick,0);
 328         penlabels(8,9,10,11);
 329         save beta; beta=45;
 330         save t; t=tense;
 331         fill z8r{dir(beta)}..z9r{right}..tension t..z10r{down}
 332                 ..tension t..
 333                 flare_path(z11r,180,-90,hair,flare, 1)
 334                 ..z11l{right}..tension t..z10l{up}..tension t
 335                 ..z9l{left}..z8l{dir(180+beta+10)}..cycle;
 336
 337 fet_endchar;
 338
 339 fet_beginchar("Numeral 6", "6", "six")
 340         draw_six;
 341 fet_endchar;
 342
 343 fet_beginchar("Numeral 7", "7", "seven")
 344         set_char_box(0, 11/15height#*widen, 0, height#);
 345         message "w:"&decimal w;
 346         message "h:"&decimal h;
 347
 348         save alpha; alpha=-180;
 349 if true:
 350         penpos1(3/2thick,180+alpha);
 351         penpos2(hair,180+alpha-45);
 352         z2=z1l+(1/4sqrt(2)*hair)*dir(alpha-135);
 353         penpos3(hair,180+alpha+45);
 354         z3=z1r+(1/4sqrt(2)*hair)*dir(alpha-45);
 355         z4=z1+kuulleke*dir(alpha-90);
 356 else:
 357         % shit, does not work
 358         calc_kuulleke(3/2thick,-alpha);
 359 fi
 360         z1l=(thin,0);
 361
 362         save beta; beta=55;
 363         penpos5(thin,90+beta);
 364         z5=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 365
 366         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 367         save delta; delta=12;
 368         pickup pencircle;
 369         fill z3l{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z2r..
 370                 z2l{dir(beta+delta)}..{dir(beta)}z5r
 371                 ..z5l{dir(180+beta)}..{dir(delta-90)}z3r..cycle;
 372         penlabels(1,2,3,4,5);
 373
 374         clearxy;
 375         save alpha; alpha=-45*widen;
 376         penpos1(1/2thick,90);
 377         z1=(3/2thin,h-(thick+thin)/2);
 378         penpos3(thin,90+beta);
 379         z3=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 380         penpos2(thick,90+alpha);
 381         x2=1/2[x1,x3]-1/4thick; y2=h-15/16thick+thin*widen;
 382
 383         penpos4(thin,0);
 384         z4l=(0,h-thin/2);
 385         penpos5(thin,0);
 386         z5l=(0,h/2+thin/2);
 387
 388         penpos6(9/8thick,90);
 389         z6r=(thin,y1r+2/16thick);
 390
 391         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(beta)}z3r
 392                 ..z3l{dir(180+beta)}..{dir(180+alpha)}z2l
 393                 ..{dir(180+beta)}z1l..z6l{down}..{down}z5r
 394                 ..z5l{up}..{up}z4l..z4r{down}..{down}z6r..{right}cycle;
 395         penlabels(1,2,3,4,5,6);
 396 fet_endchar;
 397
 398 fet_beginchar("Numeral 8", "8", "eight")
 399         set_char_box(0, 11/15height#*widen, 0, height#);
 400         message "w:"&decimal w;
 401         message "h:"&decimal h;
 402         save alpha; alpha=60;
 403         save beta; beta=alpha-15;
 404         z1=(w/2,h/2+thick/8);
 405         penpos2(hair,90+180+beta);
 406         z2=(w/3,h/2+thin);
 407         penpos3(3/2thin,0);
 408         z3l=(0,h/4+thin/2);
 409         penpos4(hair,90);
 410         z4l=(x1,0);
 411         penpos5(thick,90+90+alpha);
 412         z5=z1+w/4*dir(alpha-90);
 413         penpos6(thick,90+90+alpha);
 414         z6=z1+(w/4-thin/2)*dir(90+alpha);
 415         penpos7(hair,90);
 416         z7r=(x1,h);
 417         penpos8(3/2thin,0);
 418         z8r=(w-thin/2,3/4h+thin/2);
 419         penpos9(hair,90+180+beta);
 420         z9=(2/3w,h/2);
 421         penlabels(1,2,3,4,5,6,7,8,9);
 422         save t; t=tense;
 423         fill z2r{dir(180+beta)}..z3r{down}..z4r{right}
 424                 ..z5r{dir(90+alpha)}..z6r{dir(90+alpha)}
 425                 ..tension t..z7r{right}..z8r{down}..z9r{dir(180+beta)}
 426                 ..z9l{dir(beta)}..z8l{up}..z7l{left}..z6l{dir(alpha-90)}
 427                 ..z5l{dir(alpha-90)}..tension t..z4l{left}..z3l{up}
 428                 ..z2l{dir(beta)}..cycle;
 429 fet_endchar;
 430
 431 fet_beginchar("Numeral 9", "9", "nine")
 432         draw_six;
 433 %       xy_mirror_char;
 434         currentpicture := currentpicture scaled -1;
 435         currentpicture := currentpicture shifted (w,h);
 436 fet_endchar;
 437
 438 fet_endgroup("number")
 439