mf/feta-klef.mf

   1 % feta-klef.mf --  implement Clefs -*-Fundamental-*-
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997--2005 Han-Wen Nienhuys <hanwen@cs.uu.nl>,
   8 % Jan Nieuwenhuizen <janneke@gnu.org>,
   9 % Juergen Reuter <reuter@ipd.uka.de>
  10
  11
  12 fet_begingroup ("clefs");
  13
  14 %
  15 % [Wanske] says the bulbs should be positioned about 1/4 right of the
  16 % `arrow'.
  17 %
  18 % TODO: The hair-curve at z6r looks a little awkward.
  19 %
  20
  21 def draw_c_clef (expr reduction) =
  22         save hair, norm, reduced_ss, right_edge;
  23         save xoff;
  24
  25         reduced_ss# = staff_space# * reduction;
  26         norm# := 2/3 reduced_ss#;
  27         hair# := 0.06 reduced_ss# + 0.5 linethickness#;
  28         right_edge# = 15/4 norm# + 2 hair#;
  29         define_pixels (norm, reduced_ss, right_edge);
  30         define_whole_vertical_blacker_pixels (hair);
  31
  32         set_char_box (0, right_edge#, 2 reduced_ss#, 2 reduced_ss#);
  33
  34         % make unreduced glyph fit exactly into five staff lines
  35         if reduction = 1:
  36                 h := d := 2 staff_space_rounded;
  37         fi;
  38
  39         % assure that the gap between the left and right stem
  40         % has the same number of pixels as the thickness of the right
  41         % stem
  42         draw_block ((0, -d + feta_shift),
  43                     (3/4 norm + 1/2 hair, h));
  44         draw_block ((3/4 norm + 1/2 hair + hround (3/2 hair), -d + feta_shift),
  45                     (3/4 norm + 1/2 hair + 2 hround (3/2 hair), h));
  46
  47         % assure symmetry
  48         h := h - feta_shift;
  49
  50         pickup feta_fillpen;
  51
  52         xoff = 3/4 norm + 1/2 hair + 2 hround (3/2 hair);
  53         z5l = (xoff - 3/4 hair, 0);
  54         z5r = (x4, 0);
  55
  56         penpos1 (hair - pen_top - pen_bot, -90);
  57         top z1l = (xoff + norm + hair, h);
  58
  59         penpos2 (hround (norm - 3/2 hair) - pen_lft - pen_rt, 180);
  60         rt z2l = (w, h / 2);
  61
  62         penpos3 (hair - pen_top - pen_bot, 90);
  63         bot z3l = ((right_edge - xoff) / 2 + xoff,
  64                    vround (.5 norm - 1.5 hair));
  65
  66         penpos4 (hair - pen_lft - pen_rt, 0);
  67         top z4 = (xoff + 1/2 norm + 1/2 hair,
  68                   vfloor (reduced_ss - linethickness - .2 hair));
  69
  70         bot z6 = (xoff + 3/4 norm, vround (.5 norm - .5 hair));
  71
  72         save t;
  73         t = 0.833;
  74
  75         save pat;
  76         path pat;
  77
  78         pat = z5l{curl 1}
  79               .. z4l{up}
  80               .. z4r{down}
  81               .. z3r{right}
  82               ..tension t.. z2r{up}
  83               ..tension t.. flare_path (top z1l, 180, 90,
  84                                         hair, hfloor (norm - 1/2 hair), -1)
  85               ..tension t.. z2l{down}
  86               .. z3l{left}
  87               .. z6
  88               .. z5r{down};
  89
  90         filldraw pat shifted (0, feta_shift)
  91                  -- reverse pat yscaled -1 shifted (0, -feta_eps)
  92                  -- cycle;
  93
  94         penlabels (1, 2, 3, 4, 5, 6);
  95
  96         % ugh, should be bulb, not flare?
  97
  98         draw_staff (-2, 2, 0);
  99 enddef;
 100
 101
 102 fet_beginchar ("C clef", "C");
 103         draw_c_clef (1.0);
 104 fet_endchar;
 105
 106
 107 fet_beginchar ("C clef", "C_change");
 108         draw_c_clef (.8);
 109 fet_endchar;
 110
 111
 112 %
 113 % New bulb routine:
 114 %
 115 % Insert a brushed piece of the path, and draw the rest of the bulb
 116 % separately.
 117 %
 118 % The bulb has circular form.  Neat merging of the bulb and brushed path
 119 % is done by playing with tension.
 120 %
 121
 122 def new_bulb (expr start_point, start_angle,
 123               outer_tangent_point,
 124               end_point, end_angle,
 125               big_radius, bulb_radius, flare,
 126               direction, turning_dir) =
 127 begingroup;
 128         save pat, before, after;
 129         save center;
 130         save u, v;
 131         path pat, before, after;
 132         pair center;
 133
 134         clearxy;
 135
 136         center = outer_tangent_point
 137                  + big_radius * dir (0)
 138 %                + (big_radius - bulb_radius) * dir (-turning_dir * 90)
 139                 ;
 140
 141         z1' = center + bulb_radius * dir (turning_dir * 180);
 142         z2' = outer_tangent_point + flare * dir (0);
 143         z3' = center + bulb_radius * dir (0);
 144         z4' = center + bulb_radius * dir (turning_dir * 90);
 145         z5' = center - 0.5 [big_radius, bulb_radius] * dir (turning_dir * 90);
 146
 147         labels (1', 2', 3', 4', 5');
 148
 149         before := z3'{dir (turning_dir * 90)}
 150                   .. z4'{-dir(0)}
 151                   .. tension 1.1
 152                   .. z1'{-dir (turning_dir* 90)};
 153         after := z2'{dir (turning_dir * 90)}
 154                  .. tension 1.05
 155                  .. end_point{dir (end_angle)};
 156         (u, v) = before intersectiontimes after;
 157
 158         pat := start_point{dir (start_angle)}
 159                .. outer_tangent_point{dir (-turning_dir * 90)}
 160                .. tension 1.02
 161                .. z5'{dir(0)}
 162                .. subpath (0, u) of before
 163                .. subpath (v, infinity) of after;
 164
 165         if direction = 0:
 166                 pat := reverse pat;
 167         fi
 168         pat
 169 endgroup
 170 enddef;
 171
 172
 173 %
 174 % There is some variation in the shape of bass clefs.
 175 %
 176 % * In some clefs the size of the swoosh tip almost reaches the
 177 %   bottom staff line; in some it crosses the 2nd line from the bottom
 178 %   with a small overshoot.
 179 %
 180 %   The most popular design is where the X part of the tip is aligned
 181 %   with the left bulb boundary, and the Y part ends on the 2nd
 182 %   staffline exactly.  This is what we do.
 183 %
 184 % * The diameter of the bulb is the width of the open space.
 185 %
 186 % * The vertical center of the bulb can be on or slightly above the
 187 %   staff line.
 188 %
 189 % * The vertical position of the dots can be symmetrical around the
 190 %   staffline, centered in the staff space.  The Baerenreiter SCS has
 191 %   the bottom dot raised by approximately 0.1 staff space.
 192 %
 193 % * Uncarefully set music may have overshoots at the top.  We have none.
 194 %
 195 % * It is not exactly clear where the vertical tangent at the right
 196 %   of the swoosh should be.
 197 %
 198
 199 def draw_bass_clef (expr exact_center, reduction) =
 200         save reduced_ss, swoosh_width;
 201         save right_thickness, right_offset, tip_protude;
 202         save dot_diam, bulb_y_offset, bulb_flare;
 203         pair tip_protude;
 204
 205         reduced_ss# = staff_space# * reduction;
 206         2.2 dot_diam# = reduction * (staff_space# - stafflinethickness#);
 207         right_thickness# = 0.37 staff_space# + 1.2 linethickness#;
 208         swoosh_width# = 2.1 reduced_ss#;
 209         define_pixels (swoosh_width);
 210         define_whole_pixels (reduced_ss);
 211         define_whole_blacker_pixels (dot_diam, right_thickness);
 212
 213         right_offset = 0.05 staff_space;
 214         bulb_y_offset := 0.075 staff_space;
 215         bulb_flare := 2.5 linethickness;
 216 %       tip_protude := (-linethickness, -.2 staff_space);
 217         tip_protude := (0, 0);
 218
 219         set_char_box (-xpart exact_center,
 220                       xpart exact_center + swoosh_width# + 7/12 reduced_ss#,
 221                       -ypart exact_center + 2.5 reduced_ss#,
 222                       ypart exact_center + reduced_ss#);
 223
 224         y1 = bulb_y_offset;
 225         x1 = 0;
 226
 227         x2 = .5 [x1, x3];
 228         x2l = x2r = x2;
 229
 230         y2l := vround_pixels (reduced_ss# + 0.5 linethickness#);
 231         y2l - y2r = linethickness;
 232
 233         x3l - x1 = swoosh_width;
 234         x3l - x3r = right_thickness;
 235
 236         % optical correction: the top dot seems farther away if y3l = 0.
 237         y3l = right_offset;
 238
 239         z4 = -(0, 2.0 reduced_ss) + tip_protude;
 240
 241         penpos3 (whatever, 185);
 242         penpos4 (linethickness, 135);
 243
 244         fill new_bulb (z2l, 180, z1, z2r, 0,
 245                        0.45 reduced_ss, 0.4 reduced_ss,
 246                        bulb_flare, 1, 1)
 247              .. z3r{down}
 248              .. {curl 0}simple_serif (z4r, z4l, 90){curl 0}
 249              .. z3l{up}
 250              ..tension 0.9.. cycle;
 251
 252         pickup pencircle scaled dot_diam;
 253
 254         lft x5 = hround (x3l + 1/3 reduced_ss - dot_diam / 2);
 255         bot y5 = vfloor (.5 reduced_ss - dot_diam / 2);
 256         z6 = z5 yscaled -1;
 257
 258         % for symmetry
 259         y5 := y5 + feta_shift;
 260
 261         drawdot z5;
 262         drawdot z6;
 263
 264         penlabels (1, 2, 3, 4, 5, 6);
 265
 266         draw_staff (-3, 1, 0);
 267 enddef;
 268
 269
 270 fet_beginchar ("F clef ", "F");
 271         draw_bass_clef ((0, 0), 1.0);
 272 fet_endchar;
 273
 274
 275 fet_beginchar ("F clef (reduced)", "F_change");
 276         draw_bass_clef ((0, 0), 0.8);
 277 fet_endchar;
 278
 279
 280
 281 %
 282 % Inspired by Baerenreiter
 283 %
 284 %
 285 % Beste lezers, kijk,
 286 %
 287 % Een bolletje hebben we bij toeval allemaal wel eens getekend, maar begint u
 288 % toch eenvoudig.  Eerst een eenvoudig kruis of herstellingsteken
 289 % en via de dubbelslag naar een voorzichtig vlaggetje, en heb geduld!
 290 % Ikzelf heb bijvoorbeeld over mijn eerste gave G-sleutel
 291 % 35 kilobyte metafont, 12 patchlevels, 0 vriendinnen en 45 dagen gedaan
 292 %
 293 %  -- vrij naar Van Kooten & De Bie
 294 %
 295
 296 def debugfill = fill enddef;
 297
 298 def draw_gclef (expr reduction) =
 299         save reduced_ss, downstroke_dir, downstroke_angle, center;
 300         save breapth_factor, inner_thick_end, thinness, thickness, thinnib;
 301         save start_angle, inner_start_angle, thinness;
 302         save upward_swoosh_angle, bot_angle;
 303         save pat;
 304         path pat;
 305         pair downstroke_dir, center;
 306
 307         reduced_ss# = staff_space# * reduction;
 308         define_pixels (reduced_ss);
 309
 310         thinness = 0.10 staff_space + 0.65 linethickness;
 311         downstroke_dir = unitvector (14, -75);
 312         downstroke_angle = angle downstroke_dir;
 313         bot_angle = -180;               % downstroke_angle - 87
 314
 315         upward_swoosh_angle = 132;
 316         start_angle = -99;
 317
 318         breapth_factor = 21.0 /14;
 319         inner_thick_end = 45;
 320         inner_start_angle = downstroke_angle - 43;
 321         thickness = .32 reduced_ss + 1.1 linethickness;
 322
 323         thinnib = thinness;
 324
 325         set_char_box (0, 1.71 * breapth_factor * reduced_ss#,
 326                       2.6 * reduced_ss#, 5 * reduced_ss#);
 327
 328         center := (breapth_factor * reduced_ss, 0);
 329
 330         z1 = center + whatever * dir (inner_start_angle);
 331         x1 = xpart center - .28 reduced_ss;
 332         penpos1 (thinnib, inner_start_angle);
 333
 334         x2r = xpart center;
 335         y2r = vround_pixels (reduced_ss# + .5 stafflinethickness#);
 336         penpos2 (thickness, 90);
 337
 338         z3 = (z4 - center) rotated inner_thick_end + center;
 339         penpos3 (thinnib, -90 + inner_thick_end);
 340
 341         x4 = xpart center - .1 reduced_ss;
 342         y4r = -y2r + feta_shift;
 343         penpos4 (thinnib, -90);
 344
 345         x5r = -breapth_factor * reduced_ss + xpart center;
 346         y5r = .37 reduced_ss + ypart center;
 347         penpos5 (thickness, upward_swoosh_angle);
 348
 349         z6 = center + whatever * downstroke_dir;
 350         y6 = ypart center + 2 reduced_ss;
 351         % penpos6 is computed later
 352
 353         z7l - z6 = whatever * (z5 - z6) ;
 354         y7l = 3.5 reduced_ss;
 355         penpos7 (thickness, upward_swoosh_angle);
 356
 357         x9 = .7 [x10, x7r];
 358         top y9l = 5 reduced_ss;
 359         penpos9 (1.45 thickness, -70);
 360
 361         x11 - x13r = 1.5 reduced_ss + 0.5 thinnib;
 362         y11 = ypart center - 47/28 reduced_ss;
 363         y12 = ypart center - 71/28 reduced_ss;
 364         y13 = .48 [y12, y4r];
 365         x12r = xpart (.45 [z13r, z11] + .75 reduced_ss * downstroke_dir);
 366
 367 %       z10 = center + whatever * dir (downstroke_angle - 1.5);
 368         x10 = x6 - 2 thinnib;
 369         y10 = ypart center + 3.5 reduced_ss;
 370         y10l - y10r = 1.2 thickness;
 371         z10r - z10l = .7 thinnib * dir (downstroke_angle + 90)
 372                       + whatever * downstroke_dir;
 373         z10 = .5 [z10l, z10r];
 374
 375         z11 = center + whatever * downstroke_dir + (-0.05 reduced_ss, 0);
 376         penpos11 (thinnib, start_angle + 90);
 377
 378         penpos12 (thinnib, bot_angle + 90);
 379         penpos13 (thinnib + 0.14 staff_space, 180);
 380
 381         % this auxiliary point ensures good contour overlapping
 382         z8 = .5 [z9l, z9r] + .25 ((z9r - z9l) rotated -90);
 383
 384
 385         z20 = z9l - (0, .25 blot_diameter);
 386         penpos20(blot_diameter, 0);
 387
 388         fill
 389              z2l{right}
 390              .. z3l
 391              .. z4l{left}
 392              .. tension 1.07  % inside curve
 393              .. z5l{up}
 394              .. z7l{up}
 395              .. tension 1.2
 396              .. z20r
 397              & simple_serif (z20r,z20l, 60)
 398              -- z8
 399              -- z9r                     % {dir (downstroke_angle + 0)}
 400              ..tension 0.8.. z7r{down}
 401              .. z5r{down}
 402              .. z4r{right}
 403              .. z3r
 404              .. z2r{left}
 405              ..tension .95.. z1r
 406              -- simple_serif (z1r, z1l, 80)
 407              -- z1l
 408              ..tension 0.85.. cycle;
 409
 410         pat := z10{down}
 411                .. z6
 412                .. tension 1.02
 413                .. z11{dir (start_angle)};
 414
 415         penpos6 (thinnib, angle (direction 1 of pat) + 90);
 416
 417         % two auxiliary points to simulate `draw' with `penstroke'
 418         z10' = point 0.5 of pat;
 419         penpos10' (thinnib, angle (direction 0.5 of pat) + 90);
 420
 421         z11' = point 1.5 of pat;
 422         penpos11' (thinnib, angle (direction 1.5 of pat) + 90);
 423
 424         z21l = z20l;
 425         z21r = z9r;
 426
 427         penstroke z21e
 428                   .. z10e{down}
 429                   .. z10'e
 430                   .. z6e
 431                   .. z11'e
 432                   .. z11e{dir (-95)}
 433                   .. z12e{dir (bot_angle)};
 434
 435         fill new_bulb (z12r, bot_angle, z13r, z12l, bot_angle + 180,
 436                        0.45 reduced_ss, 0.38 reduced_ss,
 437                        thinnib + .075 staff_space, 1, -1)
 438              -- cycle;
 439
 440         penlabels (range 1 thru 20);
 441         penlabels (10', 11');
 442
 443         draw_staff (-1, 3, 0);
 444 enddef;
 445
 446
 447 fet_beginchar ("G clef", "G");
 448         draw_gclef (1.0);
 449 fet_endchar;
 450
 451
 452 fet_beginchar ("G clef", "G_change");
 453         draw_gclef (0.8);
 454 fet_endchar;
 455
 456
 457 %%%%
 458 %
 459 % PERCUSSION
 460 %
 461
 462 %
 463 % The percussion clef extent is not coincident with its bbox, since
 464 % the percussion clef needs more space in front than a normal clef.
 465 %
 466
 467 def draw_percussion_clef (expr reduction) =
 468         save reduced_ss, razt;
 469
 470         reduced_ss# = staff_space# * reduction;
 471         define_pixels (reduced_ss);
 472
 473         set_char_box (-.67 reduced_ss#, 2.0 reduced_ss#,
 474                       reduced_ss#, reduced_ss#);
 475
 476         razt := hround (0.45 reduced_ss);
 477
 478         d := d - feta_shift;
 479
 480         draw_block ((-b, -d), (-b + razt, h));
 481         draw_block ((w - razt, -d), (w, h));
 482
 483         draw_staff (-3, 1, 1);
 484 enddef;
 485
 486
 487 fet_beginchar ("percussion clef", "percussion");
 488         draw_percussion_clef (1.0);
 489 fet_endchar;
 490
 491
 492 fet_beginchar ("percussion clef (reduced)", "percussion_change");
 493         draw_percussion_clef (.8);
 494 fet_endchar;
 495
 496
 497 def draw_tab_T (expr pos, siz, slant) =
 498 begingroup;
 499         save vx, vy;
 500         pair vx, vy;
 501
 502         clearxy;
 503
 504         vx = (xpart siz) * dir 0;
 505         vy = (ypart siz) * dir 90;
 506
 507         penpos1 (.75 penh, 100);
 508         z1 = z2 + (1/6 * vx - .15 * vy);
 509         penpos2 (hround (.9 penw), 0);
 510         x2l = hround xpart (pos + .75 vy);
 511         y2l = ypart (pos + .75 vy);
 512         penpos3 (penh, -100);
 513         z3l = pos + .4 vx + vy;
 514         penpos4 (penh, -90);
 515         z4 = -.1 vy + .5 [z3, z5];
 516         penpos5 (.8 penh, -30);
 517         x5r = xpart (pos + siz);
 518         y5l = ypart (pos + siz);
 519
 520         penpos10 (penw, 170);
 521         z10 = pos + .55 vx + .9 vy;
 522         penpos11 (.75 [penh, penw], 170);
 523         z11 = z10 - .5 vy + .025 vx;
 524         penpos12 (penh, 100);
 525         z12l = (xpart .5 [z13, z11], ypart (pos - .025 * siz));
 526         penpos13 (.75 penh, 60);
 527         z13 = pos + .2 vx + .15 vy;
 528
 529         % penlabels (range 1 thru 13);
 530
 531         soft_penstroke (z1e
 532                         ..tension 1.1.. z2e
 533                         .. z3e{right}
 534                         ..tension 1.5.. z4e
 535                         ..z5e)
 536           slanted slant shifted (slant * -ypart pos, 0);
 537
 538         soft_end_penstroke (z10e
 539                             ..tension 1.5.. z11e
 540                             .. z12e
 541                             ..tension 1.1.. z13e{(z13r - z13l) rotated 90})
 542           slanted slant shifted (slant * -ypart pos, 0);
 543 endgroup;
 544 enddef;
 545
 546
 547 def draw_tab_A (expr pos, siz, slant) =
 548 begingroup;
 549         save vx, vy, pat;
 550         pair vx, vy;
 551         path pat;
 552
 553         clearxy;
 554
 555         vx = (xpart siz) * dir 0;
 556         vy = (ypart siz) * dir 90;
 557
 558         penpos1 (.75 penh, -110);
 559         z1r = pos + .07 vy;
 560         penpos2 (penh, -75);
 561         z2r = (.5 [x1, x3], ypart pos);
 562         penpos3 (.25 [penh, penw], -30);
 563         z3 = (.45 [x2, x4], .15 [y2, y4]);
 564         penpos4 (1 [penh, penw], 0);
 565         z4 = pos + .5 vx + .975 vy;
 566
 567         penpos5 (1 [penh, penw], -180);
 568         z5 = z4;
 569         penpos6 (.2 [penh, penw], -150);
 570         z6l = (.8 [x5l, x7l], .9 [y5l, y7l]);
 571         penpos7 (penh,-90);
 572         z7r = (.5 [x6, x8], ypart pos);
 573         penpos8 (.75 penh, -70);
 574         z8r = (xpart (pos + siz), y7r + .075 ypart (siz));
 575
 576         pat := z2
 577                .. z3
 578                .. z4;
 579
 580         penpos10 (penh, angle (direction 1.2 of pat) - 180);
 581         z10 = point 1.2 of pat;
 582         penpos11 (.9 penh, -90);
 583         z11 = .4 [z10, z6] - 0.05 vy;
 584         penpos12 (.75 penh, -75);
 585         z12 = .3 [z11, z6] + 0.02 vy;
 586
 587         % penlabels (range 1 thru 12);
 588
 589         soft_penstroke (z1e{(z1r - z1l) rotated 90}
 590                         .. z2e
 591                         .. z3e
 592                         .. z4e)
 593           slanted slant shifted (slant * -ypart pos, 0);
 594
 595         soft_end_penstroke (z5e
 596                             .. z6e
 597                             .. z7e
 598                             .. z8e{(z8r - z8l) rotated 90})
 599           slanted slant shifted (slant * -ypart pos, 0);
 600
 601         soft_end_penstroke (z10e
 602                             .. z11e
 603                             .. z12e)
 604           slanted slant shifted (slant * -ypart pos, 0);
 605 endgroup;
 606 enddef;
 607
 608
 609 def draw_tab_B (expr pos, siz, slant) =
 610 begingroup;
 611         save vx, vy;
 612         pair vx, vy;
 613
 614         clearxy;
 615
 616         vx = (xpart siz) * dir 0;
 617         vy = (ypart siz) * dir 90;
 618
 619         penpos1 (.75 penh, 100);
 620         z1 = z2 + (.15 * vx - .1 * vy);
 621         penpos2 (hround (.9 penw), 0);
 622         x2l = hround xpart (pos + .75 vy);
 623         y2l = ypart (pos + .75 vy);
 624         penpos3 (penh, -100);
 625         z3l = pos + .4 vx + 1.05 vy;
 626         penpos4 (.8 [penh, penw], -180);
 627         z4 = (xpart (pos + .75 siz), .5 [y3, y5]);
 628         penpos5 (.8 penh, 90);
 629         z5 = (.5 [x10, x4], ypart (pos + .55 siz));
 630
 631         penpos6 (.8 penh, 270);
 632         z6 = z5;
 633         penpos7 (penw, 180);
 634         z7l = (xpart (pos + siz), .5 [y6, y8]);
 635         penpos8 (.8 penh, 45);
 636         z8 = .5 [z12l, z11l] + .15 vx - .05 vy;
 637
 638         penpos10 (.75 [penh, penw], 170);
 639         z10 = pos + .375 vx + vy;
 640         penpos 11 (.8 [penh, penw], 150);
 641         z11 = z10 - .5 vy + .04 vx;
 642         penpos12 (penh, 100);
 643         z12l = (xpart .5 [z13, z11], ypart pos);
 644         penpos13 (.75 penh, 60);
 645         z13 = pos + .1 vx + .15 vy;
 646
 647         % penlabels (range 1 thru 13);
 648
 649         soft_penstroke (z1e
 650                         ..tension 1.1.. z2e
 651                         .. z3e
 652                         .. z4e
 653                         ..z5e {left})
 654           slanted slant shifted (slant * -ypart pos, 0);
 655
 656         soft_end_penstroke (z6e{right}
 657                             .. z7e
 658                             .. z8e{(z8r - z8l) rotated 90})
 659           slanted slant shifted (slant * -ypart pos, 0);
 660
 661         soft_end_penstroke (z10e
 662                             ..tension 1.5.. z11e
 663                             .. z12e
 664                             ..tension 1.1.. z13e{(z13r - z13l) rotated 90})
 665           slanted slant shifted (slant * -ypart pos, 0);
 666 endgroup;
 667 enddef;
 668
 669
 670 def draw_tab_clef (expr reduction) =
 671         save reduced_ss, letterheight, penw, penh;
 672
 673         reduced_ss# = staff_space# * reduction;
 674         letterheight# = 1.8 reduced_ss#;
 675         define_pixels (reduced_ss, letterheight);
 676
 677         set_char_box (-.2 reduced_ss#, 2.8 reduced_ss#,
 678                       1.6 letterheight#, 1.6 letterheight#);
 679
 680         penw = .45 reduced_ss;
 681         penh = .2 reduced_ss;
 682
 683         draw_tab_T ((-b + .15 reduced_ss, h - letterheight),
 684                     (2.1 reduced_ss, letterheight), 0.2);
 685         draw_tab_A ((-b - .05 reduced_ss, -.5 letterheight +.15 reduced_ss),
 686                     (2.2 reduced_ss, letterheight), 0.4);
 687         draw_tab_B ((-b + .025 reduced_ss, -d),
 688                     (2.1 reduced_ss, letterheight), 0.25);
 689
 690         draw_staff (-3, 2, 0.5);
 691 enddef;
 692
 693
 694 fet_beginchar ("tab clef", "tab");
 695         draw_tab_clef (1.0);
 696 fet_endchar;
 697
 698
 699 fet_beginchar ("tab clef (reduced)", "tab_change");
 700         draw_tab_clef (.8);
 701 fet_endchar;
 702
 703 fet_endgroup ("clefs");