mf/feta-klef.mf

   1 % feta-klef.mf --  implement Clefs -*-Fundamental-*-
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997--2002 Han-Wen Nienhuys <hanwen@cs.uu.nl>,
   8 % Jan Nieuwenhuizen <janneke@gnu.org>,
   9 % Juergen Reuter <reuter@ipd.uka.de>
  10
  11
  12 fet_begingroup("clefs");
  13
  14 %
  15 % [Ross] says that clefs take 1 staff_space space on the left and right
  16 %
  17 def set_horizontal_spacing =
  18         save left_space ,right_space;
  19         left_space# = 0;
  20         right_space# = 0;
  21 enddef;
  22
  23
  24 % [Wanske] says the bulbs should be positioned about 1/4 right of the
  25 % "arrow"
  26 def draw_c_clef (expr reduction) =
  27         save hair, norm, reduced_il, right_edge;
  28         reduced_il#=staff_space#*reduction;
  29         norm#:=2/3reduced_il#;
  30         hair#:=1/6norm#;
  31
  32         set_horizontal_spacing;
  33         right_edge# = 15/4norm#+2hair#;
  34
  35         set_char_box (left_space#, right_edge# + right_space#,
  36                 2 reduced_il#, 2 reduced_il#);
  37         define_pixels (hair,norm,reduced_il, right_edge);
  38
  39         draw_block ((0,-d), (3/4norm+1/2hair,h));
  40         draw_block ((3/4norm+2hair,-d),
  41                 (3/4norm+7/2hair,h));
  42
  43         save xoff;
  44         xoff=3/4norm+7/2hair;
  45         penpos1(hair,-90);
  46         z1l=(xoff+norm+hair,h);
  47         penpos2(norm-3/2hair,180);
  48         z2l=(right_edge,h/2);
  49         penpos3(hair,90);
  50         z3=(((right_edge -xoff)/2)+xoff,2hair);
  51
  52         penpos4(hair,0);
  53         z4=(xoff+1/2norm+1/2hair,reduced_il-hair);
  54
  55         penpos5(4hair,0);
  56         z5=(xoff+5/4hair,0);
  57
  58         penpos6(norm-hair,90);
  59         z6=(xoff+3/4norm,0);
  60
  61         penpos7(hair,-90);
  62         z7r=(x1,-d);
  63
  64         save t; t=0.833;
  65         save p; path p;
  66         p = z5l..z4l{up}..z4r{down}..z3r{right}..tension t..z2r{up}
  67                 ..tension t..z1r{left}..z1l{right}..tension t..z2l{down}
  68                 ..z3l{left}..z6r..z5r{down};
  69         pickup pencircle scaled 1pt#;
  70         filldraw p..(reverse p yscaled -1)..cycle;
  71         penlabels (1,2,3,4,5,6);
  72
  73         % ugh, should be bulb, not flare?
  74         draw_flare(z1l,180,90,hair,norm-1/2hair);
  75         draw_flare(z7r,180,-90,hair,norm-1/2hair);
  76         enddef;
  77
  78 fet_beginchar ("C clef", "C", "altoclef")
  79         if test = 1:
  80                 draw_staff (-2,2, 0.0);
  81         fi;
  82         draw_c_clef (1.0);
  83 fet_endchar;
  84
  85 fet_beginchar ("C clef", "C_change", "caltoclef")
  86         if test = 1:
  87                 draw_staff (-2,2, 0.0);
  88         fi;
  89         draw_c_clef (.8);
  90 fet_endchar;
  91
  92 %
  93 % Inspired by Baerenreiter and Breitkopf
  94 %
  95 % FIXME: dims
  96 % FIXME: right vertical tangent seems to be lower than the F-line
  97 % FIXME: bulb curve smoothly into "long curve" on the  inside
  98 %
  99 %
 100 % [Wanske] says that the extreme x point should be exactly between
 101 % the dots, but her picture shows that the extreme is ~ 0.2 ss lower
 102
 103 def draw_bass_clef(expr exact_center, reduction) =
 104         save reduced_il, left_tilt, left_thick, ball_to_right;
 105         reduced_il# = staff_space# * reduction;
 106
 107         set_horizontal_spacing;
 108         ball_to_right# = 2.1 reduced_il#;
 109         set_char_box(left_space# +
 110                 - xpart exact_center,
 111                 right_space# +
 112                 xpart exact_center + ball_to_right# + 7/12 reduced_il#,
 113                 - ypart exact_center + 2.5 reduced_il#,
 114                 ypart exact_center +reduced_il#);
 115
 116         define_pixels(reduced_il, ball_to_right);
 117         left_tilt = 5;
 118         left_thick = .25  reduced_il;
 119
 120         x1r - x1l = left_thick;
 121         z1l = (hround_pixels(xpart exact_center),
 122                 vround_pixels(ypart exact_center));
 123
 124         y2 = reduced_il;
 125
 126         x3l - x1l =  ball_to_right;
 127         x2 = .5 [x1,x3];
 128         x3l - x3r = .48 reduced_il;
 129         y3l = -0.05 staff_space;
 130         x4 = x1l - stafflinethickness;
 131         y4 = -2.2  reduced_il;
 132         z5 = (x3l +  1/3 reduced_il, .5 reduced_il);
 133
 134         penpos1(whatever, left_tilt);
 135         penpos2(1.2 stafflinethickness, -90);
 136         penpos3(whatever,  185);
 137         penpos4(stafflinethickness, 135);
 138
 139         draw_bulb(1, z1r,  z1l, .45 reduced_il, 1.0);
 140
 141
 142         fill z1r{up} .. z2r{right} .. tension 1.0 .. z3r{down}  .. {curl 0}
 143                 simple_serif(z4r, z4l, 90) {curl 0}
 144                 .. z3l{up} .. tension 0.9 .. z2l{left}
 145                 .. z1l{dir (-90 + left_tilt)} -- cycle;
 146         labels(2,4);
 147         penlabels(1,2,3,4);
 148
 149         save dot_diam;
 150         2 dot_diam = reduction* (staff_space - stafflinethickness);
 151         pickup pencircle scaled dot_diam;
 152         draw z5;
 153         draw z5 yscaled -1;
 154 enddef;
 155
 156
 157
 158 fet_beginchar("F clef ", "F", "bassclef")
 159         if test = 1:
 160                 draw_staff(-3,1, 0.0);
 161         fi;
 162         draw_bass_clef((.5 staff_space#, 0), 1.0);
 163 fet_endchar;
 164 fet_beginchar("F clef (reduced)", "F_change", "cbassclef")
 165         draw_bass_clef((.4 staff_space#, 0),0.8);
 166 fet_endchar;
 167
 168
 169
 170 %
 171 % Inspired by Baerenreiter
 172 %
 173 % FIXME bulb should curve (see bass clef)
 174 % FIXME start (inside) should be little thinner
 175 % FIXME parametrise.
 176 %
 177
 178 % Beste lezers, kijk,
 179 %
 180 % Een bolletje  hebben we bij toeval allemaal wel eens getekend, maar begint u
 181 % toch eenvoudig.   Eerst een eenvoudig kruis of herstellingsteken
 182 % en via de dubbelslag naar een voorzichtig vlaggetje, en heb geduld!
 183 % Ikzelf heb bijvoorbeeld over mijn eerste gave G-sleutel
 184 % 35 kilobyte metafont, 12 patchlevels, 0 vriendinnen en 45 dagen gedaan
 185 %
 186 %  -- vrij naar Van Kooten & De Bie
 187 %
 188
 189 def draw_gclef (expr exact_center, reduction)=
 190         save reduced_il, downstroke_dir, downstroke_angle, hair, center;
 191         save breapth_factor, inner_thick_end, thinness, thickness, thinnib;
 192         save inner_start_angle, thinness, thinpen;
 193         reduced_il# = staff_space# * reduction;
 194         define_pixels(reduced_il);
 195         pair downstroke_dir, center;
 196
 197         center := (hround_pixels(xpart exact_center),
 198                 vround_pixels(ypart exact_center));
 199
 200         hair =  .3 stafflinethickness;
 201         thinness = 1.3 stafflinethickness;
 202         downstroke_dir = (14, -75);
 203         breapth_factor = 11/7;
 204         inner_thick_end = 45;
 205         inner_start_angle = downstroke_angle - 43;
 206         thickness = .4 reduced_il - hair;
 207
 208         thinnib = thinness - hair;
 209         thinpen = thinness;
 210         set_horizontal_spacing;
 211
 212         set_char_box(
 213                 left_space# +
 214                 -xpart exact_center + 1.0 * breapth_factor* reduced_il#,
 215                 right_space# +
 216                 xpart exact_center + .66 breapth_factor* reduced_il#,
 217                 -ypart exact_center + 3 * reduced_il#,
 218                 ypart exact_center + 5 * reduced_il#);
 219
 220         pickup pencircle scaled hair;
 221         downstroke_angle = angle downstroke_dir;
 222
 223         z1 = center + whatever * dir (inner_start_angle);
 224         x1 = xpart center -.28 reduced_il;
 225
 226         top z2r = center + (0,reduced_il + stafflinethickness/2);
 227
 228         x4 = xpart center - .1 reduced_il;
 229         bot y4r = -(reduced_il + .5 stafflinethickness);
 230
 231         z3 = (z4 - center) rotated inner_thick_end + center;
 232
 233         z5r = (- breapth_factor, .37)* reduced_il + center;
 234         penpos5(thickness, 135);
 235
 236         z6 = center + whatever * downstroke_dir;
 237         y6 = ypart center + 2 reduced_il;
 238
 239         z7l - z6 = whatever *(z5- z6) ;
 240         y7l = 3.5 reduced_il;
 241         z8r = .4 [z9r, z7r] + 1.5 stafflinethickness * dir 52;
 242
 243         x9 = .7 [x10, x7r];
 244         top y9l = 5 reduced_il;
 245
 246         y10 = 3. reduced_il;
 247         y11 = -11/7 reduced_il;
 248
 249         y12 = ypart center - 18.5/7 reduced_il;
 250         x12 = x11 - 5 /7 reduced_il;
 251
 252         z13 = z12 + .6 reduced_il*(-1,1);
 253
 254         (z10r - z10l) dotprod (unitvector downstroke_dir rotated 90) =
 255                 thinnib;
 256
 257         center - z10= whatever * downstroke_dir;
 258         center - z11 =  whatever * downstroke_dir;
 259         center - z14 = .8 (center - z11);
 260         penpos1(thinnib, inner_start_angle);
 261         penpos2(thickness, 90);
 262         penpos3(thinnib, -90 + inner_thick_end);
 263         penpos4(thinnib, -90);
 264
 265
 266         penpos7(thickness, 135);
 267         penpos8(1.5 thinnib, - 70 + angle downstroke_dir);
 268         penpos9(1.4 thickness, -80);  % ugh
 269         penpos10(whatever, downstroke_angle + 10);
 270         penpos11(thinnib, downstroke_angle + 90);
 271         penpos14(thinnib, downstroke_angle + 90);
 272         penpos12(thinnib, -90);
 273         penpos13(3 thinnib, 180);
 274
 275         filldraw z2l{right}   .. z3l.. z4l{left} .. z5l{up}  .. z7l{up}
 276                 %.. z8l
 277                 .. tension 1.2
 278                 .. z9l & z9l ..
 279                 {downstroke_dir}z10l --- z11l -- z11r --- z10r{- downstroke_dir}
 280                 .. tension .8
 281                 .. z9r & z9r{dir (downstroke_angle+ 40)} % ugh
 282                 %.. z8r
 283                 .. z7r{down} .. z5r{down} .. z4r{right}
 284                 .. z3r .. z2r{left} ..
 285                 tension .95 ..
 286                 z1r -- z1l
 287                 .. tension 0.85 ..cycle;
 288
 289         filldraw simple_serif(z1r, z1l, 90)  -- cycle;
 290
 291         filldraw z12r{left} .. z13r{up} -- z13l{down} .. z12l{right} .. cycle;
 292
 293         draw_bulb(-1,  z13l, lft z13r, 6/14 reduced_il, 1.0);
 294
 295         pickup pencircle scaled (thinpen);
 296         draw z10 --- z14 .. z11  .. tension 0.85 ..  z12{left};
 297
 298         penlabels(range 1 thru 15);
 299 enddef;
 300
 301
 302 fet_beginchar("G clef", "G", "trebleclef")
 303         if test = 1:
 304                 draw_staff(-1,3, 0.0);
 305         fi;
 306         draw_gclef((1.7 staff_space#,0), 1.0);
 307 fet_endchar;
 308 fet_beginchar("G clef", "G_change", "ctrebleclef")
 309         draw_gclef((1.3 staff_space#,0), .8);
 310 fet_endchar;
 311
 312 %%%%
 313 % PERCUSSION
 314 %
 315 %
 316
 317
 318 def draw_percussion_clef(expr reduction) =
 319         save reduced_il;
 320         reduced_il# = staff_space# * reduction;
 321         define_pixels(reduced_il);
 322         set_char_box(-.67reduced_il#,2.0reduced_il#,reduced_il#,reduced_il#);
 323         razt := 0.45reduced_il;
 324         draw_block((-b,-d),(-b+razt,h));
 325         draw_block((w-razt,-d),(w,h));
 326 enddef;
 327
 328 fet_beginchar("percussion clef", "percussion", "percussionclef")
 329         draw_percussion_clef(1.0);
 330 fet_endchar;
 331
 332 fet_beginchar("percussion clef (reduced)", "percussion_change", "cpercussionclef")
 333         draw_percussion_clef(.8);
 334 fet_endchar;
 335
 336 def draw_tab_T(expr pos, siz, slant) =
 337         begingroup;
 338         clearxy;
 339         pair vx,vy;
 340         vx=(xpart siz) * dir 0;
 341         vy=(ypart siz) * dir 90;
 342
 343         penpos1(.75penh, 100);
 344         z1=z2+(1/6*vx-.15*vy);
 345         penpos2(.9penw, 0);
 346         z2l = pos+.75vy;
 347         penpos3(penh,-100);
 348         z3l = pos+.4vx+vy;
 349         penpos4(penh,-90);
 350         z4=-.1vy+.5[z3,z5];
 351         penpos5(.8penh,-30);
 352         x5r=xpart (pos+siz);
 353         y5l=ypart (pos+siz);
 354
 355         penpos10(penw,170);
 356         z10=pos+.55vx+.85vy;
 357         penpos11(.75[penh,penw],170);
 358         z11=z10-.5vy+.025vx;
 359         penpos12(penh,100);
 360         z12l=(xpart .5[z13,z11],ypart (pos-.025*siz));
 361         penpos13(.75penh,60);
 362         z13=pos +.2vx+.15vy;
 363
 364         % penlabels (1,2,3,4,5,10,11,12,13);
 365
 366         soft_penstroke (z1e..tension 1.1
 367                 ..z2e
 368                 ..z3e{right}..tension 1.5
 369                 ..z4e
 370                 ..z5e
 371                 ) slanted slant shifted (slant*-ypart pos,0);
 372
 373         soft_penstroke (z10e..tension 1.5
 374                 ..z11e
 375                 ..z12e..tension 1.1
 376                 ..z13e{(z13r-z13l) rotated 90}
 377                 ) slanted slant shifted (slant*-ypart pos,0);
 378         endgroup;
 379 enddef;
 380
 381 def draw_tab_A(expr pos, siz, slant) =
 382         begingroup;
 383         clearxy;
 384         pair vx,vy;
 385         vx=(xpart siz) * dir 0;
 386         vy=(ypart siz) * dir 90;
 387
 388         penpos1(.75penh,-110);
 389         z1r=pos+.07vy;
 390         penpos2(penh,-75);
 391         z2r=(.5[x1,x3],ypart pos);
 392         penpos3(.25[penh,penw],-30);
 393         z3=(.45[x2,x4],.15[y2,y4]);
 394         penpos4(1[penh,penw],0);
 395         z4=pos+.5vx+.975vy;
 396
 397         penpos5(1[penh,penw],-180);
 398         z5=z4;
 399         penpos6(.2[penh,penw],-150);
 400         z6l=(.8[x5l,x7l],.9[y5l,y7l]);
 401         penpos7(penh,-90);
 402         z7r=(.5[x6,x8],ypart pos);
 403         penpos8(.75penh,-70);
 404         z8r=(xpart(pos+siz),y7r+.075ypart(siz));
 405
 406         penpos10(penh,-105);
 407         z10=.2[z3,z4];
 408         penpos11(.9penh,-90);
 409         z11=.4[z10,z6]-0.05vy;
 410         penpos12(.75penh,-75);
 411         z12=.3[z11,z6]+0.02vy;
 412
 413         % penlabels(1,2,3,4,5,6,7,8,10,11,12);
 414
 415         soft_penstroke (z1e {(z1r-z1l) rotated 90}
 416                 ..z2e
 417                 ..z3e
 418                 ..z4e
 419                 ) slanted slant shifted (slant*-ypart pos,0);
 420
 421         soft_penstroke (z5e
 422                 ..z6e
 423                 ..z7e
 424                 ..z8e {(z8r-z8l) rotated 90}
 425                 ) slanted slant shifted (slant*-ypart pos,0);
 426
 427         soft_penstroke (z10e
 428                 ..z11e
 429                 ..z12e
 430                 ) slanted slant shifted (slant*-ypart pos,0);
 431
 432         endgroup;
 433 enddef;
 434
 435 def draw_tab_B(expr pos, siz, slant) =
 436         begingroup;
 437         clearxy;
 438         pair vx,vy;
 439         vx=(xpart siz) * dir 0;
 440         vy=(ypart siz) * dir 90;
 441
 442         penpos1(.75penh, 100);
 443         z1=z2+(.15*vx-.1*vy);
 444         penpos2(.9penw, 0);
 445         z2l = pos+.75vy;
 446         penpos3(penh,-100);
 447         z3l = pos+.4vx+1.05vy;
 448         penpos4(.8[penh,penw],-180);
 449         z4=(xpart(pos+.75siz),.5[y3,y5]);
 450         penpos5(.8penh,90);
 451         z5=(.5[x10,x4],ypart (pos+.55siz));
 452
 453         penpos6(.8penh,270);
 454         z6=z5;
 455         penpos7(penw,180);
 456         z7l=(xpart(pos+siz),.5[y6,y8]);
 457         penpos8(.8penh,45);
 458         z8=.5[z12l,z11l]+.15vx-.05vy;
 459
 460         penpos10(.75[penh,penw],170);
 461         z10=pos+.375vx+.95vy;
 462         penpos11(.8[penh,penw],150);
 463         z11=z10-.5vy+.04vx;
 464         penpos12(penh,100);
 465         z12l=(xpart .5[z13,z11],ypart pos);
 466         penpos13(.75penh,60);
 467         z13=pos+.1vx+.15vy;
 468
 469         % penlabels (1,2,3,4,5,6,7,8,10,11,12,13);
 470
 471         soft_penstroke (z1e..tension 1.1
 472                 ..z2e
 473                 ..z3e
 474                 ..z4e
 475                 ..z5e{left}
 476                 ) slanted slant shifted (slant*-ypart pos,0);
 477
 478         soft_penstroke (z6e{right}
 479                 ..z7e
 480                 ..z8e{(z8r-z8l) rotated 90}
 481                 ) slanted slant shifted (slant*-ypart pos,0);
 482
 483         soft_penstroke (z10e.. tension 1.5
 484                 ..z11e
 485                 ..z12e..tension 1.1
 486                 ..z13e{(z13r-z13l) rotated 90}
 487                 ) slanted slant shifted (slant*-ypart pos,0);
 488         endgroup;
 489 enddef;
 490
 491 def draw_tab_clef(expr reduction) =
 492         save reduced_il,vx,vy,letterheight,penw,penh;
 493         reduced_il# = staff_space# * reduction;
 494         letterheight# = 1.8*reduced_il#;
 495         define_pixels(reduced_il,letterheight);
 496         set_char_box(-.2*reduced_il#,2.8*reduced_il#,1.6*letterheight#,1.6*letterheight#);
 497
 498                 %draw_staff (-3,2, 0.5);
 499
 500         penw = .45reduced_il;
 501         penh = .2reduced_il;
 502
 503         draw_tab_T((-b+.15reduced_il,h-letterheight),
 504           (2.1*reduced_il,letterheight),0.2);
 505         draw_tab_A((-b-.05reduced_il,-.5letterheight +.15reduced_il),
 506           (2.2*reduced_il,letterheight),0.4);
 507         draw_tab_B((-b+.025reduced_il,-d),
 508           (2.1*reduced_il,letterheight),0.25);
 509 enddef;
 510
 511 fet_beginchar("tab clef", "tab", "tabclef")
 512         draw_tab_clef(1.0);
 513 fet_endchar;
 514
 515 fet_beginchar("tab clef (reduced)", "tab_change", "ctabclef")
 516         draw_tab_clef(.8);
 517 fet_endchar;
 518
 519 fet_endgroup("clefs");