mf/feta-nummer-code.mf

   1 % feta-nummer.mf -- implement bold Orator numerals
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997--2002 Jan Nieuwenhuizen <janneke@gnu.org>
   8
   9
  10 %
  11 % TODO all the invocation of flare_path are weird --
  12 % the horizontal tangents should be more at the center of the
  13 % glyph.
  14 %
  15
  16 fet_begingroup("number")
  17
  18 define_pixels(height,thick,thick,thin,hair,flare);
  19 define_pixels(foot_top,foot_width);
  20 define_pixels(kuulleke);
  21
  22
  23
  24 %
  25 % Yet Another Bulb Routine with smooth inside curve.
  26 %
  27 % alpha = start direction.
  28 % beta = which side to turn to.
  29 % flare = diameter of the bulb
  30 % line = diameter of line attachment
  31 % direction = is ink on left or right side (1 or -1)
  32 %
  33
  34 %
  35 % The basic idea, is to put a really bulb shaped ending at
  36 % an angle of 45 degrees with the normal ending.
  37 % the length  can be controlled using flare_len and flare_thick.
  38 def number_flare_path(expr pos,alpha,beta,line,flare,
  39
  40                         move_away_to,
  41                         turn_to,
  42                         away_from_start_pos, direction) =
  43         begingroup;
  44         clearxy;
  45         save flare_thick, flare_len;
  46
  47         flare_thick= 0.7 flare;
  48         flare_len = 0.9 * 0.75 flare;
  49         save taille;
  50         taille = -0.05 flare;
  51
  52
  53         penpos1(line,180+beta+alpha);
  54         z1r=pos;
  55
  56         z2r = z1r + move_away_to *dir (alpha) + (line + turn_to) * dir(alpha+beta);
  57         penpos2(flare_thick, alpha + 0.45 beta);
  58         penpos3(flare_thick, alpha + 0.5 beta);
  59
  60         z3 = 0.5 [z2l,z2r] + flare_len* dir (alpha + 3/2 beta);
  61
  62         z4 = z2l + taille * dir (alpha);
  63         penlabels(1,2,3,4);
  64         pickup pencircle;
  65
  66         save p;
  67         path p;
  68         p := z1r{dir(alpha)}
  69                 .. super_curvelet (z1r, z2r, 0.73, -1)
  70                 .. z2r{dir(180+alpha-beta)}.. z3r{dir(alpha+180)}
  71                 ..z3l{dir(180+alpha+beta)}
  72
  73                 ..z4{dir(180+alpha+beta)}
  74                 .. super_curvelet (z4, z1l, 0.69, 1)
  75                 ..z1l{dir(alpha+180)};
  76 %       draw p ;
  77         if direction = 1:
  78                 p
  79         else:
  80                 reverse p
  81         fi
  82         endgroup
  83         enddef;
  84
  85
  86
  87 def calc_kuulleke(expr w,alpha) =
  88         begingroup;
  89         save beta; beta=(alpha-90)/2;
  90         save gamma; gamma=(90+alpha)/2;
  91
  92         penpos1(w/cosd(alpha),alpha);
  93         penpos2(hair,90+beta);
  94         z2=z1l+(1/2hair/tand((alpha+90)/2))*dir(beta);
  95
  96         penpos3(hair,gamma-90);
  97         z3=z1r-(1/2hair/tand((90-alpha)/2))*dir(gamma);
  98         z4=z1+kuulleke*dir(alpha-90);
  99         endgroup;
 100         enddef;
 101
 102 % should make generic macro?
 103 %
 104 def draw_foot(expr xpos) =
 105         begingroup;
 106         clearxy;
 107         penpos1(thick,0);
 108         z1=(xpos,foot_top);
 109         penpos2(foot_width,0);
 110         z2=(x1,0);
 111         penpos3(hair,-90);
 112         z3r=z2r;
 113         penpos4(hair,90);
 114         z4l=z2l;
 115         z5=(x1,kuulleke);
 116         penlabels(1,2,3,4);
 117         fill z1..{right}z1r{down}..{right}z3l..z3r{left}..z5
 118                 ..{left}z4l..z4r{right}..{up}z1l{right}..z1..cycle;
 119         endgroup;
 120         enddef;
 121
 122 def draw_six =
 123         set_char_box(0, 2/3height#*widen, 0, height#);
 124         message "w:"&decimal w;
 125         message "h:"&decimal h;
 126
 127         penpos1(thin,90);
 128         z1=(thick,h/2+thin-hair/2);
 129         penpos2(hair,90);
 130
 131         z2=(w/2,y1);
 132         penpos3(7/8thick,0);
 133         % yup, should use the path fract [] "everywhere"
 134         z3r=(w,1/2[0,y1]);
 135         penpos4(hair,-90);
 136         z4r=(x2,0);
 137         penpos6(hair,90);
 138         z6r=(w-flare,h);
 139         penpos7(7/8thick,180);
 140         z7r=(0,h/2);
 141         penpos10(7/8thick,180);
 142         z10r=(0,y3);
 143         penlabels(1,2,3,4,5,6,7,8,9,10,11);
 144
 145
 146         save t; t=tense;
 147         fill z7{right}..z2r{right}..tension t..z3r{down}
 148                 ..tension t..z4r{left}
 149                 ..tension t..z7r{up}
 150                 .. super_curvelet(z7r, z6r, 0.76, 1)
 151                 .. flare_path (z6r,0,-90,hair,flare, 1)
 152
 153                 ..tension t..z7l{down}..z10l{up}..cycle;
 154
 155         unfill z2l{right}..tension t..z3l{down}..tension t
 156                 ..z4l{left}..tension t..z10l{up}..tension t..cycle;
 157         enddef;
 158
 159 save dot_diam;
 160 dot_diam# = 7/8flare#;
 161 define_pixels(dot_diam);
 162
 163 code := 32;
 164 fet_beginchar("Space", "space", "space")
 165         set_char_box(0, space#,  0,height#);
 166 fet_endchar;
 167
 168 code := 43;  % , = 44
 169
 170 % urg
 171 fet_beginchar("Numeral comma", ",", "comma")
 172         set_char_box(0, dot_diam#, 3/2dot_diam#, dot_diam#);
 173         pickup pencircle scaled dot_diam;
 174         draw (dot_diam/2,dot_diam/2);
 175         z0=(w/3,0);
 176         alpha=65;
 177         penpos1(thin,alpha+90);
 178         z1l=(w/2,-1.5h+hair);
 179         z2=(w,h/2);
 180         pickup pencircle;
 181         filldraw z1l{dir(alpha)}..{up}z2..{z0-z2}z0{right}..{dir(180+alpha)}z1r..cycle;
 182         labels(0,1,2);
 183         penlabels(1);
 184 fet_endchar;
 185
 186 fet_beginchar("Numeral dash", "-", "dash")
 187         set_char_box(0, height#/3, 0, height#);
 188         pickup pencircle scaled thin;
 189         lft x1 = -b;
 190         rt x2 = w;
 191         y1 = y2 = h/3;
 192         draw z1 .. z2;
 193 fet_endchar;
 194
 195 fet_beginchar("Numeral dot", ".", "dot")
 196         set_char_box(0, dot_diam#, 0, dot_diam#);
 197         pickup pencircle scaled dot_diam;
 198         draw (dot_diam/2,dot_diam/2);
 199 fet_endchar;
 200
 201
 202 % skip slash
 203
 204 code := 47; % 0 = 48
 205
 206 fet_beginchar("Numeral 0", "0", "zero")
 207 %       set_char_box(0, 4/5height#*widen, 0, height#);
 208         set_char_box(0, 11/15height#*widen, 0, height#);
 209         message "w:"&decimal w;
 210         message "h:"&decimal h;
 211         penpos1(thin,90);
 212         z1r=(w/2,h);
 213         penpos2(thick,180);
 214         z2r=(0,h/2);
 215         penpos3(thin,-90);
 216         z3r=(w/2,0);
 217         penpos4(thick,0);
 218         z4r=(w,h/2);
 219         fill z1r..z2r..z3r..z4r..cycle;
 220         save t; t=1/tense;
 221         penlabels(1,2,3,4);
 222         unfill z1l..tension t..z2l..tension t..z3l
 223                 ..tension t..z4l..tension t..cycle;
 224 fet_endchar;
 225
 226 fet_beginchar("Numeral 1", "1", "one")
 227 %       set_char_box(0, 19/30height#*widen, 0, height#);
 228         set_char_box(0, 1/2foot_width#+3/2thick#+1/2hair#, 0, height#);
 229         message "w:"&decimal w;
 230         message "h:"&decimal h;
 231
 232         save alpha; alpha=0;
 233         calc_kuulleke(thick,alpha);
 234         z1=(3/2thick,height);
 235
 236         penpos5(thick,0);
 237         z5=(x1,foot_top);
 238
 239         z6=(0,h/2);
 240         save beta; beta=angle(z1l-z6);
 241         penpos7(thin,beta-90);
 242         z7l=z6;
 243         penpos8(thin/cosd(beta),-90);
 244         z8l=z1l;
 245         penpos9(thin,beta-90);
 246         z9r=z8r+(thin/cosd(beta))*(0,-1);
 247         penlabels(1,2,3,4,5,6,7,8,9);
 248         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 249         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l..z3r{down}
 250                 ..{down}z5r{left}..z5..{left}z5l{up}..{up}z2l..cycle;
 251         fill z7l{dir(beta)}..{dir(beta)}z1l..z2r..z9r{up}
 252                 ..z9l{dir(180+beta)}..{dir(180+beta)}z7r..cycle;
 253         penlabels(7,8,9);
 254
 255         draw_foot(x1);
 256 fet_endchar;
 257
 258 fet_beginchar("Numeral 2", "2", "two")
 259         set_char_box(0, 11/15height#*widen, 0, height#);
 260         message "w:"&decimal w;
 261         message "h:"&decimal h;
 262         clearxy;
 263         save alpha; alpha=-45*widen;
 264         save beta; beta=85;
 265         save gamma; gamma=beta-10;
 266         save flare_start_distance;
 267
 268         flare_start = 0.25 ;
 269         save theta; theta=20/widen;
 270         penpos1(hair,90+beta);
 271         z1=(0,0)+(1/2sqrt(2)*hair)*dir(45);
 272         penpos3(hair,90+gamma);
 273         z3=(w,thick)+(1/2sqrt(2)*hair)*dir(-135);
 274         penpos2(thick,90+alpha);
 275         x2-x1=x3-x2; y2=11/16thick/widen;
 276         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(gamma)}z3r
 277                 ..z3l{dir(180+gamma)}..{dir(180+alpha)}z2l
 278                 ..{dir(180+beta)}z1l..cycle;
 279
 280         penpos4(thick,0);
 281         z4r=(w-thin/2, .71 h);
 282         penpos5(thin,90);
 283         y5r = h;
 284         x5r = 1/2 hair + 1.0 flare + flare_start* flare;
 285
 286         penlabels(1,2,3,4);
 287         penlabels(5,6);
 288         save t; t=tense;
 289
 290         save p;
 291         path p ;
 292         p := z1l{dir(beta)}..tension t..z4r{up}
 293                 .. number_flare_path(z5r,180,90,thin, flare,
 294                                 x5r  - 1/2 hair,
 295                                 .22 h,
 296                                 flare_start* flare, 1)
 297                 .. z4l{down}..tension t
 298                 ..{dir(180+beta)}z1r..cycle;
 299
 300         pickup pencircle scaled 1;
 301 %       draw p;
 302         fill p;
 303
 304 fet_endchar;
 305
 306 fet_beginchar("Numeral 3", "3", "three")
 307         set_char_box(0, 2/3height#*widen, 0, height#);
 308         message "w:"&decimal w;
 309         message "h:"&decimal h;
 310         penpos1(hair,-90);
 311         z1l=(17/16thick,h);
 312         penpos2(7/8thick,180);
 313         z2l=(w-thick/8,3/4h+thick/16);
 314         penpos3(thin,90);
 315         z3=(w/2,h/2+1/8thick);
 316         penpos4(thin,90);
 317         z4=(5/8thick+1/2thin,y3);
 318         penpos5(thick,0);
 319         z5r=(w,1/4h+thick/16);
 320         penpos6(hair,-90);
 321         z6r=(9/8thick,0);
 322         penpos7(3/2thin,90);
 323         z7=(x5,y3);
 324         penlabels(1,2,3,4,5,6,7);
 325         save alpha; alpha=25;
 326         save t; t=tense;
 327         pickup pencircle scaled 1;
 328 %       draw
 329         fill
 330                 flare_path (z1l, 180, 90, hair, 7/8 flare, -1)
 331                 .. super_curvelet(z1l, z2l, 0.76, -1)
 332                 .. z2l{down}..z7r{dir(180+alpha)}
 333                 ..z7l{dir(-alpha)}..z5r{down}..tension t..
 334
 335                 flare_path (z6r, 180, -90, hair, flare, 1) ..tension t..
 336
 337                 z5l{up}
 338                 ..tension t..z3l{left}..z4l{left}
 339                 ..z4r{right}..z3r{right}..tension t..z2r{up}
 340                 ..tension t.. cycle
 341 ;
 342 fet_endchar;
 343
 344
 345
 346 fet_beginchar("Numeral 4", "4", "four")
 347         set_char_box(0, 4/5height#*widen, 0, height#);
 348         message "w:"&decimal w;
 349         message "h:"&decimal h;
 350
 351         save alpha; alpha=0;
 352         calc_kuulleke(3/2thick,alpha);
 353         z1r=(w-3/4thick,height);
 354
 355         z5=(thin,1/4height+thin);
 356         save beta; beta=angle(z3r-z5);
 357         penpos6(thin,-90);
 358         z6l=z5;
 359         penpos7(thin,-90);
 360         y7=y6; x7=w-1/2thin;
 361         penpos8(thin,-alpha);
 362         z8r=z5;
 363         penlabels(1,2,3,4,5,6,7);
 364         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 365         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 366                 ..z3r{dir(180+beta)}..{dir(180+beta)}z8r{right}
 367                 ..{right}z7l..z7r{left}..{left}z6r..z8l{dir(beta)}
 368                 ..{up}z2l..cycle;
 369
 370         clearxy;
 371
 372         save alpha; alpha=beta;
 373         calc_kuulleke(thick,alpha);
 374         z1r=(w-3/4thick,height-(3/2thin)/cosd(alpha));
 375
 376         penpos5(thick,0);
 377         z5=(x1,foot_top);
 378
 379         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 380         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 381                 ..z3r{down}..{down}z5r{left}..z5..{left}z5l{up}
 382                 ..{up}z2l..cycle;
 383         penlabels(1,2,3,4,5);
 384
 385         draw_foot(x5);
 386 fet_endchar;
 387
 388 fet_beginchar("Numeral 5", "5", "five")
 389         set_char_box(0, 7/10height#*widen, 0, height#);
 390         message "w:"&decimal w;
 391         message "h:"&decimal h;
 392         calc_kuulleke(w-thin,0);
 393         z1=(w/2+1/8thick,h);
 394         save alpha; alpha=0;
 395         penpos5(thin,0);
 396         z5l=(x1l,h-15/16thick);
 397         penpos6(hair,90-45);
 398         z6=z5r+1/2hair*dir(-45);
 399         penpos7(thin,0);
 400         z7l=(x1l,h/2+thin-hair);
 401         penlabels(1,2,3,4,5,6,7);
 402         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 403         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 404                 ..z3r{dir(-135)}..{left}z6r..z6l{down}..z7r{down}
 405                 ..z7l{up}..{up}z2l..cycle;
 406         penpos8(thin,90);
 407         z8l=(x7r,y7r-1/16thick);
 408         penpos9(thin,90);
 409         z9=(x11+3/16thick,10/16[y5,y7]);
 410         penpos10(thick,0);
 411         z10r=(w,1/2[y9r,y11r]);
 412         penpos11(hair,-90);
 413         z11r=(9/8thick,0);
 414         penlabels(8,9,10,11);
 415         save beta; beta=45;
 416         save t; t=tense;
 417         fill z8r{dir(beta)}..z9r{right}..tension t..z10r{down}
 418                 .. super_curvelet(z10r, z11r, 0.76, 1)
 419                 .. flare_path(z11r,180,-90,hair,flare, 1)
 420                 ..z11l{right}..tension t..z10l{up}..tension t
 421                 ..z9l{left}..z8l{dir(180+beta+10)}..cycle;
 422
 423 fet_endchar;
 424
 425 fet_beginchar("Numeral 6", "6", "six")
 426         draw_six;
 427 fet_endchar;
 428
 429 fet_beginchar("Numeral 7", "7", "seven")
 430         set_char_box(0, 11/15height#*widen, 0, height#);
 431         message "w:"&decimal w;
 432         message "h:"&decimal h;
 433
 434         save alpha; alpha=-180;
 435 if true:
 436         penpos1(3/2thick,180+alpha);
 437         penpos2(hair,180+alpha-45);
 438         z2=z1l+(1/4sqrt(2)*hair)*dir(alpha-135);
 439         penpos3(hair,180+alpha+45);
 440         z3=z1r+(1/4sqrt(2)*hair)*dir(alpha-45);
 441         z4=z1+kuulleke*dir(alpha-90);
 442 else:
 443         % shit, does not work
 444         calc_kuulleke(3/2thick,-alpha);
 445 fi
 446         z1l=(thin,0);
 447
 448         save beta; beta=55;
 449         penpos5(thin,90+beta);
 450         z5=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 451
 452         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 453         save delta; delta=12;
 454         pickup pencircle;
 455         fill z3l{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z2r..
 456                 z2l{dir(beta+delta)}..{dir(beta)}z5r
 457                 ..z5l{dir(180+beta)}..{dir(delta-90)}z3r..cycle;
 458         penlabels(1,2,3,4,5);
 459
 460         clearxy;
 461         save alpha; alpha=-45*widen;
 462         penpos1(1/2thick,90);
 463         z1=(3/2thin,h-(thick+thin)/2);
 464         penpos3(thin,90+beta);
 465         z3=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 466         penpos2(thick,90+alpha);
 467         x2=1/2[x1,x3]-1/4thick; y2=h-15/16thick+thin*widen;
 468
 469         penpos4(thin,0);
 470         z4l=(0,h-thin/2);
 471         penpos5(thin,0);
 472         z5l=(0,h/2+thin/2);
 473
 474         penpos6(9/8thick,90);
 475         z6r=(thin,y1r+2/16thick);
 476
 477         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(beta)}z3r
 478                 ..z3l{dir(180+beta)}..{dir(180+alpha)}z2l
 479                 ..{dir(180+beta)}z1l..z6l{down}..{down}z5r
 480                 ..z5l{up}..{up}z4l..z4r{down}..{down}z6r..{right}cycle;
 481         penlabels(1,2,3,4,5,6);
 482 fet_endchar;
 483
 484 fet_beginchar("Numeral 8", "8", "eight")
 485         set_char_box(0, 11/15height#*widen, 0, height#);
 486         message "w:"&decimal w;
 487         message "h:"&decimal h;
 488         save alpha; alpha=60;
 489         save beta; beta=alpha-15;
 490         z1=(w/2,h/2+thick/8);
 491         penpos2(hair,90+180+beta);
 492         z2=(w/3,h/2+thin);
 493         penpos3(3/2thin,0);
 494         z3l=(0,h/4+thin/2);
 495         penpos4(hair,90);
 496         z4l=(x1,0);
 497         penpos5(thick,90+90+alpha);
 498         z5=z1+w/4*dir(alpha-90);
 499         penpos6(thick,90+90+alpha);
 500         z6=z1+(w/4-thin/2)*dir(90+alpha);
 501         penpos7(hair,90);
 502         z7r=(x1,h);
 503         penpos8(3/2thin,0);
 504         z8r=(w-thin/2,3/4h+thin/2);
 505         penpos9(hair,90+180+beta);
 506         z9=(2/3w,h/2);
 507         penlabels(1,2,3,4,5,6,7,8,9);
 508         save t; t=tense;
 509         fill z2r{dir(180+beta)}..z3r{down}..z4r{right}
 510                 ..z5r{dir(90+alpha)}..z6r{dir(90+alpha)}
 511                 ..tension t..z7r{right}..z8r{down}..z9r{dir(180+beta)}
 512                 ..z9l{dir(beta)}..z8l{up}..z7l{left}..z6l{dir(alpha-90)}
 513                 ..z5l{dir(alpha-90)}..tension t..z4l{left}..z3l{up}
 514                 ..z2l{dir(beta)}..cycle;
 515 fet_endchar;
 516
 517 fet_beginchar("Numeral 9", "9", "nine")
 518         draw_six;
 519 %       xy_mirror_char;
 520         currentpicture := currentpicture scaled -1;
 521         currentpicture := currentpicture shifted (w,h);
 522 fet_endchar;
 523
 524 fet_endgroup("number")
 525