mf/feta-klef.mf

   1 %
   2 % feta-klef.mf --  implement Clefs
   3 %
   4 % source file of the Feta (Font-En-Tja) music font
   5 %
   6 % (c) 1997 Han-Wen Nienhuys <hanwen@stack.nl>
   7 %
   8
   9 fet_begingroup("klef");
  10
  11
  12 def draw_staff(expr first, last)=
  13         pickup pencircle scaled stafflinethickness;
  14         for i:= first step 1 until last:
  15                 draw (- interline, i* interline) .. (4 interline, i* interline);
  16         endfor
  17
  18  enddef;
  19
  20
  21
  22 %
  23 % Inspired by Baerenreiter and Breitkopf
  24 %
  25 % FIXME: dims
  26 % FIXME: right vertical tangent seems to be lower than the F-line
  27 % FIXME: bulb curve smoothly into "long curve" on the  inside
  28 %
  29 %
  30 % [Wanske] says that the extreme x point should be exactly between
  31 % the dots, but her picture shows that the extreme is ~ 0.2 ss lower
  32
  33 def draw_bass_klef(expr exact_center, reduction) =
  34         save reduced_il, left_tilt, left_thick;
  35         reduced_il# = interline# * reduction;
  36         left_tilt = 5;
  37         define_pixels(reduced_il);
  38         left_thick = .25  reduced_il;
  39
  40         set_char_box(
  41                 - xpart exact_center+ .2 reduced_il#,
  42                 xpart exact_center + 2.7 reduced_il#,
  43                 - ypart exact_center + 2.5 reduced_il#,
  44                 ypart exact_center +reduced_il#);
  45         x1r - x1l = left_thick;
  46         z1l = (hround_pixels(xpart exact_center),
  47                 vround_pixels(ypart exact_center));
  48
  49         y2 = reduced_il;
  50
  51         x3l - x1l =  2.1 reduced_il;
  52         x2 = .5 [x1,x3];
  53         x3l - x3r = .48 reduced_il;
  54         y3l = -0.05 interline;
  55         x4 = x1l - stafflinethickness;
  56         y4 = -2.2  reduced_il;
  57         z5 = (x3l +  1/3 reduced_il, .5 reduced_il);
  58
  59         penpos1(whatever, left_tilt);
  60         penpos2(1.2 stafflinethickness, -90);
  61         penpos3(whatever,  185);
  62         penpos4(stafflinethickness, 135);
  63
  64         draw_bulb(1, z1r,  z1l, .45 reduced_il, 1.0);
  65
  66
  67         fill z1r{up} .. z2r{right} .. tension 1.0 .. z3r{down}  .. {curl 0}
  68                 simple_serif(z4r, z4l, 90) {curl 0}
  69                 .. z3l{up} .. tension 0.9 .. z2l{left}
  70                 .. z1l{dir (-90 + left_tilt)} -- cycle;
  71         labels(2,4);
  72         penlabels(1,2,3,4);
  73
  74         pickup pencircle scaled (.35 reduced_il);
  75         draw z5;
  76         draw z5 yscaled -1;
  77 enddef;
  78
  79
  80
  81 fet_beginchar("F clef ", "bass", "bassclef")
  82         if test = 1:
  83                 draw_staff(-3,1);
  84         fi;
  85         draw_bass_klef((.5 interline#, 0), 1.0);
  86 fet_endchar;
  87 fet_beginchar("F clef (reduced)", "bass_change", "cbassclef")
  88         draw_bass_klef((.4 interline#, 0),0.8);
  89 fet_endchar;
  90
  91
  92
  93 %
  94 % Inspired by Baerenreiter
  95 %
  96 % FIXME top
  97 % FIXME bulb should curve (see bass clef)
  98 % FIXME start (inside) should be little thinner
  99 % FIXME parametrise.
 100 % FIXME should be a bit more upright
 101 %
 102 def draw_gclef (expr exact_center, reduction)=
 103         save reduced_il, downstroke_dir, downstroke_angle, hair, center;
 104         save breapth_factor, inner_thick_end, thinness, thickness, thinnib
 105 , thinness, thinpen;
 106         reduced_il# = interline# * reduction;
 107         define_pixels(reduced_il);
 108         pair downstroke_dir, center;
 109
 110         center := (hround_pixels(xpart exact_center),
 111                 vround_pixels(ypart exact_center));
 112
 113         hair =  .3 stafflinethickness;
 114         thinness = 1.3 stafflinethickness;
 115         downstroke_dir = (14, -75);
 116         breapth_factor = 11/7;
 117         inner_thick_end = 45;
 118         thickness = .4 interline - hair;
 119
 120         thinnib = thinness - hair;
 121         thinpen = thinness;
 122         set_char_box(-xpart exact_center + breapth_factor* reduced_il#,
 123                 xpart exact_center + .66 breapth_factor* reduced_il#,
 124                 -ypart exact_center + 3 * reduced_il#,
 125                 ypart exact_center + 5 * reduced_il#);
 126
 127         pickup pencircle scaled hair;
 128
 129         downstroke_angle = angle downstroke_dir;
 130         z1 = center + whatever * (-1, -2);
 131         x1 = xpart center -.28 reduced_il;
 132
 133         top z2r = center + (0,reduced_il + stafflinethickness/2);
 134
 135         x4 = xpart center - .1 reduced_il;
 136         bot y4r = -(reduced_il + .5 stafflinethickness);
 137
 138         z3 = (z4 - center) rotated inner_thick_end + center;
 139
 140         z5r = (- breapth_factor, .37)* reduced_il + center;
 141         penpos5(thickness, 135);
 142
 143         z6 = center + whatever * downstroke_dir;
 144         y6 = ypart center + 2 reduced_il;
 145
 146
 147         z7l - z6 = whatever *(z5- z6) ;
 148         y7l = 3.5 reduced_il;
 149
 150
 151
 152         z8r = .4 [z9r, z7r] + 1.5 stafflinethickness * dir 52;
 153
 154         x9 = .7 [x10, x7r];
 155         top y9l = 5 reduced_il;
 156
 157         y10 = 3. reduced_il;
 158         y11 = -11/7 reduced_il;
 159
 160         y12 = ypart center - 18.5/7 reduced_il;
 161         x12 = x11 - 5 /7 reduced_il;
 162
 163         z13 = z12 + .6 reduced_il*(-1,1);
 164
 165         (z10r - z10l) dotprod (unitvector downstroke_dir rotated 90) =
 166                 thinnib;
 167
 168         center - z10= whatever * downstroke_dir;
 169         center - z11 =  whatever * downstroke_dir;
 170
 171         penpos1(thinnib, angle(-1,-2));
 172         penpos2(thickness, 90);
 173         penpos3(thinnib, -90 + inner_thick_end);
 174         penpos4(thinnib, -90);
 175
 176
 177         penpos7(thickness, 135);
 178         penpos8(1.5 thinnib, - 70 + angle downstroke_dir);
 179         penpos9(1.5 thickness, -80);
 180         penpos10(whatever, downstroke_angle + 10);
 181         penpos11(thinnib, downstroke_angle + 90);
 182         penpos12(thinnib, -90);
 183         penpos13(3 thinnib, 180);
 184
 185
 186         filldraw z2l{right}   .. z3l.. z4l{left} .. z5l{up}  .. z7l{up}
 187                 %.. z8l
 188                 .. z9l & z9l ..
 189                 {downstroke_dir}z10l --- z11l -- z11r --- z10r{- downstroke_dir}
 190                 .. tension .8
 191                 .. z9r & z9r
 192                 %.. z8r
 193                 .. z7r{down} .. z5r{down} .. z4r{right}
 194                 .. z3r .. z2r{left} ..
 195                 tension .95 ..
 196                 z1r -- z1l
 197                 .. tension 0.85 ..cycle;
 198
 199         filldraw simple_serif(z1r, z1l, 90)  -- cycle;
 200
 201         filldraw z12r{left} .. z13r{up} -- z13l{down} .. z12l{right} .. cycle;
 202
 203         draw_bulb(-1,  z13l, lft z13r, 6/14 reduced_il, 1.0);
 204
 205         pickup pencircle scaled (thinpen);
 206         draw z10 --- z11 .. z12{left};
 207
 208         penlabels(range 1 thru 15);
 209 enddef;
 210
 211
 212 fet_beginchar("G clef", "violin", "violinclef")
 213         if test = 1:
 214                 draw_staff(-1,3);
 215         fi;
 216         draw_gclef((1.6 interline#,0), 1.0);
 217 fet_endchar;
 218 fet_beginchar("G clef", "violin_change", "cviolinclef")
 219         draw_gclef((1.2 interline#,0), .8);
 220 fet_endchar;
 221
 222 fet_endgroup("klef");