lilypond-texi2html.init

   1 #!/usr/bin/env perl
   2
   3 ### texi2html customization script for Lilypond
   4 ### Author: Reinhold Kainhofer <reinhold@kainhofer.com>, 2008.
   5 ###         Some code parts copied from texi2html and adapted.
   6 ### License: GPLv2+
   7 ###
   8 ###
   9 ### Features implemented here:
  10 ### -) For split manuals, the main page is index.html.
  11 ### -) All @unnumbered* sections are placed into the same file
  12 ###    (implemented by split_at_numbered_sections)
  13 ### -) Use our custom CSS file, with IE-specific fixes in another CSS file,
  14 ###    impelmented by lilypond_css_lines
  15 ### -) TOC (folded, with the current page highlighted) in an iframe is added
  16 ###    to every page; implemented by:
  17 ###           lilypond_print_element_header -- building of the TOC
  18 ###           lilypond_toc_body -- generation of customized TOC output
  19 ###           lilypond_print_page_head -- start <div id="main">
  20 ###           print_lilypond_page_foot -- closing id=main, output of footer & TOC
  21 ### -) External refs are formatted only as "Text of the node" (not as >>see
  22 ###    "NODE" section "SECTION" in "BOOK"<< like with default texi2html). Also,
  23 ###    the leading "(book-name)" is removed.
  24 ###    Implemented by overriding lilypond_external_ref
  25 ### -) Navigation bars on top/bottom of the page and between sections are not
  26 ###    left-aligned, but use a combination of left/center/right aligned table
  27 ###    cells; For this, I heavily extend the texi2html code to allow for
  28 ###    differently aligned cells and for multi-line tables);
  29 ###    Implemented in lilypond_print_navigation
  30 ### -) Different formatting than the default: example uses the same formatting
  31 ###    as quote.
  32 ### -) Allow translated section titles: All section titles can be translated,
  33 ###    the original (English) title is associated with @translationof. This is
  34 ###    needed, because the file name / anchor is generated from the original
  35 ###    English title, since otherwise language-autoselection would break with
  36 ###    posted links.
  37 ###    Since it is then no longer possible to obtain the file name from the
  38 ###    section title, I keep a sectionname<=>filename/anchor around. This way,
  39 ###    xrefs from other manuals can simply load that map and retrieve the
  40 ###    correct file name for the link. Implemented in:
  41 ###           lilypond_unknown (handling of @translationof, in case
  42 ###                             extract_texi_filenames.py messes up...)
  43 ###           split_at_numbered_sections (correct file name: use the map)
  44 ###           lilypond_init_map (read in the externally created map from disk)
  45 ###           lilypond_external_href (load the map for xrefs, use the correct
  46 ###                                   link target)
  47 ###
  48 ###
  49 ### Useful helper functions:
  50 ### -) texinfo_file_name($node_name): returns a texinfo-compatible file name
  51 ###    for the given string $node_name (whitespace trimmed/replaced by -,
  52 ###    non-standard chars replaced by _xxxx (ascii char code) and forced to
  53 ###    start with a letter by prepending t_g if necessary)
  54
  55
  56 package Texi2HTML::Config;
  57
  58
  59
  60
  61
  62 #############################################################################
  63 ###  SETTINGS FOR TEXI2HTML
  64 #############################################################################
  65
  66 @Texi2HTML::Config::CSS_REFS      = ("lilypond.css");
  67 $Texi2HTML::Config::USE_ACCESSKEY = 1;
  68 $Texi2HTML::Config::USE_LINKS     = 1;
  69 $Texi2HTML::Config::USE_REL_REV   = 1;
  70 $Texi2HTML::Config::element_file_name    = \&split_at_numbered_sections;
  71 $Texi2HTML::Config::print_element_header = \&lilypond_print_element_header;
  72 $Texi2HTML::Config::print_page_foot      = \&print_lilypond_page_foot;
  73 $Texi2HTML::Config::print_navigation     = \&lilypond_print_navigation;
  74 $Texi2HTML::Config::external_ref         = \&lilypond_external_ref;
  75 $Texi2HTML::Config::external_href        = \&lilypond_external_href;
  76 $Texi2HTML::Config::toc_body             = \&lilypond_toc_body;
  77 $Texi2HTML::Config::css_lines            = \&lilypond_css_lines;
  78 $Texi2HTML::Config::unknown              = \&lilypond_unknown;
  79 $Texi2HTML::Config::print_page_head      = \&lilypond_print_page_head;
  80
  81 # Examples should be formatted similar to quotes:
  82 $Texi2HTML::Config::complex_format_map->{'example'} = {
  83   'begin' => q{"<blockquote><pre class=\"example\">"},
  84   'end' => q{"</pre></blockquote>\n"},
  85  };
  86
  87
  88 my @section_to_filename;
  89
  90
  91
  92
  93 #############################################################################
  94 ###  DEBUGGING
  95 #############################################################################
  96
  97 use Data::Dumper;
  98 $Data::Dumper::Maxdepth = 2;
  99
 100 sub print_element_info($)
 101 {
 102   my $element = shift;
 103   print "~~~~~~~~~~~~~~~~~~~~~~~~~~~~\n";
 104   print "Element: $element\n";
 105   print Dumper($element);
 106 }
 107
 108
 109
 110
 111
 112 #############################################################################
 113 ###  HELPER FUNCTIONS
 114 #############################################################################
 115
 116 # Convert a given node name to its proper file name (normalization as explained
 117 # in the texinfo manual:
 118 # http://www.gnu.org/software/texinfo/manual/texinfo/html_node/HTML-Xref-Node-Name-Expansion.html
 119 sub texinfo_file_name($)
 120 {
 121   my $text = shift;
 122   my $result = '';
 123   # File name normalization by texinfo:
 124   # 1/2: letters and numbers are left unchanged
 125   # 3/4: multiple, leading and trailing whitespace is removed
 126   $text = main::normalise_space($text);
 127   # 5/6: all remaining spaces are converted to '-', all other 7- or 8-bit
 128   #      chars are replaced by _xxxx (xxxx=ascii character code)
 129   while ($text ne '') {
 130     if ($text =~ s/^([A-Za-z0-9]+)//o) { # number or letter stay unchanged
 131       $result .= $1;
 132     } elsif ($text =~ s/^ //o) { # space -> '-'
 133       $result .= '-';
 134     } elsif ($text =~ s/^(.)//o) { # Otherwise use _xxxx (ascii char code)
 135       my $ccode = ord($1);
 136       if ( $ccode <= 0xFFFF ) {
 137         $result .= sprintf("_%04x", $ccode);
 138       } else {
 139         $result .= sprintf("__%06x", $ccode);
 140       }
 141     }
 142   }
 143   # 7: if name does not begin with a letter, prepend 't_g' (so it starts with a letter)
 144   if ($result !~ /^[a-zA-Z]/) {
 145     $result = 't_g' . $result;
 146   }
 147   # DONE
 148   return $result
 149 }
 150
 151
 152 # Load a file containing a nodename<=>filename map (tab-sepatared, i.e.
 153 # NODENAME\tFILENAME\tANCHOR
 154 # Returns a ref to a hash "Node title" => ["FilenameWithoutExt", "Anchor"]
 155 sub load_map_file ($)
 156 {
 157     my $mapfile = shift;
 158     my $node_map = ();
 159
 160     if (open(XREFFILE, $mapfile)) {
 161         while ( <XREFFILE> ) {
 162             # parse the tab-separated entries and insert them into the map:
 163             chomp($_);
 164             my @entries = split(/\t/, $_);
 165             if (scalar (@entries) == 3) {
 166               $node_map->{$entries[0]} = [$entries[1], $entries[2]];
 167             } else {
 168               print STDERR "Invalid entry in the node file $mapfile: $_\n";
 169             }
 170         }
 171         close (XREFFILE);
 172     } else {
 173         print STDERR "Unable to load the map file $mapfile\n";
 174     }
 175     return $node_map;
 176 }
 177
 178
 179 # Split the given path into dir and basename (with .texi removed). Used mainly
 180 # to get the path/basename of the original texi input file
 181 sub split_texi_filename ($)
 182 {
 183   my $docu = shift;
 184   my $docu_dir, $docu_name;
 185   if ($docu =~ /(.*\/)/) {
 186     chop($docu_dir = $1);
 187     $docu_name = $docu;
 188     $docu_name =~ s/.*\///;
 189   } else {
 190      $docu_dir = '.';
 191      $docu_name = $docu;
 192   }
 193   $docu_name =~ s/\.te?x(i|info)?$//;
 194   return ($docu_dir, $docu_name);
 195 }
 196
 197
 198
 199
 200
 201 #############################################################################
 202 ###  CSS HANDLING
 203 #############################################################################
 204
 205 # Include our standard CSS file, not hard-coded CSS code directly in the HTML!
 206 # For IE, conditionally include the lilypond-ie-fixes.css style sheet
 207 sub lilypond_css_lines ($$)
 208 {
 209     my $import_lines = shift;
 210     my $rule_lines = shift;
 211     return if (defined($CSS_LINES));
 212     if (@$rule_lines or @$import_lines)
 213     {
 214         $CSS_LINES = "<style type=\"text/css\">\n<!--\n";
 215         $CSS_LINES .= join('',@$import_lines) . "\n" if (@$import_lines);
 216         $CSS_LINES .= join('',@$rule_lines) . "\n" if (@$rule_lines);
 217         $CSS_LINES .= "-->\n</style>\n";
 218     }
 219     foreach my $ref (@CSS_REFS)
 220     {
 221         $CSS_LINES .= "<link rel=\"stylesheet\" type=\"text/css\" href=\"$ref\">\n";
 222     }
 223     $CSS_LINES .= "<!--[if lte IE 7]>\n<link href=\"lilypond-ie-fixes.css\" rel=\"stylesheet\" type=\"text/css\">\n<![endif]-->\n";
 224 }
 225
 226
 227
 228
 229
 230 #############################################################################
 231 ###  SPLITTING BASED ON NUMBERED SECTIONS
 232 #############################################################################
 233
 234 my $lastfilename;
 235 my $docnr = 0;
 236 my $node_to_filename_map = ();
 237
 238 # This function makes sure that files are only generated for numbered sections,
 239 # but not for unnumbered ones. It is called after texi2html has done its own
 240 # splitting and simply returns the filename for the node given as first argument
 241 # Nodes with the same filename will be printed out to the same filename, so
 242 # this really all we need. Also, make sure that the file names for sections
 243 # are derived from the section title. We also might want to name the anchors
 244 # according to node titles, which works by simply overriding the id element of
 245 # the $element hash.
 246 # If an external nodename<=>filename/anchor map file is found (loaded in
 247 # lilypond_init_out, use the externally created values, otherwise use the
 248 # same logic here.
 249 sub split_at_numbered_sections($$$)
 250 {
 251   my $element = shift;
 252   my $type = shift;
 253   my $docu_name = shift;
 254   my $docu_ext = $Texi2HTML::Config::EXTENSION;
 255
 256   my $node_name = main::remove_texi($element->{'node_ref'}->{'texi'});
 257   # the snippets page does not use nodes for the snippets, so in this case
 258   # we'll have to use the section name!
 259   if ($node_name eq '') {
 260     $node_name = main::remove_texi($element->{'texi'});
 261   }
 262
 263   # If we have an entry in the section<=>filename map, use that one, otherwise
 264   # generate the filename/anchor here. In the latter case, external manuals
 265   # will not be able to retrieve the file name for xrefs!!! Still, I already
 266   # had that code, so I'll leave it in in case something goes wrong with the
 267   # extract_texi_filenames.py script in the lilypond build process!
 268   if (exists ($node_to_filename_map->{$node_name})) {
 269     (my $filename, my $anchor) = @{$node_to_filename_map->{$node_name}};
 270     $filename .= ".$docu_ext" if (defined($docu_ext));
 271
 272     $element->{id} = $anchor;
 273     if ($filename eq $lastfilename) {
 274       $$element{doc_nr} = $docnr;
 275     } else {
 276       $docnr += 1;
 277       $$element{doc_nr} = $docnr;
 278       $lastfilename = $filename;
 279     }
 280     return $filename;
 281
 282   } elsif ($type eq "top" or $type eq "toc" or $type eq "doc" or $type eq "stoc" or $type eq "foot" or $type eq "about") {
 283     # TOC, footer, about etc. are called with undefined $element and $type == "toc"|"stoc"|"foot"|"about"
 284     return;
 285   } else {
 286     print STDERR "WARNING: Node '$node_name' was NOT found in the map\n"
 287         unless ($node_name eq '') or ($element->{'tag'} eq 'unnumberedsec')
 288                or ($node_name =~ /NOT REALLY USED/);
 289
 290     # derive the name of the anchor (i.e. the part after # in the links!),
 291     # don't use texi2html's SECx.x default!
 292     my $sec_name = main::remove_texi($element->{'texi'});
 293     # if we have a node, use its name:
 294     if ($element->{'node_ref'}->{'texi'} ne '') {
 295       $sec_name = main::remove_texi($element->{'node_ref'}->{'texi'});
 296     }
 297     my $anchor = $sec_name;
 298     if ($element->{translationof}) {
 299       $anchor = main::remove_texi($$element{translationof});
 300     }
 301     # normalize to the same file name as texinfo
 302     $anchor = texinfo_file_name($anchor);
 303     $$element{id} = $anchor;
 304     # Numbered sections will get a filename Node_title, unnumbered sections will use
 305     # the file name of the previous numbered section:
 306     if (($element->{number}) or ($lastfilename eq '') or ($element->{level} == 1)) {
 307       my $filename = $anchor;
 308       $filename .= ".$docu_ext" if (defined($docu_ext));
 309       $docnr += 1;
 310       $$element{doc_nr} = $docnr;
 311       $lastfilename = $filename;
 312       return $filename;
 313     } else {
 314       $$element{doc_nr} = $docnr;
 315       return $lastfilename;
 316     }
 317   }
 318
 319   return;
 320 }
 321
 322
 323 ## Load the map file for the corrently processed texi file. We do this
 324 #  (mis-)using a command init handler, since texi2html does not have any
 325 #  other hooks that are called after THISDOC is filled but before phase 2
 326 #  of the texi2html conversion.
 327 sub lilypond_init_map ()
 328 {
 329     my ($docu_dir, $docu_name) = split_texi_filename ($Texi2HTML::THISDOC{'input_file_name'});
 330     my $map_filename = "$docu_dir/${docu_name}.xref-map";
 331     $node_to_filename_map = load_map_file ($map_filename);
 332 }
 333 push @Texi2HTML::Config::command_handler_init, \&lilypond_init_map;
 334
 335
 336
 337 #############################################################################
 338 ###  CLEANER LINK TITLE FOR EXTERNAL REFS
 339 #############################################################################
 340
 341 # The default formatting of external refs returns e.g.
 342 # "(lilypond-internals)Timing_translator", so we remove all (...) from the
 343 # file_and_node argument. Also, we want only a very simple format, so we don't
 344 # even call the default handler!
 345 sub lilypond_external_ref($$$$$$)
 346 {
 347   my $type = shift;
 348   my $section = shift;
 349   my $book = shift;
 350   my $file_node = shift;
 351   my $href = shift;
 352   my $cross_ref = shift;
 353
 354   $file_node =~ s/\(.*\)//;
 355   $file_node = &$anchor('', $href, $file_node) if ($file_node ne '');
 356   return &$I('%{node_file_href}', { 'node_file_href' => $file_node });
 357
 358 #  Default: format as "see <a ..>NODE</a> section 'SECTION' in BOOK". We don't want this!
 359 #   return t2h_default_external_ref($type, $section, $book, $file_node, $href, $cross_ref);
 360 }
 361
 362
 363
 364
 365
 366 #############################################################################
 367 ###  HANDLING TRANSLATED SECTIONS: handle @translationof, secname<->filename
 368 ###                  map stored on disk, xrefs in other manuals load that map
 369 #############################################################################
 370
 371
 372 # Try to make use of @translationof to generate files according to the original
 373 # English section title...
 374 sub lilypond_unknown($$$$$)
 375 {
 376     my $macro = shift;
 377     my $line = shift;
 378     my $pass = shift;
 379     my $stack = shift;
 380     my $state = shift;
 381
 382     # the @translationof macro provides the original English section title,
 383     # which should be used for file/anchor naming, while the title will be
 384     # translated to each language
 385     # It is already used by extract_texi_filenames.py, so this should not be
 386     # necessary here at all. Still, I'll leave the code in just in case the
 387     # python script messed up ;-)
 388     if ($pass == 1 and $macro eq "translationof") {
 389       if (ref($state->{'element'}) eq 'HASH') {
 390         $state->{'element'}->{'translationof'} = main::normalise_space($line);
 391       }
 392       return ('', true, undef, undef);
 393     } else {
 394       return t2h_default_unknown($macro, $line, $pass, $stack, $state);
 395     }
 396 }
 397
 398
 399
 400
 401 my %translated_books = ();
 402 # Construct a href to an external source of information.
 403 # node is the node with texinfo @-commands
 404 # node_id is the node transliterated and transformed as explained in the
 405 #         texinfo manual
 406 # node_xhtml_id is the node transformed such that it is unique and can
 407 #     be used to make an html cross ref as explained in the texinfo manual
 408 # file is the file in '(file)node'
 409 sub lilypond_external_href($$$)
 410 {
 411   my $node = shift;
 412   my $node_id = shift;
 413   my $node_xhtml_id = shift;
 414   my $file = shift;
 415   my $original_func = \&t2h_default_external_href;
 416
 417   # 1) Keep a hash of book->section_map
 418   # 2) if not file in keys hash => try to load the map (assign empty map if
 419   #    non-existent => will load only once!)
 420   # 3) if node in the section=>(file, anchor) map, replace node_id and
 421   #    node_xhtml_id by the map's values
 422   # 4) call the t2h_default_external_href with these values (or the old ones if not found)
 423
 424   if (($node_id ne '') and defined($file) and ($node_id ne 'Top')) {
 425     my $map_name = $file;
 426     $map_name =~ s/-big-page//;
 427
 428     # Load the map if we haven't done so already
 429     if (!exists($translated_books{$map_name})) {
 430       my ($docu_dir, $docu_name) = split_texi_filename ($Texi2HTML::THISDOC{'input_file_name'});
 431       my $map_filename = "$docu_dir/${map_name}.xref-map";
 432       $translated_books{$map_name} = load_map_file ($map_filename);
 433     }
 434
 435     # look up translation. use these values instead of the old filename/anchor
 436     my $section_name_map = $translated_books{$map_name};
 437     my $node_text = main::remove_texi($node);
 438     if (defined($section_name_map->{$node_text})) {
 439       (my $node_id, $node_hxmlt_id) = @{$section_name_map->{$node_text}};
 440     } else {
 441       print STDERR "Unable to find key '$node_text' in section_name_map for book $map_name\n";
 442     }
 443   }
 444
 445   if (defined $file) {
 446     return &$original_func($node, $node_id, $node_hxmlt_id, $file);
 447   } else {
 448     return &$original_func($node, $node_id, $node_hxmlt_id);
 449   }
 450 }
 451
 452
 453
 454
 455
 456 #############################################################################
 457 ###  CUSTOM TOC FOR EACH PAGE (in a frame on the left)
 458 #############################################################################
 459
 460 my $page_toc_depth = 2;
 461 my @default_toc = [];
 462
 463 # recursively generate the TOC entries for the element and its children (which
 464 # are only shown up to maxlevel. All ancestors of the current element are also
 465 # shown with their immediate children, irrespective of their level.
 466 # Unnumbered entries are only printed out if they are at top-level or their
 467 # parent element is an ancestor of the currently viewed node.
 468 sub generate_ly_toc_entries($$$$)
 469 {
 470   my $element = shift;
 471   my $element_path = shift;
 472   my $maxlevel = shift;
 473   my $always_show_unnumbered_children = shift;
 474   # Skip undefined sections, plus all sections generated by index splitting
 475   return() if (not defined($element) or exists($element->{'index_page'}));
 476   my @result = ();
 477   my $level = $element->{'toc_level'};
 478   my $is_parent_of_current = $element->{'id'} && $element_path->{$element->{'id'}};
 479   my $print_children = ( ($level < $maxlevel) or $is_parent_of_current );
 480   my $ind = '  ' x $level;
 481   my $this_css_class = $is_parent_of_current ? " class=\"toc_current\"" : "";
 482
 483   my $entry = "$ind<li$this_css_class>" . &$anchor ($element->{'tocid'}, "$element->{'file'}#$element->{'id'}",$element->{'text'});
 484
 485   my $children = $element->{'section_childs'};
 486   # Don't add unnumbered entries, unless they are at top-level or a parent of the current!
 487   if (not ($element->{'number'} or $always_show_unnumbered_children)) {
 488     return @result;
 489   }
 490   if ( $print_children and defined($children) and (ref($children) eq "ARRAY") ) {
 491     push (@result, $entry);
 492     my @child_result = ();
 493     foreach (@$children) {
 494       push (@child_result, generate_ly_toc_entries($_, $element_path, $maxlevel, $is_parent_of_current));
 495     }
 496     # if no child nodes were generated, e.g. for the index, where expanded pages
 497     # are ignored, don't generate a list at all...
 498     if (@child_result) {
 499       push (@result, "\n$ind<ul$NO_BULLET_LIST_ATTRIBUTE>\n");
 500       push (@result, @child_result);
 501       push (@result, "$ind</ul></li>\n");
 502     }
 503   } else {
 504     push (@result, $entry . "</li>\n");
 505   }
 506   return @result;
 507 }
 508
 509
 510 # Print a customized TOC, containing only the first two levels plus the whole
 511 # path to the current page
 512 sub lilypond_generate_page_toc_body($)
 513 {
 514     my $element = shift;
 515     my $current_element = $element;
 516     my %parentelements;
 517     $parentelements{$element->{'id'}} = 1;
 518     # Find the path to the current element
 519     while ( defined($current_element->{'sectionup'}) and
 520            ($current_element->{'sectionup'} ne $current_element) )
 521     {
 522       $parentelements{$current_element->{'sectionup'}->{'id'}} = 1
 523               if ($current_element->{'sectionup'}->{'id'} ne '');
 524       $current_element = $current_element->{'sectionup'};
 525     }
 526     return () if not defined($current_element);
 527     # Create the toc entries recursively
 528     my @toc_entries = ("<div class=\"contents\">\n", "<ul$NO_BULLET_LIST_ATTRIBUTE>\n");
 529     my $children = $current_element->{'section_childs'};
 530     foreach ( @$children ) {
 531       push (@toc_entries, generate_ly_toc_entries($_, \%parentelements, $page_toc_depth, False));
 532     }
 533     push (@toc_entries, "</ul>\n");
 534     push (@toc_entries, "</div>\n");
 535     return @toc_entries;
 536 }
 537
 538 sub lilypond_print_toc_div ($$)
 539 {
 540   my $fh = shift;
 541   my $tocref = shift;
 542   my @lines = @$tocref;
 543   # use default TOC if no custom lines have been generated
 544   @lines = @default_toc if (not @lines);
 545   if (@lines) {
 546     print $fh "\n\n<div id=\"tocframe\">\n";
 547     print $fh '<h4> ' . $Texi2HTML::NAME{'Contents'}  . "</h4>\n";
 548     foreach my $line (@lines) {
 549       print $fh $line;
 550     }
 551     print $fh "</div>\n\n";
 552   }
 553 }
 554
 555 # Create the custom TOC for this page (partially folded, current page is
 556 # highlighted) and store it in a global variable. The TOC is written out after
 557 # the html contents (but positioned correctly using CSS), so that browsers with
 558 # css turned off still show the contents first.
 559 our @this_page_toc = ();
 560 sub lilypond_print_element_header
 561 {
 562   my $fh = shift;
 563   my $first_in_page = shift;
 564   my $previous_is_top = shift;
 565   if ($first_in_page and not @this_page_toc) {
 566     if (defined($Texi2HTML::THIS_ELEMENT)) {
 567       # Create the TOC for this page
 568       @this_page_toc = lilypond_generate_page_toc_body($Texi2HTML::THIS_ELEMENT);
 569     }
 570   }
 571   return T2H_DEFAULT_print_element_header( $fh, $first_in_page, $previous_is_top);
 572 }
 573
 574 # Generate the HTML output for the TOC
 575 sub lilypond_toc_body($)
 576 {
 577     my $elements_list = shift;
 578     # Generate a default TOC for pages without THIS_ELEMENT
 579     @default_toc = lilypond_generate_page_toc_body(@$elements_list[0]);
 580     return T2H_GPL_toc_body($elements_list);
 581 }
 582
 583 # Print out the TOC in a <div> at the beginning of the page
 584 sub lilypond_print_page_head($)
 585 {
 586     my $fh = shift;
 587     T2H_DEFAULT_print_page_head($fh);
 588     print $fh "<div id=\"main\">\n";
 589 }
 590
 591 # Print out the TOC in a <div> at the end of th page, which will be formatted as a
 592 # sidebar mimicking a TOC frame
 593 sub print_lilypond_page_foot($)
 594 {
 595   my $fh = shift;
 596   my $program_string = &$program_string();
 597   print $fh "<p><font size='-1'>$program_string</font><br>$PRE_BODY_CLOSE</p>\n";
 598   print $fh "<!-- FOOTER -->\n\n";
 599   print $fh "<!-- end div#main here -->\n</div>\n\n";
 600
 601   # Print the TOC frame and reset the TOC:
 602   lilypond_print_toc_div ($fh, \@this_page_toc);
 603   @this_page_toc = ();
 604
 605   # Close the page:
 606   print $fh "</body>\n</html>\n";
 607 }
 608
 609
 610
 611
 612
 613 #############################################################################
 614 ###  NICER / MORE FLEXIBLE NAVIGATION PANELS
 615 #############################################################################
 616
 617 sub get_navigation_text
 618 {
 619   my $button = shift;
 620   my $text = $NAVIGATION_TEXT{$button};
 621   if ( ($button eq 'Back') or ($button eq 'FastBack') ) {
 622     $text = $text . $Texi2HTML::NODE{$button} . "&nbsp;";
 623   } elsif ( ($button eq 'Forward') or ($button eq 'FastForward') ) {
 624     $text = "&nbsp;" . $Texi2HTML::NODE{$button} . $text;
 625   } elsif ( $button eq 'Up' ) {
 626     $text = "&nbsp;".$text.":&nbsp;" . $Texi2HTML::NODE{$button} . "&nbsp;";
 627   }
 628   return $text;
 629 }
 630
 631
 632 # Don't automatically create left-aligned table cells for every link, but
 633 # instead create a <td> only on an appropriate '(left|right|center)-aligned-cell-n'
 634 # button text. It's alignment as well as the colspan will be taken from the
 635 # name of the button. Also, add 'newline' button text to create a new table
 636 # row. The texts of the buttons are generated by get_navigation_text and
 637 # will contain the name of the next/previous section/chapter.
 638 sub lilypond_print_navigation
 639 {
 640     my $fh = shift;
 641     my $buttons = shift;
 642     my $vertical = shift;
 643     my $spacing = 1;
 644 #     print $fh '<table cellpadding="', $spacing, '" cellspacing="', $spacing,
 645 #       "\" border=\"0\" class=\"nav_table\">\n";
 646     print $fh "<table class=\"nav_table\">\n";
 647
 648     print $fh "<tr>" unless $vertical;
 649     my $beginofline = 1;
 650     foreach my $button (@$buttons)
 651     {
 652         print $fh qq{<tr valign="top" align="left">\n} if $vertical;
 653         # Allow (left|right|center)-aligned-cell and newline as buttons!
 654         if ( $button =~ /^(.*)-aligned-cell-(.*)$/ )
 655         {
 656           print $fh qq{</td>} unless $beginofline;
 657           print $fh qq{<td valign="middle" align="$1" colspan="$2">};
 658           $beginofline = 0;
 659         }
 660         elsif ( $button eq 'newline' )
 661         {
 662           print $fh qq{</td>} unless $beginofline;
 663           print $fh qq{</tr>};
 664           print $fh qq{<tr>};
 665           $beginofline = 1;
 666
 667         }
 668         elsif (ref($button) eq 'CODE')
 669         {
 670             &$button($fh, $vertical);
 671         }
 672         elsif (ref($button) eq 'SCALAR')
 673         {
 674             print $fh "$$button" if defined($$button);
 675         }
 676         elsif (ref($button) eq 'ARRAY')
 677         {
 678             my $text = $button->[1];
 679             my $button_href = $button->[0];
 680             # verify that $button_href is simple text and text is a reference
 681             if (defined($button_href) and !ref($button_href)
 682                and defined($text) and (ref($text) eq 'SCALAR') and defined($$text))
 683             {             # use given text
 684                 if ($Texi2HTML::HREF{$button_href})
 685                 {
 686                   my $anchor_attributes = '';
 687                   if ($USE_ACCESSKEY and (defined($BUTTONS_ACCESSKEY{$button_href})) and ($BUTTONS_ACCESSKEY{$button_href} ne ''))
 688                   {
 689                       $anchor_attributes = "accesskey=\"$BUTTONS_ACCESSKEY{$button_href}\"";
 690                   }
 691                   if ($USE_REL_REV and (defined($BUTTONS_REL{$button_href})) and ($BUTTONS_REL{$button_href} ne ''))
 692                   {
 693                       $anchor_attributes .= " rel=\"$BUTTONS_REL{$button_href}\"";
 694                   }
 695                   print $fh "" .
 696                         &$anchor('',
 697                                     $Texi2HTML::HREF{$button_href},
 698                                     get_navigation_text($$text),
 699                                     $anchor_attributes
 700                                    );
 701                 }
 702                 else
 703                 {
 704                   print $fh get_navigation_text($$text);
 705                 }
 706             }
 707         }
 708         elsif ($button eq ' ')
 709         {                       # handle space button
 710             print $fh
 711                 ($ICONS && $ACTIVE_ICONS{' '}) ?
 712                     &$button_icon_img($BUTTONS_NAME{$button}, $ACTIVE_ICONS{' '}) :
 713                         $NAVIGATION_TEXT{' '};
 714             #next;
 715         }
 716         elsif ($Texi2HTML::HREF{$button})
 717         {                       # button is active
 718             my $btitle = $BUTTONS_GOTO{$button} ?
 719                 'title="' . $BUTTONS_GOTO{$button} . '"' : '';
 720             if ($USE_ACCESSKEY and (defined($BUTTONS_ACCESSKEY{$button})) and ($BUTTONS_ACCESSKEY{$button} ne ''))
 721             {
 722                 $btitle .= " accesskey=\"$BUTTONS_ACCESSKEY{$button}\"";
 723             }
 724             if ($USE_REL_REV and (defined($BUTTONS_REL{$button})) and ($BUTTONS_REL{$button} ne ''))
 725             {
 726                 $btitle .= " rel=\"$BUTTONS_REL{$button}\"";
 727             }
 728             if ($ICONS && $ACTIVE_ICONS{$button})
 729             {                   # use icon
 730                 print $fh '' .
 731                     &$anchor('',
 732                         $Texi2HTML::HREF{$button},
 733                         &$button_icon_img($BUTTONS_NAME{$button},
 734                                    $ACTIVE_ICONS{$button},
 735                                    $Texi2HTML::SIMPLE_TEXT{$button}),
 736                         $btitle
 737                       );
 738             }
 739             else
 740             {                   # use text
 741                 print $fh
 742                     '[' .
 743                         &$anchor('',
 744                                     $Texi2HTML::HREF{$button},
 745                                     get_navigation_text ($button),
 746                                     $btitle
 747                                    ) .
 748                                        ']';
 749             }
 750         }
 751         else
 752         {                       # button is passive
 753             print $fh
 754                 $ICONS && $PASSIVE_ICONS{$button} ?
 755                     &$button_icon_img($BUTTONS_NAME{$button},
 756                                           $PASSIVE_ICONS{$button},
 757                                           $Texi2HTML::SIMPLE_TEXT{$button}) :
 758
 759                                               "[" . get_navigation_text($button) . "]";
 760         }
 761         print $fh "</td>\n" if $vertical;
 762         print $fh "</tr>\n" if $vertical;
 763     }
 764     print $fh "</td>" unless $beginofline;
 765     print $fh "</tr>" unless $vertical;
 766     print $fh "</table>\n";
 767 }
 768
 769
 770 @Texi2HTML::Config::SECTION_BUTTONS =
 771     ('left-aligned-cell-1', 'FastBack',
 772      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 773      'right-aligned-cell-1', 'FastForward',
 774      'newline',
 775      'left-aligned-cell-2', 'Back',
 776      'center-aligned-cell-1', 'Up',
 777      'right-aligned-cell-2', 'Forward'
 778     );
 779
 780 # buttons for misc stuff
 781 @Texi2HTML::Config::MISC_BUTTONS = ('center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About');
 782
 783 # buttons for chapter file footers
 784 # (and headers but only if SECTION_NAVIGATION is false)
 785 @Texi2HTML::Config::CHAPTER_BUTTONS =
 786     ('left-aligned-cell-1', 'FastBack',
 787      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 788      'right-aligned-cell-1', 'FastForward',
 789     );
 790
 791 # buttons for section file footers
 792 @Texi2HTML::Config::SECTION_FOOTER_BUTTONS =
 793     ('left-aligned-cell-1', 'FastBack',
 794      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 795      'right-aligned-cell-1', 'FastForward',
 796      'newline',
 797      'left-aligned-cell-2', 'Back',
 798      'center-aligned-cell-1', 'Up',
 799      'right-aligned-cell-2', 'Forward'
 800     );
 801
 802 @Texi2HTML::Config::NODE_FOOTER_BUTTONS =
 803     ('left-aligned-cell-1', 'FastBack',
 804      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 805      'right-aligned-cell-1', 'FastForward',
 806      'newline',
 807      'left-aligned-cell-2', 'Back',
 808      'center-aligned-cell-1', 'Up',
 809      'right-aligned-cell-2', 'Forward'
 810     );
 811
 812
 813
 814
 815
 816 #############################################################################
 817 ###  OTHER SETTINGS
 818 #############################################################################
 819
 820 # For split pages, use index.html as start page!
 821 if ($Texi2HTML::Config::SPLIT eq 'section') {
 822   $Texi2HTML::Config::TOP_FILE = 'index.html';
 823 }
 824
 825
 826 return 1;