mf/feta-klef.mf

   1 % feta-klef.mf --  implement Clefs -*-Fundamental-*-
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997--2000 Han-Wen Nienhuys <hanwen@cs.uu.nl>,
   8 % Jan Nieuwenhuizen <janneke@gnu.org>,
   9 % Juergen Reuter <reuterj@ira.uka.de>
  10
  11
  12 fet_begingroup("clefs");
  13
  14 %
  15 % [Ross] says that clefs take 1 staff_space space on the left and right
  16 %
  17 def set_horizontal_spacing =
  18         save left_space ,right_space;
  19         left_space# = 0;
  20         right_space# = 0;
  21 enddef;
  22
  23
  24 % [Wanske] says the bulbs should be positioned about 1/4 right of the
  25 % "arrow"
  26 def draw_c_clef (expr reduction) =
  27         save hair, norm, reduced_il, right_edge;
  28         reduced_il#=staff_space#*reduction;
  29         norm#:=2/3reduced_il#;
  30         hair#:=1/6norm#;
  31
  32         set_horizontal_spacing;
  33         right_edge# = 15/4norm#+2hair#;
  34
  35         set_char_box (left_space#, right_edge# + right_space#,
  36                 2 reduced_il#, 2 reduced_il#);
  37         define_pixels (hair,norm,reduced_il, right_edge);
  38
  39         draw_block ((0,-d), (3/4norm+1/2hair,h));
  40         draw_block ((3/4norm+2hair,-d),
  41                 (3/4norm+7/2hair,h));
  42
  43         save xoff;
  44         xoff=3/4norm+7/2hair;
  45         penpos1(hair,-90);
  46         z1l=(xoff+norm+hair,h);
  47         penpos2(norm-3/2hair,180);
  48         z2l=(right_edge,h/2);
  49         penpos3(hair,90);
  50         z3=(((right_edge -xoff)/2)+xoff,2hair);
  51
  52         penpos4(hair,0);
  53         z4=(xoff+1/2norm+1/2hair,reduced_il-hair);
  54
  55         penpos5(4hair,0);
  56         z5=(xoff+5/4hair,0);
  57
  58         penpos6(norm-hair,90);
  59         z6=(xoff+3/4norm,0);
  60
  61         penpos7(hair,-90);
  62         z7r=(x1,-d);
  63
  64         save t; t=0.833;
  65         save p; path p;
  66         p = z5l..z4l{up}..z4r{down}..z3r{right}..tension t..z2r{up}
  67                 ..tension t..z1r{left}..z1l{right}..tension t..z2l{down}
  68                 ..z3l{left}..z6r..z5r{down};
  69         pickup pencircle scaled 1pt#;
  70         filldraw p..(reverse p yscaled -1)..cycle;
  71         penlabels (1,2,3,4,5,6);
  72
  73         % ugh, should be bulb, not flare?
  74         draw_flare(z1l,180,90,hair,norm-1/2hair);
  75         draw_flare(z7r,180,-90,hair,norm-1/2hair);
  76         enddef;
  77
  78 fet_beginchar ("C clef", "C", "altoclef")
  79         if test = 1:
  80                 draw_staff (-2,2, 0.0);
  81         fi;
  82         draw_c_clef (1.0);
  83 fet_endchar;
  84
  85 fet_beginchar ("C clef", "C_change", "caltoclef")
  86         if test = 1:
  87                 draw_staff (-2,2, 0.0);
  88         fi;
  89         draw_c_clef (.8);
  90 fet_endchar;
  91
  92 %
  93 % Inspired by Baerenreiter and Breitkopf
  94 %
  95 % FIXME: dims
  96 % FIXME: right vertical tangent seems to be lower than the F-line
  97 % FIXME: bulb curve smoothly into "long curve" on the  inside
  98 %
  99 %
 100 % [Wanske] says that the extreme x point should be exactly between
 101 % the dots, but her picture shows that the extreme is ~ 0.2 ss lower
 102
 103 def draw_bass_clef(expr exact_center, reduction) =
 104         save reduced_il, left_tilt, left_thick, ball_to_right;
 105         reduced_il# = staff_space# * reduction;
 106
 107         set_horizontal_spacing;
 108         ball_to_right# = 2.1 reduced_il#;
 109         set_char_box(left_space# +
 110                 - xpart exact_center,
 111                 right_space# +
 112                 xpart exact_center + ball_to_right# + 7/12 reduced_il#,
 113                 - ypart exact_center + 2.5 reduced_il#,
 114                 ypart exact_center +reduced_il#);
 115
 116         define_pixels(reduced_il, ball_to_right);
 117         left_tilt = 5;
 118         left_thick = .25  reduced_il;
 119
 120         x1r - x1l = left_thick;
 121         z1l = (hround_pixels(xpart exact_center),
 122                 vround_pixels(ypart exact_center));
 123
 124         y2 = reduced_il;
 125
 126         x3l - x1l =  ball_to_right;
 127         x2 = .5 [x1,x3];
 128         x3l - x3r = .48 reduced_il;
 129         y3l = -0.05 staff_space;
 130         x4 = x1l - stafflinethickness;
 131         y4 = -2.2  reduced_il;
 132         z5 = (x3l +  1/3 reduced_il, .5 reduced_il);
 133
 134         penpos1(whatever, left_tilt);
 135         penpos2(1.2 stafflinethickness, -90);
 136         penpos3(whatever,  185);
 137         penpos4(stafflinethickness, 135);
 138
 139         draw_bulb(1, z1r,  z1l, .45 reduced_il, 1.0);
 140
 141
 142         fill z1r{up} .. z2r{right} .. tension 1.0 .. z3r{down}  .. {curl 0}
 143                 simple_serif(z4r, z4l, 90) {curl 0}
 144                 .. z3l{up} .. tension 0.9 .. z2l{left}
 145                 .. z1l{dir (-90 + left_tilt)} -- cycle;
 146         labels(2,4);
 147         penlabels(1,2,3,4);
 148
 149         save dot_diam;
 150         2 dot_diam = reduction* (staff_space - stafflinethickness);
 151         pickup pencircle scaled dot_diam;
 152         draw z5;
 153         draw z5 yscaled -1;
 154 enddef;
 155
 156
 157
 158 fet_beginchar("F clef ", "F", "bassclef")
 159         if test = 1:
 160                 draw_staff(-3,1, 0.0);
 161         fi;
 162         draw_bass_clef((.5 staff_space#, 0), 1.0);
 163 fet_endchar;
 164 fet_beginchar("F clef (reduced)", "F_change", "cbassclef")
 165         draw_bass_clef((.4 staff_space#, 0),0.8);
 166 fet_endchar;
 167
 168
 169
 170 %
 171 % Inspired by Baerenreiter
 172 %
 173 % FIXME bulb should curve (see bass clef)
 174 % FIXME start (inside) should be little thinner
 175 % FIXME parametrise.
 176 %
 177
 178 % Beste lezers, kijk,
 179 %
 180 % Een bolletje  hebben we bij toeval allemaal wel eens getekend, maar begint u
 181 % toch eenvoudig.   Eerst een eenvoudig kruis of herstellingsteken
 182 % en via de dubbelslag naar een voorzichtig vlaggetje, en heb geduld!
 183 % Ikzelf heb bijvoorbeeld over mijn eerste gave G-sleutel
 184 % 35 kilobyte metafont, 12 patchlevels, 0 vriendinnen en 45 dagen gedaan
 185 %
 186 %  -- vrij naar Van Kooten & De Bie
 187 %
 188
 189 def draw_gclef (expr exact_center, reduction)=
 190         save reduced_il, downstroke_dir, downstroke_angle, hair, center;
 191         save breapth_factor, inner_thick_end, thinness, thickness, thinnib;
 192         save inner_start_angle, thinness, thinpen;
 193         reduced_il# = staff_space# * reduction;
 194         define_pixels(reduced_il);
 195         pair downstroke_dir, center;
 196
 197         center := (hround_pixels(xpart exact_center),
 198                 vround_pixels(ypart exact_center));
 199
 200         hair =  .3 stafflinethickness;
 201         thinness = 1.3 stafflinethickness;
 202         downstroke_dir = (14, -75);
 203         breapth_factor = 11/7;
 204         inner_thick_end = 45;
 205         inner_start_angle = downstroke_angle - 43;
 206         thickness = .4 reduced_il - hair;
 207
 208         thinnib = thinness - hair;
 209         thinpen = thinness;
 210         set_horizontal_spacing;
 211
 212         set_char_box(
 213                 left_space# +
 214                 -xpart exact_center + 1.0 * breapth_factor* reduced_il#,
 215                 right_space# +
 216                 xpart exact_center + .66 breapth_factor* reduced_il#,
 217                 -ypart exact_center + 3 * reduced_il#,
 218                 ypart exact_center + 5 * reduced_il#);
 219
 220         pickup pencircle scaled hair;
 221         downstroke_angle = angle downstroke_dir;
 222
 223         z1 = center + whatever * dir (inner_start_angle);
 224         x1 = xpart center -.28 reduced_il;
 225
 226         top z2r = center + (0,reduced_il + stafflinethickness/2);
 227
 228         x4 = xpart center - .1 reduced_il;
 229         bot y4r = -(reduced_il + .5 stafflinethickness);
 230
 231         z3 = (z4 - center) rotated inner_thick_end + center;
 232
 233         z5r = (- breapth_factor, .37)* reduced_il + center;
 234         penpos5(thickness, 135);
 235
 236         z6 = center + whatever * downstroke_dir;
 237         y6 = ypart center + 2 reduced_il;
 238
 239         z7l - z6 = whatever *(z5- z6) ;
 240         y7l = 3.5 reduced_il;
 241         z8r = .4 [z9r, z7r] + 1.5 stafflinethickness * dir 52;
 242
 243         x9 = .7 [x10, x7r];
 244         top y9l = 5 reduced_il;
 245
 246         y10 = 3. reduced_il;
 247         y11 = -11/7 reduced_il;
 248
 249         y12 = ypart center - 18.5/7 reduced_il;
 250         x12 = x11 - 5 /7 reduced_il;
 251
 252         z13 = z12 + .6 reduced_il*(-1,1);
 253
 254         (z10r - z10l) dotprod (unitvector downstroke_dir rotated 90) =
 255                 thinnib;
 256
 257         center - z10= whatever * downstroke_dir;
 258         center - z11 =  whatever * downstroke_dir;
 259         center - z14 = .8 (center - z11);
 260         penpos1(thinnib, inner_start_angle);
 261         penpos2(thickness, 90);
 262         penpos3(thinnib, -90 + inner_thick_end);
 263         penpos4(thinnib, -90);
 264
 265
 266         penpos7(thickness, 135);
 267         penpos8(1.5 thinnib, - 70 + angle downstroke_dir);
 268         penpos9(1.4 thickness, -80);  % ugh
 269         penpos10(whatever, downstroke_angle + 10);
 270         penpos11(thinnib, downstroke_angle + 90);
 271         penpos14(thinnib, downstroke_angle + 90);
 272         penpos12(thinnib, -90);
 273         penpos13(3 thinnib, 180);
 274
 275         filldraw z2l{right}   .. z3l.. z4l{left} .. z5l{up}  .. z7l{up}
 276                 %.. z8l
 277                 .. tension 1.2
 278                 .. z9l & z9l ..
 279                 {downstroke_dir}z10l --- z11l -- z11r --- z10r{- downstroke_dir}
 280                 .. tension .8
 281                 .. z9r & z9r{dir (downstroke_angle+ 40)} % ugh
 282                 %.. z8r
 283                 .. z7r{down} .. z5r{down} .. z4r{right}
 284                 .. z3r .. z2r{left} ..
 285                 tension .95 ..
 286                 z1r -- z1l
 287                 .. tension 0.85 ..cycle;
 288
 289         filldraw simple_serif(z1r, z1l, 90)  -- cycle;
 290
 291         filldraw z12r{left} .. z13r{up} -- z13l{down} .. z12l{right} .. cycle;
 292
 293         draw_bulb(-1,  z13l, lft z13r, 6/14 reduced_il, 1.0);
 294
 295         pickup pencircle scaled (thinpen);
 296         draw z10 --- z14 .. z11  .. tension 0.85 ..  z12{left};
 297
 298         penlabels(range 1 thru 15);
 299 enddef;
 300
 301
 302 fet_beginchar("G clef", "G", "trebleclef")
 303         if test = 1:
 304                 draw_staff(-1,3, 0.0);
 305         fi;
 306         draw_gclef((1.7 staff_space#,0), 1.0);
 307 fet_endchar;
 308 fet_beginchar("G clef", "G_change", "ctrebleclef")
 309         draw_gclef((1.3 staff_space#,0), .8);
 310 fet_endchar;
 311
 312 %%%%%%%%
 313 %
 314 %
 315 %
 316 % Editio Vaticana
 317 %
 318 %
 319 %
 320 def draw_vaticana_do_clef(expr exact_center, reduction) =
 321         save reduced_il;
 322
 323         reduced_il# = staff_space# * reduction;
 324
 325         set_char_box(0.4reduced_il#, 0.4reduced_il#, 0, reduced_il#);
 326
 327         define_pixels(reduced_il);
 328
 329         pickup pencircle xscaled stafflinethickness yscaled 0.6reduced_il;
 330
 331         save za, zb, zc, zd, ze, zf;
 332         pair za, zb, zc, zd, ze, zf;
 333
 334         za = exact_center + (-0.0reduced_il, -.45reduced_il);
 335         zb = exact_center + (-0.2reduced_il, -.50reduced_il);
 336         zc = exact_center + (-0.4reduced_il, -.25reduced_il);
 337         zd = exact_center + (-0.4reduced_il, +.25reduced_il);
 338         ze = exact_center + (-0.2reduced_il, +.50reduced_il);
 339         zf = exact_center + (-0.0reduced_il, +.45reduced_il);
 340         draw za .. zb .. zc --  % lower punctum
 341              zd .. ze .. zf;    % upper punctum
 342 enddef;
 343
 344
 345 fet_beginchar("Ed. Vat. do clef", "vaticana_do", "vatdoclef")
 346         if test = 1:
 347                 draw_staff(-1,3, 0.0);
 348         fi;
 349         draw_vaticana_do_clef((0,0), 1.0);
 350 fet_endchar;
 351 fet_beginchar("Ed. Vat. do clef", "vaticana_do_change", "vatcdoclef")
 352         draw_vaticana_do_clef((0,0), 1.0); % no reduction
 353 fet_endchar;
 354
 355
 356 def draw_vaticana_fa_clef(expr exact_center, reduction) =
 357
 358         save reduced_il, z;
 359         reduced_il# = staff_space# * reduction;
 360         define_pixels(reduced_il);
 361
 362         save za, zb, zc, zd, ze;
 363         pair za, zb, zc, zd, ze;
 364
 365         %stem
 366         pickup pencircle scaled stafflinethickness;
 367         xpart za = xpart zb =
 368                 xpart exact_center + 0.4reduced_il;
 369         ypart za = ypart exact_center = ypart zb + 1.5reduced_il;
 370         draw za .. zb;
 371
 372         %left-handed punctum
 373         pickup pencircle xscaled stafflinethickness yscaled 0.5reduced_il;
 374         zc = exact_center +
 375                 (+0.4reduced_il, -0.05reduced_il);
 376         zd = exact_center +
 377                 (+0.2reduced_il, +0.05reduced_il);
 378         ze = exact_center +
 379                 (+0.0reduced_il, +0.00reduced_il);
 380         draw zc .. zd .. ze;
 381
 382         %right-handed puncta as in do clef
 383         draw_vaticana_do_clef(
 384                 exact_center +
 385                 (+0.8reduced_il + 1.25stafflinethickness, 0),
 386                 reduction);
 387
 388         set_char_box(0.5reduced_il#, 1.5reduced_il#, 0, reduced_il#);
 389 enddef;
 390
 391
 392 fet_beginchar("Ed. Vat. fa clef", "vaticana_fa", "vatfaclef")
 393         if test = 1:
 394                 draw_staff(-1,3, 0.0);
 395         fi;
 396         draw_vaticana_fa_clef((0,0), 1.0);
 397 fet_endchar;
 398 fet_beginchar("Ed. Vat. fa clef", "vaticana_fa_change", "vatcfaclef")
 399         draw_vaticana_fa_clef((0,0), 1.0); % no reduction
 400 fet_endchar;
 401
 402 %%%%%%%%
 403 %
 404 %
 405 %
 406 % Editio Medicaea
 407 %
 408 %
 409 %
 410 def draw_medicaea_do_clef(expr exact_center, reduction) =
 411         save reduced_il, reduced_slt;
 412         reduced_il# = staff_space# * reduction;
 413         reduced_slt# = stafflinethickness# * reduction;
 414         define_pixels(reduced_il);
 415         define_pixels(reduced_slt);
 416
 417         save flag_height;
 418         flag_height# = 0.5 reduced_il#;
 419         define_pixels(flag_height);
 420
 421         %lower flag
 422         save za, zb;
 423         pair za, zb;
 424         pickup pencircle xscaled reduced_slt yscaled flag_height;
 425         xpart exact_center
 426                 = xpart za + 0.5 reduced_il
 427                 = xpart zb - 0.5 reduced_il;
 428         ypart za = ypart exact_center - 0.5 flag_height
 429                         - 0.5 (staff_space - reduced_il);
 430         ypart zb = ypart za - reduced_il + flag_height;
 431         draw za .. zb;
 432
 433         %upper flag
 434         save za, zb;
 435         pair za, zb;
 436         pickup pencircle xscaled reduced_slt yscaled flag_height;
 437         xpart exact_center
 438                 = xpart za + 0.5 reduced_il
 439                 = xpart zb - 0.5 reduced_il;
 440         ypart za = ypart exact_center - 0.5 flag_height
 441                         - 0.5 (staff_space - reduced_il)
 442                         + staff_space;
 443         ypart zb = ypart za - reduced_il + flag_height;
 444         draw za .. zb;
 445
 446         %stem
 447         save za, zb;
 448         pair za, zb;
 449         pickup pencircle scaled reduced_slt;
 450         xpart za = xpart zb = xpart exact_center - 0.5 reduced_il;
 451         ypart exact_center
 452                 = ypart za + 1.5 reduced_il
 453                 = ypart zb - 1.5 reduced_il;
 454         draw za .. zb;
 455
 456         set_char_box(0.5reduced_il#, 1.5reduced_il#,
 457                      1.5reduced_il#, 1.5reduced_il#);
 458 enddef;
 459
 460
 461 fet_beginchar("Ed. Med. do clef", "medicaea_do", "meddoclef")
 462         if test = 1:
 463                 draw_staff(-1,3, 0.0);
 464         fi;
 465         draw_medicaea_do_clef((0,0), 1.0);
 466 fet_endchar;
 467 fet_beginchar("Ed. Med. do clef", "medicaea_do_change", "cmeddoclef")
 468         draw_medicaea_do_clef((0,0), .8);
 469 fet_endchar;
 470
 471
 472 def draw_medicaea_fa_clef(expr exact_center, reduction) =
 473         % inspired by Regensburger Edition of Medicaea (1885/86), in:
 474         % MGG, volume 2, col. 1327 ("Choralreform"), fig. 2.
 475
 476         save reduced_il, reduced_slt;
 477         reduced_il# = staff_space# * reduction;
 478         reduced_slt# = stafflinethickness# * reduction;
 479         define_pixels(reduced_il);
 480         define_pixels(reduced_slt);
 481
 482         save za, zb, zc, zd, ze;
 483         pair za, zb, zc, zd, ze;
 484
 485         %stem
 486         pickup pencircle scaled stafflinethickness;
 487         xpart za = xpart zb =
 488                 xpart exact_center + 0.4reduced_il;
 489         ypart za = ypart exact_center = ypart zb + 1.5reduced_il;
 490         draw za -- zb;
 491
 492         %left-handed punctum
 493         pickup pencircle xscaled reduced_slt yscaled reduced_il;
 494         zc = exact_center +
 495                 (+0.4reduced_il, 0);
 496         zd = exact_center +
 497                 (+0.0reduced_il, 0);
 498         draw zc -- zd;
 499
 500         %right-handed puncta as in do clef
 501         draw_medicaea_do_clef(
 502                 exact_center +
 503                 (+1.1reduced_il + 1.25stafflinethickness, 0),
 504                 reduction);
 505
 506         set_char_box(reduced_il#/2, 2.6reduced_il#, 0, reduced_il#);
 507 enddef;
 508
 509
 510 fet_beginchar("Ed. Med. fa clef", "medicaea_fa", "medfaclef")
 511         if test = 1:
 512                 draw_staff(-1,3, 0.0);
 513         fi;
 514         draw_medicaea_fa_clef((0,0), 1.0);
 515 fet_endchar;
 516 fet_beginchar("Ed. Med. fa clef", "medicaea_fa_change", "cmedfaclef")
 517         draw_medicaea_fa_clef((0,0), .8);
 518 fet_endchar;
 519
 520
 521 %%%%%%%%
 522 %
 523 %
 524 %
 525 % Mensural Notation
 526 %
 527 %
 528 %
 529 brevis_wid# := 2 staff_space#;
 530
 531 def draw_brevis(expr exact_center, reduction, small_width, small_height) =
 532         %
 533         % inspired by function draw_brevis of
 534         % feta-bolletjes.mf
 535         %
 536         save reduced_slt, reduced_nht;
 537         save stem_width, head_width;
 538         save serif_size, serif_protrude;
 539         save holeheight, beamheight;
 540
 541         reduced_slt# = stafflinethickness# * reduction;
 542         reduced_nht# = noteheight# * reduction;
 543         stem_width# = 1.4 reduced_slt#;
 544         if small_width:
 545                 head_width# = 0.5brevis_wid# * reduction;
 546         else:
 547                 head_width# = brevis_wid# * reduction;
 548         fi;
 549         if small_height:
 550                 serif_size# = 0.64 reduced_slt#;
 551                 serif_protrude# = 0.96 serif_size#;
 552                 holeheight# = 3 reduced_slt#;
 553                 beamheight# = 0.32(reduced_nht# - holeheight#);
 554         else:
 555                 serif_size# = 1.0 reduced_slt#;
 556                 serif_protrude# = 1.5 serif_size#;
 557                 holeheight# = 3 reduced_slt#;
 558                 beamheight# = 0.5(reduced_nht# - holeheight#);
 559         fi;
 560         define_pixels(reduced_slt);
 561         define_pixels(stem_width);
 562         define_pixels(head_width);
 563         define_pixels(serif_size);
 564         define_pixels(serif_protrude);
 565         define_pixels(beamheight);
 566
 567         penpos1(stem_width, 0);
 568         penpos2(stem_width, 0);
 569         penpos3(beamheight, 90);
 570         penpos4(beamheight, 90);
 571         penpos5(stem_width, 180);
 572
 573         z1l = exact_center;
 574         z2l = z1l + (0, -reduced_slt/2);
 575         z3r = z2r + serif_size*(1,-1);
 576         y4r = y3r;
 577         x4l = x1l + head_width/2;
 578         z5l = z3l + (-serif_size, -serif_protrude);
 579
 580         penlabels(1,2,3,4,5);
 581         fill z1r -- z1l -- z5r{down} .. z5l{up} .. z3l{right}
 582                 -- z4l -- z4r -- z3r{left} .. z2r{up} -- cycle;
 583 enddef;
 584
 585
 586 def draw_mensural_i_c_clef(expr exact_center, reduction) =
 587         draw_brevis(exact_center, reduction, false, false);
 588
 589         save reduced_il, reduced_slt;
 590         save stem_width;
 591
 592         reduced_il# = staff_space# * reduction;
 593         reduced_slt# = stafflinethickness# * reduction;
 594         stem_width# = 1.4 reduced_slt#;
 595
 596         define_pixels(reduced_il);
 597         define_pixels(reduced_slt);
 598         define_pixels(stem_width);
 599
 600         penpos6(stem_width, 0);
 601         penpos7(stem_width, 0);
 602         z6l = exact_center;
 603         z7l = z6l + (0, -2reduced_il);
 604         fill z6l -- z7l -- z7r -- z6r -- cycle;
 605         penpos8(stem_width, 0);
 606         penpos9(stem_width, 0);
 607         z8l = z6l + (-3reduced_slt, 0);
 608         z9l = z8l + (0, -2reduced_il);
 609         fill z8l -- z9l -- z9r -- z8r -- cycle;
 610
 611         addto currentpicture also currentpicture
 612                 yscaled -1 shifted (0, 2*(ypart exact_center));
 613         addto currentpicture also currentpicture
 614                 xscaled -1 shifted (2x4l,0);
 615
 616         set_char_box(0, 2head_width#,
 617                      6reduced_slt#*reduction, 6reduced_slt#*reduction);
 618 enddef;
 619
 620
 621 fet_beginchar("mensural c clef", "mensural1_c", "mens1cclef")
 622         if test = 1:
 623                 draw_staff(-1,3, 0.0);
 624         fi;
 625         draw_mensural_i_c_clef((0,0), 1.0);
 626 fet_endchar;
 627 fet_beginchar("mensural c clef", "mensural1_c_change", "cmens1cclef")
 628         draw_mensural_i_c_clef((1.3 staff_space#,0), .8);
 629 fet_endchar;
 630
 631
 632 def draw_mensural_ii_c_clef(expr exact_center, reduction) =
 633         draw_brevis(exact_center, reduction, true, true);
 634
 635         save reduced_il, reduced_slt;
 636         save stem_width, interline;
 637
 638         reduced_il# = staff_space# * reduction;
 639         reduced_slt# = stafflinethickness# * reduction;
 640         stem_width# = 1.4 reduced_slt#;
 641         interline# = staff_space#;
 642
 643         define_pixels(reduced_il);
 644         define_pixels(reduced_slt);
 645         define_pixels(stem_width);
 646         define_pixels(interline);
 647
 648         penpos6(stem_width, 0);
 649         penpos7(stem_width, 0);
 650         z6l = exact_center + (0, -interline/2);
 651         z7l = z6l + (0, -1.5reduced_il);
 652         fill z6l -- z7l -- z7r -- z6r -- cycle;
 653
 654         addto currentpicture also currentpicture
 655                 yscaled -1 shifted (0, 2*(ypart exact_center) - interline);
 656         addto currentpicture also currentpicture
 657                 yscaled -1 shifted (0, 4*(ypart exact_center));
 658         addto currentpicture also currentpicture
 659                 xscaled -1 shifted (2x4l,0);
 660
 661         set_char_box(0, 2head_width#,
 662                      noteheight#*4*reduction, noteheight#*4*reduction);
 663 enddef;
 664
 665
 666 fet_beginchar("mensural c clef", "mensural2_c", "mens2cclef")
 667         if test = 1:
 668                 draw_staff(-1,3, 0.0);
 669         fi;
 670         draw_mensural_ii_c_clef((0,0), 1.0);
 671 fet_endchar;
 672 fet_beginchar("mensural c clef", "mensural2_c_change", "cmens2cclef")
 673         draw_mensural_ii_c_clef((1.3 staff_space#,0), .8);
 674 fet_endchar;
 675
 676
 677 def draw_mensural_iii_c_clef(expr exact_center, reduction) =
 678         % inspired by Ockeghem, "Missa Prolationum", in: MGG, volume
 679         % 9, table 94.
 680         draw_mensural_ii_c_clef(exact_center, reduction);
 681
 682         addto currentpicture also currentpicture
 683                 shifted (0, -interline);
 684
 685         set_char_box(0, 2head_width#,
 686                      noteheight#*6*reduction, noteheight#*6*reduction);
 687 enddef;
 688
 689
 690 fet_beginchar("mensural c clef", "mensural3_c", "mens3cclef")
 691         if test = 1:
 692                 draw_staff(-1,3, 0.0);
 693         fi;
 694         draw_mensural_iii_c_clef((0,0), 1.0);
 695 fet_endchar;
 696 fet_beginchar("mensural c clef", "mensural3_c_change", "cmens3cclef")
 697         draw_mensural_iii_c_clef((0,0), .8);
 698 fet_endchar;
 699
 700 def draw_diamond(expr exact_center, reduction) =
 701         save stem_width, reduced_il, reduced_nht, holeheight, beamheight;
 702         save rh_height, rh_width;
 703
 704         stem_width# = 1.4 reduced_slt#;
 705         reduced_il# = staff_space# * reduction;
 706         reduced_nht# = noteheight# * reduction;
 707         holeheight# = 3 reduced_slt#;
 708         beamheight# = 0.4(reduced_nht# - holeheight#);
 709
 710         rh_height# = 1.2reduced_il#;
 711         rh_width# / rh_height# = 0.58; % tan(30)
 712
 713         define_pixels(beamheight);
 714         define_pixels(stem_width);
 715         define_pixels(rh_height);
 716         define_pixels(rh_width);
 717
 718         pickup pencircle
 719                 xscaled beamheight
 720                 yscaled stem_width
 721                 rotated 45;
 722
 723         draw
 724                 exact_center + (-rh_width/2, 0) --
 725                 exact_center + (0, rh_height/2) --
 726                 exact_center + (+rh_width/2, 0) --
 727                 exact_center + (0, -rh_height/2) --
 728                 cycle;
 729 enddef;
 730
 731 def draw_mensural_i_f_clef(expr exact_center, reduction) =
 732         %
 733         % inspired by Gaspar van Weerbeke, "Virgo Maria" (1502), in:
 734         % MGG, volume 9, col. 653 ("Motette"), fig. 3.; also by
 735         % Andr'e Campra, "Entr'ee des s'er'enades" (1710), in: MGG,
 736         % volume 2, col. 1649 ("Contredanse"), fig. 2.
 737         %
 738         draw_brevis(exact_center, reduction, true, false);
 739
 740         save reduced_il, reduced_slt;
 741         save stem_width, interline;
 742
 743         reduced_il# = staff_space# * reduction;
 744         reduced_slt# = stafflinethickness# * reduction;
 745         stem_width# = 1.4 reduced_slt#;
 746         interline# = staff_space#;
 747
 748         define_pixels(reduced_il);
 749         define_pixels(reduced_slt);
 750         define_pixels(stem_width);
 751         define_pixels(interline);
 752
 753         addto currentpicture also currentpicture
 754                 yscaled -1 shifted (0, 2*(ypart exact_center));
 755         addto currentpicture also currentpicture
 756                 xscaled -1 shifted (2x4l,0);
 757
 758         penpos6(stem_width, 0);
 759         penpos7(stem_width, 0);
 760         z6r = exact_center + (2x4l, 0);
 761         z7r = z6r + (0, -4reduced_il);
 762         fill z6l -- z7l -- z7r -- z6r -- cycle;
 763
 764         draw_diamond(exact_center +
 765                      (1.6interline*reduction, interline/2), reduction);
 766         %% some editions put a stem on top of the upper note head:
 767         % penpos8(stem_width, 0);
 768         % penpos9(stem_width, 0);
 769         % z8l = exact_center + (1.6interline*reduction, interline*reduction);
 770         % z9l = z8l + (0, 1.5interline*reduction);
 771         % fill z8l -- z9l -- z9r -- z8r -- cycle;
 772
 773         draw_diamond(exact_center +
 774                      (1.6interline*reduction, -interline/2), reduction);
 775         penpos10(stem_width, 0);
 776         penpos11(stem_width, 0);
 777         z10r = exact_center + (1.6interline*reduction, -interline*reduction);
 778         z11r = z10r + (0, -3.5interline*reduction);
 779         fill z10l -- z11l -- z11r -- z10r -- cycle;
 780
 781         set_char_box(0, 3head_width#,
 782                      3.5noteheight#*reduction, 1.5noteheight#*reduction);
 783 enddef;
 784
 785
 786 fet_beginchar("mensural f clef", "mensural1_f", "mens1fclef")
 787         if test = 1:
 788                 draw_staff(-1,3, 0.0);
 789         fi;
 790         draw_mensural_i_f_clef((0,0), 1.0);
 791 fet_endchar;
 792 fet_beginchar("mensural f clef", "mensural1_f_change", "cmens1fclef")
 793         draw_mensural_i_f_clef((0,0), .8);
 794 fet_endchar;
 795
 796
 797 def draw_mensural_ii_f_clef(expr exact_center, reduction) =
 798         %
 799         % inspired by Philippe le Duc, "Dite Signori" (1590), in: MGG,
 800         % volume 3, col. 848 ("Duc"); also by John Dowland, "The First
 801         % Booke of Songes" (1597), in: MGG, volume 3, col. 721
 802         % ("Dowland"), fig. 3.
 803
 804         save reduced_slt, stem_width, reduced_nht, holeheight, beamheight;
 805
 806         reduced_slt# = stafflinethickness# * reduction;
 807         stem_width# = 1.4 reduced_slt#;
 808         reduced_nht# = noteheight# * reduction;
 809         holeheight# = 3 reduced_slt#;
 810         beamheight# = 0.4(reduced_nht# - holeheight#);
 811
 812         define_pixels(beamheight, stem_width, staff_space);
 813
 814         pickup pencircle
 815                 xscaled beamheight
 816                 yscaled stem_width
 817                 rotated 45;
 818
 819         draw
 820                 exact_center + (1.0 staff_space, 0.6 staff_space) --
 821                 exact_center + (1.25 staff_space, 0.4 staff_space);
 822
 823         draw
 824                 exact_center + (1.0 staff_space, -0.4 staff_space) --
 825                 exact_center + (1.25 staff_space, -0.6 staff_space);
 826
 827         draw    halfcircle scaled 1.2 staff_space rotated -90
 828                 shifted (-exact_center + (+0.1 staff_space, 0));
 829
 830         set_char_box(0, 3staff_space#, 3staff_space#, 0);
 831 enddef;
 832
 833 fet_beginchar("mensural f clef", "mensural2_f", "mens2fclef")
 834         if test = 1:
 835                 draw_staff(-1,3, 0.0);
 836         fi;
 837         draw_mensural_ii_f_clef((0,0), 1.0);
 838 fet_endchar;
 839 fet_beginchar("mensural f clef", "mensural2_f_change", "cmens2fclef")
 840         draw_mensural_ii_f_clef((0,0), .8);
 841 fet_endchar;
 842
 843
 844 def draw_mensural_g_clef(expr exact_center, reduction) =
 845         %
 846         % inspired by Francisco Guerrero, "Lib. 1.  Missarum" (1566),
 847         % in: MGG, volume 3, col. 858 ("Ducis"); also by Stefano
 848         % Fabri, "Quam speciosa veteranis" (1611), in: MGG, volume 3,
 849         % col. 1698 ("Fabri"); also by Philippus Dulichius,
 850         % "Fasciculus novus ..." (1598), in: MGG, volume 3, col. 919
 851         % ("Dulichius"), fig. 1; also by Noe Faignient, "Ic sal de
 852         % Heer myn God gebenedye" (1568), in: MGG, volume 3, col. 1735
 853         % ("Faignient").
 854         %
 855         % Metafont code partially inspired by Schwabacher 'G' of yswab
 856         % font.
 857
 858         save reduced_il, stem_width, height, width, apex_o, hair;
 859
 860         reduced_il#=staff_space#*reduction;
 861
 862         set_char_box(0.5reduced_il#, 1.5reduced_il#,
 863                      1.5reduced_il#, 1.5reduced_il#);
 864
 865         stem_width# = 0.17 reduced_il#;
 866         height# = 1.5 reduced_il#;
 867         width# = 1.13 reduced_il#;
 868         apex_o# = 0.02 reduced_il#;
 869         hair# =  3 stafflinethickness#;
 870         define_pixels(reduced_il, stem_width, height, width, apex_o, hair);
 871
 872         penpos1(2 stem_width, -142);
 873         z1l = (0.715 width, 0.742 height);
 874         penpos1'(hair, -90);
 875         z1'l = z1r;
 876         penpos2(1.179 stem_width, -142);
 877         z2l = (width, 0.466 height);
 878         penpos3(hair, 77);
 879         z3 = (0.764 width, 0.067 height);
 880         z4 = (0.59 width, -apex_o);
 881         penpos5(1.179 stem_width, 32);
 882         z5l=(0, 0.457 height);
 883         penpos6(hair, -56.5);
 884         z7 = (x4 - 0.843 stem_width, height + apex_o);
 885         z7 - z6l = whatever * dir33.5;
 886         penpos8(1.286 stem_width, -130);
 887         z8r = (0.715 width, 0.742 height) + (-apex_o, apex_o);
 888         z6r - z8r = whatever * (z7 - z8l);
 889         filldraw
 890                 z1'r{dir45} .. z2r{down} .. z3r{dir207} .. z5r{up} ..
 891                 z6r{z7-z6l} & z6r -- z8r -- z8l -- z7 --- z6l ...
 892                 z5l{down} .. z4{right} .. z3l{dir27} .. z2l{up} ..
 893                 z1l{1/3[z6l,z7]-z1l} & z1l -- z1r -- z1'r & cycle
 894                 shifted (-exact_center + (0, -0.75reduced_il));
 895
 896         penpos9(stem_width, 0);
 897         x9r = x4; y9 = 0.3 height;
 898
 899         pickup pencircle
 900                 scaled stem_width
 901                 rotated 45;
 902         draw    z9 -- (z9 + (0, -0.4reduced_il))
 903                 shifted (-exact_center + (0, -0.75reduced_il));
 904
 905         pickup pencircle
 906                 xscaled stem_width
 907                 yscaled hair
 908                 rotated 30;
 909
 910         draw halfcircle
 911                 scaled 0.5 reduced_il
 912                 rotated -90
 913                 shifted z8
 914                 shifted (0, 0.25reduced_il)
 915                 shifted (-exact_center + (0, -0.75reduced_il));
 916
 917         draw halfcircle
 918                 scaled 0.4 reduced_il
 919                 rotated 90
 920                 shifted (z8 + (0, 0.45 reduced_il))
 921                 shifted (0, 0.25reduced_il)
 922                 shifted (-exact_center + (0, -0.75reduced_il));
 923 enddef;
 924
 925
 926 fet_beginchar("mensural g clef", "mensural_g", "mensgclef")
 927         if test = 1:
 928                 draw_staff(-1,3, 0.0);
 929         fi;
 930         draw_mensural_g_clef((0,0), 1.0);
 931 fet_endchar;
 932 fet_beginchar("mensural g clef", "mensural_g_change", "cmensgclef")
 933         draw_mensural_g_clef((0,0), .8);
 934 fet_endchar;
 935
 936
 937
 938 %%%%%%%%
 939 %
 940 %
 941 %
 942 % Hufnagel
 943 %
 944 %
 945 %
 946 def draw_hufnagel_do_clef(expr exact_center, reduction) =
 947         %
 948         % inspired by Graduale of Friedrich Zollner (1442), in: MGG,
 949         % volume 9, col. 1413 ("Neustift"), fig. 1.
 950         %
 951         save reduced_il;
 952
 953         reduced_il# = staff_space# * reduction;
 954
 955         define_pixels(reduced_il);
 956
 957         pickup pencircle
 958                 xscaled (0.60reduced_il)
 959                 yscaled (0.10reduced_il)
 960                 rotated 40;
 961         save za, zb, zc, zd, ze, zf;
 962         pair za, zb, zc, zd, ze, zf;
 963
 964         za = exact_center + (+0.30reduced_il, +.45reduced_il);
 965         zb = exact_center + (+0.20reduced_il, +.45reduced_il);
 966         zc = exact_center + (-0.10reduced_il, +.60reduced_il);
 967         zd = exact_center + (-0.40reduced_il, +.45reduced_il);
 968         ze = exact_center + (-0.40reduced_il, -.45reduced_il);
 969         zf = exact_center + (-0.20reduced_il, -.55reduced_il);
 970         draw za .. zb .. zc -- zd -- ze -- zf;
 971
 972         set_char_box(0.5reduced_il#, 0.5reduced_il#, 0, reduced_il#);
 973 enddef;
 974
 975
 976 fet_beginchar("Hufnagel do clef", "hufnagel_do", "hufnageldoclef")
 977         if test = 1:
 978                 draw_staff(-1,3, 0.0);
 979         fi;
 980         draw_hufnagel_do_clef((0,0), 1.0);
 981 fet_endchar;
 982 fet_beginchar("Hufnagel do clef", "hufnagel_do_change", "chufnageldoclef")
 983         draw_hufnagel_do_clef((1.3 staff_space#,0), .8);
 984 fet_endchar;
 985
 986
 987 def draw_hufnagel_fa_clef(expr exact_center, reduction) =
 988         %
 989         % inspired by Bamberger Manuscript (15th century), in:
 990         % MGG, volume 2, table 59.
 991         %
 992         save reduced_il;
 993
 994         reduced_il# = staff_space# * reduction;
 995
 996         define_pixels(reduced_il);
 997
 998         pickup pencircle
 999                 xscaled (0.60reduced_il)
1000                 yscaled (0.10reduced_il)
1001                 rotated 40;
1002         save za, zb, zc, zd, ze, zf;
1003         pair za, zb, zc, zd, ze, zf;
1004
1005         za = exact_center + (+0.30reduced_il, +0.70reduced_il);
1006         zb = exact_center + (+0.20reduced_il, +0.70reduced_il);
1007         zc = exact_center + (-0.10reduced_il, +0.85reduced_il);
1008         zd = exact_center + (-0.40reduced_il, +0.70reduced_il);
1009         ze = exact_center + (-0.40reduced_il, -1.10reduced_il);
1010         draw za .. zb .. zc -- zd -- ze;
1011
1012         save zg, zh, zi, zj;
1013         pair zg, zh, zi, zj;
1014
1015         zg = exact_center + (+0.30reduced_il, -0.05reduced_il);
1016         zh = exact_center + (+0.20reduced_il, -0.05reduced_il);
1017         zi = exact_center + (-0.10reduced_il, +0.10reduced_il);
1018         zj = exact_center + (-0.40reduced_il, -0.05reduced_il);
1019         draw zg .. zh .. zi -- zj;
1020
1021         set_char_box(0.5reduced_il#, 0.5reduced_il#, 0, reduced_il#);
1022 enddef;
1023
1024
1025 fet_beginchar("Hufnagel fa clef", "hufnagel_fa", "hufnagelfaclef")
1026         if test = 1:
1027                 draw_staff(-1,3, 0.0);
1028         fi;
1029         draw_hufnagel_fa_clef((0,0), 1.0);
1030 fet_endchar;
1031 fet_beginchar("Hufnagel fa clef", "hufnagel_fa_change", "chufnagelfaclef")
1032         draw_hufnagel_fa_clef((0,0), .8);
1033 fet_endchar;
1034
1035
1036 def draw_hufnagel_do_fa_clef(expr exact_center, reduction) =
1037         draw_hufnagel_do_clef(exact_center, reduction);
1038         draw_hufnagel_fa_clef(exact_center + (0, -2staff_space), reduction);
1039 enddef;
1040
1041
1042 fet_beginchar("Hufnagel do/fa clef", "hufnagel_do_fa", "hufnageldofaclef")
1043         if test = 1:
1044                 draw_staff(-1,3, 0.0);
1045         fi;
1046         draw_hufnagel_do_fa_clef((0,0), 1.0);
1047 fet_endchar;
1048 fet_beginchar("Hufnagel do/fa clef", "hufnagel_do_fa_change",
1049               "chufnageldofaclef")
1050         draw_hufnagel_do_fa_clef((0,0), .8);
1051 fet_endchar;
1052
1053 def draw_percussion_clef(expr reduction) =
1054         save reduced_il;
1055         reduced_il# = staff_space# * reduction;
1056         define_pixels(reduced_il);
1057         set_char_box(0,.6reduced_il#,reduced_il#,reduced_il#);
1058         pickup pencircle scaled 1.5 stafflinethickness;
1059         draw (b,h) -- (b,-d);
1060         draw (w,h) -- (w,-d);
1061 enddef;
1062
1063 fet_beginchar("percussion clef", "percussion", "percussionclef")
1064         draw_percussion_clef(1.0);
1065 fet_endchar;
1066
1067 fet_beginchar("percussion clef", "percussion_change", "cpercussionclef")
1068         draw_percussion_clef(.8);
1069 fet_endchar;
1070
1071 fet_endgroup("clefs");