mf/autometric.mf

   1 %
   2 % autometric.mf -- administrative MF routines
   3 %
   4 % source file of the Feta (Font-En-Tja) pretty-but-neat music font
   5 %
   6 % (c) 1997 Han-Wen Nienhuys <hanwen@stack.nl>
   7 %          Jan Nieuwenhuizen <jan@digicash.com>
   8 %
   9 % these macros help create ascii logging output
  10 % to automate generation of lily tables and tex backend
  11 % The output should be parsed by the mf-to-table script
  12
  13 % font or database?
  14 def fet_beginfont(expr name,size) =
  15         font_identifier:=name&decimal size;
  16         font_size size;
  17         message "@{font@:"&name&"@:"&decimal size&"@}";
  18         message "";
  19         enddef;
  20
  21 def fet_endfont(expr name) =
  22         message "@{tnof@:"&name&"@}";
  23         message "";
  24         enddef;
  25
  26 % group or table?
  27 def fet_begingroup(expr name) =
  28         message "@{group@:"&name&"@}";
  29         message "";
  30         begingroup
  31 enddef;
  32
  33 def fet_endgroup(expr name) =
  34         endgroup;
  35         message "@{puorg@:"&name&"@}";
  36         message "";
  37 enddef;
  38
  39 def autometric_output_char=
  40         message "@{char@:"&charnamestr&"@:"&decimal charcode&"@:"&decimal charbp&"@:"&decimal charwd&"@:"&decimal chardp&"@:"&decimal charht&"@:"&idstr&"@:"&texstr&"@}";
  41 enddef;
  42
  43 def tand(expr alpha) =
  44         (sind alpha/cosd alpha)
  45         enddef;
  46
  47 %breapth, width, depth, height
  48 %     breapth   x-depth
  49 def set_char_box(expr b_sharp, w_sharp, d_sharp,h_sharp) =
  50         save scharbp, scharht, scharwd, schardp;
  51
  52         % some paranoia if someone calls set_char_box(charwd, charbp, .. )
  53         scharbp := b_sharp;
  54         scharht := h_sharp;
  55         schardp := d_sharp;
  56         scharwd := w_sharp;
  57
  58         charbp := scharbp;
  59         charht := scharht;
  60         chardp := schardp;
  61         charwd := scharwd;
  62
  63         w := hround(w_sharp *hppp);
  64         b := hround(b_sharp *hppp);
  65         h := hround(h_sharp *vppp);
  66         d := hround(d_sharp *vppp);
  67 enddef;
  68
  69 def no_dimen_beginchar(expr c) =
  70         begingroup
  71         charcode := if known c: byte c else: 0; fi;
  72         charic := 0;
  73         clearxy;
  74         clearit;
  75         clearpen;
  76         scantokens extra_beginchar;
  77 enddef;
  78
  79 code:=-1;
  80
  81 % starts just as plain mf's beginchar:
  82 %     charcode,
  83 % and then adds:
  84 %     charname  see below
  85 %     id        index in lily's table
  86 %     texstr    name of tex macro in lily's table and tex backend
  87
  88 % the dims are uninitialised; you should use set_char_box manually.
  89 def fet_beginchar(expr name, id_lit, texstr_lit) =
  90         save texstr, idstr, charnamestr;
  91         save charbp;
  92         save w,b,h,d;
  93         string texstr, idstr, charnamestr;
  94         texstr := texstr_lit;
  95         charnamestr := name;
  96         idstr := id_lit;
  97
  98         no_dimen_beginchar(incr code) name;
  99         enddef;
 100
 101
 102 def makebox_with_breapth(text r) =
 103         for y = -d, 0, h: r((-b, y),(w,y)); endfor
 104         for x = -b, 0, w: r((x, -d),(x, h)); endfor
 105 enddef;
 106
 107 %
 108 % override plain endchar.  We want a different box.
 109 %
 110 def breapth_endchar =
 111         scantokens extra_endchar;
 112         if proofing > 0: makebox_with_breapth(proofrule); fi
 113         chardx := 10*(w + b);
 114         shipit;
 115         endgroup
 116 enddef;
 117
 118 def fet_endchar=
 119         autometric_output_char;
 120         breapth_endchar;
 121         enddef;