mf/feta-klef.mf

   1 %
   2 % feta-klef.mf --  implement Clefs
   3 %
   4 % source file of the Feta (Font-En-Tja) music font
   5 %
   6 % (c) 1997 Han-Wen Nienhuys <hanwen@stack.nl>,
   7 % Jan Nieuwenhuizen <jan@digicash.com>
   8
   9 fet_begingroup("clefs");
  10
  11 def draw_staff(expr first, last)=
  12         pickup pencircle scaled stafflinethickness;
  13         for i:= first step 1 until last:
  14                 draw (- interline, i* interline) .. (4 interline, i* interline);
  15         endfor
  16         enddef;
  17
  18 % [Wanske] says the bulbs should be positioned about 1/4 right of the
  19 % "arrow"
  20 def draw_c_clef (expr reduction) =
  21         save hair, norm, reduced_il;
  22         reduced_il#=interline#*reduction;
  23         norm#:=2/3reduced_il#;
  24         hair#:=1/6norm#;
  25         define_pixels (hair,norm,reduced_il);
  26         set_char_box (0, 15/4norm#+2hair#,
  27                 2 reduced_il#, 2 reduced_il#);
  28         draw_block ((0,-d), (3/4norm+1/2hair,h));
  29         draw_block ((3/4norm+2hair,-d),
  30                 (3/4norm+7/2hair,h));
  31
  32         save xoff;
  33         xoff=3/4norm+7/2hair;
  34         penpos1(hair,-90);
  35         z1l=(xoff+norm+hair,h);
  36         penpos2(norm-3/2hair,180);
  37         z2l=(w,h/2);
  38         penpos3(hair,90);
  39         z3=(((w-xoff)/2)+xoff,2hair);
  40
  41         penpos4(hair,0);
  42         z4=(xoff+1/2norm+1/2hair,reduced_il-hair);
  43
  44         penpos5(4hair,0);
  45         z5=(xoff+5/4hair,0);
  46
  47         penpos6(norm-hair,90);
  48         z6=(xoff+3/4norm,0);
  49
  50         penpos7(hair,-90);
  51         z7r=(x1,-d);
  52
  53         save t; t=0.833;
  54         save p; path p;
  55         p = z5l..z4l{up}..z4r{down}..z3r{right}..tension t..z2r{up}
  56                 ..tension t..z1r{left}..z1l{right}..tension t..z2l{down}
  57                 ..z3l{left}..z6r..z5r{down};
  58         pickup pencircle scaled 1pt#;
  59         filldraw p..(reverse p yscaled -1)..cycle;
  60         penlabels (1,2,3,4,5,6);
  61
  62         % ugh, should be bulb, not flare?
  63         draw_flare(z1l,180,90,hair,norm-1/2hair);
  64         draw_flare(z7r,180,-90,hair,norm-1/2hair);
  65         enddef;
  66
  67 fet_beginchar ("C clef", "alto", "altoclef")
  68         if test = 1:
  69                 draw_staff (-2,2);
  70         fi;
  71         draw_c_clef (1.0);
  72 fet_endchar;
  73
  74 fet_beginchar ("C clef", "alto_change", "caltoclef")
  75         if test = 1:
  76                 draw_staff (-2,2);
  77         fi;
  78         draw_c_clef (.8);
  79 fet_endchar;
  80
  81 %
  82 % Inspired by Baerenreiter and Breitkopf
  83 %
  84 % FIXME: dims
  85 % FIXME: right vertical tangent seems to be lower than the F-line
  86 % FIXME: bulb curve smoothly into "long curve" on the  inside
  87 %
  88 %
  89 % [Wanske] says that the extreme x point should be exactly between
  90 % the dots, but her picture shows that the extreme is ~ 0.2 ss lower
  91
  92 def draw_bass_klef(expr exact_center, reduction) =
  93         save reduced_il, left_tilt, left_thick;
  94         reduced_il# = interline# * reduction;
  95         left_tilt = 5;
  96         define_pixels(reduced_il);
  97         left_thick = .25  reduced_il;
  98
  99         set_char_box(
 100                 - xpart exact_center+ .2 reduced_il#,
 101                 xpart exact_center + 2.7 reduced_il#,
 102                 - ypart exact_center + 2.5 reduced_il#,
 103                 ypart exact_center +reduced_il#);
 104         x1r - x1l = left_thick;
 105         z1l = (hround_pixels(xpart exact_center),
 106                 vround_pixels(ypart exact_center));
 107
 108         y2 = reduced_il;
 109
 110         x3l - x1l =  2.1 reduced_il;
 111         x2 = .5 [x1,x3];
 112         x3l - x3r = .48 reduced_il;
 113         y3l = -0.05 interline;
 114         x4 = x1l - stafflinethickness;
 115         y4 = -2.2  reduced_il;
 116         z5 = (x3l +  1/3 reduced_il, .5 reduced_il);
 117
 118         penpos1(whatever, left_tilt);
 119         penpos2(1.2 stafflinethickness, -90);
 120         penpos3(whatever,  185);
 121         penpos4(stafflinethickness, 135);
 122
 123         draw_bulb(1, z1r,  z1l, .45 reduced_il, 1.0);
 124
 125
 126         fill z1r{up} .. z2r{right} .. tension 1.0 .. z3r{down}  .. {curl 0}
 127                 simple_serif(z4r, z4l, 90) {curl 0}
 128                 .. z3l{up} .. tension 0.9 .. z2l{left}
 129                 .. z1l{dir (-90 + left_tilt)} -- cycle;
 130         labels(2,4);
 131         penlabels(1,2,3,4);
 132
 133         save dot_diam;
 134         2 dot_diam = reduction* (interline - stafflinethickness);
 135         pickup pencircle scaled dot_diam;
 136         draw z5;
 137         draw z5 yscaled -1;
 138 enddef;
 139
 140
 141
 142 fet_beginchar("F clef ", "bass", "bassclef")
 143         if test = 1:
 144                 draw_staff(-3,1);
 145         fi;
 146         draw_bass_klef((.5 interline#, 0), 1.0);
 147 fet_endchar;
 148 fet_beginchar("F clef (reduced)", "bass_change", "cbassclef")
 149         draw_bass_klef((.4 interline#, 0),0.8);
 150 fet_endchar;
 151
 152
 153
 154 %
 155 % Inspired by Baerenreiter
 156 %
 157 % FIXME top should be thinner at z8,
 158 % FIXME bulb should curve (see bass clef)
 159 % FIXME start (inside) should be little thinner
 160 % FIXME parametrise.
 161 %
 162
 163 % Beste lezers, kijk,
 164 %
 165 % Een bolletje  hebben we bij toeval allemaal wel eens getekend, maar begint u
 166 % toch eenvoudig.   Eerst een eenvoudig kruis of herstellingsteken
 167 % en via de dubbelslag naar een voorzichtig vlaggetje, en heb geduld!
 168 % Ikzelf heb bijvoorbeeld over mijn eerste gave G-sleutel
 169 % 35 kilobyte metafont, 12 patchlevels, 0 vriendinnen en 45 dagen gedaan
 170 %
 171 def draw_gclef (expr exact_center, reduction)=
 172         save reduced_il, downstroke_dir, downstroke_angle, hair, center;
 173         save breapth_factor, inner_thick_end, thinness, thickness, thinnib;
 174         save inner_start_angle, thinness, thinpen;
 175         reduced_il# = interline# * reduction;
 176         define_pixels(reduced_il);
 177         pair downstroke_dir, center;
 178
 179         center := (hround_pixels(xpart exact_center),
 180                 vround_pixels(ypart exact_center));
 181
 182         hair =  .3 stafflinethickness;
 183         thinness = 1.3 stafflinethickness;
 184         downstroke_dir = (14, -75);
 185         breapth_factor = 11/7;
 186         inner_thick_end = 45;
 187         inner_start_angle = downstroke_angle - 43;
 188         thickness = .4 reduced_il - hair;
 189
 190         thinnib = thinness - hair;
 191         thinpen = thinness;
 192         set_char_box(-xpart exact_center + 1.1 * breapth_factor* reduced_il#,
 193                 xpart exact_center + .66 breapth_factor* reduced_il#,
 194                 -ypart exact_center + 3 * reduced_il#,
 195                 ypart exact_center + 5 * reduced_il#);
 196
 197         pickup pencircle scaled hair;
 198         downstroke_angle = angle downstroke_dir;
 199
 200         z1 = center + whatever * dir (inner_start_angle);
 201         x1 = xpart center -.28 reduced_il;
 202
 203         top z2r = center + (0,reduced_il + stafflinethickness/2);
 204
 205         x4 = xpart center - .1 reduced_il;
 206         bot y4r = -(reduced_il + .5 stafflinethickness);
 207
 208         z3 = (z4 - center) rotated inner_thick_end + center;
 209
 210         z5r = (- breapth_factor, .37)* reduced_il + center;
 211         penpos5(thickness, 135);
 212
 213         z6 = center + whatever * downstroke_dir;
 214         y6 = ypart center + 2 reduced_il;
 215
 216         z7l - z6 = whatever *(z5- z6) ;
 217         y7l = 3.5 reduced_il;
 218         z8r = .4 [z9r, z7r] + 1.5 stafflinethickness * dir 52;
 219
 220         x9 = .7 [x10, x7r];
 221         top y9l = 5 reduced_il;
 222
 223         y10 = 3. reduced_il;
 224         y11 = -11/7 reduced_il;
 225
 226         y12 = ypart center - 18.5/7 reduced_il;
 227         x12 = x11 - 5 /7 reduced_il;
 228
 229         z13 = z12 + .6 reduced_il*(-1,1);
 230
 231         (z10r - z10l) dotprod (unitvector downstroke_dir rotated 90) =
 232                 thinnib;
 233
 234         center - z10= whatever * downstroke_dir;
 235         center - z11 =  whatever * downstroke_dir;
 236
 237         penpos1(thinnib, inner_start_angle);
 238         penpos2(thickness, 90);
 239         penpos3(thinnib, -90 + inner_thick_end);
 240         penpos4(thinnib, -90);
 241
 242
 243         penpos7(thickness, 135);
 244         penpos8(1.5 thinnib, - 70 + angle downstroke_dir);
 245         penpos9(1.5 thickness, -80);
 246         penpos10(whatever, downstroke_angle + 10);
 247         penpos11(thinnib, downstroke_angle + 90);
 248         penpos12(thinnib, -90);
 249         penpos13(3 thinnib, 180);
 250
 251
 252         filldraw z2l{right}   .. z3l.. z4l{left} .. z5l{up}  .. z7l{up}
 253                 %.. z8l
 254                 .. z9l & z9l ..
 255                 {downstroke_dir}z10l --- z11l -- z11r --- z10r{- downstroke_dir}
 256                 .. tension .8
 257                 .. z9r & z9r
 258                 %.. z8r
 259                 .. z7r{down} .. z5r{down} .. z4r{right}
 260                 .. z3r .. z2r{left} ..
 261                 tension .95 ..
 262                 z1r -- z1l
 263                 .. tension 0.85 ..cycle;
 264
 265         filldraw simple_serif(z1r, z1l, 90)  -- cycle;
 266
 267         filldraw z12r{left} .. z13r{up} -- z13l{down} .. z12l{right} .. cycle;
 268
 269         draw_bulb(-1,  z13l, lft z13r, 6/14 reduced_il, 1.0);
 270
 271         pickup pencircle scaled (thinpen);
 272         draw z10 --- z11 .. z12{left};
 273
 274         penlabels(range 1 thru 15);
 275 enddef;
 276
 277
 278 fet_beginchar("G clef", "violin", "violinclef")
 279         if test = 1:
 280                 draw_staff(-1,3);
 281         fi;
 282         draw_gclef((1.7 interline#,0), 1.0);
 283 fet_endchar;
 284 fet_beginchar("G clef", "violin_change", "cviolinclef")
 285         draw_gclef((1.3 interline#,0), .8);
 286 fet_endchar;
 287
 288 fet_endgroup("clefs");