mf/feta-bolletjes.mf

   1 %  -*-Fundamental-*-
   2 % feta-bolletjes.mf --  implement noteheads
   3 %
   4 % source file of LilyPond's pretty-but-neat music font
   5 %
   6 % (c)  1997--2003 Jan Nieuwenhuizen <janneke@gnu.org>
   7 % & Han-Wen Nienhuys <hanwen@cs.uu.nl>
   8 % & Juergen Reuter <reuter@ipd.uka.de>
   9 %
  10
  11 test_outlines := 0;
  12
  13
  14 % most beautiful noteheads are pronounced, not circular,
  15 % and not even symmetric.
  16 % These examples are inspired by [Wanske], see literature list
  17
  18
  19
  20 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  21 % NOTE HEAD VARIABLES
  22 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  23 save black_notehead_width, noteheight,
  24         slash_thick, slash_slope, overdone_heads;
  25 numeric black_notehead_width, noteheight, slash_thick;
  26
  27 fet_begingroup("noteheads");
  28
  29
  30
  31 % slope of slash. From scm/grob-description.scm. How to auto-copy?
  32 slash_slope := 1.7;
  33
  34 % thickness of slash lines. quarter notes get 1.5slt width.
  35 slash_thick# := 2/3*0.48staff_space#;
  36
  37
  38 %
  39 % Hand-engraved music often has balls extending above and below
  40 % the lines.  If you like that, modify overdone heads (unit:
  41 % stafflinethickness)
  42 %
  43 overdone_heads = 0.0;
  44 noteheight#:=staff_space#+ (1 + overdone_heads) *stafflinethickness#;
  45
  46 define_pixels(slash_thick, noteheight);
  47
  48
  49 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  50 %
  51 % SLANT moves both extremes on the long axis (by SLANT * ELLIPSIDITY,
  52 % so SLANT = -1, puts the extreme on the long axis next to the short axis one.)
  53 %
  54
  55 def draw_outside_ellipse (expr ellipsidity, tilt, superness,
  56                         slant) =
  57         save attachment_y;
  58         save p;
  59         path p;
  60
  61         p := superellipse ((ellipsidity, 0), (-slant * ellipsidity, 1.0),
  62                         (- ellipsidity, 0), (slant * ellipsidity, -1.0), superness);
  63
  64         p := p rotated tilt;
  65
  66         save top_point, right_point;
  67         pair top_point, right_point;
  68
  69         top_point := directionpoint left of p;
  70         right_point := directionpoint up of p;
  71
  72         save scaling, width, height;
  73
  74         scaling# = noteheight# /(2 ypart (top_point));
  75         width# := 2 xpart (right_point) * scaling#;
  76
  77         define_pixels (width, scaling);
  78
  79         set_char_box (0, width#, noteheight#/2, noteheight#/2);
  80
  81         % attachment Y
  82         charwy := ypart (right_point) * scaling#;
  83         charwx := width# ;
  84
  85         p := p scaled scaling shifted (width/2, 0) ;
  86         if test_outlines = 1:
  87                 pickup pencircle scaled 1 ; draw p;
  88         else:
  89                 fill p;
  90         fi;
  91 enddef;
  92
  93
  94 def undraw_inside_ellipse (expr ellipsidity, tilt, superness, clearance,
  95                         center) =
  96 begingroup
  97         save p;
  98         path p;
  99
 100         p := superellipse ((ellipsidity, 0), (0, 1.0),
 101                         (- ellipsidity, 0), (0, -1.0), superness);
 102
 103         p := p rotated tilt;
 104
 105         save top_point, right_point;
 106         pair top_point, right_point;
 107
 108         top_point := directionpoint left of p;
 109         right_point := directionpoint up of p;
 110
 111         save height, scaling;
 112
 113         height# = staff_space# + stafflinethickness# - clearance;
 114         scaling# = height# /(2 ypart (top_point));
 115
 116         define_pixels (scaling);
 117         p := (p scaled scaling) shifted center;
 118
 119         if test_outlines = 1:
 120                 pickup pencircle scaled 1; draw p;
 121         else:
 122                 unfill p;
 123         fi
 124 endgroup;
 125 enddef;
 126
 127
 128
 129
 130
 131 %
 132 % dimensions aren't entirely right.
 133 %
 134 fet_beginchar ("Brevis notehead", "-1", "brevishead");
 135         save stemthick, fudge;
 136         define_pixels (stemthick);
 137         fudge = blot_diameter /2;
 138         stemthick# = 2 stafflinethickness#;
 139
 140         draw_outside_ellipse (1.80, 0, 0.707, 0);
 141         undraw_inside_ellipse (1.30, 125, 0.68, 2 stafflinethickness#,
 142                                 (w /2, 0));
 143
 144         pickup pencircle scaled stemthick;
 145
 146         bot y1 = -d;
 147         top y2 = h;
 148         rt x1 - fudge = 0;
 149         x1 = x2;
 150
 151         fudge + lft x3 = w;
 152         x4 = x3;
 153         y4 = y2;
 154         y3 = y1;
 155
 156         draw_gridline(z1,z2,stemthick);
 157         draw_gridline(z3,z4,stemthick);
 158
 159 fet_endchar;
 160
 161
 162
 163 fet_beginchar("Whole notehead", "0", "wholehead")
 164         draw_outside_ellipse (1.80 - puff_up_factor / 3.0, 0, 0.707, 0);
 165         undraw_inside_ellipse (1.30, 125 - puff_up_factor *10,
 166                         0.68, 2 stafflinethickness#,
 167                         (w /2, 0));
 168
 169 %       draw_staff_outline (-2, 2, 0.5);
 170
 171 fet_endchar;
 172
 173
 174 fet_beginchar("Half notehead", "1", "halfhead")
 175         draw_outside_ellipse (1.53 - puff_up_factor / 3.0, 34, 0.66, 0.17);
 176         undraw_inside_ellipse (3.25, 33, 0.81,
 177                 2.5 stafflinethickness#, (w/2, 0));
 178
 179 fet_endchar;
 180
 181 fet_beginchar("Quart notehead", "2", "quarthead")
 182         draw_outside_ellipse (1.54 - puff_up_factor / 2.0, 32, 0.707, 0);
 183         black_notehead_width# := charwd;
 184 fet_endchar;
 185
 186 fet_beginchar("Quart notehead", "2AA", "quarthead")
 187         draw_outside_ellipse (1.6 - puff_up_factor / 2.0, 32, 0.707, 0);
 188         black_notehead_width# := charwd;
 189 fet_endchar;
 190 fet_beginchar("Quart notehead", "2AB", "quarthead")
 191         draw_outside_ellipse (1.65 - puff_up_factor / 2.0, 32, 0.707, 0);
 192         black_notehead_width# := charwd;
 193 fet_endchar;
 194 fet_beginchar("Quart notehead", "2AC", "quarthead")
 195         draw_outside_ellipse (1.7 - puff_up_factor / 2.0, 32, 0.707, 0);
 196         black_notehead_width# := charwd;
 197 fet_endchar;
 198 fet_beginchar("Quart notehead", "2AD", "quarthead")
 199         draw_outside_ellipse (1.75 - puff_up_factor / 2.0, 32, 0.707, 0);
 200         black_notehead_width# := charwd;
 201 fet_endchar;
 202 fet_beginchar("Quart notehead", "2BA", "quarthead")
 203         draw_outside_ellipse (1.6 - puff_up_factor / 2.0, 35, 0.707, 0);
 204         black_notehead_width# := charwd;
 205 fet_endchar;
 206 fet_beginchar("Quart notehead", "2BB", "quarthead")
 207         draw_outside_ellipse (1.65 - puff_up_factor / 2.0, 35, 0.707, 0);
 208         black_notehead_width# := charwd;
 209 fet_endchar;
 210 fet_beginchar("Quart notehead", "2BC", "quarthead")
 211         draw_outside_ellipse (1.7 - puff_up_factor / 2.0, 35, 0.707, 0);
 212         black_notehead_width# := charwd;
 213 fet_endchar;
 214 fet_beginchar("Quart notehead", "2BD", "quarthead")
 215         draw_outside_ellipse (1.75 - puff_up_factor / 2.0, 35, 0.707, 0);
 216         black_notehead_width# := charwd;
 217 fet_endchar;
 218 fet_beginchar("Quart notehead", "2CA", "quarthead")
 219         draw_outside_ellipse (1.6 - puff_up_factor / 2.0, 38, 0.707, 0);
 220         black_notehead_width# := charwd;
 221 fet_endchar;
 222 fet_beginchar("Quart notehead", "2CB", "quarthead")
 223         draw_outside_ellipse (1.65 - puff_up_factor / 2.0, 38, 0.707, 0);
 224         black_notehead_width# := charwd;
 225 fet_endchar;
 226 fet_beginchar("Quart notehead", "2CC", "quarthead")
 227         draw_outside_ellipse (1.7 - puff_up_factor / 2.0, 38, 0.707, 0);
 228         black_notehead_width# := charwd;
 229 fet_endchar;
 230 fet_beginchar("Quart notehead", "2CD", "quarthead")
 231         draw_outside_ellipse (1.75 - puff_up_factor / 2.0, 38, 0.707, 0);
 232         black_notehead_width# := charwd;
 233 fet_endchar;
 234
 235 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 236
 237
 238 fet_beginchar("Whole diamondhead", "0diamond", "wholediamondhead")
 239         draw_outside_ellipse (1.80, 0, 0.495, 0);
 240         undraw_inside_ellipse (1.30, 125, 0.6,
 241                         .4 staff_space# +  stafflinethickness#,
 242                                 (w /2, 0));
 243
 244 fet_endchar;
 245
 246 fet_beginchar("Half diamondhead", "1diamond",
 247         "halfdiamondhead")
 248
 249         draw_outside_ellipse (1.50, 34, 0.49, 0.17);
 250         undraw_inside_ellipse (3.5, 33, 0.80,
 251                 .3 staff_space# + 1.5 stafflinethickness#, (w/2, 0));
 252
 253 fet_endchar;
 254
 255 fet_beginchar("Quart diamondheadh", "2diamondh", "diamondheadh")
 256         draw_outside_ellipse (1.80, 35, 0.495, -0.25);
 257 fet_endchar;
 258
 259 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 260
 261
 262
 263
 264
 265 def def_triangle =
 266         save triangle,kern; path triangle;
 267         save left_point, height, width;
 268         pair exact_left_point;
 269         save pen_thick;
 270         pen_thick# = stafflinethickness#  + .1 staff_space#;
 271         define_pixels(pen_thick);
 272
 273         exact_left_point := llap# * dir (90 + tilt);
 274         height# = max (ypart exact_left_point,
 275                         -ypart  (exact_left_point rotated 120)) + pen_thick#/2;
 276
 277         kern# = 1/3 xpart (exact_left_point - (exact_left_point rotated 120));
 278         width# = xpart (-exact_left_point + (exact_left_point rotated 240));
 279         define_pixels (kern);
 280         z1 = (hround_pixels (xpart exact_left_point), vround_pixels  (ypart exact_left_point));
 281         z2 = z1 rotated 120;
 282         z3 = z1 rotated 240;
 283
 284         z12 = caveness[.5[z1,z2],z3];
 285         z23 = z12 rotated 120;
 286         z31 = z12 rotated 240;
 287         triangle = z1 .. z12 .. z2 ..
 288                     z2 .. z23 .. z3 ..
 289                     z3 .. z31 .. z1 ..
 290                     cycle;
 291         triangle := triangle shifted (-x1+pen_thick/2-kern,0) xscaled xs;
 292         pickup pencircle scaled pen_thick xscaled xs;
 293 %       labels(1,2,12,23,31,3);
 294         set_char_box(0, width# - kern#+ pen_thick#, height#, height#);
 295 enddef;
 296
 297 fet_beginchar("Whole trianglehead", "0triangle", "wholetrianglehead")
 298         save hei,xs;
 299         save llap;
 300         save tilt;
 301
 302         tilt = 40;
 303         llap# = 3/4noteheight#;
 304
 305         xs = 1.5;
 306         caveness:=0.1;
 307         def_triangle;
 308         draw triangle;
 309 fet_endchar;
 310
 311 fet_beginchar("Half trianglehead", "1triangle", "halftrianglehead")
 312         save hei,xs;
 313         save llap;
 314         save tilt;
 315
 316         tilt = 40;
 317         llap# = 2/3noteheight#;
 318         xs = 1.2;
 319         caveness:=0.1;
 320         def_triangle;
 321         draw triangle;
 322 fet_endchar;
 323
 324 fet_beginchar("Quart trianglehead", "2triangle", "trianglehead")
 325         save hei,xs;
 326         save llap;
 327         save tilt;
 328         tilt = 40;
 329         llap# = 2/3noteheight#;
 330         xs = 1.0;
 331         caveness:=0.1;
 332         def_triangle;
 333         filldraw triangle;
 334 fet_endchar;
 335
 336 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 337 %
 338 % slash heads are for indicating improvisation. They are
 339 % twice as high as normal heads.
 340 %
 341 def draw_slash(expr hwid_hash) =
 342         save exact_height;
 343         save ne_dir;
 344         pair ne_dir;
 345         exact_height =  staff_space# + stafflinethickness#/2;
 346
 347         set_char_box (0, 2 exact_height / slash_slope + hwid_hash,
 348                         exact_height, exact_height);
 349
 350         charwx := charwd;
 351         charwy := charht;
 352
 353         clearxy;
 354         pickup pencircle scaled blot_diameter;
 355
 356         bot y1 = - d;
 357         top y2 = h;
 358         lft x1 = 0;
 359         lft x2 = 2 h / slash_slope;
 360
 361         rt x3 = w;
 362         y3 = y2;
 363         y4 = y1;
 364         x3- x2 = x4 - x1;
 365
 366         ne_dir := unitvector( z3  - z4);
 367         filldraw z1 --- z2 --- z3 --- z4 --- cycle;
 368
 369         if hwid_hash > 2 slash_thick#:
 370                 save th;
 371
 372                 th = slash_thick - blot_diameter;
 373                 y6 = y7;
 374                 y5 = y8;
 375                 y3 - y7 = th;
 376                 y5 - y1 = th;
 377                 z6 - z5 = whatever * ne_dir;
 378                 z8 - z7 = whatever * ne_dir;
 379
 380                 z5  = z1 + whatever * ne_dir + th * (ne_dir rotated -90);
 381                 z8  = z4 + whatever * ne_dir + th * (ne_dir rotated 90);
 382
 383                 unfill
 384                         z5 -- z6 -- z7 -- z8 -- cycle;
 385         fi
 386         labels (range 1 thru 10);
 387 enddef;
 388
 389 fet_beginchar("Whole slashhead","0slash","wholeslashhead")
 390         draw_slash(4 slash_thick# + 0.5 staff_space#);
 391 fet_endchar;
 392
 393 fet_beginchar("Half slashhead","1slash","halfslashhead")
 394         draw_slash(3.0 slash_thick# + 0.15 staff_space#);
 395 fet_endchar;
 396
 397 fet_beginchar("Quart slashhead","2slash","quartslashhead")
 398         draw_slash(1.5 slash_thick#);
 399 fet_endchar;
 400
 401 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 402 % thick is the distance between the NE/SW parallel lines in the cross
 403 % (distance between centres of lines)
 404 % in stafflinethickness def
 405 %
 406 def draw_cross(expr thick) =
 407         save pent, slant, ne_dir;
 408         pair ne_dir;
 409         save crz; path crz;
 410
 411         pen_thick# := 1.2stafflinethickness#;
 412         define_pixels (pen_thick);
 413         pickup pencircle scaled pen_thick;
 414
 415         top y3 = h;
 416         ne_dir := unitvector ((1, (2 h -pen_thick)/(w - pen_thick)));
 417         rt x4 = w/2;
 418         y5 = 0;
 419         z4 - z5 = whatever * ne_dir;
 420         x6 = 0;
 421         z6 - z3 = whatever * ne_dir;
 422         z3 - z4 = whatever * (ne_dir yscaled -1);
 423
 424         z4 - z3 = whatever * (ne_dir) + (ne_dir rotated -90) * thick * stafflinethickness;
 425
 426         x1 = charwd/2 - .5 pen_thick#;
 427         z1 = whatever * ne_dir + thick/2 * stafflinethickness# * (ne_dir rotated -90);
 428
 429
 430         labels (1,2,3,4,5,6);
 431
 432         crz = (z6 -- z3 -- z4 -- z5) ;
 433
 434         draw crz shifted(w/2,0);
 435         draw crz xscaled -1 shifted(w/2,0);
 436         draw crz yscaled -1 shifted(w/2,0);
 437         draw crz scaled -1 shifted(w/2,0);
 438
 439         charwx := charwd;
 440         charwy := y1;
 441                 message (decimal charwx);
 442                 message (decimal charwy);
 443         z12 = (charwx * hppp, y1 * vppp);
 444         labels (12);
 445 enddef;
 446
 447 fet_beginchar("Whole Crossed notehead", "0cross", "wholecrossedhead")
 448         wid# := black_notehead_width#+4stafflinethickness#;
 449         hei# := noteheight#+stafflinethickness#;
 450         set_char_box(0, wid#,hei#/2,hei#/2);
 451
 452         draw_cross (3.75);
 453 fet_endchar;
 454
 455 fet_beginchar("Half Crossed notehead", "1cross", "halfcrossedhead")
 456         wid# := black_notehead_width#+2stafflinethickness#;
 457         hei# := noteheight#+stafflinethickness#/2;
 458         set_char_box(0, wid#,hei#/2,hei#/2);
 459         draw_cross(3.0);
 460 fet_endchar;
 461
 462 fet_beginchar("Crossed notehead", "2cross", "crossedhead")
 463         wid# := black_notehead_width#;
 464         hei# := noteheight#;
 465         set_char_box(0, wid#,hei#/2,hei#/2);
 466         draw_cross(1.0);
 467 fet_endchar;
 468
 469 fet_beginchar("X-Circled notehead", "2xcircle", "xcircledhead")
 470         wid# := black_notehead_width#*sqrt(sqrt2);
 471         hei# := noteheight#*sqrt(sqrt2);
 472         set_char_box(0, wid#,hei#/2,hei#/2);
 473         cthick := (1.2+1/4)*stafflinethickness;
 474         cxr := w/2-cthick/2;
 475         cyr := h-cthick/2;
 476         pickup pencircle scaled cthick;
 477         draw fullcircle xscaled 2cxr yscaled 2cyr shifted (w/2,0);
 478         xpos := cxr/sqrt2;
 479         ypos := cyr/sqrt2;
 480         draw (-xpos+w/2,-ypos) -- (xpos+w/2,ypos);
 481         draw (-xpos+w/2,ypos) -- (xpos+w/2,-ypos);
 482
 483         charwx := charwd ;
 484         charwy := 0 ;
 485
 486         z12 = (charwx * hppp , charwy * vppp );
 487         labels (12);
 488 fet_endchar;
 489
 490
 491
 492 fet_endgroup("noteheads");
 493
 494 define_pixels(black_notehead_width);