mf/feta-bolletjes.mf

   1 %  -*-Fundamental-*-
   2 % feta-bolletjes.mf --  implement noteheads
   3 %
   4 % source file of LilyPond's pretty-but-neat music font
   5 %
   6 % (c) 1997--2004 Jan Nieuwenhuizen <janneke@gnu.org>
   7 % & Han-Wen Nienhuys <hanwen@cs.uu.nl>
   8 % & Juergen Reuter <reuter@ipd.uka.de>
   9 %
  10
  11 test_outlines := 0;
  12
  13
  14 % most beautiful noteheads are pronounced, not circular,
  15 % and not even symmetric.
  16 % These examples are inspired by [Wanske], see literature list
  17
  18
  19
  20 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  21 % NOTE HEAD VARIABLES
  22 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  23 save black_notehead_width, noteheight,
  24         slash_thick, slash_slope, overdone_heads;
  25 numeric black_notehead_width, noteheight, slash_thick;
  26
  27 fet_begingroup("noteheads");
  28
  29
  30
  31 % slope of slash. From scm/grob-description.scm. How to auto-copy?
  32 slash_slope := 1.7;
  33
  34 % thickness of slash lines. quarter notes get 1.5slt width.
  35 slash_thick# := 2/3*0.48staff_space#;
  36
  37
  38 %
  39 % Hand-engraved music often has balls extending above and below
  40 % the lines.  If you like that, modify overdone heads (unit:
  41 % stafflinethickness)
  42 %
  43 overdone_heads = 0.0;
  44 noteheight#:=staff_space#+ (1 + overdone_heads) *stafflinethickness#;
  45
  46 define_pixels(slash_thick, noteheight);
  47
  48
  49 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  50 %
  51 % SLANT moves both extremes on the long axis (by SLANT * ELLIPSIDITY,
  52 % so SLANT = -1, puts the extreme on the long axis next to the short axis one.)
  53 %
  54
  55 def draw_outside_ellipse (expr ellipsidity, tilt, superness,
  56                         slant) =
  57         save attachment_y;
  58         save p;
  59         path p;
  60
  61         p := superellipse ((ellipsidity, 0), (-slant * ellipsidity, 1.0),
  62                         (- ellipsidity, 0), (slant * ellipsidity, -1.0), superness);
  63
  64         p := p rotated tilt;
  65
  66         save top_point, right_point;
  67         pair top_point, right_point;
  68
  69         top_point := directionpoint left of p;
  70         right_point := directionpoint up of p;
  71
  72         save scaling, width, height;
  73
  74         scaling# = noteheight# /(2 ypart (top_point));
  75         width# := 2 xpart (right_point) * scaling#;
  76
  77         define_pixels (width, scaling);
  78
  79         set_char_box (0, width#, noteheight#/2, noteheight#/2);
  80
  81         % attachment Y
  82         charwy := ypart (right_point) * scaling#;
  83         charwx := width# ;
  84
  85         p := p scaled scaling shifted (width/2, 0) ;
  86         if test_outlines = 1:
  87                 pickup pencircle scaled 1 ; draw p;
  88         else:
  89                 fill p;
  90         fi;
  91 enddef;
  92
  93
  94 def undraw_inside_ellipse (expr ellipsidity, tilt, superness, clearance,
  95                         center) =
  96 begingroup
  97         save p;
  98         path p;
  99
 100         p := superellipse ((ellipsidity, 0), (0, 1.0),
 101                         (- ellipsidity, 0), (0, -1.0), superness);
 102
 103         p := p rotated tilt;
 104
 105         save top_point, right_point;
 106         pair top_point, right_point;
 107
 108         top_point := directionpoint left of p;
 109         right_point := directionpoint up of p;
 110
 111         save height, scaling;
 112
 113         height# = staff_space# + stafflinethickness# - clearance;
 114         scaling# = height# /(2 ypart (top_point));
 115
 116         define_pixels (scaling);
 117         p := (p scaled scaling) shifted center;
 118
 119         if test_outlines = 1:
 120                 pickup pencircle scaled 1; draw p;
 121         else:
 122                 unfill p;
 123         fi
 124 endgroup;
 125 enddef;
 126
 127
 128
 129
 130
 131 %
 132 % dimensions aren't entirely right.
 133 %
 134 fet_beginchar ("Brevis notehead", "-1", "brevishead");
 135         save stemthick, fudge;
 136         define_pixels (stemthick);
 137         fudge = blot_diameter /2;
 138         stemthick# = 2 stafflinethickness#;
 139
 140         draw_outside_ellipse (1.80, 0, 0.707, 0);
 141         undraw_inside_ellipse (1.30, 125, 0.68, 2 stafflinethickness#,
 142                                 (w /2, 0));
 143
 144         pickup pencircle scaled stemthick;
 145
 146         bot y1 = -d;
 147         top y2 = h;
 148         rt x1 - fudge = 0;
 149         x1 = x2;
 150
 151         fudge + lft x3 = w;
 152         x4 = x3;
 153         y4 = y2;
 154         y3 = y1;
 155
 156         draw_gridline(z1,z2,stemthick);
 157         draw_gridline(z3,z4,stemthick);
 158
 159 fet_endchar;
 160
 161
 162
 163 fet_beginchar("Whole notehead", "0", "wholehead")
 164         draw_outside_ellipse (1.80 - puff_up_factor / 3.0, 0, 0.707, 0);
 165         undraw_inside_ellipse (1.30, 125 - puff_up_factor *10,
 166                         0.68, 2 stafflinethickness#,
 167                         (w /2, 0));
 168
 169 %       draw_staff_outline (-2, 2, 0.5);
 170
 171 fet_endchar;
 172
 173
 174 fet_beginchar("Half notehead", "1", "halfhead")
 175         draw_outside_ellipse (1.53 - puff_up_factor / 3.0, 34, 0.66, 0.17);
 176         undraw_inside_ellipse (3.25, 33, 0.81,
 177                 2.5 stafflinethickness#, (w/2, 0));
 178
 179 fet_endchar;
 180
 181 fet_beginchar("Quart notehead", "2", "quarthead")
 182
 183         % used to have 32. With 31, they are slightly bolder.
 184         draw_outside_ellipse (1.49 - puff_up_factor / 3.0, 31, 0.707, 0);
 185         black_notehead_width# := charwd;
 186 fet_endchar;
 187
 188 %%%%%%%%%%%%%%%%
 189
 190 %% testing shapes.
 191
 192 if 0 = 1 :
 193
 194
 195 fet_beginchar("Quart noteheadPQ", "2PQ", "quartheadPQ")
 196         draw_outside_ellipse (1.0 - puff_up_factor / 2.0, 32, 0.707, 0);
 197 fet_endchar;
 198
 199 fet_beginchar("Quart noteheadAA", "2AA", "quartheadAA")
 200         draw_outside_ellipse (1.35 - puff_up_factor / 2.0, 32, 0.707, 0);
 201 fet_endchar;
 202
 203 fet_beginchar("Quart noteheadAB", "2AB", "quartheadAB")
 204         draw_outside_ellipse (1.4 - puff_up_factor / 2.0, 32, 0.707, 0);
 205
 206 fet_endchar;
 207 fet_beginchar("Quart noteheadAC", "2AC", "quartheadAC")
 208         draw_outside_ellipse (1.45 - puff_up_factor / 2.0, 32, 0.707, 0);
 209 fet_endchar;
 210
 211 fet_beginchar("Quart noteheadAD", "2AD", "quartheadAD")
 212         draw_outside_ellipse (1.5 - puff_up_factor / 2.0, 32, 0.707, 0);
 213 fet_endchar;
 214
 215 fet_beginchar("Quart noteheadAD", "2AE", "quartheadAD")
 216         draw_outside_ellipse (1.55 - puff_up_factor / 2.0, 32, 0.707, 0);
 217 fet_endchar;
 218
 219 fet_beginchar("Quart noteheadAD", "2AF", "quartheadAD")
 220         draw_outside_ellipse (1.6 - puff_up_factor / 2.0, 32, 0.707, 0);
 221 fet_endchar;
 222 fet_beginchar("Quart noteheadAD", "2AG", "quartheadAD")
 223         draw_outside_ellipse (1.65 - puff_up_factor / 2.0, 32, 0.707, 0);
 224 fet_endchar;
 225
 226
 227 fet_beginchar("Quart noteheadBA", "2BA", "quartheadBA")
 228         draw_outside_ellipse (1.35 - puff_up_factor / 2.0, 35, 0.707, 0);
 229 fet_endchar;
 230 fet_beginchar("Quart noteheadBB", "2BB", "quartheadBB")
 231         draw_outside_ellipse (1.4 - puff_up_factor / 2.0, 35, 0.707, 0);
 232
 233 fet_endchar;
 234 fet_beginchar("Quart noteheadBC", "2BC", "quartheadBC")
 235         draw_outside_ellipse (1.45 - puff_up_factor / 2.0, 35, 0.707, 0);
 236 fet_endchar;
 237 fet_beginchar("Quart noteheadBD", "2BD", "quartheadBD")
 238         draw_outside_ellipse (1.5 - puff_up_factor / 2.0, 35, 0.707, 0);
 239 fet_endchar;
 240 fet_beginchar("Quart noteheadBD", "2BE", "quartheadBD")
 241         draw_outside_ellipse (1.55 - puff_up_factor / 2.0, 35, 0.707, 0);
 242 fet_endchar;
 243 fet_beginchar("Quart noteheadBD", "2BF", "quartheadBD")
 244         draw_outside_ellipse (1.6 - puff_up_factor / 2.0, 35, 0.707, 0);
 245 fet_endchar;
 246 fet_beginchar("Quart noteheadBD", "2BG", "quartheadBD")
 247         draw_outside_ellipse (1.65 - puff_up_factor / 2.0, 35, 0.707, 0);
 248 fet_endchar;
 249
 250
 251
 252 fet_beginchar("Quart noteheadCA", "2CA", "quartheadCA")
 253         draw_outside_ellipse (1.35 - puff_up_factor / 2.0, 40, 0.707, 0);
 254 fet_endchar;
 255 fet_beginchar("Quart noteheadCB", "2CB", "quartheadCB")
 256         draw_outside_ellipse (1.4 - puff_up_factor / 2.0, 40, 0.707, 0);
 257 fet_endchar;
 258 fet_beginchar("Quart noteheadCC", "2CC", "quartheadCC")
 259         draw_outside_ellipse (1.45 - puff_up_factor / 2.0, 40, 0.707, 0);
 260 fet_endchar;
 261 fet_beginchar("Quart noteheadCD", "2CD", "quartheadCD")
 262         draw_outside_ellipse (1.5 - puff_up_factor / 2.0, 40, 0.707, 0);
 263 fet_endchar;
 264 fet_beginchar("Quart noteheadCD", "2CE", "quartheadCD")
 265         draw_outside_ellipse (1.55 - puff_up_factor / 2.0, 40, 0.707, 0);
 266 fet_endchar;
 267 fet_beginchar("Quart noteheadCD", "2CF", "quartheadCD")
 268         draw_outside_ellipse (1.6 - puff_up_factor / 2.0, 40, 0.707, 0);
 269 fet_endchar;
 270 fet_beginchar("Quart noteheadCD", "2CG", "quartheadCD")
 271         draw_outside_ellipse (1.65 - puff_up_factor / 2.0, 40, 0.707, 0);
 272 fet_endchar;
 273
 274 fi
 275
 276 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 277
 278
 279 fet_beginchar("Whole diamondhead", "0diamond", "wholediamondhead")
 280         draw_outside_ellipse (1.80, 0, 0.495, 0);
 281         undraw_inside_ellipse (1.30, 125, 0.6,
 282                         .4 staff_space# +  stafflinethickness#,
 283                                 (w /2, 0));
 284
 285 fet_endchar;
 286
 287 fet_beginchar("Half diamondhead", "1diamond",
 288         "halfdiamondhead")
 289
 290         draw_outside_ellipse (1.50, 34, 0.49, 0.17);
 291         undraw_inside_ellipse (3.5, 33, 0.80,
 292                 .3 staff_space# + 1.5 stafflinethickness#, (w/2, 0));
 293
 294 fet_endchar;
 295
 296 fet_beginchar("Quart diamondhead", "2diamond", "diamondhead")
 297         draw_outside_ellipse (1.80, 35, 0.495, -0.25);
 298 fet_endchar;
 299
 300 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 301
 302
 303
 304
 305
 306 def def_triangle =
 307         save triangle,kern; path triangle;
 308         save left_point, height, width;
 309         pair exact_left_point;
 310         save pen_thick;
 311         pen_thick# = stafflinethickness#  + .1 staff_space#;
 312         define_pixels(pen_thick);
 313
 314         exact_left_point := llap# * dir (90 + tilt);
 315         height# = max (ypart exact_left_point,
 316                         -ypart  (exact_left_point rotated 120)) + pen_thick#/2;
 317
 318         kern# = 1/3 xpart (exact_left_point - (exact_left_point rotated 120));
 319         width# = xpart (-exact_left_point + (exact_left_point rotated 240));
 320         define_pixels (kern);
 321         z1 = (hround_pixels (xpart exact_left_point), vround_pixels  (ypart exact_left_point));
 322         z2 = z1 rotated 120;
 323         z3 = z1 rotated 240;
 324
 325         z12 = caveness[.5[z1,z2],z3];
 326         z23 = z12 rotated 120;
 327         z31 = z12 rotated 240;
 328         triangle = z1 .. z12 .. z2 ..
 329                     z2 .. z23 .. z3 ..
 330                     z3 .. z31 .. z1 ..
 331                     cycle;
 332         triangle := triangle shifted (-x1+pen_thick/2-kern,0) xscaled xs;
 333         pickup pencircle scaled pen_thick xscaled xs;
 334 %       labels(1,2,12,23,31,3);
 335         set_char_box(0, width# - kern#+ pen_thick#, height#, height#);
 336 enddef;
 337
 338 fet_beginchar("Whole trianglehead", "0triangle", "wholetrianglehead")
 339         save hei,xs;
 340         save llap;
 341         save tilt;
 342
 343         tilt = 40;
 344         llap# = 3/4noteheight#;
 345
 346         xs = 1.5;
 347         caveness:=0.1;
 348         def_triangle;
 349         draw triangle;
 350 fet_endchar;
 351
 352 fet_beginchar("Half trianglehead", "1triangle", "halftrianglehead")
 353         save hei,xs;
 354         save llap;
 355         save tilt;
 356
 357         tilt = 40;
 358         llap# = 2/3noteheight#;
 359         xs = 1.2;
 360         caveness:=0.1;
 361         def_triangle;
 362         draw triangle;
 363 fet_endchar;
 364
 365 fet_beginchar("Quart trianglehead", "2triangle", "trianglehead")
 366         save hei,xs;
 367         save llap;
 368         save tilt;
 369         tilt = 40;
 370         llap# = 2/3noteheight#;
 371         xs = 1.0;
 372         caveness:=0.1;
 373         def_triangle;
 374         filldraw triangle;
 375 fet_endchar;
 376
 377 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 378 %
 379 % slash heads are for indicating improvisation. They are
 380 % twice as high as normal heads.
 381 %
 382 def draw_slash(expr hwid_hash) =
 383         save exact_height;
 384         save ne_dir;
 385         pair ne_dir;
 386         exact_height =  staff_space# + stafflinethickness#/2;
 387
 388         set_char_box (0, 2 exact_height / slash_slope + hwid_hash,
 389                         exact_height, exact_height);
 390
 391         charwx := charwd;
 392         charwy := charht;
 393
 394         clearxy;
 395         pickup pencircle scaled blot_diameter;
 396
 397         bot y1 = - d;
 398         top y2 = h;
 399         lft x1 = 0;
 400         lft x2 = 2 h / slash_slope;
 401
 402         rt x3 = w;
 403         y3 = y2;
 404         y4 = y1;
 405         x3- x2 = x4 - x1;
 406
 407         ne_dir := unitvector( z3  - z4);
 408         filldraw z1 --- z2 --- z3 --- z4 --- cycle;
 409
 410         if hwid_hash > 2 slash_thick#:
 411                 save th;
 412
 413                 th = slash_thick - blot_diameter;
 414                 y6 = y7;
 415                 y5 = y8;
 416                 y3 - y7 = th;
 417                 y5 - y1 = th;
 418                 z6 - z5 = whatever * ne_dir;
 419                 z8 - z7 = whatever * ne_dir;
 420
 421                 z5  = z1 + whatever * ne_dir + th * (ne_dir rotated -90);
 422                 z8  = z4 + whatever * ne_dir + th * (ne_dir rotated 90);
 423
 424                 unfill
 425                         z5 -- z6 -- z7 -- z8 -- cycle;
 426         fi
 427         labels (range 1 thru 10);
 428 enddef;
 429
 430 fet_beginchar("Whole slashhead","0slash","wholeslashhead")
 431         draw_slash(4 slash_thick# + 0.5 staff_space#);
 432 fet_endchar;
 433
 434 fet_beginchar("Half slashhead","1slash","halfslashhead")
 435         draw_slash(3.0 slash_thick# + 0.15 staff_space#);
 436 fet_endchar;
 437
 438 fet_beginchar("Quart slashhead","2slash","quartslashhead")
 439         draw_slash(1.5 slash_thick#);
 440 fet_endchar;
 441
 442 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 443 % thick is the distance between the NE/SW parallel lines in the cross
 444 % (distance between centres of lines)
 445 % in stafflinethickness def
 446 %
 447 def draw_cross(expr thick) =
 448         save pent, slant, ne_dir;
 449         pair ne_dir;
 450         save crz; path crz;
 451
 452         pen_thick# := 1.2stafflinethickness#;
 453         define_pixels (pen_thick);
 454         pickup pencircle scaled pen_thick;
 455
 456         top y3 = h;
 457         ne_dir := unitvector ((1, (2 h -pen_thick)/(w - pen_thick)));
 458         rt x4 = w/2;
 459         y5 = 0;
 460         z4 - z5 = whatever * ne_dir;
 461         x6 = 0;
 462         z6 - z3 = whatever * ne_dir;
 463         z3 - z4 = whatever * (ne_dir yscaled -1);
 464
 465         z4 - z3 = whatever * (ne_dir) + (ne_dir rotated -90) * thick * stafflinethickness;
 466
 467         x1 = charwd/2 - .5 pen_thick#;
 468         z1 = whatever * ne_dir + thick/2 * stafflinethickness# * (ne_dir rotated -90);
 469
 470
 471         labels (1,2,3,4,5,6);
 472
 473         crz = (z6 -- z3 -- z4 -- z5) ;
 474
 475         draw crz shifted(w/2,0);
 476         draw crz xscaled -1 shifted(w/2,0);
 477         draw crz yscaled -1 shifted(w/2,0);
 478         draw crz scaled -1 shifted(w/2,0);
 479
 480         charwx := charwd;
 481         charwy := y1;
 482                 message (decimal charwx);
 483                 message (decimal charwy);
 484         z12 = (charwx * hppp, y1 * vppp);
 485         labels (12);
 486 enddef;
 487
 488 fet_beginchar("Whole Crossed notehead", "0cross", "wholecrossedhead")
 489         wid# := black_notehead_width#+4stafflinethickness#;
 490         hei# := noteheight#+stafflinethickness#;
 491         set_char_box(0, wid#,hei#/2,hei#/2);
 492
 493         draw_cross (3.75);
 494 fet_endchar;
 495
 496 fet_beginchar("Half Crossed notehead", "1cross", "halfcrossedhead")
 497         wid# := black_notehead_width#+2stafflinethickness#;
 498         hei# := noteheight#+stafflinethickness#/2;
 499         set_char_box(0, wid#,hei#/2,hei#/2);
 500         draw_cross(3.0);
 501 fet_endchar;
 502
 503 fet_beginchar("Crossed notehead", "2cross", "crossedhead")
 504         wid# := black_notehead_width#;
 505         hei# := noteheight#;
 506         set_char_box(0, wid#,hei#/2,hei#/2);
 507         draw_cross(1.0);
 508 fet_endchar;
 509
 510 fet_beginchar("X-Circled notehead", "2xcircle", "xcircledhead")
 511         wid# := black_notehead_width#*sqrt(sqrt2);
 512         hei# := noteheight#*sqrt(sqrt2);
 513         set_char_box(0, wid#,hei#/2,hei#/2);
 514         cthick := (1.2+1/4)*stafflinethickness;
 515         cxr := w/2-cthick/2;
 516         cyr := h-cthick/2;
 517         pickup pencircle scaled cthick;
 518         draw fullcircle xscaled 2cxr yscaled 2cyr shifted (w/2,0);
 519         xpos := cxr/sqrt2;
 520         ypos := cyr/sqrt2;
 521         draw (-xpos+w/2,-ypos) -- (xpos+w/2,ypos);
 522         draw (-xpos+w/2,ypos) -- (xpos+w/2,-ypos);
 523
 524         charwx := charwd ;
 525         charwy := 0 ;
 526
 527         z12 = (charwx * hppp , charwy * vppp );
 528         labels (12);
 529 fet_endchar;
 530
 531
 532 fet_endgroup("noteheads");
 533
 534 % what is this doing here?
 535 define_pixels(black_notehead_width);
 536
 537
 538 if 0 = 1:
 539
 540 % free space: ascii a-i
 541 code:=106;
 542
 543 %
 544 % testing unicode/gnome-canvas
 545 %
 546 savecode:=code;
 547 code:=96;
 548 %fet_beginchar("Whole notehead", "0", "wholehead")
 549 fet_beginchar("Ascii a", "a", "a")
 550         draw_outside_ellipse (1.80 - puff_up_factor / 3.0, 0, 0.707, 0);
 551         undraw_inside_ellipse (1.30, 125 - puff_up_factor *10,
 552                         0.68, 2 stafflinethickness#,
 553                         (w /2, 0));
 554 %       draw_staff_outline (-2, 2, 0.5);
 555 fet_endchar;
 556
 557 code:=savecode;
 558 fi