mf/feta-eindelijk.mf

   1 % feta-eindelijk.mf -- implement rest symbols
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997, 1998 Jan Nieuwenhuizen <janneke@gnu.org>
   8
   9 fet_begingroup("rests");
  10
  11 begingroup
  12
  13 thick#:=1/16designsize;
  14 define_blacker_pixels(thick);
  15
  16 rthin:=1/8*interline;
  17 % rthick:=2rthin;
  18 rthick:=2thick+rthin;
  19
  20 def shift_pic (expr pone, ptwo) =
  21   currentpicture:=currentpicture shifted (round(pone),round(ptwo))
  22 enddef;
  23
  24 % stuff for     8th,16th etc rests
  25 %
  26 save stem, ball_crook_stem, ball_crook_balldiam, flare;
  27
  28 % stem#:=1/8*interline#;
  29 stem# = 1/5interline#;
  30 % flare# = 2/3interline#;
  31 flare# = 2/3interline# - 1/8stafflinethickness#;
  32
  33 define_pixels(stem,flare);
  34
  35 ball_crook_stem = stem;
  36 ball_crook_balldiam =flare;
  37
  38
  39 save block_rest_y, block_rest_x;
  40
  41 block_rest_y# = 5/8 interline#;
  42 block_rest_x# = 3/2 interline#;
  43
  44 define_pixels(block_rest_y, block_rest_x);
  45
  46 def block_rest =
  47         draw_block ((0,0), (block_rest_x, block_rest_y));
  48         enddef;
  49
  50 fet_beginchar( "whole rest", "0", "wholerest");
  51         set_char_box(0, block_rest_x#,
  52                 block_rest_y#,  0);
  53         block_rest;
  54         currentpicture := currentpicture shifted (0,- block_rest_y);
  55 fet_endchar;
  56
  57 fet_beginchar("half rest", "1", "halfrest");
  58         set_char_box(0, block_rest_x#, 0, block_rest_y#);
  59         block_rest;
  60 fet_endchar;
  61
  62
  63 %
  64 % should use ledgerline thickness?
  65 %
  66 fet_beginchar( "whole rest (outside staff)", "0o", "outsidewholerest");
  67         set_char_box(block_rest_y#, block_rest_x# + block_rest_y#,
  68                 block_rest_y#, ledgerlinethickness#/2);
  69         block_rest;
  70         currentpicture := currentpicture shifted (0, - block_rest_y);
  71         pickup pencircle scaled ledgerlinethickness;
  72
  73         y5 = y6 = 0;
  74         lft x5 = - b;
  75         rt x6 = w;
  76         draw z5 .. z6;
  77 fet_endchar;
  78
  79 fet_beginchar("half rest (outside staff)", "1o", "outsidehalfrest");
  80         set_char_box(block_rest_y#, block_rest_x#+ block_rest_y#,
  81                 ledgerlinethickness#/2, block_rest_y#);
  82         block_rest;
  83         pickup pencircle scaled ledgerlinethickness;
  84         y5 = y6 = 0;
  85         lft x5 = - b;
  86         rt x6 = w;
  87         draw z5 .. z6;
  88 fet_endchar;
  89
  90
  91 save breve_rest_y, breve_rest_x;
  92
  93 breve_rest_y# =  interline#;
  94 breve_rest_x# = 3/5 interline#;
  95
  96 define_pixels(breve_rest_y, breve_rest_x);
  97
  98 fet_beginchar("breve rest", "-1", "breverest");
  99        set_char_box(0, breve_rest_x#, 0, breve_rest_y#);
 100        draw_block ((0,0), (breve_rest_x, breve_rest_y));
 101 fet_endchar;
 102
 103 fet_beginchar("longa rest", "-2", "longarest");
 104        set_char_box(0, breve_rest_x#, breve_rest_y#, breve_rest_y#);
 105        draw_block ((0,-breve_rest_y), (breve_rest_x, breve_rest_y));
 106 fet_endchar;
 107
 108
 109 fet_beginchar("Quarter rest","2","quartrest");
 110         save alpha;
 111         alpha:=-50;
 112         save ne,nw,se,sw; pair ne,nw,se,sw;
 113         se=dir alpha; nw=dir (alpha+180);
 114         ne=dir (alpha+90); sw=dir (alpha-90);
 115         penpos1(rthin,alpha+90);
 116         penpos2(5/4rthick,alpha);
 117         penpos4(5/4rthick,alpha);
 118         penpos5(rthin,alpha+90);
 119         penpos3(3/4rthick,alpha);
 120 %       penpos6(5/8rthick,alpha);
 121         penpos6(2/3rthick,alpha);
 122         penpos7(1/2rthin,alpha+90);
 123
 124         z10=z2l+1/2rthin*sw;
 125 %       z11=z4l+1/2rthin*sw;
 126         z11=z4l+1/2rthin*sw+1/2rthin*se;
 127         z12=z4r+1/2rthin*ne;
 128 %       z13=z2r+1/2rthin*ne;
 129         z13=z2r+1/2rthin*ne+1/2rthin*nw;
 130
 131         y1l=7/2interline; x1l=1/3interline;
 132         z2r=z1+interline*se;
 133         z3=1/2[z2,z4];
 134         x4=3/8interline; y4=2interline;
 135         z5=z4l+1.3interline*se;
 136         x6l=x4l; y6l=y4r;
 137         x7=2/5interline; y7=3/4interline;
 138         fill z1l{se}..{se}z10..z3l..z11{se}..{se}z5l..z5r{nw}..{nw}z12..z3r..z13{nw}..{nw}z1r.. cycle;
 139         fill z5r{nw}..tension1.4..z6l..tension1.4..{se}z7l..z7r{nw}..tension1.4..z6r..tension1.4..{se}z5l..cycle;
 140         penlabels(1,2,3,4,5,6,7);
 141         penlabels(10,11,12,13);
 142         set_char_box(0, 27/25interline#, -3/4 interline#, 18/5interline#);
 143         fet_endchar;
 144
 145 def rest_crook(expr a, w) =
 146         balled_crook(a, w, ball_crook_balldiam, ball_crook_stem)
 147 enddef;
 148
 149 fet_beginchar("8th rest","3","eighthrest");
 150         set_char_box(0, 4/3interline#,-interline#, 8/3interline#+7/4stafflinethickness#);
 151         save x,y, ht;
 152         ht = h + d;
 153         x1=w-stem/6; y1=ht-flare/4;
 154         rest_crook (z1,w-stem/6);
 155         z2-z1=whatever*dir70;
 156         y2=stem/2;
 157         brush(z1,2/3stem,z2,stem);
 158         % ugh
 159         currentpicture:=currentpicture shifted (0,interline);
 160         fet_endchar;
 161
 162 fet_beginchar("16th rest","4","sixteenthrest");
 163         save alpha,cw,h,w;
 164         alpha=74;
 165         cw#=7/6interline#;
 166 %       h#=5/3interline#+interline#+2stafflinethickness#;
 167         h#=5/3interline#+interline#+7/4stafflinethickness#;
 168         w#=cw#+(h#-3/2interline#)/tand(alpha);
 169         set_char_box(0,w#,0,h#);
 170         define_pixels(cw);
 171         save x,y;
 172         x1=w-stem/6; y1=h-flare/4;
 173         z2-z1=whatever*dir alpha;
 174         y2=stem/2;
 175         brush(z1,2/3stem,z2,stem);
 176         rest_crook (z1,cw);
 177         z3-z1=whatever*dir alpha;
 178         y3=y1-interline;
 179         rest_crook (z3,cw);
 180         penlabels(1,2);
 181         fet_endchar;
 182
 183 fet_beginchar("32th rest","5","thirtysecondrest");
 184         save alpha,cw,h,w;
 185         alpha=76;
 186         cw#=7/6interline#;
 187         h#=5/3interline#+2interline#+7/4stafflinethickness#;
 188         w#=cw#+(h#-3/2interline#)/tand(alpha);
 189         set_char_box(0,w#,0,h#);
 190         define_pixels(cw);
 191         save x,y;
 192         x1=w-stem/6; y1=h-flare/4;
 193         z2-z1=whatever*dir alpha;
 194         y2=stem/2;
 195         brush(z1,2/3stem,z2,stem);
 196         rest_crook (z1,cw);
 197         z3-z1=whatever*dir alpha;
 198         y3=y1-interline;
 199         rest_crook (z3,cw);
 200         z4-z1=whatever*dir alpha;
 201         y4=y1-2interline;
 202         rest_crook (z4,cw);
 203         fet_endchar;
 204
 205 fet_beginchar("64th rest","6","sixtyfourthrest");
 206         save alpha,cw,h,w;
 207         alpha=78;
 208         cw#=7/6interline#;
 209         h#=5/3interline#+3interline#+7/4stafflinethickness#;
 210         w#=cw#+(h#-3/2interline#)/tand(alpha);
 211         set_char_box(0,w#,0,h#);
 212         define_pixels(cw);
 213         save x,y;
 214         x1=w-stem/6; y1=h-flare/4;
 215         z2-z1=whatever*dir alpha;
 216         y2=stem/2;
 217         brush (z1,2/3stem,z2,stem);
 218         rest_crook (z1,cw);
 219         z3-z1=whatever*dir alpha;
 220         y3=y1-interline;
 221         rest_crook (z3,cw);
 222         z4-z1=whatever*dir alpha;
 223         y4=y1-2interline;
 224         rest_crook (z4,cw);
 225         z5-z1=whatever*dir alpha;
 226         y5=y1-3interline;
 227         rest_crook (z5,cw);
 228         % ugh
 229         currentpicture:=currentpicture shifted (0,-interline);
 230         fet_endchar;
 231
 232 fet_beginchar("128th rest","7","hundredtwentyeighthrest");
 233         save alpha,cw,h,w;
 234         alpha=78;
 235         cw#=7/6interline#;
 236         h#=5/3interline#+4interline#+7/4stafflinethickness#;
 237         w#=cw#+(h#-3/2interline#)/tand(alpha);
 238         set_char_box(0,w#,0,h#);
 239         define_pixels(cw);
 240         save x,y;
 241         x1=w-stem/6; y1=h-flare/4;
 242         z2-z1=whatever*dir alpha;
 243         y2=stem/2;
 244         brush (z1,2/3stem,z2,stem);
 245         rest_crook (z1,cw);
 246         z3-z1=whatever*dir alpha;
 247         y3=y1-interline;
 248         rest_crook (z3,cw);
 249         z4-z1=whatever*dir alpha;
 250         y4=y1-2interline;
 251         rest_crook (z4,cw);
 252         z5-z1=whatever*dir alpha;
 253         y5=y1-3interline;
 254         rest_crook (z5,cw);
 255         z6-z1=whatever*dir alpha;
 256         y6=y1-4interline;
 257         rest_crook (z6,cw);
 258         % ugh
 259         currentpicture:=currentpicture shifted (0,-interline);
 260         fet_endchar;
 261
 262 endgroup;
 263 fet_endgroup("rests");
 264