mf/feta-bolletjes.mf

   1 %  -*-Fundamental-*-
   2 % feta-bolletjes.mf --  implement noteheads
   3 %
   4 % source file of LilyPond's pretty-but-neat music font
   5 %
   6 % (c)  1997--2003 Jan Nieuwenhuizen <janneke@gnu.org>
   7 % & Han-Wen Nienhuys <hanwen@cs.uu.nl>
   8 % & Juergen Reuter <reuter@ipd.uka.de>
   9 %
  10
  11 test_outlines := 0;
  12
  13
  14 % most beautiful noteheads are pronounced, not circular,
  15 % and not even symmetric.
  16 % These examples are inspired by [Wanske], see literature list
  17
  18
  19
  20 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  21 % NOTE HEAD VARIABLES
  22 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  23 save black_notehead_width, noteheight,
  24         slash_thick, slash_slope, overdone_heads;
  25 numeric black_notehead_width, noteheight, slash_thick;
  26
  27 fet_begingroup("noteheads");
  28
  29
  30
  31 % slope of slash. From scm/grob-description.scm. How to auto-copy?
  32 slash_slope := 1.7;
  33
  34 % thickness of slash lines. quarter notes get 1.5slt width.
  35 slash_thick# := 2/3*0.48staff_space#;
  36
  37
  38 %
  39 % Hand-engraved music often has balls extending above and below
  40 % the lines.  If you like that, modify overdone heads (unit:
  41 % stafflinethickness)
  42 %
  43 overdone_heads = 0.0;
  44 noteheight#:=staff_space#+ (1 + overdone_heads) *stafflinethickness#;
  45
  46 define_pixels(slash_thick, noteheight);
  47
  48
  49 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  50 %
  51 % SLANT moves both extremes on the long axis (by SLANT * ELLIPSIDITY,
  52 % so SLANT = -1, puts the extreme on the long axis next to the short axis one.)
  53 %
  54
  55 def draw_outside_ellipse (expr ellipsidity, tilt, superness,
  56                         slant) =
  57         save attachment_y;
  58         save p;
  59         path p;
  60
  61         p := superellipse ((ellipsidity, 0), (-slant * ellipsidity, 1.0),
  62                         (- ellipsidity, 0), (slant * ellipsidity, -1.0), superness);
  63
  64         p := p rotated tilt;
  65
  66         save top_point, right_point;
  67         pair top_point, right_point;
  68
  69         top_point := directionpoint left of p;
  70         right_point := directionpoint up of p;
  71
  72         save scaling, width, height;
  73
  74         scaling# = noteheight# /(2 ypart (top_point));
  75         width# := 2 xpart (right_point) * scaling#;
  76
  77         define_pixels (width, scaling);
  78
  79         set_char_box (0, width#, noteheight#/2, noteheight#/2);
  80
  81         % attachment Y
  82         charwy := ypart (right_point) * scaling#;
  83         charwx := width# ;
  84
  85         p := p scaled scaling shifted (width/2, 0) ;
  86         if test_outlines = 1:
  87                 pickup pencircle scaled 1 ; draw p;
  88         else:
  89                 fill p;
  90         fi;
  91 enddef;
  92
  93
  94 def undraw_inside_ellipse (expr ellipsidity, tilt, superness, clearance,
  95                         center) =
  96 begingroup
  97         save p;
  98         path p;
  99
 100         p := superellipse ((ellipsidity, 0), (0, 1.0),
 101                         (- ellipsidity, 0), (0, -1.0), superness);
 102
 103         p := p rotated tilt;
 104
 105         save top_point, right_point;
 106         pair top_point, right_point;
 107
 108         top_point := directionpoint left of p;
 109         right_point := directionpoint up of p;
 110
 111         save height, scaling;
 112
 113         height# = staff_space# + stafflinethickness# - clearance;
 114         scaling# = height# /(2 ypart (top_point));
 115
 116         define_pixels (scaling);
 117         p := (p scaled scaling) shifted center;
 118
 119         if test_outlines = 1:
 120                 pickup pencircle scaled 1; draw p;
 121         else:
 122                 unfill p;
 123         fi
 124 endgroup;
 125 enddef;
 126
 127
 128
 129
 130
 131 %
 132 % dimensions aren't entirely right.
 133 %
 134 fet_beginchar ("Brevis notehead", "-1", "brevishead");
 135         save stemthick, fudge;
 136         define_pixels (stemthick);
 137         fudge = blot_diameter /2;
 138         stemthick# = 2 stafflinethickness#;
 139
 140         draw_outside_ellipse (1.80, 0, 0.707, 0);
 141         undraw_inside_ellipse (1.30, 125, 0.68, 2 stafflinethickness#,
 142                                 (w /2, 0));
 143
 144         pickup pencircle scaled stemthick;
 145
 146         bot y1 = -d;
 147         top y2 = h;
 148         rt x1 - fudge = 0;
 149         x1 = x2;
 150
 151         fudge + lft x3 = w;
 152         x4 = x3;
 153         y4 = y2;
 154         y3 = y1;
 155
 156         draw_gridline(z1,z2,stemthick);
 157         draw_gridline(z3,z4,stemthick);
 158
 159 fet_endchar;
 160
 161
 162
 163 fet_beginchar("Whole notehead", "0", "wholehead")
 164         draw_outside_ellipse (1.80 - puff_up_factor / 3.0, 0, 0.707, 0);
 165         undraw_inside_ellipse (1.30, 125 - puff_up_factor *10,
 166                         0.68, 2 stafflinethickness#,
 167                         (w /2, 0));
 168
 169 %       draw_staff_outline (-2, 2, 0.5);
 170
 171 fet_endchar;
 172
 173
 174 fet_beginchar("Half notehead", "1", "halfhead")
 175         draw_outside_ellipse (1.53 - puff_up_factor / 3.0, 34, 0.66, 0.17);
 176         undraw_inside_ellipse (3.25, 33, 0.81,
 177                 2.5 stafflinethickness#, (w/2, 0));
 178
 179 fet_endchar;
 180
 181 fet_beginchar("Quart notehead", "2", "quarthead")
 182         draw_outside_ellipse (1.54 - puff_up_factor / 2.0, 32, 0.707, 0);
 183         black_notehead_width# := charwd;
 184 fet_endchar;
 185
 186 %%%%%%%%%%%%%%%%
 187
 188 fet_beginchar("Quart noteheadPQ", "2PQ", "quartheadPQ")
 189         draw_outside_ellipse (1.0 - puff_up_factor / 2.0, 32, 0.707, 0);
 190 fet_endchar;
 191
 192 fet_beginchar("Quart noteheadAA", "2AA", "quartheadAA")
 193         draw_outside_ellipse (1.35 - puff_up_factor / 2.0, 32, 0.707, 0);
 194 fet_endchar;
 195
 196 fet_beginchar("Quart noteheadAB", "2AB", "quartheadAB")
 197         draw_outside_ellipse (1.4 - puff_up_factor / 2.0, 32, 0.707, 0);
 198
 199 fet_endchar;
 200 fet_beginchar("Quart noteheadAC", "2AC", "quartheadAC")
 201         draw_outside_ellipse (1.45 - puff_up_factor / 2.0, 32, 0.707, 0);
 202 fet_endchar;
 203
 204 fet_beginchar("Quart noteheadAD", "2AD", "quartheadAD")
 205         draw_outside_ellipse (1.5 - puff_up_factor / 2.0, 32, 0.707, 0);
 206 fet_endchar;
 207
 208 fet_beginchar("Quart noteheadAD", "2AE", "quartheadAD")
 209         draw_outside_ellipse (1.55 - puff_up_factor / 2.0, 32, 0.707, 0);
 210 fet_endchar;
 211
 212 fet_beginchar("Quart noteheadAD", "2AF", "quartheadAD")
 213         draw_outside_ellipse (1.6 - puff_up_factor / 2.0, 32, 0.707, 0);
 214 fet_endchar;
 215 fet_beginchar("Quart noteheadAD", "2AG", "quartheadAD")
 216         draw_outside_ellipse (1.65 - puff_up_factor / 2.0, 32, 0.707, 0);
 217 fet_endchar;
 218
 219
 220 fet_beginchar("Quart noteheadBA", "2BA", "quartheadBA")
 221         draw_outside_ellipse (1.35 - puff_up_factor / 2.0, 35, 0.707, 0);
 222 fet_endchar;
 223 fet_beginchar("Quart noteheadBB", "2BB", "quartheadBB")
 224         draw_outside_ellipse (1.4 - puff_up_factor / 2.0, 35, 0.707, 0);
 225
 226 fet_endchar;
 227 fet_beginchar("Quart noteheadBC", "2BC", "quartheadBC")
 228         draw_outside_ellipse (1.45 - puff_up_factor / 2.0, 35, 0.707, 0);
 229 fet_endchar;
 230 fet_beginchar("Quart noteheadBD", "2BD", "quartheadBD")
 231         draw_outside_ellipse (1.5 - puff_up_factor / 2.0, 35, 0.707, 0);
 232 fet_endchar;
 233 fet_beginchar("Quart noteheadBD", "2BE", "quartheadBD")
 234         draw_outside_ellipse (1.55 - puff_up_factor / 2.0, 35, 0.707, 0);
 235 fet_endchar;
 236 fet_beginchar("Quart noteheadBD", "2BF", "quartheadBD")
 237         draw_outside_ellipse (1.6 - puff_up_factor / 2.0, 35, 0.707, 0);
 238 fet_endchar;
 239 fet_beginchar("Quart noteheadBD", "2BG", "quartheadBD")
 240         draw_outside_ellipse (1.65 - puff_up_factor / 2.0, 35, 0.707, 0);
 241 fet_endchar;
 242
 243
 244
 245 fet_beginchar("Quart noteheadCA", "2CA", "quartheadCA")
 246         draw_outside_ellipse (1.35 - puff_up_factor / 2.0, 40, 0.707, 0);
 247 fet_endchar;
 248 fet_beginchar("Quart noteheadCB", "2CB", "quartheadCB")
 249         draw_outside_ellipse (1.4 - puff_up_factor / 2.0, 40, 0.707, 0);
 250 fet_endchar;
 251 fet_beginchar("Quart noteheadCC", "2CC", "quartheadCC")
 252         draw_outside_ellipse (1.45 - puff_up_factor / 2.0, 40, 0.707, 0);
 253 fet_endchar;
 254 fet_beginchar("Quart noteheadCD", "2CD", "quartheadCD")
 255         draw_outside_ellipse (1.5 - puff_up_factor / 2.0, 40, 0.707, 0);
 256 fet_endchar;
 257 fet_beginchar("Quart noteheadCD", "2CE", "quartheadCD")
 258         draw_outside_ellipse (1.55 - puff_up_factor / 2.0, 40, 0.707, 0);
 259 fet_endchar;
 260 fet_beginchar("Quart noteheadCD", "2CF", "quartheadCD")
 261         draw_outside_ellipse (1.6 - puff_up_factor / 2.0, 40, 0.707, 0);
 262 fet_endchar;
 263 fet_beginchar("Quart noteheadCD", "2CG", "quartheadCD")
 264         draw_outside_ellipse (1.65 - puff_up_factor / 2.0, 40, 0.707, 0);
 265 fet_endchar;
 266
 267 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 268
 269
 270 fet_beginchar("Whole diamondhead", "0diamond", "wholediamondhead")
 271         draw_outside_ellipse (1.80, 0, 0.495, 0);
 272         undraw_inside_ellipse (1.30, 125, 0.6,
 273                         .4 staff_space# +  stafflinethickness#,
 274                                 (w /2, 0));
 275
 276 fet_endchar;
 277
 278 fet_beginchar("Half diamondhead", "1diamond",
 279         "halfdiamondhead")
 280
 281         draw_outside_ellipse (1.50, 34, 0.49, 0.17);
 282         undraw_inside_ellipse (3.5, 33, 0.80,
 283                 .3 staff_space# + 1.5 stafflinethickness#, (w/2, 0));
 284
 285 fet_endchar;
 286
 287 fet_beginchar("Quart diamondheadh", "2diamondh", "diamondheadh")
 288         draw_outside_ellipse (1.80, 35, 0.495, -0.25);
 289 fet_endchar;
 290
 291 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 292
 293
 294
 295
 296
 297 def def_triangle =
 298         save triangle,kern; path triangle;
 299         save left_point, height, width;
 300         pair exact_left_point;
 301         save pen_thick;
 302         pen_thick# = stafflinethickness#  + .1 staff_space#;
 303         define_pixels(pen_thick);
 304
 305         exact_left_point := llap# * dir (90 + tilt);
 306         height# = max (ypart exact_left_point,
 307                         -ypart  (exact_left_point rotated 120)) + pen_thick#/2;
 308
 309         kern# = 1/3 xpart (exact_left_point - (exact_left_point rotated 120));
 310         width# = xpart (-exact_left_point + (exact_left_point rotated 240));
 311         define_pixels (kern);
 312         z1 = (hround_pixels (xpart exact_left_point), vround_pixels  (ypart exact_left_point));
 313         z2 = z1 rotated 120;
 314         z3 = z1 rotated 240;
 315
 316         z12 = caveness[.5[z1,z2],z3];
 317         z23 = z12 rotated 120;
 318         z31 = z12 rotated 240;
 319         triangle = z1 .. z12 .. z2 ..
 320                     z2 .. z23 .. z3 ..
 321                     z3 .. z31 .. z1 ..
 322                     cycle;
 323         triangle := triangle shifted (-x1+pen_thick/2-kern,0) xscaled xs;
 324         pickup pencircle scaled pen_thick xscaled xs;
 325 %       labels(1,2,12,23,31,3);
 326         set_char_box(0, width# - kern#+ pen_thick#, height#, height#);
 327 enddef;
 328
 329 fet_beginchar("Whole trianglehead", "0triangle", "wholetrianglehead")
 330         save hei,xs;
 331         save llap;
 332         save tilt;
 333
 334         tilt = 40;
 335         llap# = 3/4noteheight#;
 336
 337         xs = 1.5;
 338         caveness:=0.1;
 339         def_triangle;
 340         draw triangle;
 341 fet_endchar;
 342
 343 fet_beginchar("Half trianglehead", "1triangle", "halftrianglehead")
 344         save hei,xs;
 345         save llap;
 346         save tilt;
 347
 348         tilt = 40;
 349         llap# = 2/3noteheight#;
 350         xs = 1.2;
 351         caveness:=0.1;
 352         def_triangle;
 353         draw triangle;
 354 fet_endchar;
 355
 356 fet_beginchar("Quart trianglehead", "2triangle", "trianglehead")
 357         save hei,xs;
 358         save llap;
 359         save tilt;
 360         tilt = 40;
 361         llap# = 2/3noteheight#;
 362         xs = 1.0;
 363         caveness:=0.1;
 364         def_triangle;
 365         filldraw triangle;
 366 fet_endchar;
 367
 368 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 369 %
 370 % slash heads are for indicating improvisation. They are
 371 % twice as high as normal heads.
 372 %
 373 def draw_slash(expr hwid_hash) =
 374         save exact_height;
 375         save ne_dir;
 376         pair ne_dir;
 377         exact_height =  staff_space# + stafflinethickness#/2;
 378
 379         set_char_box (0, 2 exact_height / slash_slope + hwid_hash,
 380                         exact_height, exact_height);
 381
 382         charwx := charwd;
 383         charwy := charht;
 384
 385         clearxy;
 386         pickup pencircle scaled blot_diameter;
 387
 388         bot y1 = - d;
 389         top y2 = h;
 390         lft x1 = 0;
 391         lft x2 = 2 h / slash_slope;
 392
 393         rt x3 = w;
 394         y3 = y2;
 395         y4 = y1;
 396         x3- x2 = x4 - x1;
 397
 398         ne_dir := unitvector( z3  - z4);
 399         filldraw z1 --- z2 --- z3 --- z4 --- cycle;
 400
 401         if hwid_hash > 2 slash_thick#:
 402                 save th;
 403
 404                 th = slash_thick - blot_diameter;
 405                 y6 = y7;
 406                 y5 = y8;
 407                 y3 - y7 = th;
 408                 y5 - y1 = th;
 409                 z6 - z5 = whatever * ne_dir;
 410                 z8 - z7 = whatever * ne_dir;
 411
 412                 z5  = z1 + whatever * ne_dir + th * (ne_dir rotated -90);
 413                 z8  = z4 + whatever * ne_dir + th * (ne_dir rotated 90);
 414
 415                 unfill
 416                         z5 -- z6 -- z7 -- z8 -- cycle;
 417         fi
 418         labels (range 1 thru 10);
 419 enddef;
 420
 421 fet_beginchar("Whole slashhead","0slash","wholeslashhead")
 422         draw_slash(4 slash_thick# + 0.5 staff_space#);
 423 fet_endchar;
 424
 425 fet_beginchar("Half slashhead","1slash","halfslashhead")
 426         draw_slash(3.0 slash_thick# + 0.15 staff_space#);
 427 fet_endchar;
 428
 429 fet_beginchar("Quart slashhead","2slash","quartslashhead")
 430         draw_slash(1.5 slash_thick#);
 431 fet_endchar;
 432
 433 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 434 % thick is the distance between the NE/SW parallel lines in the cross
 435 % (distance between centres of lines)
 436 % in stafflinethickness def
 437 %
 438 def draw_cross(expr thick) =
 439         save pent, slant, ne_dir;
 440         pair ne_dir;
 441         save crz; path crz;
 442
 443         pen_thick# := 1.2stafflinethickness#;
 444         define_pixels (pen_thick);
 445         pickup pencircle scaled pen_thick;
 446
 447         top y3 = h;
 448         ne_dir := unitvector ((1, (2 h -pen_thick)/(w - pen_thick)));
 449         rt x4 = w/2;
 450         y5 = 0;
 451         z4 - z5 = whatever * ne_dir;
 452         x6 = 0;
 453         z6 - z3 = whatever * ne_dir;
 454         z3 - z4 = whatever * (ne_dir yscaled -1);
 455
 456         z4 - z3 = whatever * (ne_dir) + (ne_dir rotated -90) * thick * stafflinethickness;
 457
 458         x1 = charwd/2 - .5 pen_thick#;
 459         z1 = whatever * ne_dir + thick/2 * stafflinethickness# * (ne_dir rotated -90);
 460
 461
 462         labels (1,2,3,4,5,6);
 463
 464         crz = (z6 -- z3 -- z4 -- z5) ;
 465
 466         draw crz shifted(w/2,0);
 467         draw crz xscaled -1 shifted(w/2,0);
 468         draw crz yscaled -1 shifted(w/2,0);
 469         draw crz scaled -1 shifted(w/2,0);
 470
 471         charwx := charwd;
 472         charwy := y1;
 473                 message (decimal charwx);
 474                 message (decimal charwy);
 475         z12 = (charwx * hppp, y1 * vppp);
 476         labels (12);
 477 enddef;
 478
 479 fet_beginchar("Whole Crossed notehead", "0cross", "wholecrossedhead")
 480         wid# := black_notehead_width#+4stafflinethickness#;
 481         hei# := noteheight#+stafflinethickness#;
 482         set_char_box(0, wid#,hei#/2,hei#/2);
 483
 484         draw_cross (3.75);
 485 fet_endchar;
 486
 487 fet_beginchar("Half Crossed notehead", "1cross", "halfcrossedhead")
 488         wid# := black_notehead_width#+2stafflinethickness#;
 489         hei# := noteheight#+stafflinethickness#/2;
 490         set_char_box(0, wid#,hei#/2,hei#/2);
 491         draw_cross(3.0);
 492 fet_endchar;
 493
 494 fet_beginchar("Crossed notehead", "2cross", "crossedhead")
 495         wid# := black_notehead_width#;
 496         hei# := noteheight#;
 497         set_char_box(0, wid#,hei#/2,hei#/2);
 498         draw_cross(1.0);
 499 fet_endchar;
 500
 501 fet_beginchar("X-Circled notehead", "2xcircle", "xcircledhead")
 502         wid# := black_notehead_width#*sqrt(sqrt2);
 503         hei# := noteheight#*sqrt(sqrt2);
 504         set_char_box(0, wid#,hei#/2,hei#/2);
 505         cthick := (1.2+1/4)*stafflinethickness;
 506         cxr := w/2-cthick/2;
 507         cyr := h-cthick/2;
 508         pickup pencircle scaled cthick;
 509         draw fullcircle xscaled 2cxr yscaled 2cyr shifted (w/2,0);
 510         xpos := cxr/sqrt2;
 511         ypos := cyr/sqrt2;
 512         draw (-xpos+w/2,-ypos) -- (xpos+w/2,ypos);
 513         draw (-xpos+w/2,ypos) -- (xpos+w/2,-ypos);
 514
 515         charwx := charwd ;
 516         charwy := 0 ;
 517
 518         z12 = (charwx * hppp , charwy * vppp );
 519         labels (12);
 520 fet_endchar;
 521
 522
 523
 524 fet_endgroup("noteheads");
 525
 526 define_pixels(black_notehead_width);