mf/feta-banier.mf

   1 % flags
   2 %
   3
   4
   5 fet_begingroup("flags")
   6 save outer_path;
   7 path outer_path;
   8 % Flags pointing down overlap with  the notehead (in x-direction), so
   9 % the down-flag can be bigger
  10 upflag_width# = .750 black_notehead_width# + stemthickness#/2;
  11 downflag_width# = .833 black_notehead_width# + stemthickness#/2;
  12
  13 right_upflag_space# = .2 upflag_width#;
  14 right_downflag_space# = .2 downflag_width#;
  15
  16 %
  17 % Flags pointing down cannot overlap with the notehead in y-direction,
  18 % so they have less slant.
  19
  20 % Because of optical illusion, the utmost flag (bottom for
  21 % down-pointing, top for up-pointing) should be smaller than the other
  22 % flags.  Adobe Sonata doesn't do this correctly.  (Instead they have
  23 % an extension flag, which looks less elegant)
  24 %
  25
  26 save hip_thickness, foot_thickness;
  27 hip_thickness# = 1.3 stemthickness#;
  28 foot_thickness# =  hip_thickness#;
  29
  30 %
  31 % Inspired by Adobe Sonata and [Wanske]
  32 % for example, see POSTSCRIPT Language -- program design,
  33 % page 119, and [Wanske], p 41,42
  34 %
  35 def draw_flag(expr center, flare,
  36         dims, hip_depth, foot_wid, hip_thickness, foot_thickness)=
  37         clearxy;
  38
  39         penpos1(flare, 90);
  40         penpos2(whatever, 0);
  41         x2r - x2l = hip_thickness;
  42         penpos3(foot_thickness, 0) ;
  43
  44         z1r  = center;
  45         z2r = center + (xpart dims, -ypart(dims) * hip_depth);
  46         z3r = center + (xpart(dims) * foot_wid, -ypart dims);
  47
  48         outer_path := z3r{curl 0} .. z2r{up} .. {up}z1r;
  49
  50         penlabels(1, 2, 3);
  51         fill z1l{curl 0}
  52                 ..tension 1.1 .. z2l{down} ..
  53                 {curl 0} simple_serif(z3l, z3r, 80) &
  54                 outer_path & z1r -- cycle;
  55 enddef;
  56
  57 %
  58 % TODO: calc intersectpoint
  59 % TODO: calc incision_depth
  60 %
  61 def add_flag(expr yoff, flare, hip_wid_multiplier,
  62                 hip_dep_multiplier,
  63                 intersectpoint, hip_thickness, foot_thickness) =
  64         begingroup
  65         save prev_center, prev_xextreme, prev_yextreme;
  66         save rel_foot, ip, center, incision_depth;
  67         save prev_hipwid, prev_footdep, prev_hipdep, wid, dep, hip_dep;
  68         save hip_dep_ratio, foot_wid_ratio;
  69         pair prev_center, center, foot, prev_xextreme, prev_yextreme;
  70         pair ip, rel_foot;
  71
  72         incision_depth = 1.013;
  73         prev_center = point 2 of outer_path;
  74         prev_xextreme = point 1 of outer_path;
  75         prev_yextreme = point 0 of outer_path;
  76         prev_hipwid = xpart (prev_xextreme - prev_center);
  77         prev_footdep = -ypart (prev_yextreme - prev_center);
  78         prev_hipdep = -ypart(prev_xextreme - prev_center);
  79         ip = point intersectpoint of outer_path;
  80
  81         wid = prev_hipwid * hip_wid_multiplier;
  82         hip_dep = prev_hipdep * hip_dep_multiplier;
  83
  84         center = prev_center + (0,yoff);
  85         rel_foot = incision_depth [(wid, hip_dep), ip - center];
  86         dep = -ypart(rel_foot);
  87         foot_wid_ratio = xpart(rel_foot ) / wid;
  88         hip_dep_ratio = hip_dep / dep;
  89
  90         draw_flag(center, flare,
  91                 (wid, dep), hip_dep_ratio, foot_wid_ratio,
  92                 hip_thickness, foot_thickness);
  93         endgroup
  94 enddef;
  95
  96 fet_beginchar("8th Flag (up)", "u3", "eighthflag")
  97         save flare,
  98                 hip_depth_ratio, hip_width,
  99                 foot_depth, foot_width_ratio;
 100
 101         flare# = 1.0 staff_space#;
 102         hip_depth_ratio = .72;
 103         foot_width_ratio = .8;
 104         hip_width# = upflag_width# - hip_thickness#/2;
 105
 106         foot_depth# =  3 staff_space#;
 107
 108         set_char_box(stemthickness# /2, hip_width#
 109                 + stemthickness#/2 + right_upflag_space#,
 110                  foot_depth# + foot_thickness#/2, stemthickness#/2)
 111
 112         define_pixels(flare, hip_width, hip_thickness,
 113                 foot_depth, foot_thickness);
 114         draw_flag((stemthickness/2,0), flare,
 115                 (hip_width, foot_depth),
 116                 hip_depth_ratio, foot_width_ratio, hip_thickness, foot_thickness);
 117
 118         pickup pencircle scaled stemthickness;
 119         draw (0, 0) .. (0,-2 staff_space);
 120 fet_endchar;
 121
 122 fet_beginchar("16th Flag (up)", "u4", "sixteenthflag")
 123         save flare,
 124                 hip_depth_ratio, hip_width,
 125                 foot_depth, foot_width_ratio;
 126         save flagspace, total_depth, flag_count;
 127         total_depth# = 3.5 staff_space#;
 128         flag_count = 2;
 129         flare# = .85 staff_space#;
 130         flagspace# = .85 staff_space#;
 131         hip_depth_ratio = .72 ;
 132         hip_width# = upflag_width# - hip_thickness#/2;
 133         flagspace# + foot_depth# = total_depth#;
 134
 135         foot_width_ratio = .8;
 136
 137         set_char_box(stemthickness# /2, hip_width#
 138                 + stemthickness#/2 + right_upflag_space#,
 139                 total_depth# + foot_thickness#/2, stemthickness#/2)
 140
 141         define_pixels(flare, hip_width, hip_thickness,
 142                 flagspace,
 143                 foot_depth,  foot_thickness);
 144         draw_flag((stemthickness/2,- flagspace), flare,
 145                 (hip_width, foot_depth),
 146                 hip_depth_ratio,foot_width_ratio, hip_thickness, foot_thickness);
 147
 148         add_flag(flagspace, flare,
 149                 .97, 1.00, 1.25, hip_thickness, foot_thickness);
 150
 151         pickup pencircle scaled stemthickness;
 152         draw (0, 0) .. (0,-2 staff_space);
 153 fet_endchar;
 154
 155
 156 fet_beginchar("32nd Flag (up)", "u5", "thirtysecondflag")
 157         save flare,
 158                 hip_depth_ratio, hip_width,
 159                 foot_depth, foot_width_ratio;
 160         save flagspace, total_depth, flag_count;
 161         flag_count = 3;
 162         total_depth#=4.25 staff_space#;
 163         flare# = .85 staff_space#;
 164         flagspace# = .87 staff_space#;
 165         hip_depth_ratio = .72 ;
 166         hip_width# = upflag_width# - hip_thickness#/2;
 167         (flag_count-1) * flagspace# + foot_depth# = total_depth#;
 168
 169         foot_width_ratio = .8;
 170
 171         set_char_box(stemthickness# /2, hip_width#
 172                 + stemthickness#/2 + right_upflag_space#,
 173                 total_depth# + foot_thickness#/2, stemthickness#/2)
 174
 175         define_pixels(flare, hip_width, hip_thickness,
 176                 flagspace,
 177                 foot_depth,  foot_thickness);
 178
 179         draw_flag((stemthickness/2,- 2 flagspace), flare,
 180                 (hip_width, foot_depth),
 181                 hip_depth_ratio,foot_width_ratio, hip_thickness, foot_thickness);
 182
 183         add_flag(flagspace, flare,
 184                 .97, 1.00, 1.25, hip_thickness, foot_thickness);
 185
 186         add_flag(flagspace, flare,
 187                 .95, 1.05, 1.25, hip_thickness, foot_thickness);
 188
 189         pickup pencircle scaled stemthickness;
 190         draw (0, 0) .. (0,-2 staff_space);
 191 fet_endchar;
 192
 193 fet_beginchar("64th Flag (up)", "u6", "sixtyfourthflag")
 194         save flare,
 195                 hip_depth_ratio, hip_width,
 196                 foot_depth, foot_width_ratio;
 197         save flagspace, total_depth, flag_count;
 198
 199         flag_count = 4;
 200         flare# = .85 staff_space#;
 201         flagspace# = .9 staff_space#;
 202         hip_depth_ratio = .72 ;
 203         hip_width# = upflag_width# - hip_thickness#/2;
 204         total_depth# = 5.25 staff_space#;
 205         (flag_count-1) * flagspace# + foot_depth# = total_depth#;
 206
 207         foot_width_ratio = .8;
 208
 209         set_char_box(stemthickness# /2, hip_width#
 210                 + stemthickness#/2 + right_upflag_space#,
 211                 total_depth# + foot_thickness#/2, stemthickness#/2)
 212
 213         define_pixels(flare, hip_width, hip_thickness,
 214                 flagspace,
 215                 foot_depth,  foot_thickness);
 216
 217         draw_flag((stemthickness/2,- (flag_count-1)* flagspace), flare,
 218                 (hip_width, foot_depth),
 219                 hip_depth_ratio,foot_width_ratio, hip_thickness, foot_thickness);
 220
 221         add_flag(flagspace, flare,
 222                 .97, 1.00, 1.3, hip_thickness, foot_thickness);
 223
 224         add_flag(flagspace, flare,
 225                 1.00, 1.00, 1.25, hip_thickness, foot_thickness);
 226         add_flag(flagspace, flare,
 227                 .95, 1.05, 1.25, hip_thickness, foot_thickness);
 228         pickup pencircle scaled stemthickness;
 229         draw (0, 0) .. (0,-2 staff_space);
 230 fet_endchar;
 231
 232 fet_beginchar("8th (down)", "d3", "deighthflag")
 233         save flare,
 234                 hip_depth_ratio, hip_width,
 235                 foot_depth, foot_width_ratio;
 236         save flagspace, total_depth, flag_count;
 237
 238         flag_count = 1;
 239         flare# = .99 staff_space#;
 240         flagspace# = .9 staff_space#;
 241         hip_depth_ratio = .72 ;
 242         hip_width# = downflag_width# - hip_thickness#/2;
 243         total_depth# = 2.85 staff_space#;
 244         (flag_count-1) * flagspace# + foot_depth# = total_depth#;
 245
 246         foot_width_ratio = .8;
 247
 248         set_char_box(stemthickness# /2, hip_width#
 249                 + stemthickness#/2 + right_downflag_space#,
 250                 total_depth# + foot_thickness#/2, stemthickness#/2)
 251
 252         define_pixels(flare, hip_width, hip_thickness,
 253                 flagspace,
 254                 foot_depth,  foot_thickness);
 255
 256         draw_flag((stemthickness/2,- (flag_count-1) *flagspace), flare,
 257                 (hip_width, foot_depth),
 258                 hip_depth_ratio,foot_width_ratio, hip_thickness, foot_thickness);
 259
 260         pickup pencircle scaled stemthickness;
 261         draw (0, 0) .. (0,-2 staff_space);
 262         y_mirror_char;
 263 fet_endchar;
 264
 265 %%%%%%%%
 266 %
 267 %
 268 %
 269 % Single Stroke for Short Appogiatura
 270 %
 271 %
 272 %
 273
 274 fet_beginchar("grace dash (up)", "ugrace", "gracedash")
 275         save flare,
 276                 hip_depth_ratio, hip_width,
 277                 foot_depth;
 278
 279         flare# = 1.0 staff_space#;
 280         hip_depth_ratio = .72;
 281         hip_width# = upflag_width# - hip_thickness#/2;
 282
 283         foot_depth# =  3 staff_space#;
 284
 285         define_pixels(flare, hip_width, hip_thickness,
 286                 foot_depth, foot_thickness);
 287
 288         set_char_box(hip_width# * hip_depth_ratio,
 289           hip_width# + stemthickness#/2 + right_upflag_space#,
 290           foot_depth# * hip_depth_ratio, -flare#)
 291
 292         pickup pencircle scaled 1.5 stemthickness;
 293         draw (-b ,-d) ..
 294           (w, h);
 295 fet_endchar;
 296
 297 fet_beginchar("16th (down)", "d4", "dsixteenthflag")
 298         save flare,
 299                 hip_depth_ratio, hip_width,
 300                 foot_depth, foot_width_ratio;
 301         save flagspace, total_depth, flag_count;
 302
 303         flag_count = 2;
 304         flare# = .8 staff_space#;
 305         flagspace# = .9 staff_space#;
 306         hip_depth_ratio = .85 ;
 307         hip_width# = downflag_width# - hip_thickness#/2;
 308         total_depth# = 3.0 staff_space#;
 309         (flag_count-1) * flagspace# + foot_depth# = total_depth#;
 310
 311         foot_width_ratio = .95;
 312
 313         set_char_box(stemthickness# /2, hip_width#
 314                 + stemthickness#/2 + right_downflag_space#,
 315                 total_depth# + foot_thickness#/2, stemthickness#/2)
 316
 317         define_pixels(flare, hip_width, hip_thickness,
 318                 flagspace,
 319                 foot_depth,  foot_thickness);
 320
 321         draw_flag((stemthickness/2,- (flag_count-1) *flagspace), flare,
 322                 (hip_width, foot_depth),
 323                 hip_depth_ratio,foot_width_ratio, hip_thickness, foot_thickness);
 324         add_flag(flagspace, flare,
 325                 .95, 1.00, 1.25, hip_thickness, foot_thickness);
 326
 327
 328
 329         pickup pencircle scaled stemthickness;
 330         draw (0, 0) .. (0,-2 staff_space);
 331         y_mirror_char;
 332 fet_endchar;
 333
 334 fet_beginchar("32nd (down)", "d5", "dthirtysecondflag")
 335         save flare,
 336                 hip_depth_ratio, hip_width,
 337                 foot_depth, foot_width_ratio;
 338         save flagspace, total_depth, flag_count;
 339
 340         flag_count = 3;
 341         flare# = .84 staff_space#;
 342         flagspace# = .9 staff_space#;
 343         hip_depth_ratio = .85 ;
 344         hip_width# = downflag_width# - hip_thickness#/2;
 345         total_depth# = 3.85 staff_space#;
 346         (flag_count-1) * flagspace# + foot_depth# = total_depth#;
 347
 348         foot_width_ratio = .95;
 349
 350         set_char_box(stemthickness# /2, hip_width#
 351                 + stemthickness#/2 + right_downflag_space#,
 352                 total_depth# + foot_thickness#/2, stemthickness#/2)
 353
 354         define_pixels(flare, hip_width, hip_thickness,
 355                 flagspace,
 356                 foot_depth,  foot_thickness);
 357
 358         draw_flag((stemthickness/2,- (flag_count-1) *flagspace), flare,
 359                 (hip_width, foot_depth),
 360                 hip_depth_ratio,foot_width_ratio, hip_thickness, foot_thickness);
 361         add_flag(flagspace, flare,
 362                 .97, 1.00, 1.25, hip_thickness, foot_thickness);
 363
 364         add_flag(flagspace, flare,
 365                 .95, 1.05, 1.25, hip_thickness, foot_thickness);
 366
 367
 368
 369         pickup pencircle scaled stemthickness;
 370         draw (0, 0) .. (0,-2 staff_space);
 371         y_mirror_char;
 372 fet_endchar;
 373 fet_beginchar("64th (down)", "d6", "dsixtyfourthflag")
 374         save flare,
 375                 hip_depth_ratio, hip_width,
 376                 foot_depth, foot_width_ratio;
 377         save flagspace, total_depth, flag_count;
 378
 379         flag_count = 4;
 380         flare# = .8 staff_space#;
 381         flagspace# = .9 staff_space#;
 382         hip_depth_ratio = .85 ;
 383         hip_width# = downflag_width# - hip_thickness#/2;
 384         total_depth# = 4.35 staff_space#;
 385         (flag_count-1) * flagspace# + foot_depth# = total_depth#;
 386
 387         foot_width_ratio = .98;
 388
 389         set_char_box(stemthickness# /2, hip_width#
 390                 + stemthickness#/2 + right_downflag_space#,
 391                 total_depth# + foot_thickness#/2, stemthickness#/2)
 392
 393         define_pixels(flare, hip_width, hip_thickness,
 394                 flagspace,
 395                 foot_depth,  foot_thickness);
 396
 397         draw_flag((stemthickness/2,- (flag_count-1) *flagspace), flare,
 398                 (hip_width, foot_depth),
 399                 hip_depth_ratio,foot_width_ratio, hip_thickness, foot_thickness);
 400         add_flag(flagspace, flare,
 401                 .97, 1.20, 1.175, hip_thickness, foot_thickness);
 402         add_flag(flagspace, flare,
 403                 .97, 1.10, 1.175, hip_thickness, foot_thickness);
 404
 405         add_flag(.98 flagspace, flare,
 406                 .91, 1.05, 1.2, hip_thickness, foot_thickness);
 407
 408
 409
 410         pickup pencircle scaled stemthickness;
 411         draw (0, 0) .. (0,-2 staff_space);
 412         y_mirror_char;
 413 fet_endchar;
 414
 415 % ustem?
 416 %
 417 %
 418 % Stem characters so we can compose metronome markings with Feta
 419 % entirely.
 420 %
 421
 422 fet_beginchar("stem (up)", "stem", "stem")
 423         set_char_box(stemthickness#/2, stemthickness#/2, 0, 3.5staff_space#);
 424         pickup pencircle scaled stemthickness;
 425         draw (0, 0.2staff_space) .. (0, 3.5staff_space);
 426 fet_endchar;
 427
 428 % do we want this?
 429 fet_beginchar("stem (down)", "dstem", "dstem")
 430         set_char_box(stemthickness#/2, stemthickness#/2, 3.5staff_space#, 0);
 431         pickup pencircle scaled stemthickness;
 432         draw (0, -0.2staff_space) .. (0, -3.5staff_space);
 433 fet_endchar;
 434
 435
 436 fet_endgroup("flags");