mf/feta-bolletjes.mf

   1 %  -*-Fundamental-*-
   2 % feta-bolletjes.mf --  implement noteheads
   3 %
   4 % source file of LilyPond's pretty-but-neat music font
   5 %
   6 % (c)  1997--2003 Jan Nieuwenhuizen <janneke@gnu.org>
   7 % & Han-Wen Nienhuys <hanwen@cs.uu.nl>
   8 % & Juergen Reuter <reuter@ipd.uka.de>
   9 %
  10
  11 test_outlines := 0;
  12
  13
  14 % most beautiful noteheads are pronounced, not circular,
  15 % and not even symmetric.
  16 % These examples are inspired by [Wanske], see literature list
  17
  18
  19
  20 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  21 % NOTE HEAD VARIABLES
  22 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  23 save black_notehead_width, noteheight,
  24         slash_thick, slash_slope, overdone_heads;
  25 numeric black_notehead_width, noteheight, slash_thick;
  26
  27 fet_begingroup("noteheads");
  28
  29
  30
  31 % slope of slash. From scm/grob-description.scm. How to auto-copy?
  32 slash_slope := 1.7;
  33
  34 % thickness of slash lines. quarter notes get 1.5slt width.
  35 slash_thick# := 2/3*0.48staff_space#;
  36
  37
  38 %
  39 % Hand-engraved music often has balls extending above and below
  40 % the lines.  If you like that, modify overdone heads (unit:
  41 % stafflinethickness)
  42 %
  43 overdone_heads = 0.0;
  44 noteheight#:=staff_space#+ (1 + overdone_heads) *stafflinethickness#;
  45
  46 define_pixels(slash_thick, noteheight);
  47
  48
  49 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  50 %
  51 % SLANT moves both extremes on the long axis (by SLANT * ELLIPSIDITY,
  52 % so SLANT = -1, puts the extreme on the long axis next to the short axis one.)
  53 %
  54
  55 def draw_outside_ellipse (expr ellipsidity, tilt, superness,
  56                         slant) =
  57         save attachment_y;
  58         save p;
  59         path p;
  60
  61         p := superellipse ((ellipsidity, 0), (-slant * ellipsidity, 1.0),
  62                         (- ellipsidity, 0), (slant * ellipsidity, -1.0), superness);
  63
  64         p := p rotated tilt;
  65
  66         save top_point, right_point;
  67         pair top_point, right_point;
  68
  69         top_point := directionpoint left of p;
  70         right_point := directionpoint up of p;
  71
  72         save scaling, width, height;
  73
  74         scaling# = noteheight# /(2 ypart (top_point));
  75         width# := 2 xpart (right_point) * scaling#;
  76
  77         define_pixels (width, scaling);
  78
  79         set_char_box (0, width#, noteheight#/2, noteheight#/2);
  80
  81         % attachment Y
  82         charwy := ypart (right_point) * scaling#;
  83         charwx := width# ;
  84
  85         p := p scaled scaling shifted (width/2, 0) ;
  86         if test_outlines = 1:
  87                 pickup pencircle scaled 1 ; draw p;
  88         else:
  89                 fill p;
  90         fi;
  91 enddef;
  92
  93
  94 def undraw_inside_ellipse (expr ellipsidity, tilt, superness, clearance,
  95                         center) =
  96 begingroup
  97         save p;
  98         path p;
  99
 100         p := superellipse ((ellipsidity, 0), (0, 1.0),
 101                         (- ellipsidity, 0), (0, -1.0), superness);
 102
 103         p := p rotated tilt;
 104
 105         save top_point, right_point;
 106         pair top_point, right_point;
 107
 108         top_point := directionpoint left of p;
 109         right_point := directionpoint up of p;
 110
 111         save height, scaling;
 112
 113         height# = staff_space# + stafflinethickness# - clearance;
 114         scaling# = height# /(2 ypart (top_point));
 115
 116         define_pixels (scaling);
 117         p := (p scaled scaling) shifted center;
 118
 119         if test_outlines = 1:
 120                 pickup pencircle scaled 1; draw p;
 121         else:
 122                 unfill p;
 123         fi
 124 endgroup;
 125 enddef;
 126
 127
 128
 129
 130
 131 %
 132 % dimensions aren't entirely right.
 133 %
 134 fet_beginchar ("Brevis notehead", "-1", "brevishead");
 135         save stemthick, fudge;
 136         define_pixels (stemthick);
 137         fudge = blot_diameter /2;
 138         stemthick# = 2 stafflinethickness#;
 139
 140         draw_outside_ellipse (1.80, 0, 0.707, 0);
 141         undraw_inside_ellipse (1.30, 125, 0.68, 2 stafflinethickness#,
 142                                 (w /2, 0));
 143
 144         pickup pencircle scaled stemthick;
 145
 146         bot y1 = -d;
 147         top y2 = h;
 148         rt x1 - fudge = 0;
 149         x1 = x2;
 150
 151         fudge + lft x3 = w;
 152         x4 = x3;
 153         y4 = y2;
 154         y3 = y1;
 155
 156         draw_gridline(z1,z2,stemthick);
 157         draw_gridline(z3,z4,stemthick);
 158
 159 fet_endchar;
 160
 161
 162
 163 fet_beginchar("Whole notehead", "0", "wholehead")
 164         draw_outside_ellipse (1.80 - puff_up_factor / 3.0, 0, 0.707, 0);
 165         undraw_inside_ellipse (1.30, 125 - puff_up_factor *10,
 166                         0.68, 2 stafflinethickness#,
 167                         (w /2, 0));
 168
 169 %       draw_staff_outline (-2, 2, 0.5);
 170
 171 fet_endchar;
 172
 173
 174 fet_beginchar("Half notehead", "1", "halfhead")
 175         draw_outside_ellipse (1.53 - puff_up_factor / 3.0, 34, 0.66, 0.17);
 176         undraw_inside_ellipse (3.25, 33, 0.81,
 177                 2.5 stafflinethickness#, (w/2, 0));
 178
 179 fet_endchar;
 180
 181 fet_beginchar("Quart notehead", "2", "quarthead")
 182         draw_outside_ellipse (1.54 - puff_up_factor / 2.0, 32, 0.707, 0);
 183         black_notehead_width# := charwd;
 184 fet_endchar;
 185
 186 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 187
 188
 189 fet_beginchar("Whole diamondhead", "0diamond", "wholediamondhead")
 190         draw_outside_ellipse (1.80, 0, 0.495, 0);
 191         undraw_inside_ellipse (1.30, 125, 0.6,
 192                         .4 staff_space# +  stafflinethickness#,
 193                                 (w /2, 0));
 194
 195 fet_endchar;
 196
 197 fet_beginchar("Half diamondhead", "1diamond",
 198         "halfdiamondhead")
 199
 200         draw_outside_ellipse (1.50, 34, 0.49, 0.17);
 201         undraw_inside_ellipse (3.5, 33, 0.80,
 202                 .3 staff_space# + 1.5 stafflinethickness#, (w/2, 0));
 203
 204 fet_endchar;
 205
 206 fet_beginchar("Quart diamondheadh", "2diamondh", "diamondheadh")
 207         draw_outside_ellipse (1.80, 35, 0.495, -0.25);
 208 fet_endchar;
 209
 210 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 211
 212
 213
 214
 215
 216 def def_triangle =
 217         save triangle,kern; path triangle;
 218         save left_point, height, width;
 219         pair exact_left_point;
 220         save pen_thick;
 221         pen_thick# = stafflinethickness#  + .1 staff_space#;
 222         define_pixels(pen_thick);
 223
 224         exact_left_point := llap# * dir (90 + tilt);
 225         height# = max (ypart exact_left_point,
 226                         -ypart  (exact_left_point rotated 120)) + pen_thick#/2;
 227
 228         kern# = 1/3 xpart (exact_left_point - (exact_left_point rotated 120));
 229         width# = xpart (-exact_left_point + (exact_left_point rotated 240));
 230         define_pixels (kern);
 231         z1 = (hround_pixels (xpart exact_left_point), vround_pixels  (ypart exact_left_point));
 232         z2 = z1 rotated 120;
 233         z3 = z1 rotated 240;
 234
 235         z12 = caveness[.5[z1,z2],z3];
 236         z23 = z12 rotated 120;
 237         z31 = z12 rotated 240;
 238         triangle = z1 .. z12 .. z2 ..
 239                     z2 .. z23 .. z3 ..
 240                     z3 .. z31 .. z1 ..
 241                     cycle;
 242         triangle := triangle shifted (-x1+pen_thick/2-kern,0) xscaled xs;
 243         pickup pencircle scaled pen_thick xscaled xs;
 244 %       labels(1,2,12,23,31,3);
 245         set_char_box(0, width# - kern#+ pen_thick#, height#, height#);
 246 enddef;
 247
 248 fet_beginchar("Whole trianglehead", "0triangle", "wholetrianglehead")
 249         save hei,xs;
 250         save llap;
 251         save tilt;
 252
 253         tilt = 40;
 254         llap# = 3/4noteheight#;
 255
 256         xs = 1.5;
 257         caveness:=0.1;
 258         def_triangle;
 259         draw triangle;
 260 fet_endchar;
 261
 262 fet_beginchar("Half trianglehead", "1triangle", "halftrianglehead")
 263         save hei,xs;
 264         save llap;
 265         save tilt;
 266
 267         tilt = 40;
 268         llap# = 2/3noteheight#;
 269         xs = 1.2;
 270         caveness:=0.1;
 271         def_triangle;
 272         draw triangle;
 273 fet_endchar;
 274
 275 fet_beginchar("Quart trianglehead", "2triangle", "trianglehead")
 276         save hei,xs;
 277         save llap;
 278         save tilt;
 279         tilt = 40;
 280         llap# = 2/3noteheight#;
 281         xs = 1.0;
 282         caveness:=0.1;
 283         def_triangle;
 284         filldraw triangle;
 285 fet_endchar;
 286
 287 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 288
 289 def draw_slash(expr hwid_hash) =
 290
 291
 292         set_char_box (0, staff_space# / slash_slope + hwid_hash,
 293                         staff_space#/2 + stafflinethickness#/2,
 294                         staff_space#/2 + stafflinethickness#/2);
 295
 296         charwx := charwd;
 297         charwy := charht;
 298
 299         clearxy;
 300         pickup pencircle scaled blot_diameter;
 301
 302         bot y1 = - d;
 303         top y2 = h;
 304         lft x1 = 0;
 305         lft x2 = staff_space / slash_slope;
 306
 307         rt x3 = w;
 308         y3 = y2;
 309         y4 = y1;
 310         x3- x2 = x4 - x1;
 311
 312         filldraw z1 --- z2 --- z3 --- z4 --- cycle;
 313
 314         if hwid_hash > 2 slash_thick#:
 315                 save th;
 316
 317                 th = slash_thick - blot_diameter;
 318                 y6 = y7;
 319                 y5 = y8;
 320                 y3 - y7 = th;
 321                 y5 - y1 = th;
 322                 z6 - z5 = whatever * (1,  slash_slope);
 323                 z8 - z7 = whatever * (1,  slash_slope);
 324
 325                 z5  = z1 + whatever * (1,  slash_slope) + (th, 0);
 326                 z8  = z4 + whatever * (1,  slash_slope) + (-th, 0);
 327
 328                 unfill
 329                         z5 -- z6 -- z7 -- z8 -- cycle;
 330         fi
 331         labels (range 1 thru 10);
 332 enddef;
 333
 334 fet_beginchar("Whole slashhead","0slash","wholeslashhead")
 335         draw_slash(2 slash_thick# + 0.5 staff_space#);
 336 fet_endchar;
 337
 338 fet_beginchar("Half slashhead","1slash","halfslashhead")
 339         draw_slash(2 slash_thick# + 0.15 staff_space#);
 340 fet_endchar;
 341
 342 fet_beginchar("Quart slashhead","2slash","quartslashhead")
 343         draw_slash(slash_thick#);
 344 fet_endchar;
 345
 346 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 347
 348 % thick is the distance between the NE/SW parallel lines in the cross
 349 % (distance between centres of lines)
 350 % in stafflinethickness def
 351 %
 352 def draw_cross(expr thick) =
 353         save pent, slant, ne_dir;
 354         pair ne_dir;
 355         save crz; path crz;
 356
 357         pen_thick# := 1.2stafflinethickness#;
 358         define_pixels (pen_thick);
 359         pickup pencircle scaled pen_thick;
 360
 361         top y3 = h;
 362         ne_dir := unitvector ((1, (2 h -pen_thick)/(w - pen_thick)));
 363         rt x4 = w/2;
 364         y5 = 0;
 365         z4 - z5 = whatever * ne_dir;
 366         x6 = 0;
 367         z6 - z3 = whatever * ne_dir;
 368         z3 - z4 = whatever * (ne_dir yscaled -1);
 369
 370         z4 - z3 = whatever * (ne_dir) + (ne_dir rotated -90) * thick * stafflinethickness;
 371
 372         x1 = charwd/2 - .5 pen_thick#;
 373         z1 = whatever * ne_dir + thick/2 * stafflinethickness# * (ne_dir rotated -90);
 374
 375
 376         labels (1,2,3,4,5,6);
 377
 378         crz = (z6 -- z3 -- z4 -- z5) ;
 379
 380         draw crz shifted(w/2,0);
 381         draw crz xscaled -1 shifted(w/2,0);
 382         draw crz yscaled -1 shifted(w/2,0);
 383         draw crz scaled -1 shifted(w/2,0);
 384
 385         charwx := charwd;
 386         charwy := y1;
 387                 message (decimal charwx);
 388                 message (decimal charwy);
 389         z12 = (charwx * hppp, y1 * vppp);
 390         labels (12);
 391 enddef;
 392
 393 fet_beginchar("Whole Crossed notehead", "0cross", "wholecrossedhead")
 394         wid# := black_notehead_width#+4stafflinethickness#;
 395         hei# := noteheight#+stafflinethickness#;
 396         set_char_box(0, wid#,hei#/2,hei#/2);
 397
 398         draw_cross (3.75);
 399 fet_endchar;
 400
 401 fet_beginchar("Half Crossed notehead", "1cross", "halfcrossedhead")
 402         wid# := black_notehead_width#+2stafflinethickness#;
 403         hei# := noteheight#+stafflinethickness#/2;
 404         set_char_box(0, wid#,hei#/2,hei#/2);
 405         draw_cross(3.0);
 406 fet_endchar;
 407
 408 fet_beginchar("Crossed notehead", "2cross", "crossedhead")
 409         wid# := black_notehead_width#;
 410         hei# := noteheight#;
 411         set_char_box(0, wid#,hei#/2,hei#/2);
 412         draw_cross(1.0);
 413 fet_endchar;
 414
 415 fet_beginchar("X-Circled notehead", "2xcircle", "xcircledhead")
 416         wid# := black_notehead_width#*sqrt(sqrt2);
 417         hei# := noteheight#*sqrt(sqrt2);
 418         set_char_box(0, wid#,hei#/2,hei#/2);
 419         cthick := (1.2+1/4)*stafflinethickness;
 420         cxr := w/2-cthick/2;
 421         cyr := h-cthick/2;
 422         pickup pencircle scaled cthick;
 423         draw fullcircle xscaled 2cxr yscaled 2cyr shifted (w/2,0);
 424         xpos := cxr/sqrt2;
 425         ypos := cyr/sqrt2;
 426         draw (-xpos+w/2,-ypos) -- (xpos+w/2,ypos);
 427         draw (-xpos+w/2,ypos) -- (xpos+w/2,-ypos);
 428
 429         charwx := charwd ;
 430         charwy := 0 ;
 431
 432         z12 = (charwx * hppp , charwy * vppp );
 433         labels (12);
 434 fet_endchar;
 435
 436
 437
 438 fet_endgroup("noteheads");
 439
 440 define_pixels(black_notehead_width);