mf/feta-klef.mf

   1 %
   2 % feta-klef.mf --  implement Clefs
   3 %
   4 % source file of the Feta (Font-En-Tja) music font
   5 %
   6 % (c) 1997 Han-Wen Nienhuys <hanwen@stack.nl>,
   7 % Jan Nieuwenhuizen <jan@digicash.com>
   8
   9 fet_begingroup("klef");
  10
  11 def draw_staff(expr first, last)=
  12         pickup pencircle scaled stafflinethickness;
  13         for i:= first step 1 until last:
  14                 draw (- interline, i* interline) .. (4 interline, i* interline);
  15         endfor
  16         enddef;
  17
  18 % [Wanske] says the bulbs should be positioned about 1/4 right of the
  19 % "arrow"
  20 def draw_c_clef (expr reduction) =
  21         save hair, norm, reduced_il;
  22         reduced_il#=interline#*reduction;
  23         norm#:=2/3reduced_il#;
  24         hair#:=1/6norm#;
  25         define_pixels (hair,norm,reduced_il);
  26         set_char_box (0, 5/2reduced_il#, 2 reduced_il#, 2 reduced_il#);
  27         draw_block ((0,-d), (1/2reduced_il,h));
  28         draw_block ((1/2reduced_il+stafflinethickness,-d),
  29           (1/2reduced_il+2stafflinethickness,h));
  30
  31         save xoff;
  32         xoff=1/2reduced_il+2hair;
  33         penpos1(hair,-90);
  34         z1l=(xoff+norm+hair,h);
  35         penpos2(norm-hair,180);
  36         z2l=(w,h/2);
  37         penpos3(hair,90);
  38         z3=(((w-xoff)/2)+xoff,2hair);
  39
  40         penpos4(hair,0);
  41         z4=(xoff+1/2norm+1/2hair,reduced_il-hair);
  42
  43         penpos5(4hair,0);
  44         z5=(xoff+5/4hair,0);
  45
  46         penpos6(norm-hair,90);
  47         z6=(xoff+3/4norm,0);
  48
  49         penpos7(hair,-90);
  50         z7r=(x1,-d);
  51
  52         save t; t=0.833;
  53         save p; path p;
  54 %       p = z5l..z4l{up}..z4r{down}..z3r{right}..tension t..z2r{up}
  55 %               ..z1r{left}..z1l{right}..z2l{down}
  56 %               ..z3l{left}..z5r{down};
  57         p = z5l..z4l{up}..z4r{down}..z3r{right}..tension t..z2r{up}
  58                 ..z1r{left}..z1l{right}..z2l{down}
  59                 ..z3l{left}..z6r..z5r{down};
  60         pickup pencircle scaled 1pt#;
  61         filldraw p..(reverse p yscaled -1)..cycle;
  62         penlabels (1,2,3,4,5,6);
  63
  64         % ugh, should be bulb, not flare?
  65         draw_flare(z1l,180,90,hair,norm-1/4hair);
  66         draw_flare(z7r,180,-90,hair,norm-1/4hair);
  67         enddef;
  68
  69 fet_beginchar ("C clef", "alto", "altoclef")
  70         if test = 1:
  71                 draw_staff (-2,2);
  72         fi;
  73         draw_c_clef (1.0);
  74 fet_endchar;
  75
  76 fet_beginchar ("C clef", "alto_change", "caltoclef")
  77         if test = 1:
  78                 draw_staff (-2,2);
  79         fi;
  80         draw_c_clef (.8);
  81 fet_endchar;
  82
  83 %
  84 % Inspired by Baerenreiter and Breitkopf
  85 %
  86 % FIXME: dims
  87 % FIXME: right vertical tangent seems to be lower than the F-line
  88 % FIXME: bulb curve smoothly into "long curve" on the  inside
  89 %
  90 %
  91 % [Wanske] says that the extreme x point should be exactly between
  92 % the dots, but her picture shows that the extreme is ~ 0.2 ss lower
  93
  94 def draw_bass_klef(expr exact_center, reduction) =
  95         save reduced_il, left_tilt, left_thick;
  96         reduced_il# = interline# * reduction;
  97         left_tilt = 5;
  98         define_pixels(reduced_il);
  99         left_thick = .25  reduced_il;
 100
 101         set_char_box(
 102                 - xpart exact_center+ .2 reduced_il#,
 103                 xpart exact_center + 2.7 reduced_il#,
 104                 - ypart exact_center + 2.5 reduced_il#,
 105                 ypart exact_center +reduced_il#);
 106         x1r - x1l = left_thick;
 107         z1l = (hround_pixels(xpart exact_center),
 108                 vround_pixels(ypart exact_center));
 109
 110         y2 = reduced_il;
 111
 112         x3l - x1l =  2.1 reduced_il;
 113         x2 = .5 [x1,x3];
 114         x3l - x3r = .48 reduced_il;
 115         y3l = -0.05 interline;
 116         x4 = x1l - stafflinethickness;
 117         y4 = -2.2  reduced_il;
 118         z5 = (x3l +  1/3 reduced_il, .5 reduced_il);
 119
 120         penpos1(whatever, left_tilt);
 121         penpos2(1.2 stafflinethickness, -90);
 122         penpos3(whatever,  185);
 123         penpos4(stafflinethickness, 135);
 124
 125         draw_bulb(1, z1r,  z1l, .45 reduced_il, 1.0);
 126
 127
 128         fill z1r{up} .. z2r{right} .. tension 1.0 .. z3r{down}  .. {curl 0}
 129                 simple_serif(z4r, z4l, 90) {curl 0}
 130                 .. z3l{up} .. tension 0.9 .. z2l{left}
 131                 .. z1l{dir (-90 + left_tilt)} -- cycle;
 132         labels(2,4);
 133         penlabels(1,2,3,4);
 134
 135         pickup pencircle scaled (.35 reduced_il);
 136         draw z5;
 137         draw z5 yscaled -1;
 138 enddef;
 139
 140
 141
 142 fet_beginchar("F clef ", "bass", "bassclef")
 143         if test = 1:
 144                 draw_staff(-3,1);
 145         fi;
 146         draw_bass_klef((.5 interline#, 0), 1.0);
 147 fet_endchar;
 148 fet_beginchar("F clef (reduced)", "bass_change", "cbassclef")
 149         draw_bass_klef((.4 interline#, 0),0.8);
 150 fet_endchar;
 151
 152
 153
 154 %
 155 % Inspired by Baerenreiter
 156 %
 157 % FIXME top should be thinner at z8,
 158 % FIXME bulb should curve (see bass clef)
 159 % FIXME start (inside) should be little thinner
 160 % FIXME parametrise.
 161 % FIXME should be a bit more upright
 162 %
 163
 164 % Beste lezers, kijk,
 165 %
 166 % Een bolletje  hebben we bij toeval allemaal wel eens getekend, maar begint u
 167 % toch eenvoudig.   Eerst een eenvoudig kruis of herstellingsteken
 168 % en via de dubbelslag naar een voorzichtig vlaggetje, en heb geduld!
 169 % Ikzelf heb bijvoorbeeld over mijn eerste gave G-sleutel
 170 % 35 kilobyte metafont, 12 patchlevels, 0 vriendinnen en 45 dagen gedaan
 171 %
 172 def draw_gclef (expr exact_center, reduction)=
 173         save reduced_il, downstroke_dir, downstroke_angle, hair, center;
 174         save breapth_factor, inner_thick_end, thinness, thickness, thinnib;
 175         save inner_start_angle, thinness, thinpen;
 176         reduced_il# = interline# * reduction;
 177         define_pixels(reduced_il);
 178         pair downstroke_dir, center;
 179
 180         center := (hround_pixels(xpart exact_center),
 181                 vround_pixels(ypart exact_center));
 182
 183         hair =  .3 stafflinethickness;
 184         thinness = 1.3 stafflinethickness;
 185         downstroke_dir = (14, -75);
 186         breapth_factor = 11/7;
 187         inner_thick_end = 45;
 188         inner_start_angle = angle(-1,-2);
 189         thickness = .4 reduced_il - hair;
 190
 191         thinnib = thinness - hair;
 192         thinpen = thinness;
 193         set_char_box(-xpart exact_center + breapth_factor* reduced_il#,
 194                 xpart exact_center + .66 breapth_factor* reduced_il#,
 195                 -ypart exact_center + 3 * reduced_il#,
 196                 ypart exact_center + 5 * reduced_il#);
 197
 198         pickup pencircle scaled hair;
 199
 200         downstroke_angle = angle downstroke_dir;
 201         z1 = center + whatever * dir inner_start_angle;
 202         x1 = xpart center -.28 reduced_il;
 203
 204         top z2r = center + (0,reduced_il + stafflinethickness/2);
 205
 206         x4 = xpart center - .1 reduced_il;
 207         bot y4r = -(reduced_il + .5 stafflinethickness);
 208
 209         z3 = (z4 - center) rotated inner_thick_end + center;
 210
 211         z5r = (- breapth_factor, .37)* reduced_il + center;
 212         penpos5(thickness, 135);
 213
 214         z6 = center + whatever * downstroke_dir;
 215         y6 = ypart center + 2 reduced_il;
 216
 217         z7l - z6 = whatever *(z5- z6) ;
 218         y7l = 3.5 reduced_il;
 219         z8r = .4 [z9r, z7r] + 1.5 stafflinethickness * dir 52;
 220
 221         x9 = .7 [x10, x7r];
 222         top y9l = 5 reduced_il;
 223
 224         y10 = 3. reduced_il;
 225         y11 = -11/7 reduced_il;
 226
 227         y12 = ypart center - 18.5/7 reduced_il;
 228         x12 = x11 - 5 /7 reduced_il;
 229
 230         z13 = z12 + .6 reduced_il*(-1,1);
 231
 232         (z10r - z10l) dotprod (unitvector downstroke_dir rotated 90) =
 233                 thinnib;
 234
 235         center - z10= whatever * downstroke_dir;
 236         center - z11 =  whatever * downstroke_dir;
 237
 238         penpos1(thinnib, inner_start_angle);
 239         penpos2(thickness, 90);
 240         penpos3(thinnib, -90 + inner_thick_end);
 241         penpos4(thinnib, -90);
 242
 243
 244         penpos7(thickness, 135);
 245         penpos8(1.5 thinnib, - 70 + angle downstroke_dir);
 246         penpos9(1.5 thickness, -80);
 247         penpos10(whatever, downstroke_angle + 10);
 248         penpos11(thinnib, downstroke_angle + 90);
 249         penpos12(thinnib, -90);
 250         penpos13(3 thinnib, 180);
 251
 252
 253         filldraw z2l{right}   .. z3l.. z4l{left} .. z5l{up}  .. z7l{up}
 254                 %.. z8l
 255                 .. z9l & z9l ..
 256                 {downstroke_dir}z10l --- z11l -- z11r --- z10r{- downstroke_dir}
 257                 .. tension .8
 258                 .. z9r & z9r
 259                 %.. z8r
 260                 .. z7r{down} .. z5r{down} .. z4r{right}
 261                 .. z3r .. z2r{left} ..
 262                 tension .95 ..
 263                 z1r -- z1l
 264                 .. tension 0.85 ..cycle;
 265
 266         filldraw simple_serif(z1r, z1l, 90)  -- cycle;
 267
 268         filldraw z12r{left} .. z13r{up} -- z13l{down} .. z12l{right} .. cycle;
 269
 270         draw_bulb(-1,  z13l, lft z13r, 6/14 reduced_il, 1.0);
 271
 272         pickup pencircle scaled (thinpen);
 273         draw z10 --- z11 .. z12{left};
 274
 275         penlabels(range 1 thru 15);
 276 enddef;
 277
 278
 279 fet_beginchar("G clef", "violin", "violinclef")
 280         if test = 1:
 281                 draw_staff(-1,3);
 282         fi;
 283         draw_gclef((1.6 interline#,0), 1.0);
 284 fet_endchar;
 285 fet_beginchar("G clef", "violin_change", "cviolinclef")
 286         draw_gclef((1.3 interline#,0), .8);
 287 fet_endchar;
 288
 289 fet_endgroup("klef");