mf/feta-klef.mf

   1 %
   2 % feta-klef.mf --  implement Clefs
   3 %
   4 % source file of the Feta (Font-En-Tja) music font
   5 %
   6 % (c) 1997 Han-Wen Nienhuys <hanwen@stack.nl>,
   7 % Jan Nieuwenhuizen <jan@digicash.com>
   8
   9 fet_begingroup("clefs");
  10
  11 def draw_staff(expr first, last)=
  12         pickup pencircle scaled stafflinethickness;
  13         for i:= first step 1 until last:
  14                 draw (- interline, i* interline) .. (4 interline, i* interline);
  15         endfor
  16         enddef;
  17
  18 % [Wanske] says the bulbs should be positioned about 1/4 right of the
  19 % "arrow"
  20 def draw_c_clef (expr reduction) =
  21         save hair, norm, reduced_il;
  22         reduced_il#=interline#*reduction;
  23         norm#:=2/3reduced_il#;
  24         hair#:=1/6norm#;
  25         define_pixels (hair,norm,reduced_il);
  26         set_char_box (0, 15/4norm#+2hair#,
  27                 2 reduced_il#, 2 reduced_il#);
  28         draw_block ((0,-d), (3/4norm+1/2hair,h));
  29         draw_block ((3/4norm+2hair,-d),
  30                 (3/4norm+7/2hair,h));
  31
  32         save xoff;
  33         xoff=3/4norm+7/2hair;
  34         penpos1(hair,-90);
  35         z1l=(xoff+norm+hair,h);
  36         penpos2(norm-hair,180);
  37         z2l=(w,h/2);
  38         penpos3(hair,90);
  39         z3=(((w-xoff)/2)+xoff,2hair);
  40
  41         penpos4(hair,0);
  42         z4=(xoff+1/2norm+1/2hair,reduced_il-hair);
  43
  44         penpos5(4hair,0);
  45         z5=(xoff+5/4hair,0);
  46
  47         penpos6(norm-hair,90);
  48         z6=(xoff+3/4norm,0);
  49
  50         penpos7(hair,-90);
  51         z7r=(x1,-d);
  52
  53         save t; t=0.833;
  54         save p; path p;
  55         p = z5l..z4l{up}..z4r{down}..z3r{right}..tension t..z2r{up}
  56                 ..tension t..z1r{left}..z1l{right}..tension t..z2l{down}
  57                 ..z3l{left}..z6r..z5r{down};
  58         pickup pencircle scaled 1pt#;
  59         filldraw p..(reverse p yscaled -1)..cycle;
  60         penlabels (1,2,3,4,5,6);
  61
  62         % ugh, should be bulb, not flare?
  63         draw_flare(z1l,180,90,hair,norm-1/4hair);
  64         draw_flare(z7r,180,-90,hair,norm-1/4hair);
  65         enddef;
  66
  67 fet_beginchar ("C clef", "alto", "altoclef")
  68         if test = 1:
  69                 draw_staff (-2,2);
  70         fi;
  71         draw_c_clef (1.0);
  72 fet_endchar;
  73
  74 fet_beginchar ("C clef", "alto_change", "caltoclef")
  75         if test = 1:
  76                 draw_staff (-2,2);
  77         fi;
  78         draw_c_clef (.8);
  79 fet_endchar;
  80
  81 %
  82 % Inspired by Baerenreiter and Breitkopf
  83 %
  84 % FIXME: dims
  85 % FIXME: right vertical tangent seems to be lower than the F-line
  86 % FIXME: bulb curve smoothly into "long curve" on the  inside
  87 %
  88 %
  89 % [Wanske] says that the extreme x point should be exactly between
  90 % the dots, but her picture shows that the extreme is ~ 0.2 ss lower
  91
  92 def draw_bass_klef(expr exact_center, reduction) =
  93         save reduced_il, left_tilt, left_thick;
  94         reduced_il# = interline# * reduction;
  95         left_tilt = 5;
  96         define_pixels(reduced_il);
  97         left_thick = .25  reduced_il;
  98
  99         set_char_box(
 100                 - xpart exact_center+ .2 reduced_il#,
 101                 xpart exact_center + 2.7 reduced_il#,
 102                 - ypart exact_center + 2.5 reduced_il#,
 103                 ypart exact_center +reduced_il#);
 104         x1r - x1l = left_thick;
 105         z1l = (hround_pixels(xpart exact_center),
 106                 vround_pixels(ypart exact_center));
 107
 108         y2 = reduced_il;
 109
 110         x3l - x1l =  2.1 reduced_il;
 111         x2 = .5 [x1,x3];
 112         x3l - x3r = .48 reduced_il;
 113         y3l = -0.05 interline;
 114         x4 = x1l - stafflinethickness;
 115         y4 = -2.2  reduced_il;
 116         z5 = (x3l +  1/3 reduced_il, .5 reduced_il);
 117
 118         penpos1(whatever, left_tilt);
 119         penpos2(1.2 stafflinethickness, -90);
 120         penpos3(whatever,  185);
 121         penpos4(stafflinethickness, 135);
 122
 123         draw_bulb(1, z1r,  z1l, .45 reduced_il, 1.0);
 124
 125
 126         fill z1r{up} .. z2r{right} .. tension 1.0 .. z3r{down}  .. {curl 0}
 127                 simple_serif(z4r, z4l, 90) {curl 0}
 128                 .. z3l{up} .. tension 0.9 .. z2l{left}
 129                 .. z1l{dir (-90 + left_tilt)} -- cycle;
 130         labels(2,4);
 131         penlabels(1,2,3,4);
 132
 133         pickup pencircle scaled (.35 reduced_il);
 134         draw z5;
 135         draw z5 yscaled -1;
 136 enddef;
 137
 138
 139
 140 fet_beginchar("F clef ", "bass", "bassclef")
 141         if test = 1:
 142                 draw_staff(-3,1);
 143         fi;
 144         draw_bass_klef((.5 interline#, 0), 1.0);
 145 fet_endchar;
 146 fet_beginchar("F clef (reduced)", "bass_change", "cbassclef")
 147         draw_bass_klef((.4 interline#, 0),0.8);
 148 fet_endchar;
 149
 150
 151
 152 %
 153 % Inspired by Baerenreiter
 154 %
 155 % FIXME top should be thinner at z8,
 156 % FIXME bulb should curve (see bass clef)
 157 % FIXME start (inside) should be little thinner
 158 % FIXME parametrise.
 159 %
 160
 161 % Beste lezers, kijk,
 162 %
 163 % Een bolletje  hebben we bij toeval allemaal wel eens getekend, maar begint u
 164 % toch eenvoudig.   Eerst een eenvoudig kruis of herstellingsteken
 165 % en via de dubbelslag naar een voorzichtig vlaggetje, en heb geduld!
 166 % Ikzelf heb bijvoorbeeld over mijn eerste gave G-sleutel
 167 % 35 kilobyte metafont, 12 patchlevels, 0 vriendinnen en 45 dagen gedaan
 168 %
 169 def draw_gclef (expr exact_center, reduction)=
 170         save reduced_il, downstroke_dir, downstroke_angle, hair, center;
 171         save breapth_factor, inner_thick_end, thinness, thickness, thinnib;
 172         save inner_start_angle, thinness, thinpen;
 173         reduced_il# = interline# * reduction;
 174         define_pixels(reduced_il);
 175         pair downstroke_dir, center;
 176
 177         center := (hround_pixels(xpart exact_center),
 178                 vround_pixels(ypart exact_center));
 179
 180         hair =  .3 stafflinethickness;
 181         thinness = 1.3 stafflinethickness;
 182         downstroke_dir = (14, -75);
 183         breapth_factor = 11/7;
 184         inner_thick_end = 45;
 185         inner_start_angle = downstroke_angle - 43;
 186         thickness = .4 reduced_il - hair;
 187
 188         thinnib = thinness - hair;
 189         thinpen = thinness;
 190         set_char_box(-xpart exact_center + 1.1 * breapth_factor* reduced_il#,
 191                 xpart exact_center + .66 breapth_factor* reduced_il#,
 192                 -ypart exact_center + 3 * reduced_il#,
 193                 ypart exact_center + 5 * reduced_il#);
 194
 195         pickup pencircle scaled hair;
 196         downstroke_angle = angle downstroke_dir;
 197
 198         z1 = center + whatever * dir (inner_start_angle);
 199         x1 = xpart center -.28 reduced_il;
 200
 201         top z2r = center + (0,reduced_il + stafflinethickness/2);
 202
 203         x4 = xpart center - .1 reduced_il;
 204         bot y4r = -(reduced_il + .5 stafflinethickness);
 205
 206         z3 = (z4 - center) rotated inner_thick_end + center;
 207
 208         z5r = (- breapth_factor, .37)* reduced_il + center;
 209         penpos5(thickness, 135);
 210
 211         z6 = center + whatever * downstroke_dir;
 212         y6 = ypart center + 2 reduced_il;
 213
 214         z7l - z6 = whatever *(z5- z6) ;
 215         y7l = 3.5 reduced_il;
 216         z8r = .4 [z9r, z7r] + 1.5 stafflinethickness * dir 52;
 217
 218         x9 = .7 [x10, x7r];
 219         top y9l = 5 reduced_il;
 220
 221         y10 = 3. reduced_il;
 222         y11 = -11/7 reduced_il;
 223
 224         y12 = ypart center - 18.5/7 reduced_il;
 225         x12 = x11 - 5 /7 reduced_il;
 226
 227         z13 = z12 + .6 reduced_il*(-1,1);
 228
 229         (z10r - z10l) dotprod (unitvector downstroke_dir rotated 90) =
 230                 thinnib;
 231
 232         center - z10= whatever * downstroke_dir;
 233         center - z11 =  whatever * downstroke_dir;
 234
 235         penpos1(thinnib, inner_start_angle);
 236         penpos2(thickness, 90);
 237         penpos3(thinnib, -90 + inner_thick_end);
 238         penpos4(thinnib, -90);
 239
 240
 241         penpos7(thickness, 135);
 242         penpos8(1.5 thinnib, - 70 + angle downstroke_dir);
 243         penpos9(1.5 thickness, -80);
 244         penpos10(whatever, downstroke_angle + 10);
 245         penpos11(thinnib, downstroke_angle + 90);
 246         penpos12(thinnib, -90);
 247         penpos13(3 thinnib, 180);
 248
 249
 250         filldraw z2l{right}   .. z3l.. z4l{left} .. z5l{up}  .. z7l{up}
 251                 %.. z8l
 252                 .. z9l & z9l ..
 253                 {downstroke_dir}z10l --- z11l -- z11r --- z10r{- downstroke_dir}
 254                 .. tension .8
 255                 .. z9r & z9r
 256                 %.. z8r
 257                 .. z7r{down} .. z5r{down} .. z4r{right}
 258                 .. z3r .. z2r{left} ..
 259                 tension .95 ..
 260                 z1r -- z1l
 261                 .. tension 0.85 ..cycle;
 262
 263         filldraw simple_serif(z1r, z1l, 90)  -- cycle;
 264
 265         filldraw z12r{left} .. z13r{up} -- z13l{down} .. z12l{right} .. cycle;
 266
 267         draw_bulb(-1,  z13l, lft z13r, 6/14 reduced_il, 1.0);
 268
 269         pickup pencircle scaled (thinpen);
 270         draw z10 --- z11 .. z12{left};
 271
 272         penlabels(range 1 thru 15);
 273 enddef;
 274
 275
 276 fet_beginchar("G clef", "violin", "violinclef")
 277         if test = 1:
 278                 draw_staff(-1,3);
 279         fi;
 280         draw_gclef((1.7 interline#,0), 1.0);
 281 fet_endchar;
 282 fet_beginchar("G clef", "violin_change", "cviolinclef")
 283         draw_gclef((1.3 interline#,0), .8);
 284 fet_endchar;
 285
 286 fet_endgroup("clefs");