mf/feta-eindelijk.mf

   1 % feta-eindelijk.mf -- implement rest symbols -*-Fundamental-*-
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997--2002 Jan Nieuwenhuizen <janneke@gnu.org>
   8
   9 fet_begingroup("rests");
  10
  11 begingroup
  12
  13 thick#:=1/16designsize;
  14 define_blacker_pixels(thick);
  15
  16 rthin:=1/8*staff_space;
  17 % rthick:=2rthin;
  18 rthick:=2thick+rthin;
  19
  20 def shift_pic (expr pone, ptwo) =
  21   currentpicture:=currentpicture shifted (round(pone),round(ptwo))
  22 enddef;
  23
  24 % stuff for     8th,16th etc rests
  25 %
  26 save stem, ball_crook_stem, ball_crook_balldiam, flare;
  27
  28 % stem#:=1/8*staff_space#;
  29 stem# = 1/5staff_space#;
  30 % flare# = 2/3staff_space#;
  31 flare# = 2/3staff_space# - 1/8stafflinethickness#;
  32
  33 define_pixels(stem,flare);
  34
  35 ball_crook_stem = stem;
  36 ball_crook_balldiam =flare;
  37
  38
  39 save block_rest_y, block_rest_x;
  40
  41 block_rest_y# = 5/8 staff_space#;
  42 block_rest_x# = 3/2 staff_space#;
  43
  44 define_pixels(block_rest_y, block_rest_x);
  45
  46 def block_rest =
  47         draw_block ((0,0), (block_rest_x, block_rest_y));
  48         enddef;
  49
  50 fet_beginchar( "whole rest", "0", "wholerest");
  51         set_char_box(0, block_rest_x#,
  52                 block_rest_y#,  0);
  53         block_rest;
  54         currentpicture := currentpicture shifted (0,- block_rest_y);
  55 fet_endchar;
  56
  57 fet_beginchar("half rest", "1", "halfrest");
  58         set_char_box(0, block_rest_x#, 0, block_rest_y#);
  59         block_rest;
  60 fet_endchar;
  61
  62
  63 %
  64 % should use ledgerline thickness?
  65 %
  66 fet_beginchar( "whole rest (outside staff)", "0o", "outsidewholerest");
  67         set_char_box(0, block_rest_x#,
  68                 block_rest_y#, ledgerlinethickness#/2);
  69         block_rest;
  70         currentpicture := currentpicture shifted (0, - block_rest_y);
  71         pickup pencircle scaled ledgerlinethickness;
  72
  73         y5 = y6 = 0;
  74         lft x5 = - b - block_rest_y;
  75         rt x6 = w + block_rest_y;
  76         draw_gridline(z5,z6,ledgerlinethickness);
  77 fet_endchar;
  78
  79 fet_beginchar("half rest (outside staff)", "1o", "outsidehalfrest");
  80         set_char_box(0, block_rest_x#,
  81                 ledgerlinethickness#/2, block_rest_y#);
  82         block_rest;
  83         pickup pencircle scaled ledgerlinethickness;
  84         y5 = y6 = 0;
  85         lft x5 = - b - block_rest_y ;
  86         rt x6 = w + block_rest_y;
  87         draw_gridline (z5,z6,ledgerlinethickness);
  88 fet_endchar;
  89
  90
  91 save breve_rest_y, breve_rest_x;
  92
  93 breve_rest_y# =  staff_space#;
  94 breve_rest_x# = 3/5 staff_space#;
  95 multi_rest_x# = 4 staff_space#;
  96 multi_beam_height# = 1/3 staff_space#;
  97
  98 define_pixels(breve_rest_y, breve_rest_x, multi_rest_x, multi_beam_height);
  99
 100 fet_beginchar("breve rest", "-1", "breverest");
 101        set_char_box(0, breve_rest_x#, 0, breve_rest_y#);
 102        draw_block ((0,0), (breve_rest_x, breve_rest_y));
 103 fet_endchar;
 104
 105 fet_beginchar("longa rest", "-2", "longarest");
 106        set_char_box(0, breve_rest_x#, breve_rest_y#, breve_rest_y#);
 107        draw_block ((0,-breve_rest_y), (breve_rest_x, breve_rest_y));
 108 fet_endchar;
 109
 110 tracingvariables := 1;
 111
 112 fet_beginchar("multi rest", "-4", "multirest");
 113        set_char_box(multi_rest_x#, multi_rest_x#,
 114                     breve_rest_y#, breve_rest_y#);
 115        draw_block ((- b, - multi_beam_height),
 116                    (w, multi_beam_height));
 117        draw_block ((- b,-breve_rest_y),
 118                    (rthin - b, breve_rest_y));
 119        draw_block ((w - rthin,-breve_rest_y),
 120                    (w, breve_rest_y));
 121 fet_endchar;
 122
 123 fet_beginchar("Quarter rest","2","quartrest");
 124 %       draw_staff (-2, 2, 0.0);
 125         save alpha, yshift, height;
 126         alpha:=-50;
 127         yshift# = -1.25 staff_space#;
 128         height# = 2.8125 staff_space#;
 129         define_pixels (yshift, height);
 130
 131
 132         set_char_box(0, 27/25staff_space#,
 133           -yshift#,
 134           yshift# + height#);
 135
 136         save ne,nw,se,sw; pair ne,nw,se,sw;
 137
 138         se=dir alpha; nw=dir (alpha+180);
 139         ne=dir (alpha+90); sw=dir (alpha-90);
 140         penpos1(rthin,alpha+90);
 141         penpos2(5/4rthick,alpha);
 142         penpos4(5/4rthick,alpha);
 143         penpos5(rthin,alpha+90);
 144         penpos3(3/4rthick,alpha);
 145 %       penpos6(5/8rthick,alpha);
 146         penpos6(2/3rthick,alpha);
 147         penpos7(1/2rthin,alpha+90);
 148
 149         z10=z2l+1/2rthin*sw;
 150 %       z11=z4l+1/2rthin*sw;
 151         z11=z4l+1/2rthin*sw+1/2rthin*se;
 152         z12=z4r+1/2rthin*ne;
 153 %       z13=z2r+1/2rthin*ne;
 154         z13=z2r+1/2rthin*ne+1/2rthin*nw;
 155
 156         y1r = h;
 157         x1l=1/3staff_space;
 158         z2r=z1+staff_space*se;
 159         z3=1/2[z2,z4];
 160         x4=3/8staff_space;
 161         y4= 0;
 162         z5=z4l+1.3staff_space*se;
 163         x6l=x4l;
 164         y6l=y4r;
 165         x7=2/5staff_space;
 166         y7= -d;
 167
 168         fill z1l{se}..{se}z10..z3l..z11{se}..{se}z5l..z5r{nw}..{nw}z12..z3r..z13{nw}..{nw}z1r.. cycle;
 169         fill z5r{nw}..tension1.4..z6l..tension1.4..{se}z7l..z7r{nw}..tension1.4..z6r..tension1.4..{se}z5l..cycle;
 170         penlabels(1,2,3,4,5,6,7);
 171         penlabels(10,11,12,13);
 172
 173 %         3/4 staff_space# + yshift#,
 174 %         18/5staff_space# + yshift#)
 175
 176         fet_endchar;
 177
 178 def rest_crook(expr a, w) =
 179         balled_crook(a, w, ball_crook_balldiam, ball_crook_stem)
 180 enddef;
 181
 182 %
 183 % Notes about 8th rest:
 184 %
 185 % * 8th rest should be no wider than the black note head
 186 %
 187 % * The inside corner of the horizontal portion is usually a little blotted.
 188 %
 189 % * The top of the crook chops off the vertical brush
 190 %
 191 % * The crook widens a little
 192 %
 193 % * The bottom of the brush is slightly flat, as it has to align with
 194 % stafflines if it is inside the staff.
 195 %
 196 % * The top of the brush usually is a little lower than the top of bulb.
 197 %
 198 % * The bulb can vary. Sometimes it is open (like in the clefs). Sometimes
 199 % it is closed, or even a flare.
 200 %
 201
 202 def normalize (expr p) =
 203         (p / length (p))
 204 enddef ;
 205
 206 def draw_eighth_rest =
 207         save width, bulb_diam, thin, thick;
 208         save ycenter, crook_thick, crook_thin;
 209         save crook_dir, lower_brush;
 210         pair crook_dir;
 211
 212
 213         width# := 1.0 staff_space#;
 214         bulb_diam# := 0.64 staff_space#;
 215         thin# := 1.1 stafflinethickness#;
 216         thick# :=  2.2 stafflinethickness#;
 217         crook_thick# := 1.8 stafflinethickness#;
 218         crook_thin := 1.3 stafflinethickness;
 219
 220         lower_brush = 1.5 stafflinethickness;
 221         ycenter := 0.5 staff_space;
 222
 223         define_pixels (width, bulb_diam, thin, thick, crook_thick);
 224         set_char_box (0, width#,
 225                 1.0 staff_space# + 0.5 stafflinethickness#, 0.5 staff_space# + bulb_diam#/2);
 226
 227         penpos1 (thick, 0);
 228         penpos2 (thin, 0);
 229
 230         y1 = ycenter + - 1.5 staff_space ;
 231 %       y9 = y5 -  lower_brush;
 232         y2 = y5 -  lower_brush;
 233
 234         x2r = width;
 235
 236         y3 - y2l = 0.25 staff_space;
 237         x2r - x1 = 0.5 staff_space;
 238
 239         x3 = x1l ;
 240
 241
 242         x4 = 1.02 bulb_diam ;
 243         y4 := ceiling (ycenter - 2 stafflinethickness + crook_thin);
 244
 245         x5 = 0.5 bulb_diam - 0.25 stafflinethickness;
 246         y5 = ycenter +bulb_diam/2;
 247
 248         z9 = z2 + 0.46 stafflinethickness * dir (angle(z2 - z1)- 10);
 249
 250 %       z7 = %(bulb_diam/2,ycenter) + 0.23 staff_space * dir ( 35);
 251         z7 = 0.5 [z4, z5] + (0.45 stafflinethickness,0.4 stafflinethickness);
 252         z8 = (0, ycenter + 0.5 stafflinethickness);
 253
 254         z6 = whatever [z1l, z2l];
 255         z6 = whatever [z2l, z4] + crook_thick * (crook_dir rotated -90);
 256         crook_dir = normalize(z2l - z4);
 257
 258         y3 := ycenter +floor (- bulb_diam/2);
 259
 260
 261         penlabels (1, 2);
 262         labels(3, 4, 5, 6, 7, 8, 9);
 263
 264         fill z2r -- z2l -- simple_serif (z1l, z1r, 40) -- cycle;
 265         fill z2r{z2r-z1r} .. z9 .. z2l{dir(232)} .. tension 2
 266                 .. z4{left} .. tension 0.9 .. z7 %{dir(90 + 25)}
 267                 .. z5{left} .. z8 .. z3{right}
 268                 .. {curl 0.2}z6 -- cycle;
 269
 270
 271         enddef;
 272
 273 fet_beginchar("8th rest","3","eighthrest");
 274         draw_eighth_rest;
 275         fet_endchar;
 276
 277 fet_beginchar("Classical quarter rest","2classical","clasquartrest");
 278         draw_eighth_rest;
 279         currentpicture := currentpicture xscaled -1 shifted (w,0);
 280         fet_endchar;
 281
 282
 283 fet_beginchar("16th rest","4","sixteenthrest");
 284 %       draw_staff (-2, 2, 0.0);
 285         save yshift, ballcorrection;
 286         ballcorrection = 0.005 staff_space;
 287
 288         yshift# := - 2 staff_space#;
 289         define_pixels(yshift);
 290
 291         save alpha,cw,h,w, height;
 292         alpha=74;
 293         cw#=7/6staff_space#;
 294         height# =  5/3staff_space#+staff_space#+7/4stafflinethickness#;
 295         set_char_box(0, cw#+(height#-3/2staff_space#)/tand(alpha),
 296                 -yshift#, height# + yshift#);
 297
 298         define_pixels(cw);
 299         save x,y;
 300         x1=w-stem/6;
 301         y1 = yshift + 2.5 staff_space + flare/4 + ballcorrection;
 302
 303         z2-z1=whatever*dir alpha;
 304         y2= yshift + stem/2;
 305         brush(z1,2/3stem,z2,stem);
 306         rest_crook (z1,cw);
 307         z3-z1=whatever*dir alpha;
 308         y3=y1-staff_space;
 309         rest_crook (z3,cw);
 310         penlabels(1,2);
 311         fet_endchar;
 312
 313 fet_beginchar("32th rest","5","thirtysecondrest");
 314 %       draw_staff (-2, 2, 0.0);
 315         save yshift, ballcorrection;
 316         ballcorrection = 0.005 staff_space;
 317
 318         yshift# := -2 staff_space#;
 319         define_pixels(yshift);
 320
 321         save alpha,cw,h;
 322         alpha=76;
 323         cw#=7/6staff_space#;
 324         h#=5/3staff_space#+2staff_space#+7/4stafflinethickness#;
 325
 326         set_char_box(0, cw#+(h#-3/2staff_space#)/tand(alpha),
 327                 -yshift#,yshift# +h#);
 328         define_pixels(cw);
 329         save x,y;
 330         x1=w-stem/6;
 331         y1 = yshift + 3.5 staff_space + flare/4 + ballcorrection;
 332
 333         z2-z1=whatever*dir alpha;
 334         y2=stem/2 + yshift;
 335         brush(z1,2/3stem,z2,stem);
 336         rest_crook (z1,cw);
 337         z3-z1=whatever*dir alpha;
 338         y3=y1-staff_space;
 339         rest_crook (z3,cw);
 340         z4-z1=whatever*dir alpha;
 341         y4=y1-2staff_space;
 342         rest_crook (z4,cw);
 343         fet_endchar;
 344
 345 fet_beginchar("64th rest","6","sixtyfourthrest");
 346 %       draw_staff (-2, 2, 0.0);
 347         save yshift, ballcorrection;
 348         ballcorrection = 0.005 staff_space;
 349
 350         yshift# := -3 staff_space#;
 351         define_pixels(yshift);
 352
 353         save alpha,cw,h,w;
 354         alpha=78;
 355         cw#=7/6staff_space#;
 356         h#=5/3staff_space#+3staff_space#+7/4stafflinethickness#;
 357         w#=cw#+(h#-3/2staff_space#)/tand(alpha);
 358         set_char_box(0,w#,-yshift# ,yshift# + h#);
 359
 360         define_pixels(cw);
 361         save x,y;
 362         x1=w-stem/6;
 363
 364         y1 = yshift + 4.5 staff_space + flare/4 + ballcorrection;
 365
 366         z2-z1=whatever*dir alpha;
 367         y2=stem/2 + yshift;
 368         brush (z1,2/3stem,z2,stem);
 369         rest_crook (z1,cw);
 370         z3-z1=whatever*dir alpha;
 371         y3=y1-staff_space;
 372         rest_crook (z3,cw);
 373         z4-z1=whatever*dir alpha;
 374         y4=y1-2staff_space;
 375         rest_crook (z4,cw);
 376         z5-z1=whatever*dir alpha;
 377         y5=y1-3staff_space;
 378         rest_crook (z5,cw);
 379
 380         fet_endchar;
 381
 382 fet_beginchar("128th rest","7","hundredtwentyeighthrest");
 383 %       draw_staff (-2, 2, 0.0);
 384         save yshift, ballcorrection;
 385         ballcorrection = 0.005 staff_space;
 386
 387         yshift# := -3 staff_space#;
 388         define_pixels(yshift);
 389         save alpha,cw,h,w;
 390         alpha=78;
 391         cw#=7/6staff_space#;
 392         h#=5/3staff_space#+4staff_space#+7/4stafflinethickness#;
 393         w#=cw#+(h#-3/2staff_space#)/tand(alpha);
 394         set_char_box(0,w#, -yshift#,yshift#  + h#);
 395         define_pixels(cw);
 396         save x,y;
 397         x1=w-stem/6;
 398         y1 = yshift + 5.5 staff_space + flare/4 + ballcorrection;
 399
 400         z2-z1=whatever*dir alpha;
 401         y2=stem/2 + yshift;
 402         brush (z1,2/3stem,z2,stem);
 403         rest_crook (z1,cw);
 404         z3-z1=whatever*dir alpha;
 405         y3=y1-staff_space;
 406         rest_crook (z3,cw);
 407         z4-z1=whatever*dir alpha;
 408         y4=y1-2staff_space;
 409         rest_crook (z4,cw);
 410         z5-z1=whatever*dir alpha;
 411         y5=y1-3staff_space;
 412         rest_crook (z5,cw);
 413         z6-z1=whatever*dir alpha;
 414         y6=y1-4staff_space;
 415         rest_crook (z6,cw);
 416
 417         fet_endchar;
 418
 419
 420 endgroup;
 421
 422
 423 %%%%%%%%
 424 %
 425 %
 426 %
 427 % MENSURAL NOTATION
 428 %
 429 %
 430 %
 431
 432 % Neo-mensural longa and breve are identical with default longa and breve.
 433
 434 neomens_block_rest_x# = 2/5 staff_space#;
 435 neomens_block_rest_y# = 1/1 staff_space#;
 436 neomens_half_block_rest_y# = 5/8 staff_space#;
 437
 438 define_pixels(neomens_block_rest_x,
 439               neomens_block_rest_y, neomens_half_block_rest_y);
 440
 441 def neomens_half_block_rest =
 442         draw_block ((0,0), (neomens_block_rest_x, neomens_half_block_rest_y));
 443         enddef;
 444
 445 fet_beginchar("Neo-mensural maxima rest", "-3neo_mensural", "neomensmaximarest");
 446        set_char_box(0, neomens_block_rest_x#,
 447                     neomens_block_rest_y#, 2 neomens_block_rest_y#);
 448        draw_block ((0,-neomens_block_rest_y),
 449                    (neomens_block_rest_x, 2 neomens_block_rest_y));
 450 fet_endchar;
 451
 452 fet_beginchar("Neo-mensural longa rest", "-2neo_mensural", "neomenslongarest");
 453        set_char_box(0, neomens_block_rest_x#,
 454                     neomens_block_rest_y#, neomens_block_rest_y#);
 455        draw_block ((0,-neomens_block_rest_y),
 456                    (neomens_block_rest_x, neomens_block_rest_y));
 457 fet_endchar;
 458
 459 fet_beginchar("Neo-mensural breve rest", "-1neo_mensural", "neomensbreverest");
 460        set_char_box(0, neomens_block_rest_x#,
 461                     0, neomens_block_rest_y#);
 462        draw_block ((0,0), (neomens_block_rest_x, neomens_block_rest_y));
 463 fet_endchar;
 464
 465 fet_beginchar("Neo-mensural whole rest", "0neo_mensural", "neomenssemibrevisrest");
 466         set_char_box(0, neomens_block_rest_x#,
 467                      neomens_half_block_rest_y#,  0);
 468         neomens_half_block_rest;
 469         currentpicture :=
 470                 currentpicture shifted (0,- neomens_half_block_rest_y);
 471 fet_endchar;
 472
 473 fet_beginchar("Neo-mensural half rest", "1neo_mensural", "neomensminimahalfrest");
 474         set_char_box(0, neomens_block_rest_x#,
 475                      0, neomens_half_block_rest_y#);
 476         neomens_half_block_rest;
 477 fet_endchar;
 478
 479 neomensrestsize# = .8staff_space#;
 480
 481 fet_beginchar("Neo-mensural 4th rest","2neo_mensural","neomenssemiminimarest")
 482         set_char_box(0,neomensrestsize#,0,neomensrestsize#);
 483         pickup pencircle scaled 2 stafflinethickness;
 484         lft x1 = 0;
 485         bot y1 = 0;
 486         lft x2 = 0;
 487         top y2 = h;
 488         rt x3 = w;
 489         bot y3 = h/2;
 490         draw z1 .. z2;
 491         draw z2 .. z3;
 492 fet_endchar
 493
 494 fet_beginchar("Neo-mensural 8th rest","3neo_mensural","neomensfusarest")
 495         set_char_box(0,neomensrestsize#,0,neomensrestsize#);
 496         pickup pencircle scaled 2 stafflinethickness;
 497         rt x1 = w;
 498         bot y1 = 0;
 499         rt x2 = w;
 500         top y2 = h;
 501         lft x3 = 0;
 502         bot y3 = h/2;
 503         draw z1 .. z2;
 504         draw z2 .. z3;
 505 fet_endchar
 506
 507 fet_beginchar("Neo-mensural 16th rest","4neo_mensural","neomenssemifusarest")
 508         set_char_box(0,neomensrestsize#,0,staff_space#);
 509         pickup pencircle scaled 2 stafflinethickness;
 510         rt x1 = w;
 511         bot y1 = 0;
 512         rt x2 = w;
 513         top y2 = h;
 514
 515         draw z1 .. z2;
 516
 517         pickup pencircle scaled 2 stafflinethickness;
 518         rt x3 = w;
 519         top y3 = h;
 520         lft x4 = 0;
 521         bot y4 = h/2;
 522         rt x5 = w;
 523         top y5 = 5/8h;
 524         lft x6 = 0;
 525         bot y6 = h/8;
 526
 527         draw z3 .. z4;
 528         draw z5 .. z6;
 529 fet_endchar
 530
 531
 532 fet_endgroup("rests")