mf/feta-klef.mf

   1 %
   2 % feta-klef.mf --  implement Clefs
   3 %
   4 % source file of the Feta (Font-En-Tja) music font
   5 %
   6 % (c) 1997 Han-Wen Nienhuys <hanwen@stack.nl>,
   7 % Jan Nieuwenhuizen <jan@digicash.com>
   8
   9 fet_begingroup("klef");
  10
  11 def draw_staff(expr first, last)=
  12         pickup pencircle scaled stafflinethickness;
  13         for i:= first step 1 until last:
  14                 draw (- interline, i* interline) .. (4 interline, i* interline);
  15         endfor
  16         enddef;
  17
  18 def draw_c_clef (expr reduction) =
  19         save hair, norm, reduced_il;
  20         reduced_il#=interline#*reduction;
  21         norm#:=2/3reduced_il#;
  22         hair#:=1/6norm#;
  23         define_pixels (hair,norm,reduced_il);
  24         set_char_box (0, 11/4interline#, 2 reduced_il#, 2 reduced_il#);
  25         % huh, what's y-zero?
  26         draw_block ((0,-d), (1/2reduced_il,h));
  27         draw_block ((1/2reduced_il+stafflinethickness,-d),
  28           (1/2reduced_il+2stafflinethickness,h));
  29
  30         save xoff;
  31         xoff=1/2reduced_il+2hair;
  32         penpos1(hair,-90);
  33         z1l=(xoff+norm+hair/2,h);
  34         penpos2(norm-hair,180);
  35         z2l=(w,h/2);
  36         penpos3(hair,90);
  37         z3=(((w-xoff)/2)+xoff,2hair);
  38         penpos4(hair,90);
  39         z4=(xoff+hair+1/2norm+hair,y3);
  40
  41         penpos6(hair,-90);
  42         z6r=(xoff+norm+hair,-d);
  43
  44         save t; t=0.833;
  45         save p; path p;
  46         p = z4r{right}..z3r{right}..tension t..z2r{up}
  47                 ..z1r{left}..z1l{right}..z2l{down}
  48                 ..z3l{left}..z4l{left};
  49         pickup pencircle scaled 1pt#;
  50         % boehoe, howto?
  51 %       draw p..(p yscaled -1)..cycle;
  52         fill p..cycle;
  53         fill (p yscaled -1)..cycle;
  54         penlabels (1,2,3,4);
  55
  56         % ugh, should be bulb, not flare
  57         draw_flare(z1l,180,90,hair,norm);
  58         draw_flare(z6r,180,-90,hair,norm+hair);
  59         enddef;
  60
  61 fet_beginchar ("C clef", "ugh_alto", "ugh_altoclef")
  62         if test = 1:
  63                 draw_staff (-1,3);
  64         fi;
  65         draw_c_clef (1.0);
  66 fet_endchar;
  67
  68 fet_beginchar ("C clef", "ugh_alto_change", "ugh_caltoclef")
  69         draw_c_clef (.8);
  70 fet_endchar;
  71
  72 %
  73 % Inspired by Baerenreiter and Breitkopf
  74 %
  75 % FIXME: dims
  76 % FIXME: right vertical tangent seems to be lower than the F-line
  77 % FIXME: bulb curve smoothly into "long curve" on the  inside
  78 %
  79 %
  80 % [Wanske] says that the extreme x point should be exactly between
  81 % the dots, but her picture shows that the extreme is ~ 0.2 ss lower
  82
  83 def draw_bass_klef(expr exact_center, reduction) =
  84         save reduced_il, left_tilt, left_thick;
  85         reduced_il# = interline# * reduction;
  86         left_tilt = 5;
  87         define_pixels(reduced_il);
  88         left_thick = .25  reduced_il;
  89
  90         set_char_box(
  91                 - xpart exact_center+ .2 reduced_il#,
  92                 xpart exact_center + 2.7 reduced_il#,
  93                 - ypart exact_center + 2.5 reduced_il#,
  94                 ypart exact_center +reduced_il#);
  95         x1r - x1l = left_thick;
  96         z1l = (hround_pixels(xpart exact_center),
  97                 vround_pixels(ypart exact_center));
  98
  99         y2 = reduced_il;
 100
 101         x3l - x1l =  2.1 reduced_il;
 102         x2 = .5 [x1,x3];
 103         x3l - x3r = .48 reduced_il;
 104         y3l = -0.05 interline;
 105         x4 = x1l - stafflinethickness;
 106         y4 = -2.2  reduced_il;
 107         z5 = (x3l +  1/3 reduced_il, .5 reduced_il);
 108
 109         penpos1(whatever, left_tilt);
 110         penpos2(1.2 stafflinethickness, -90);
 111         penpos3(whatever,  185);
 112         penpos4(stafflinethickness, 135);
 113
 114         draw_bulb(1, z1r,  z1l, .45 reduced_il, 1.0);
 115
 116
 117         fill z1r{up} .. z2r{right} .. tension 1.0 .. z3r{down}  .. {curl 0}
 118                 simple_serif(z4r, z4l, 90) {curl 0}
 119                 .. z3l{up} .. tension 0.9 .. z2l{left}
 120                 .. z1l{dir (-90 + left_tilt)} -- cycle;
 121         labels(2,4);
 122         penlabels(1,2,3,4);
 123
 124         pickup pencircle scaled (.35 reduced_il);
 125         draw z5;
 126         draw z5 yscaled -1;
 127 enddef;
 128
 129
 130
 131 fet_beginchar("F clef ", "bass", "bassclef")
 132         if test = 1:
 133                 draw_staff(-3,1);
 134         fi;
 135         draw_bass_klef((.5 interline#, 0), 1.0);
 136 fet_endchar;
 137 fet_beginchar("F clef (reduced)", "bass_change", "cbassclef")
 138         draw_bass_klef((.4 interline#, 0),0.8);
 139 fet_endchar;
 140
 141
 142
 143 %
 144 % Inspired by Baerenreiter
 145 %
 146 % FIXME top should be thinner at z8,
 147 % FIXME bulb should curve (see bass clef)
 148 % FIXME start (inside) should be little thinner
 149 % FIXME parametrise.
 150 % FIXME should be a bit more upright
 151 %
 152
 153 % Beste lezers, kijk,
 154 %
 155 % Een bolletje  hebben we bij toeval allemaal wel eens getekend, maar begint u
 156 % toch eenvoudig.   Eerst een eenvoudig kruis of herstellingsteken
 157 % en via de dubbelslag naar een voorzichtig vlaggetje, en heb geduld!
 158 % Ikzelf heb bijvoorbeeld over mijn eerste gave G-sleutel
 159 % 35 kilobyte metafont, 12 patchlevels, 0 vriendinnen en 45 dagen gedaan
 160 %
 161 def draw_gclef (expr exact_center, reduction)=
 162         save reduced_il, downstroke_dir, downstroke_angle, hair, center;
 163         save breapth_factor, inner_thick_end, thinness, thickness, thinnib;
 164         save inner_start_angle, thinness, thinpen;
 165         reduced_il# = interline# * reduction;
 166         define_pixels(reduced_il);
 167         pair downstroke_dir, center;
 168
 169         center := (hround_pixels(xpart exact_center),
 170                 vround_pixels(ypart exact_center));
 171
 172         hair =  .3 stafflinethickness;
 173         thinness = 1.3 stafflinethickness;
 174         downstroke_dir = (14, -75);
 175         breapth_factor = 11/7;
 176         inner_thick_end = 45;
 177         inner_start_angle = angle(-1,-2);
 178         thickness = .4 reduced_il - hair;
 179
 180         thinnib = thinness - hair;
 181         thinpen = thinness;
 182         set_char_box(-xpart exact_center + breapth_factor* reduced_il#,
 183                 xpart exact_center + .66 breapth_factor* reduced_il#,
 184                 -ypart exact_center + 3 * reduced_il#,
 185                 ypart exact_center + 5 * reduced_il#);
 186
 187         pickup pencircle scaled hair;
 188
 189         downstroke_angle = angle downstroke_dir;
 190         z1 = center + whatever * dir inner_start_angle;
 191         x1 = xpart center -.28 reduced_il;
 192
 193         top z2r = center + (0,reduced_il + stafflinethickness/2);
 194
 195         x4 = xpart center - .1 reduced_il;
 196         bot y4r = -(reduced_il + .5 stafflinethickness);
 197
 198         z3 = (z4 - center) rotated inner_thick_end + center;
 199
 200         z5r = (- breapth_factor, .37)* reduced_il + center;
 201         penpos5(thickness, 135);
 202
 203         z6 = center + whatever * downstroke_dir;
 204         y6 = ypart center + 2 reduced_il;
 205
 206         z7l - z6 = whatever *(z5- z6) ;
 207         y7l = 3.5 reduced_il;
 208         z8r = .4 [z9r, z7r] + 1.5 stafflinethickness * dir 52;
 209
 210         x9 = .7 [x10, x7r];
 211         top y9l = 5 reduced_il;
 212
 213         y10 = 3. reduced_il;
 214         y11 = -11/7 reduced_il;
 215
 216         y12 = ypart center - 18.5/7 reduced_il;
 217         x12 = x11 - 5 /7 reduced_il;
 218
 219         z13 = z12 + .6 reduced_il*(-1,1);
 220
 221         (z10r - z10l) dotprod (unitvector downstroke_dir rotated 90) =
 222                 thinnib;
 223
 224         center - z10= whatever * downstroke_dir;
 225         center - z11 =  whatever * downstroke_dir;
 226
 227         penpos1(thinnib, inner_start_angle);
 228         penpos2(thickness, 90);
 229         penpos3(thinnib, -90 + inner_thick_end);
 230         penpos4(thinnib, -90);
 231
 232
 233         penpos7(thickness, 135);
 234         penpos8(1.5 thinnib, - 70 + angle downstroke_dir);
 235         penpos9(1.5 thickness, -80);
 236         penpos10(whatever, downstroke_angle + 10);
 237         penpos11(thinnib, downstroke_angle + 90);
 238         penpos12(thinnib, -90);
 239         penpos13(3 thinnib, 180);
 240
 241
 242         filldraw z2l{right}   .. z3l.. z4l{left} .. z5l{up}  .. z7l{up}
 243                 %.. z8l
 244                 .. z9l & z9l ..
 245                 {downstroke_dir}z10l --- z11l -- z11r --- z10r{- downstroke_dir}
 246                 .. tension .8
 247                 .. z9r & z9r
 248                 %.. z8r
 249                 .. z7r{down} .. z5r{down} .. z4r{right}
 250                 .. z3r .. z2r{left} ..
 251                 tension .95 ..
 252                 z1r -- z1l
 253                 .. tension 0.85 ..cycle;
 254
 255         filldraw simple_serif(z1r, z1l, 90)  -- cycle;
 256
 257         filldraw z12r{left} .. z13r{up} -- z13l{down} .. z12l{right} .. cycle;
 258
 259         draw_bulb(-1,  z13l, lft z13r, 6/14 reduced_il, 1.0);
 260
 261         pickup pencircle scaled (thinpen);
 262         draw z10 --- z11 .. z12{left};
 263
 264         penlabels(range 1 thru 15);
 265 enddef;
 266
 267
 268 fet_beginchar("G clef", "violin", "violinclef")
 269         if test = 1:
 270                 draw_staff(-1,3);
 271         fi;
 272         draw_gclef((1.6 interline#,0), 1.0);
 273 fet_endchar;
 274 fet_beginchar("G clef", "violin_change", "cviolinclef")
 275         draw_gclef((1.3 interline#,0), .8);
 276 fet_endchar;
 277
 278 fet_endgroup("klef");