lily/parser.yy

   1 /*
   2   This file is part of LilyPond, the GNU music typesetter.
   3
   4   Copyright (C) 1997--2011 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5                  Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7   LilyPond is free software: you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation, either version 3 of the License, or
  10   (at your option) any later version.
  11
  12   LilyPond is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  19 */
  20
  21 %{
  22
  23 #define YYDEBUG 1
  24 #define YYERROR_VERBOSE 1
  25 #define YYPARSE_PARAM my_lily_parser
  26 #define YYLEX_PARAM my_lily_parser
  27 #define PARSER ((Lily_parser *) my_lily_parser)
  28
  29 #define yyerror PARSER->parser_error
  30
  31 /* We use custom location type: Input objects */
  32 #define YYLTYPE Input
  33 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  34         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  35
  36
  37 %}
  38
  39 /* We use SCMs to do strings, because it saves us the trouble of
  40 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  41 of the parse stack onto the heap. */
  42
  43 %left PREC_BOT
  44 %nonassoc REPEAT
  45 %nonassoc ALTERNATIVE
  46
  47 /* The above precedences tackle the shift/reduce problem
  48
  49 1.  \repeat
  50         \repeat .. \alternative
  51
  52     \repeat { \repeat .. \alternative }
  53
  54 or
  55
  56     \repeat { \repeat } \alternative
  57 */
  58
  59 %nonassoc COMPOSITE
  60 %left ADDLYRICS
  61
  62  /* ADDLYRICS needs to have lower precedence than argument scanning,
  63   * or we won't be able to tell music apart from closed_music without
  64   * lookahead in the context of function calls.
  65   */
  66
  67 %nonassoc DEFAULT
  68
  69  /* \default is only applied after exhausting function arguments */
  70
  71 %nonassoc FUNCTION_ARGLIST
  72
  73  /* expressions with units are permitted into argument lists */
  74
  75 %right PITCH_IDENTIFIER NOTENAME_PITCH TONICNAME_PITCH
  76       UNSIGNED REAL DURATION_IDENTIFIER ':'
  77
  78  /* The above are the symbols that can start optional function arguments
  79     that are recognized in the grammar rather than by predicate
  80  */
  81
  82 %nonassoc NUMBER_IDENTIFIER '/'
  83
  84  /* Number-unit expressions, where permitted, are concatenated into
  85   * function arguments, just like fractions and tremoli.  Tremoli must
  86   * not have higher precedence than UNSIGNED, or Lilypond will not
  87   * join ':' with a following optional number.
  88   */
  89
  90 %left PREC_TOP
  91
  92
  93
  94
  95 %pure_parser
  96 %locations
  97
  98
  99
 100 %{ // -*-Fundamental-*-
 101
 102 /*
 103 FIXME:
 104
 105    * The rules for who is protecting what are very shady.  Uniformise
 106      this.
 107
 108    * There are too many lexical modes?
 109 */
 110
 111 #include "config.hh"
 112
 113 #include <cctype>
 114 #include <cstdlib>
 115 #include <cstdio>
 116 using namespace std;
 117
 118 #include "book.hh"
 119 #include "context-def.hh"
 120 #include "context-mod.hh"
 121 #include "dimensions.hh"
 122 #include "file-path.hh"
 123 #include "input.hh"
 124 #include "international.hh"
 125 #include "lily-guile.hh"
 126 #include "lily-lexer.hh"
 127 #include "lily-parser.hh"
 128 #include "main.hh"
 129 #include "misc.hh"
 130 #include "music.hh"
 131 #include "output-def.hh"
 132 #include "paper-book.hh"
 133 #include "scm-hash.hh"
 134 #include "score.hh"
 135 #include "text-interface.hh"
 136 #include "warn.hh"
 137
 138 #define MYBACKUP(Token, Value, Location)                                \
 139 do                                                                      \
 140         if (yychar == YYEMPTY)                                          \
 141         {                                                               \
 142                 if (Token)                                              \
 143                         PARSER->lexer_->push_extra_token (Token, Value); \
 144                 PARSER->lexer_->push_extra_token (BACKUP);              \
 145         } else {                                                        \
 146                 PARSER->parser_error                                    \
 147                         (Location, _("Too much lookahead"));            \
 148         }                                                               \
 149 while (0)
 150
 151
 152 #define MYREPARSE(Location, Default, Pred, Token, Value)                \
 153 do                                                                      \
 154         if (yychar == YYEMPTY)                                          \
 155         {                                                               \
 156                 PARSER->lexer_->push_extra_token (Token, Value);        \
 157                 if (Default != SCM_UNDEFINED)                           \
 158                         PARSER->lexer_->push_extra_token (REPARSE,      \
 159                                                           scm_cons (Default, Pred)); \
 160                 else                                                    \
 161                         PARSER->lexer_->push_extra_token (REPARSE,      \
 162                                                           Pred);        \
 163         } else {                                                        \
 164                 PARSER->parser_error                                    \
 165                         (Location, _("Too much lookahead"));            \
 166         }                                                               \
 167 while (0)
 168
 169 %}
 170
 171
 172 %union {
 173         Book *book;
 174         Output_def *outputdef;
 175         SCM scm;
 176         std::string *string;
 177         Score *score;
 178         int i;
 179 }
 180
 181 %{
 182
 183 #define MY_MAKE_MUSIC(x, spot)  make_music_with_input (ly_symbol2scm (x), spot)
 184
 185 /* ES TODO:
 186 - Don't use lily module, create a new module instead.
 187 - delay application of the function
 188 */
 189 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 190   scm_apply_0 (proc, args)
 191 /* Syntactic Sugar. */
 192 #define MAKE_SYNTAX(name, location, ...)        \
 193   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (PARSER->self_scm (), make_input (location) , ##__VA_ARGS__, SCM_UNDEFINED));
 194 #define START_MAKE_SYNTAX(name, ...)                                    \
 195         scm_list_n (ly_lily_module_constant (name) , ##__VA_ARGS__, SCM_UNDEFINED)
 196 #define FINISH_MAKE_SYNTAX(start, location, ...)                        \
 197         LOWLEVEL_MAKE_SYNTAX (scm_car (start), scm_cons2 (PARSER->self_scm (), make_input (location), scm_append_x (scm_list_2 (scm_cdr (start), scm_list_n (__VA_ARGS__, SCM_UNDEFINED)))))
 198
 199 SCM get_next_unique_context_id ();
 200 SCM get_next_unique_lyrics_context_id ();
 201
 202 #undef _
 203 #if !HAVE_GETTEXT
 204 #define _(x) x
 205 #else
 206 #include <libintl.h>
 207 #define _(x) gettext (x)
 208 #endif
 209
 210
 211 static Music *make_music_with_input (SCM name, Input where);
 212 SCM check_scheme_arg (Lily_parser *parser, Input loc, SCM fallback,
 213                       SCM arg, SCM args, SCM pred);
 214 SCM loc_on_music (Input loc, SCM arg);
 215 SCM get_first_context_id (SCM type, Music *m);
 216 SCM make_chord_elements (SCM pitch, SCM dur, SCM modification_list);
 217 SCM make_chord_step (int step, Rational alter);
 218 SCM make_simple_markup (SCM a);
 219 SCM try_unpack_lyrics (SCM pred, SCM arg);
 220 bool is_duration (int t);
 221 bool is_regular_identifier (SCM id);
 222 bool ly_input_procedure_p (SCM x);
 223 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 224 void set_music_properties (Music *p, SCM a);
 225
 226 %}
 227
 228 /* The third option is an alias that will be used to display the
 229    syntax error.  Bison CVS now correctly handles backslash escapes.
 230
 231    FIXME: Bison needs to translate some of these, eg, STRING.
 232
 233 */
 234
 235 /* Keyword tokens with plain escaped name.  */
 236 %token ACCEPTS "\\accepts"
 237 %token ADDLYRICS "\\addlyrics"
 238 %token ALIAS "\\alias"
 239 %token ALTERNATIVE "\\alternative"
 240 %token BOOK "\\book"
 241 %token BOOKPART "\\bookpart"
 242 %token CHANGE "\\change"
 243 %token CHORDMODE "\\chordmode"
 244 %token CHORDS "\\chords"
 245 %token CONSISTS "\\consists"
 246 %token CONTEXT "\\context"
 247 %token DEFAULT "\\default"
 248 %token DEFAULTCHILD "\\defaultchild"
 249 %token DENIES "\\denies"
 250 %token DESCRIPTION "\\description"
 251 %token DRUMMODE "\\drummode"
 252 %token DRUMS "\\drums"
 253 %token FIGUREMODE "\\figuremode"
 254 %token FIGURES "\\figures"
 255 %token GROBDESCRIPTIONS "\\grobdescriptions"
 256 %token HEADER "\\header"
 257 %token INVALID "\\version-error"
 258 %token LAYOUT "\\layout"
 259 %token LYRICMODE "\\lyricmode"
 260 %token LYRICS "\\lyrics"
 261 %token LYRICSTO "\\lyricsto"
 262 %token MARKUP "\\markup"
 263 %token MARKUPLIST "\\markuplist"
 264 %token MIDI "\\midi"
 265 %token NAME "\\name"
 266 %token NOTEMODE "\\notemode"
 267 %token OVERRIDE "\\override"
 268 %token PAPER "\\paper"
 269 %token REMOVE "\\remove"
 270 %token REPEAT "\\repeat"
 271 %token REST "\\rest"
 272 %token REVERT "\\revert"
 273 %token SCORE "\\score"
 274 %token SEQUENTIAL "\\sequential"
 275 %token SET "\\set"
 276 %token SIMULTANEOUS "\\simultaneous"
 277 %token TEMPO "\\tempo"
 278 %token TYPE "\\type"
 279 %token UNSET "\\unset"
 280 %token WITH "\\with"
 281
 282 /* Keyword token exceptions.  */
 283 %token NEWCONTEXT "\\new"
 284
 285
 286 /* Other string tokens.  */
 287
 288 %token CHORD_BASS "/+"
 289 %token CHORD_CARET "^"
 290 %token CHORD_COLON ":"
 291 %token CHORD_MINUS "-"
 292 %token CHORD_SLASH "/"
 293 %token ANGLE_OPEN "<"
 294 %token ANGLE_CLOSE ">"
 295 %token DOUBLE_ANGLE_OPEN "<<"
 296 %token DOUBLE_ANGLE_CLOSE ">>"
 297 %token E_BACKSLASH "\\"
 298 %token E_ANGLE_CLOSE "\\>"
 299 %token E_CHAR "\\C[haracter]"
 300 %token E_CLOSE "\\)"
 301 %token E_EXCLAMATION "\\!"
 302 %token E_BRACKET_OPEN "\\["
 303 %token E_OPEN "\\("
 304 %token E_BRACKET_CLOSE "\\]"
 305 %token E_ANGLE_OPEN "\\<"
 306 %token E_PLUS "\\+"
 307 %token E_TILDE "\\~"
 308 %token EXTENDER "__"
 309
 310 /*
 311 If we give names, Bison complains.
 312 */
 313 %token FIGURE_CLOSE /* "\\>" */
 314 %token FIGURE_OPEN /* "\\<" */
 315 %token FIGURE_SPACE "_"
 316 %token HYPHEN "--"
 317
 318 %token CHORDMODIFIERS
 319 %token LYRIC_MARKUP
 320 %token MULTI_MEASURE_REST
 321
 322
 323 %token <i> E_UNSIGNED
 324 %token <scm> UNSIGNED
 325
 326 /* Artificial tokens, for more generic function syntax */
 327 %token <i> EXPECT_MARKUP "markup?"
 328 %token <i> EXPECT_PITCH "ly:pitch?"
 329 %token <i> EXPECT_DURATION "ly:duration?"
 330 %token <scm> EXPECT_SCM "scheme?"
 331 %token <scm> BACKUP "(backed-up?)"
 332 %token <scm> REPARSE "(reparsed?)"
 333 %token <i> EXPECT_MARKUP_LIST "markup-list?"
 334 %token <scm> EXPECT_OPTIONAL "optional?"
 335 /* After the last argument. */
 336 %token <i> EXPECT_NO_MORE_ARGS;
 337
 338 /* An artificial token for parsing embedded Lilypond */
 339 %token <i> EMBEDDED_LILY "#{"
 340
 341 %token <scm> BOOK_IDENTIFIER
 342 %token <scm> CHORDMODIFIER_PITCH
 343 %token <scm> CHORD_MODIFIER
 344 %token <scm> CHORD_REPETITION
 345 %token <scm> CONTEXT_DEF_IDENTIFIER
 346 %token <scm> CONTEXT_MOD_IDENTIFIER
 347 %token <scm> DRUM_PITCH
 348 %token <scm> PITCH_IDENTIFIER
 349 %token <scm> DURATION_IDENTIFIER
 350 %token <scm> EVENT_IDENTIFIER
 351 %token <scm> EVENT_FUNCTION
 352 %token <scm> FRACTION
 353 %token <scm> LYRICS_STRING
 354 %token <scm> LYRIC_ELEMENT
 355 %token <scm> LYRIC_ELEMENT_P
 356 %token <scm> LYRIC_MARKUP_IDENTIFIER
 357 %token <scm> MARKUP_FUNCTION
 358 %token <scm> MARKUP_LIST_FUNCTION
 359 %token <scm> MARKUP_IDENTIFIER
 360 %token <scm> MARKUPLIST_IDENTIFIER
 361 %token <scm> MUSIC_FUNCTION
 362 %token <scm> MUSIC_IDENTIFIER
 363 %token <scm> NOTENAME_PITCH
 364 %token <scm> NUMBER_IDENTIFIER
 365 %token <scm> OUTPUT_DEF_IDENTIFIER
 366 %token <scm> REAL
 367 %token <scm> RESTNAME
 368 %token <scm> SCM_FUNCTION
 369 %token <scm> SCM_IDENTIFIER
 370 %token <scm> SCM_TOKEN
 371 %token <scm> SCORE_IDENTIFIER
 372 %token <scm> STRING
 373 %token <scm> STRING_IDENTIFIER
 374 %token <scm> TONICNAME_PITCH
 375
 376
 377 %type <book> book_block
 378 %type <book> book_body
 379 %type <book> bookpart_block
 380 %type <book> bookpart_body
 381
 382 %type <i> bare_unsigned
 383 %type <scm> figured_bass_alteration
 384 %type <i> dots
 385 %type <i> exclamations
 386 %type <i> optional_rest
 387 %type <i> questions
 388 %type <i> script_dir
 389 %type <i> sub_quotes
 390 %type <i> sup_quotes
 391 %type <i> tremolo_type
 392
 393 /* Music */
 394 %type <scm> composite_music
 395 %type <scm> grouped_music_list
 396 %type <scm> braced_music_list
 397 %type <scm> closed_music
 398 %type <scm> music
 399 %type <scm> music_bare
 400 %type <scm> music_arg
 401 %type <scm> complex_music
 402 %type <scm> complex_music_prefix
 403 %type <scm> mode_changed_music
 404 %type <scm> repeated_music
 405 %type <scm> sequential_music
 406 %type <scm> simple_music
 407 %type <scm> simultaneous_music
 408 %type <scm> chord_body
 409 %type <scm> chord_body_element
 410 %type <scm> command_element
 411 %type <scm> command_event
 412 %type <scm> context_modification
 413 %type <scm> context_change
 414 %type <scm> direction_less_event
 415 %type <scm> direction_reqd_event
 416 %type <scm> embedded_lilypond
 417 %type <scm> event_chord
 418 %type <scm> fingering
 419 %type <scm> gen_text_def
 420 %type <scm> music_property_def
 421 %type <scm> note_chord_element
 422 %type <scm> post_event
 423 %type <scm> post_event_nofinger
 424 %type <scm> re_rhythmed_music
 425 %type <scm> simple_element
 426 %type <scm> simple_music_property_def
 427 %type <scm> start_symbol
 428 %type <scm> string_number_event
 429 %type <scm> tempo_event
 430
 431 %type <outputdef> output_def_body
 432 %type <outputdef> output_def_head
 433 %type <outputdef> output_def_head_with_mode_switch
 434 %type <outputdef> output_def
 435 %type <outputdef> paper_block
 436
 437 %type <scm> music_function_call
 438 %type <scm> music_list
 439 %type <scm> assignment_id
 440 %type <scm> bare_number
 441 %type <scm> bare_number_closed
 442 %type <scm> unsigned_number
 443 %type <scm> bass_figure
 444 %type <scm> figured_bass_modification
 445 %type <scm> br_bass_figure
 446 %type <scm> bass_number
 447 %type <scm> chord_body_elements
 448 %type <scm> chord_item
 449 %type <scm> chord_items
 450 %type <scm> chord_separator
 451 %type <scm> context_def_mod
 452 %type <scm> context_def_spec_block
 453 %type <scm> context_def_spec_body
 454 %type <scm> context_mod
 455 %type <scm> context_mod_list
 456 %type <scm> context_prop_spec
 457 %type <scm> direction_less_char
 458 %type <scm> duration_length
 459 %type <scm> embedded_scm
 460 %type <scm> embedded_scm_arg
 461 %type <scm> embedded_scm_arg_closed
 462 %type <scm> embedded_scm_bare
 463 %type <scm> embedded_scm_bare_arg
 464 %type <scm> embedded_scm_closed
 465 %type <scm> embedded_scm_chord_body
 466 %type <scm> event_function_event
 467 %type <scm> figure_list
 468 %type <scm> figure_spec
 469 %type <scm> fraction
 470 %type <scm> full_markup
 471 %type <scm> full_markup_list
 472 %type <scm> function_arglist
 473 %type <scm> function_arglist_optional
 474 %type <scm> function_arglist_backup
 475 %type <scm> function_arglist_nonbackup
 476 %type <scm> function_arglist_skip
 477 %type <scm> function_arglist_bare
 478 %type <scm> function_arglist_closed
 479 %type <scm> function_arglist_closed_optional
 480 %type <scm> function_arglist_common
 481 %type <scm> function_arglist_common_lyric
 482 %type <scm> function_arglist_closed_common
 483 %type <scm> function_arglist_keep
 484 %type <scm> function_arglist_closed_keep
 485 %type <scm> identifier_init
 486 %type <scm> lilypond
 487 %type <scm> lilypond_header
 488 %type <scm> lilypond_header_body
 489 %type <scm> lyric_element
 490 %type <scm> lyric_element_arg
 491 %type <scm> lyric_element_music
 492 %type <scm> lyric_markup
 493 %type <scm> markup
 494 %type <scm> markup_braced_list
 495 %type <scm> markup_braced_list_body
 496 %type <scm> markup_composed_list
 497 %type <scm> markup_command_list
 498 %type <scm> markup_command_list_arguments
 499 %type <scm> markup_command_basic_arguments
 500 %type <scm> markup_head_1_item
 501 %type <scm> markup_head_1_list
 502 %type <scm> markup_list
 503 %type <scm> markup_top
 504 %type <scm> mode_changing_head
 505 %type <scm> mode_changing_head_with_context
 506 %type <scm> multiplied_duration
 507 %type <scm> music_function_event
 508 %type <scm> music_function_chord_body
 509 %type <scm> music_function_chord_body_arglist
 510 %type <scm> new_chord
 511 %type <scm> new_lyrics
 512 %type <scm> number_expression
 513 %type <scm> number_factor
 514 %type <scm> number_term
 515 %type <scm> octave_check
 516 %type <scm> optional_context_mod
 517 %type <scm> optional_id
 518 %type <scm> optional_notemode_duration
 519 %type <scm> pitch
 520 %type <scm> pitch_also_in_chords
 521 %type <scm> post_events
 522 %type <scm> property_operation
 523 %type <scm> property_path property_path_revved
 524 %type <scm> scalar
 525 %type <scm> scalar_closed
 526 %type <scm> scm_function_call
 527 %type <scm> scm_function_call_closed
 528 %type <scm> script_abbreviation
 529 %type <scm> simple_chord_elements
 530 %type <scm> simple_markup
 531 %type <scm> simple_string
 532 %type <scm> steno_duration
 533 %type <scm> steno_pitch
 534 %type <scm> steno_tonic_pitch
 535 %type <scm> step_number
 536 %type <scm> step_numbers
 537 %type <scm> string
 538 %type <scm> tempo_range
 539
 540 %type <score> score_block
 541 %type <score> score_body
 542
 543
 544 %left '-' '+'
 545
 546 /* We don't assign precedence to / and *, because we might need varied
 547 prec levels in different prods */
 548
 549 %left UNARY_MINUS
 550
 551 %%
 552
 553 start_symbol:
 554         lilypond
 555         | EMBEDDED_LILY {
 556                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
 557                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
 558         } embedded_lilypond {
 559                 PARSER->lexer_->pop_state ();
 560                 PARSER->lexer_->set_identifier (ly_symbol2scm ("parseStringResult"), $3);
 561         }
 562         ;
 563
 564 lilypond:       /* empty */ { }
 565         | lilypond toplevel_expression {
 566         }
 567         | lilypond assignment {
 568         }
 569         | lilypond error {
 570                 PARSER->error_level_ = 1;
 571         }
 572         | lilypond INVALID      {
 573                 PARSER->error_level_ = 1;
 574         }
 575         ;
 576
 577
 578 toplevel_expression:
 579         lilypond_header {
 580                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 581         }
 582         | book_block {
 583                 Book *book = $1;
 584                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 585                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 586                 book->unprotect ();
 587         }
 588         | bookpart_block {
 589                 Book *bookpart = $1;
 590                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 591                 scm_call_2 (proc, PARSER->self_scm (), bookpart->self_scm ());
 592                 bookpart->unprotect ();
 593         }
 594         | score_block {
 595                 Score *score = $1;
 596
 597                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 598                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 599                 score->unprotect ();
 600         }
 601         | composite_music {
 602                 Music *music = unsmob_music ($1);
 603                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 604                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 605         }
 606         | full_markup {
 607                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 608                 scm_call_2 (proc, PARSER->self_scm (), scm_list_1 ($1));
 609         }
 610         | full_markup_list {
 611                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 612                 scm_call_2 (proc, PARSER->self_scm (), $1);
 613         }
 614         | output_def {
 615                 SCM id = SCM_EOL;
 616                 Output_def * od = $1;
 617
 618                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 619                         id = ly_symbol2scm ("$defaultpaper");
 620                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 621                         id = ly_symbol2scm ("$defaultmidi");
 622                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 623                         id = ly_symbol2scm ("$defaultlayout");
 624
 625                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 626                 od->unprotect();
 627         }
 628         ;
 629
 630 embedded_scm_bare:
 631         SCM_TOKEN
 632         | SCM_IDENTIFIER
 633         ;
 634
 635 embedded_scm_bare_arg:
 636         embedded_scm_bare
 637         | STRING
 638         | STRING_IDENTIFIER
 639         | full_markup
 640         | full_markup_list
 641         | context_modification
 642         | score_block
 643         {
 644                 $$ = $1->self_scm ();
 645                 $1->unprotect ();
 646         }
 647         | context_def_spec_block
 648         | book_block
 649         {
 650                 $$ = $1->self_scm ();
 651                 $1->unprotect ();
 652         }
 653         | bookpart_block
 654         {
 655                 $$ = $1->self_scm ();
 656                 $1->unprotect ();
 657         }
 658         | output_def
 659         {
 660                 $$ = $1->self_scm ();
 661                 $1->unprotect ();
 662         }
 663         ;
 664
 665 /* The generic version may end in music, or not */
 666
 667 embedded_scm:
 668         embedded_scm_bare
 669         | scm_function_call
 670         ;
 671
 672 embedded_scm_arg:
 673         embedded_scm_bare_arg
 674         | scm_function_call
 675         | music_arg
 676         ;
 677
 678 scm_function_call:
 679         SCM_FUNCTION function_arglist {
 680                 $$ = MAKE_SYNTAX ("music-function", @$,
 681                                          $1, $2);
 682         }
 683         ;
 684
 685 embedded_lilypond:
 686         /* empty */
 687         {
 688                 $$ = MAKE_SYNTAX ("void-music", @$);
 689         }
 690         | identifier_init
 691         | music music music_list {
 692                 $$ = MAKE_SYNTAX ("sequential-music", @$,
 693                                   scm_cons2 ($1, $2, scm_reverse_x ($3, SCM_EOL)));
 694         }
 695         | error {
 696                 PARSER->error_level_ = 1;
 697         }
 698         | INVALID embedded_lilypond {
 699                 PARSER->error_level_ = 1;
 700         }
 701         ;
 702
 703
 704 lilypond_header_body:
 705         {
 706                 $$ = get_header (PARSER);
 707                 PARSER->lexer_->add_scope ($$);
 708         }
 709         | lilypond_header_body assignment  {
 710
 711         }
 712         ;
 713
 714 lilypond_header:
 715         HEADER '{' lilypond_header_body '}'     {
 716                 $$ = PARSER->lexer_->remove_scope ();
 717         }
 718         ;
 719
 720 /*
 721         DECLARATIONS
 722 */
 723 assignment_id:
 724         STRING          { $$ = $1; }
 725         | LYRICS_STRING { $$ = $1; }
 726         ;
 727
 728 assignment:
 729         assignment_id '=' identifier_init  {
 730                 PARSER->lexer_->set_identifier ($1, $3);
 731         }
 732         | assignment_id property_path '=' identifier_init {
 733                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 734                 PARSER->lexer_->set_identifier (path, $4);
 735         ;
 736 /*
 737  TODO: devise standard for protection in parser.
 738
 739   The parser stack lives on the C-stack, which means that
 740 all objects can be unprotected as soon as they're here.
 741
 742 */
 743         }
 744         | embedded_scm { }
 745         ;
 746
 747
 748 identifier_init:
 749         score_block {
 750                 $$ = $1->self_scm ();
 751                 $1->unprotect ();
 752         }
 753         | book_block {
 754                 $$ = $1->self_scm ();
 755                 $1->unprotect ();
 756         }
 757         | bookpart_block {
 758                 $$ = $1->self_scm ();
 759                 $1->unprotect ();
 760         }
 761         | output_def {
 762                 $$ = $1->self_scm ();
 763                 $1->unprotect ();
 764         }
 765         | context_def_spec_block {
 766                 $$ = $1;
 767         }
 768         | music  {
 769                 /* Hack: Create event-chord around standalone events.
 770                    Prevents the identifier from being interpreted as a post-event. */
 771                 Music *mus = unsmob_music ($1);
 772                 bool is_event = mus &&
 773                         (scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
 774                                 != SCM_BOOL_F);
 775                 if (!is_event)
 776                         $$ = $1;
 777                 else
 778                         $$ = MAKE_SYNTAX ("event-chord", @$, scm_list_1 ($1));
 779         }
 780         | post_event_nofinger {
 781                 $$ = $1;
 782         }
 783         | number_expression {
 784                 $$ = $1;
 785         }
 786         | string {
 787                 $$ = $1;
 788         }
 789         | embedded_scm {
 790                 $$ = $1;
 791         }
 792         | full_markup {
 793                 $$ = $1;
 794         }
 795         | full_markup_list {
 796                 $$ = $1;
 797         }
 798         | context_modification {
 799                 $$ = $1;
 800         }
 801         ;
 802
 803 context_def_spec_block:
 804         CONTEXT '{' context_def_spec_body '}'
 805                 {
 806                 $$ = $3;
 807         }
 808         ;
 809
 810 context_def_spec_body:
 811         /**/ {
 812                 $$ = Context_def::make_scm ();
 813                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 814         }
 815         | CONTEXT_DEF_IDENTIFIER {
 816                 $$ = $1;
 817                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 818         }
 819         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 820                 Context_def*td = unsmob_context_def ($$);
 821
 822                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 823                         SCM tag = scm_caar (p);
 824
 825                         /* TODO: should make new tag "grob-definition" ? */
 826                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 827                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 828                 }
 829         }
 830         | context_def_spec_body context_mod {
 831                 unsmob_context_def ($$)->add_context_mod ($2);
 832         }
 833         | context_def_spec_body context_modification {
 834                 Context_def *td = unsmob_context_def ($$);
 835                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 836                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 837                     td->add_context_mod (scm_car (m));
 838                 }
 839         }
 840         ;
 841
 842
 843
 844 book_block:
 845         BOOK '{' book_body '}'  {
 846                 $$ = $3;
 847                 pop_paper (PARSER);
 848                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 849         }
 850         ;
 851
 852 /* FIXME:
 853    * Use 'handlers' like for toplevel-* stuff?
 854    * grok \layout and \midi?  */
 855 book_body:
 856         {
 857                 $$ = new Book;
 858                 init_papers (PARSER);
 859                 $$->origin ()->set_spot (@$);
 860                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 861                 $$->paper_->unprotect ();
 862                 push_paper (PARSER, $$->paper_);
 863                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 864                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$->self_scm ());
 865                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-output-suffix"), SCM_BOOL_F);
 866                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-filename"), SCM_BOOL_F);
 867         }
 868         | BOOK_IDENTIFIER {
 869                 $$ = unsmob_book ($1);
 870                 $$->protect ();
 871                 $$->origin ()->set_spot (@$);
 872                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 873         }
 874         | book_body paper_block {
 875                 $$->paper_ = $2;
 876                 $2->unprotect ();
 877                 set_paper (PARSER, $2);
 878         }
 879         | book_body bookpart_block {
 880                 Book *bookpart = $2;
 881                 SCM proc = PARSER->lexer_->lookup_identifier ("book-bookpart-handler");
 882                 scm_call_2 (proc, $$->self_scm (), bookpart->self_scm ());
 883                 bookpart->unprotect ();
 884         }
 885         | book_body score_block {
 886                 Score *score = $2;
 887                 SCM proc = PARSER->lexer_->lookup_identifier ("book-score-handler");
 888                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 889                 score->unprotect ();
 890         }
 891         | book_body composite_music {
 892                 Music *music = unsmob_music ($2);
 893                 SCM proc = PARSER->lexer_->lookup_identifier ("book-music-handler");
 894                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 895         }
 896         | book_body full_markup {
 897                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 898                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 899         }
 900         | book_body full_markup_list {
 901                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 902                 scm_call_2 (proc, $$->self_scm (), $2);
 903         }
 904         | book_body lilypond_header {
 905                 $$->header_ = $2;
 906         }
 907         | book_body embedded_scm { }
 908         | book_body error {
 909                 $$->paper_ = 0;
 910                 $$->scores_ = SCM_EOL;
 911                 $$->bookparts_ = SCM_EOL;
 912         }
 913         ;
 914
 915 bookpart_block:
 916         BOOKPART '{' bookpart_body '}' {
 917                 $$ = $3;
 918                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 919         }
 920         ;
 921
 922 bookpart_body:
 923         {
 924                 $$ = new Book;
 925                 $$->origin ()->set_spot (@$);
 926                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$->self_scm ());
 927         }
 928         | BOOK_IDENTIFIER {
 929                 $$ = unsmob_book ($1);
 930                 $$->protect ();
 931                 $$->origin ()->set_spot (@$);
 932                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 933         }
 934         | bookpart_body paper_block {
 935                 $$->paper_ = $2;
 936                 $2->unprotect ();
 937         }
 938         | bookpart_body score_block {
 939                 Score *score = $2;
 940                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-score-handler");
 941                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 942                 score->unprotect ();
 943         }
 944         | bookpart_body composite_music {
 945                 Music *music = unsmob_music ($2);
 946                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-music-handler");
 947                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 948         }
 949         | bookpart_body full_markup {
 950                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 951                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 952         }
 953         | bookpart_body full_markup_list {
 954                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 955                 scm_call_2 (proc, $$->self_scm (), $2);
 956         }
 957         | bookpart_body lilypond_header {
 958                 $$->header_ = $2;
 959         }
 960         | bookpart_body embedded_scm { }
 961         | bookpart_body error {
 962                 $$->paper_ = 0;
 963                 $$->scores_ = SCM_EOL;
 964         }
 965         ;
 966
 967 score_block:
 968         SCORE '{' score_body '}'        {
 969                 $$ = $3;
 970         }
 971         ;
 972
 973 score_body:
 974         music {
 975                 SCM m = $1;
 976                 SCM scorify = ly_lily_module_constant ("scorify-music");
 977                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 978
 979                 // pass ownernship to C++ again.
 980                 $$ = unsmob_score (score);
 981                 $$->protect ();
 982                 $$->origin ()->set_spot (@$);
 983         }
 984         | SCORE_IDENTIFIER {
 985                 $$ = unsmob_score ($1);
 986                 $$->protect ();
 987                 $$->origin ()->set_spot (@$);
 988         }
 989         | score_body lilypond_header    {
 990                 $$->set_header ($2);
 991         }
 992         | score_body output_def {
 993                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 994                 {
 995                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 996
 997                 }
 998                 else
 999                 {
1000                         $$->add_output_def ($2);
1001                 }
1002                 $2->unprotect ();
1003         }
1004         | score_body error {
1005                 $$->error_found_ = true;
1006         }
1007         ;
1008
1009
1010 /*
1011         OUTPUT DEF
1012 */
1013
1014 paper_block:
1015         output_def {
1016                 $$ = $1;
1017                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
1018                 {
1019                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
1020                         $1->unprotect ();
1021                         $$ = get_paper (PARSER);
1022                 }
1023         }
1024         ;
1025
1026
1027 output_def:
1028         output_def_body '}' {
1029                 $$ = $1;
1030
1031                 PARSER->lexer_->remove_scope ();
1032                 PARSER->lexer_->pop_state ();
1033         }
1034         ;
1035
1036 output_def_head:
1037         PAPER {
1038                 $$ = get_paper (PARSER);
1039                 $$->input_origin_ = @$;
1040                 PARSER->lexer_->add_scope ($$->scope_);
1041         }
1042         | MIDI    {
1043                 Output_def *p = get_midi (PARSER);
1044                 $$ = p;
1045                 PARSER->lexer_->add_scope (p->scope_);
1046         }
1047         | LAYOUT        {
1048                 Output_def *p = get_layout (PARSER);
1049
1050                 PARSER->lexer_->add_scope (p->scope_);
1051                 $$ = p;
1052         }
1053         ;
1054
1055 output_def_head_with_mode_switch:
1056         output_def_head {
1057                 PARSER->lexer_->push_initial_state ();
1058                 $$ = $1;
1059         }
1060         ;
1061
1062 output_def_body:
1063         output_def_head_with_mode_switch '{' {
1064                 $$ = $1;
1065                 $$->input_origin_.set_spot (@$);
1066         }
1067         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
1068                 $1->unprotect ();
1069
1070                 Output_def *o = unsmob_output_def ($3);
1071                 o->input_origin_.set_spot (@$);
1072                 $$ = o;
1073                 $$->protect ();
1074                 PARSER->lexer_->remove_scope ();
1075                 PARSER->lexer_->add_scope (o->scope_);
1076         }
1077         | output_def_body assignment  {
1078
1079         }
1080         | output_def_body context_def_spec_block        {
1081                 assign_context_def ($$, $2);
1082         }
1083         | output_def_body error {
1084
1085         }
1086         ;
1087
1088 tempo_event:
1089         TEMPO steno_duration '=' tempo_range    {
1090                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_EOL, $2, $4);
1091         }
1092         | TEMPO scalar_closed steno_duration '=' tempo_range    {
1093                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
1094         }
1095         | TEMPO scalar {
1096                 $$ = MAKE_SYNTAX ("tempo", @$, $2);
1097         }
1098         ;
1099
1100 /*
1101 The representation of a  list is reversed to have efficient append.  */
1102
1103 music_list:
1104         /* empty */ {
1105                 $$ = SCM_EOL;
1106         }
1107         | music_list music {
1108                 $$ = scm_cons ($2, $1);
1109         }
1110         | music_list embedded_scm {
1111
1112         }
1113         | music_list error {
1114                 Music *m = MY_MAKE_MUSIC("Music", @$);
1115                 // ugh. code dup
1116                 m->set_property ("error-found", SCM_BOOL_T);
1117                 $$ = scm_cons (m->self_scm (), $1);
1118                 m->unprotect (); /* UGH */
1119         }
1120         ;
1121
1122 braced_music_list:
1123         '{' music_list '}'
1124         {
1125                 $$ = scm_reverse_x ($2, SCM_EOL);
1126         }
1127         ;
1128
1129 music:  simple_music
1130         | lyric_element_music
1131         | composite_music %prec COMPOSITE
1132         ;
1133
1134 music_arg:
1135         simple_music
1136         | composite_music %prec COMPOSITE
1137         ;
1138
1139 repeated_music:
1140         REPEAT simple_string unsigned_number music
1141         {
1142                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, SCM_EOL);
1143         }
1144         | REPEAT simple_string unsigned_number music ALTERNATIVE braced_music_list
1145         {
1146                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $6);
1147         }
1148         ;
1149
1150 sequential_music:
1151         SEQUENTIAL braced_music_list {
1152                 $$ = MAKE_SYNTAX ("sequential-music", @$, $2);
1153         }
1154         | braced_music_list {
1155                 $$ = MAKE_SYNTAX ("sequential-music", @$, $1);
1156         }
1157         ;
1158
1159 simultaneous_music:
1160         SIMULTANEOUS braced_music_list {
1161                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, $2);
1162         }
1163         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1164                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($2, SCM_EOL));
1165         }
1166         ;
1167
1168 simple_music:
1169         event_chord
1170         | music_property_def
1171         | context_change
1172         ;
1173
1174 context_modification:
1175         WITH { PARSER->lexer_->push_initial_state (); } '{' context_mod_list '}'
1176         {
1177                 PARSER->lexer_->pop_state ();
1178                 $$ = $4;
1179         }
1180         | WITH CONTEXT_MOD_IDENTIFIER
1181         {
1182                 $$ = $2;
1183         }
1184         | CONTEXT_MOD_IDENTIFIER
1185         {
1186                 $$ = $1;
1187         }
1188         ;
1189
1190 optional_context_mod:
1191         /**/ {
1192             $$ = SCM_EOL;
1193         }
1194         | context_modification
1195         {
1196               $$ = $1;
1197         }
1198         ;
1199
1200 context_mod_list:
1201         /**/ {
1202             $$ = Context_mod ().smobbed_copy ();
1203         }
1204         | context_mod_list context_mod  {
1205                  unsmob_context_mod ($1)->add_context_mod ($2);
1206         }
1207         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1208                  Context_mod *md = unsmob_context_mod ($2);
1209                  if (md)
1210                      unsmob_context_mod ($1)->add_context_mods (md->get_mods ());
1211         }
1212         ;
1213
1214 composite_music:
1215         complex_music
1216         | music_bare
1217         ;
1218
1219 /* Music that can be parsed without lookahead */
1220 closed_music:
1221         music_bare
1222         | complex_music_prefix closed_music
1223         {
1224                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1225         }
1226         ;
1227
1228 music_bare:
1229         mode_changed_music
1230         | MUSIC_IDENTIFIER
1231         | grouped_music_list
1232         ;
1233
1234 grouped_music_list:
1235         simultaneous_music              { $$ = $1; }
1236         | sequential_music              { $$ = $1; }
1237         ;
1238
1239 /* An argument list. If a function \foo expects scm scm pitch, then the lexer expands \foo into the token sequence:
1240  MUSIC_FUNCTION EXPECT_PITCH EXPECT_SCM EXPECT_SCM EXPECT_NO_MORE_ARGS
1241 and this rule returns the reversed list of arguments. */
1242
1243 function_arglist_skip:
1244         function_arglist_common
1245         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_skip
1246         {
1247                 $$ = scm_cons ($1, $3);
1248         } %prec FUNCTION_ARGLIST
1249         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_skip
1250         {
1251                 $$ = scm_cons ($1, $3);
1252         } %prec FUNCTION_ARGLIST
1253         | EXPECT_SCM EXPECT_DURATION function_arglist_skip
1254         {
1255                 $$ = scm_cons ($1, $3);
1256         } %prec FUNCTION_ARGLIST
1257         ;
1258
1259
1260 function_arglist_nonbackup:
1261         EXPECT_OPTIONAL EXPECT_PITCH function_arglist pitch_also_in_chords {
1262                 $$ = scm_cons ($4, $3);
1263         }
1264         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed duration_length {
1265                 $$ = scm_cons ($4, $3);
1266         }
1267         | EXPECT_OPTIONAL EXPECT_SCM function_arglist embedded_scm_arg_closed
1268         {
1269                 $$ = check_scheme_arg (PARSER, @4, $1, $4, $3, $2);
1270         }
1271         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed bare_number
1272         {
1273                 $$ = check_scheme_arg (PARSER, @4, $1, $4, $3, $2);
1274         }
1275         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed fraction
1276         {
1277                 $$ = check_scheme_arg (PARSER, @4, $1, $4, $3, $2);
1278         }
1279         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed post_event
1280         {
1281                 $$ = check_scheme_arg (PARSER, @4, $1, $4, $3, $2);
1282         }
1283         ;
1284
1285
1286 function_arglist_keep:
1287         function_arglist_common
1288         | function_arglist_backup
1289         ;
1290
1291 function_arglist_closed_keep:
1292         function_arglist_closed_common
1293         | function_arglist_backup
1294         ;
1295
1296 function_arglist_backup:
1297         EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep embedded_scm_arg_closed
1298         {
1299                 if (scm_is_true (scm_call_1 ($2, $4)))
1300                 {
1301                         $$ = scm_cons ($4, $3);
1302                 } else {
1303                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1304                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
1305                 }
1306         }
1307         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep post_event
1308         {
1309                 if (scm_is_true (scm_call_1 ($2, $4)))
1310                 {
1311                         $$ = scm_cons ($4, $3);
1312                 } else {
1313                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1314                         MYBACKUP (EVENT_IDENTIFIER, $4, @4);
1315                 }
1316         }
1317         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep lyric_element
1318         {
1319                 // There is no point interpreting a lyrics string as
1320                 // an event, since we don't allow music possibly
1321                 // followed by durations or postevent into closed
1322                 // music, and we only accept closed music in optional
1323                 // arguments at the moment.  If this changes, more
1324                 // complex schemes might become interesting here as
1325                 // well: see how we do this at the mandatory argument
1326                 // point.
1327                 if (scm_is_true (scm_call_1 ($2, $4)))
1328                         $$ = scm_cons ($3, $2);
1329                 else {
1330                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1331                         MYBACKUP (LYRIC_MARKUP_IDENTIFIER, $4, @4);
1332                 }
1333         }
1334         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep UNSIGNED
1335         {
1336                 if (scm_is_true (scm_call_1 ($2, $4)))
1337                 {
1338                         $$ = $3;
1339                         MYREPARSE (@4, $1, $2, UNSIGNED, $4);
1340                 } else {
1341                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1342                         MYBACKUP (UNSIGNED, $4, @4);
1343                 }
1344         }
1345         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep REAL
1346         {
1347                 if (scm_is_true (scm_call_1 ($2, $4)))
1348                 {
1349                         $$ = $3;
1350                         MYREPARSE (@4, $1, $2, REAL, $4);
1351                 } else {
1352                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1353                         MYBACKUP (REAL, $4, @4);
1354                 }
1355         }
1356         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep NUMBER_IDENTIFIER
1357         {
1358                 if (scm_is_true (scm_call_1 ($2, $4)))
1359                 {
1360                         $$ = scm_cons ($4, $3);
1361                 } else {
1362                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1363                         MYBACKUP (NUMBER_IDENTIFIER, $4, @4);
1364                 }
1365         }
1366         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep FRACTION
1367         {
1368                 if (scm_is_true (scm_call_1 ($2, $4)))
1369                 {
1370                         $$ = scm_cons ($4, $3);
1371                 } else {
1372                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1373                         MYBACKUP (FRACTION, $4, @4);
1374                 }
1375         }
1376         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_keep pitch_also_in_chords
1377         {
1378                 $$ = scm_cons ($4, $3);
1379         }
1380         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_keep duration_length
1381         {
1382                 $$ = scm_cons ($4, $3);
1383         }
1384         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup BACKUP
1385         {
1386                 $$ = scm_cons ($1, $3);
1387                 MYBACKUP(0, SCM_UNDEFINED, @3);
1388         }
1389         | function_arglist_backup REPARSE embedded_scm_arg_closed
1390         {
1391                 $$ = check_scheme_arg (PARSER, @3, scm_car ($2),
1392                                        $3, $1, scm_cdr ($2));
1393         }
1394         | function_arglist_backup REPARSE bare_number
1395         {
1396                 $$ = check_scheme_arg (PARSER, @3, scm_car ($2),
1397                                        $3, $1, scm_cdr ($2));
1398         }
1399         | function_arglist_backup REPARSE fraction
1400         {
1401                 $$ = check_scheme_arg (PARSER, @3, scm_car ($2),
1402                                        $3, $1, scm_cdr ($2));
1403         }
1404         ;
1405
1406 function_arglist:
1407         function_arglist_common
1408         | function_arglist_nonbackup
1409         ;
1410
1411 function_arglist_common:
1412         function_arglist_bare
1413         | EXPECT_SCM function_arglist_optional embedded_scm_arg
1414         {
1415                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1416                                        $3, $2, $1);
1417         }
1418         | EXPECT_SCM function_arglist_closed_optional bare_number
1419         {
1420                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1421                                        $3, $2, $1);
1422         }
1423         | EXPECT_SCM function_arglist_closed_optional fraction
1424         {
1425                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1426                                        $3, $2, $1);
1427         }
1428         | EXPECT_SCM function_arglist_closed_optional post_event
1429         {
1430                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1431                                        $3, $2, $1);
1432         }
1433         | function_arglist_common_lyric
1434         ;
1435
1436 function_arglist_common_lyric:
1437         EXPECT_SCM function_arglist_optional lyric_element
1438         {
1439                 // We check how the predicate thinks about a lyrics
1440                 // event or about a markup.  If it accepts neither, we
1441                 // backup the original token.  Otherwise we commit to
1442                 // taking the token.  Depending on what the predicate
1443                 // is willing to accept, we interpret as a string, as
1444                 // a lyric event, or ambiguously (meaning that if
1445                 // something looking like a duration or post event
1446                 // follows, we take the event, otherwise the string).
1447                 SCM lyric_event = MAKE_SYNTAX ("lyric-event", @3, $3,
1448                                                PARSER->default_duration_.smobbed_copy ());
1449                 if (scm_is_true (scm_call_1 ($1, $3)))
1450                         if (scm_is_true (scm_call_1 ($1, lyric_event)))
1451                         {
1452                                 $$ = $2;
1453                                 MYREPARSE (@3, SCM_UNDEFINED, $1, LYRIC_ELEMENT_P, $3);
1454                         } else {
1455                                 $$ = scm_cons ($3, $2);
1456                         }
1457                 else if (scm_is_true (scm_call_1 ($1, lyric_event)))
1458                 {
1459                         $$ = $2;
1460                         MYREPARSE (@3, SCM_UNDEFINED, $1, LYRIC_ELEMENT, $3);
1461                 } else {
1462                         // This is going to flag a syntax error, we
1463                         // know the predicate to be false.
1464                         check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1465                                           $3, $2, $1);
1466                 }
1467         }
1468         | function_arglist_common_lyric REPARSE lyric_element_arg
1469         {
1470                 // This should never be false
1471                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1472                                        $3, $1, $2);
1473         }
1474         ;
1475
1476 function_arglist_closed:
1477         function_arglist_closed_common
1478         | function_arglist_nonbackup
1479         ;
1480
1481 function_arglist_closed_common:
1482         function_arglist_bare
1483         | EXPECT_SCM function_arglist_optional embedded_scm_arg_closed
1484         {
1485                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1486                                        $3, $2, $1);
1487         }
1488         | EXPECT_SCM function_arglist_closed_optional bare_number_closed
1489         {
1490                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1491                                        $3, $2, $1);
1492         }
1493         | EXPECT_SCM function_arglist_closed_optional post_event
1494         {
1495                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1496                                        $3, $2, $1);
1497         }
1498         | EXPECT_SCM function_arglist_closed_optional FRACTION
1499         {
1500                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1501                                        $3, $2, $1);
1502         }
1503         | EXPECT_SCM function_arglist_optional lyric_element
1504         {
1505                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1506                                        $3, $2, $1);
1507         }
1508         ;
1509
1510 function_arglist_optional:
1511         function_arglist_keep %prec FUNCTION_ARGLIST
1512         | function_arglist_backup BACKUP
1513         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_optional
1514         {
1515                 $$ = scm_cons ($1, $3);
1516         }
1517         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_optional
1518         {
1519                 $$ = scm_cons ($1, $3);
1520         }
1521         ;
1522
1523 function_arglist_closed_optional:
1524         function_arglist_closed_keep %prec FUNCTION_ARGLIST
1525         | function_arglist_backup BACKUP
1526         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_closed_optional
1527         {
1528                 $$ = scm_cons ($1, $3);
1529         }
1530         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_optional
1531         {
1532                 $$ = scm_cons ($1, $3);
1533         }
1534         ;
1535
1536 embedded_scm_closed:
1537         embedded_scm_bare
1538         | scm_function_call_closed
1539         ;
1540
1541 embedded_scm_arg_closed:
1542         embedded_scm_bare_arg
1543         | scm_function_call_closed
1544         | closed_music
1545         ;
1546
1547 scm_function_call_closed:
1548         SCM_FUNCTION function_arglist_closed {
1549                 $$ = MAKE_SYNTAX ("music-function", @$,
1550                                          $1, $2);
1551         } %prec FUNCTION_ARGLIST
1552         ;
1553
1554 function_arglist_bare:
1555         EXPECT_NO_MORE_ARGS {
1556                 $$ = SCM_EOL;
1557         }
1558         | EXPECT_PITCH function_arglist_optional pitch_also_in_chords {
1559                 $$ = scm_cons ($3, $2);
1560         }
1561         | EXPECT_DURATION function_arglist_closed_optional duration_length {
1562                 $$ = scm_cons ($3, $2);
1563         }
1564         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_skip DEFAULT {
1565                 $$ = scm_cons ($1, $3);
1566         }
1567         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_skip DEFAULT {
1568                 $$ = scm_cons ($1, $3);
1569         }
1570         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip DEFAULT {
1571                 $$ = scm_cons ($1, $3);
1572         }
1573         ;
1574
1575 music_function_call:
1576         MUSIC_FUNCTION function_arglist {
1577                 $$ = MAKE_SYNTAX ("music-function", @$,
1578                                          $1, $2);
1579         }
1580         ;
1581
1582
1583 optional_id:
1584         /**/ { $$ = SCM_EOL; }
1585         | '=' simple_string {
1586                 $$ = $2;
1587         }
1588         ;
1589
1590 complex_music:
1591         music_function_call
1592         | repeated_music                { $$ = $1; }
1593         | re_rhythmed_music     { $$ = $1; }
1594         | complex_music_prefix music
1595         {
1596                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1597         }
1598         ;
1599
1600 complex_music_prefix:
1601         CONTEXT simple_string optional_id optional_context_mod {
1602                 Context_mod *ctxmod = unsmob_context_mod ($4);
1603                 SCM mods = SCM_EOL;
1604                 if (ctxmod)
1605                         mods = ctxmod->get_mods ();
1606                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_F);
1607         }
1608         | NEWCONTEXT simple_string optional_id optional_context_mod {
1609                 Context_mod *ctxmod = unsmob_context_mod ($4);
1610                 SCM mods = SCM_EOL;
1611                 if (ctxmod)
1612                         mods = ctxmod->get_mods ();
1613                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_T);
1614         }
1615         ;
1616
1617 mode_changed_music:
1618         mode_changing_head grouped_music_list {
1619                 if ($1 == ly_symbol2scm ("chords"))
1620                 {
1621                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1622                 }
1623                 else
1624                 {
1625                   $$ = $2;
1626                 }
1627                 PARSER->lexer_->pop_state ();
1628         }
1629         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1630                 Context_mod *ctxmod = unsmob_context_mod ($2);
1631                 SCM mods = SCM_EOL;
1632                 if (ctxmod)
1633                         mods = ctxmod->get_mods ();
1634                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, mods, SCM_BOOL_T, $3);
1635                 if ($1 == ly_symbol2scm ("ChordNames"))
1636                 {
1637                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1638                 }
1639                 PARSER->lexer_->pop_state ();
1640         }
1641         ;
1642
1643 mode_changing_head:
1644         NOTEMODE {
1645                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1646                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1647
1648                 $$ = ly_symbol2scm ("notes");
1649         }
1650         | DRUMMODE
1651                 {
1652                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1653                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1654
1655                 $$ = ly_symbol2scm ("drums");
1656         }
1657         | FIGUREMODE {
1658                 PARSER->lexer_->push_figuredbass_state ();
1659
1660                 $$ = ly_symbol2scm ("figures");
1661         }
1662         | CHORDMODE {
1663                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1664                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1665                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1666                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1667                 $$ = ly_symbol2scm ("chords");
1668
1669         }
1670         | LYRICMODE
1671                 { PARSER->lexer_->push_lyric_state ();
1672                 $$ = ly_symbol2scm ("lyrics");
1673         }
1674         ;
1675
1676 mode_changing_head_with_context:
1677         DRUMS {
1678                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1679                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1680
1681                 $$ = ly_symbol2scm ("DrumStaff");
1682         }
1683         | FIGURES {
1684                 PARSER->lexer_->push_figuredbass_state ();
1685
1686                 $$ = ly_symbol2scm ("FiguredBass");
1687         }
1688         | CHORDS {
1689                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1690                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1691                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1692                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1693                 $$ = ly_symbol2scm ("ChordNames");
1694         }
1695         | LYRICS
1696                 { PARSER->lexer_->push_lyric_state ();
1697                 $$ = ly_symbol2scm ("Lyrics");
1698         }
1699         ;
1700
1701 new_lyrics:
1702         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1703         /*cont */
1704         composite_music {
1705         /* Can also use music at the expensive of two S/Rs similar to
1706            \repeat \alternative */
1707                 PARSER->lexer_->pop_state ();
1708
1709                 $$ = scm_cons ($3, SCM_EOL);
1710         }
1711         | new_lyrics ADDLYRICS {
1712                 PARSER->lexer_->push_lyric_state ();
1713         } composite_music {
1714                 PARSER->lexer_->pop_state ();
1715                 $$ = scm_cons ($4, $1);
1716         }
1717         ;
1718
1719 re_rhythmed_music:
1720         composite_music new_lyrics {
1721                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1722         } %prec COMPOSITE
1723         | LYRICSTO simple_string {
1724                 PARSER->lexer_->push_lyric_state ();
1725         } music {
1726                 PARSER->lexer_->pop_state ();
1727                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1728         }
1729         ;
1730
1731 context_change:
1732         CHANGE STRING '=' STRING  {
1733                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1734         }
1735         ;
1736
1737
1738 property_path_revved:
1739         embedded_scm_closed {
1740                 $$ = scm_cons ($1, SCM_EOL);
1741         }
1742         | property_path_revved embedded_scm_closed {
1743                 $$ = scm_cons ($2, $1);
1744         }
1745         ;
1746
1747 property_path:
1748         property_path_revved  {
1749                 $$ = scm_reverse_x ($1, SCM_EOL);
1750         }
1751         ;
1752
1753 property_operation:
1754         STRING '=' scalar {
1755                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1756                         scm_string_to_symbol ($1), $3);
1757         }
1758         | UNSET simple_string {
1759                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1760                         scm_string_to_symbol ($2));
1761         }
1762         | OVERRIDE simple_string property_path '=' scalar {
1763                 $$ = scm_append (scm_list_2 (scm_list_3 (ly_symbol2scm ("push"),
1764                                                         scm_string_to_symbol ($2), $5),
1765                                              $3));
1766         }
1767         | REVERT simple_string embedded_scm {
1768                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1769                         scm_string_to_symbol ($2), $3);
1770         }
1771         ;
1772
1773 context_def_mod:
1774         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1775         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1776
1777         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1778         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1779         | DENIES { $$ = ly_symbol2scm ("denies"); }
1780
1781         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1782         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1783         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1784         | NAME { $$ = ly_symbol2scm ("context-name"); }
1785         ;
1786
1787 context_mod:
1788         property_operation { $$ = $1; }
1789         | context_def_mod STRING {
1790                 $$ = scm_list_2 ($1, $2);
1791         }
1792         | context_def_mod embedded_scm {
1793            if (ly_symbol2scm ("consists") != $1)
1794            {
1795              $$ = SCM_EOL;
1796              PARSER->parser_error (@1, _ ("only \\consists takes non-string argument."));
1797            }
1798            else
1799            {
1800              $$ = scm_list_2 ($1, $2);
1801            }
1802         }
1803         ;
1804
1805 context_prop_spec:
1806         simple_string {
1807                 if (!is_regular_identifier ($1))
1808                 {
1809                         @$.error (_("Grob name should be alphanumeric"));
1810                 }
1811
1812                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1813                         scm_string_to_symbol ($1));
1814         }
1815         | simple_string '.' simple_string {
1816                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1817                         scm_string_to_symbol ($3));
1818         }
1819         ;
1820
1821 simple_music_property_def:
1822         OVERRIDE context_prop_spec property_path '=' scalar {
1823                 $$ = scm_append (scm_list_2 (scm_list_n (scm_car ($2),
1824                                 ly_symbol2scm ("OverrideProperty"),
1825                                 scm_cadr ($2),
1826                                 $5, SCM_UNDEFINED),
1827                                 $3));
1828         }
1829         | REVERT context_prop_spec embedded_scm {
1830                 $$ = scm_list_4 (scm_car ($2),
1831                         ly_symbol2scm ("RevertProperty"),
1832                         scm_cadr ($2),
1833                         $3);
1834         }
1835         | SET context_prop_spec '=' scalar {
1836                 $$ = scm_list_4 (scm_car ($2),
1837                         ly_symbol2scm ("PropertySet"),
1838                         scm_cadr ($2),
1839                         $4);
1840         }
1841         | UNSET context_prop_spec {
1842                 $$ = scm_list_3 (scm_car ($2),
1843                         ly_symbol2scm ("PropertyUnset"),
1844                         scm_cadr ($2));
1845         }
1846         ;
1847
1848 music_property_def:
1849         simple_music_property_def {
1850                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons2 (PARSER->self_scm (), make_input (@$), $1));
1851         }
1852         ;
1853
1854 string:
1855         STRING {
1856                 $$ = $1;
1857         }
1858         | STRING_IDENTIFIER {
1859                 $$ = $1;
1860         }
1861         | string '+' string {
1862                 $$ = scm_string_append (scm_list_2 ($1, $3));
1863         }
1864         ;
1865
1866 simple_string: STRING {
1867                 $$ = $1;
1868         }
1869         | LYRICS_STRING {
1870                 $$ = $1;
1871         }
1872         | STRING_IDENTIFIER {
1873                 $$ = $1;
1874         }
1875         ;
1876
1877 scalar:
1878         embedded_scm_arg
1879         | bare_number
1880         | lyric_element
1881         ;
1882
1883 scalar_closed:
1884         embedded_scm_arg_closed
1885         | bare_number
1886         | lyric_element
1887         ;
1888
1889
1890 event_chord:
1891         /* TODO: Create a special case that avoids the creation of
1892            EventChords around simple_elements that have no post_events?
1893          */
1894         simple_chord_elements post_events       {
1895                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1896
1897                 Input i;
1898                 /* why is this giving wrong start location? -ns
1899                  * i = @$; */
1900                 i.set_location (@1, @2);
1901                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1902         }
1903         | CHORD_REPETITION optional_notemode_duration post_events {
1904                 Input i;
1905                 i.set_location (@1, @3);
1906                 $$ = MAKE_SYNTAX ("repetition-chord", i,
1907                                   PARSER->lexer_->chord_repetition_.last_chord_,
1908                                   PARSER->lexer_->chord_repetition_.repetition_function_,
1909                                   $2, scm_reverse_x ($3, SCM_EOL));
1910         }
1911         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1912                 Input i;
1913                 i.set_location (@1, @3);
1914                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
1915                                   scm_reverse_x ($3, SCM_EOL));
1916         }
1917         | command_element
1918         /* note chord elements are memorized into
1919            PARSER->lexer_->chord_repetition_ so that the chord repetition
1920            mechanism copy them when a chord repetition symbol is found
1921         */
1922         | note_chord_element    {
1923                 PARSER->lexer_->chord_repetition_.last_chord_ = $$;
1924         }
1925         ;
1926
1927
1928 note_chord_element:
1929         chord_body optional_notemode_duration post_events
1930         {
1931                 Music *m = unsmob_music ($1);
1932                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1933                 SCM es = m->get_property ("elements");
1934                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1935
1936                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1937                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1938                 es = ly_append2 (es, postevs);
1939
1940                 m-> set_property ("elements", es);
1941                 m->set_spot (@$);
1942                 $$ = m->self_scm ();
1943         }
1944         ;
1945
1946 chord_body:
1947         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1948         {
1949                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1950         }
1951         ;
1952
1953 chord_body_elements:
1954         /* empty */             { $$ = SCM_EOL; }
1955         | chord_body_elements chord_body_element {
1956                 $$ = scm_cons ($2, $1);
1957         }
1958         ;
1959
1960 chord_body_element:
1961         pitch exclamations questions octave_check post_events
1962         {
1963                 int q = $3;
1964                 int ex = $2;
1965                 SCM check = $4;
1966                 SCM post = $5;
1967
1968                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1969                 n->set_property ("pitch", $1);
1970                 if (q % 2)
1971                         n->set_property ("cautionary", SCM_BOOL_T);
1972                 if (ex % 2 || q % 2)
1973                         n->set_property ("force-accidental", SCM_BOOL_T);
1974
1975                 if (scm_is_pair (post)) {
1976                         SCM arts = scm_reverse_x (post, SCM_EOL);
1977                         n->set_property ("articulations", arts);
1978                 }
1979                 if (scm_is_number (check))
1980                 {
1981                         int q = scm_to_int (check);
1982                         n->set_property ("absolute-octave", scm_from_int (q-1));
1983                 }
1984
1985                 $$ = n->unprotect ();
1986         }
1987         | DRUM_PITCH post_events {
1988                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1989                 n->set_property ("drum-type", $1);
1990
1991                 if (scm_is_pair ($2)) {
1992                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1993                         n->set_property ("articulations", arts);
1994                 }
1995                 $$ = n->unprotect ();
1996         }
1997         | music_function_chord_body
1998         ;
1999
2000 /* We can't accept a music argument, not even a closed one,
2001  * immediately before chord_body_elements, otherwise a function \fun
2002  * with a signature of two music arguments can't be sorted out
2003  * properly in a construct like
2004  * <\fun { c } \fun { c } c>
2005  * The second call could be interpreted either as a chord constituent
2006  * or a music expression.
2007  */
2008
2009 music_function_chord_body_arglist:
2010         function_arglist_bare
2011         | EXPECT_SCM music_function_chord_body_arglist embedded_scm_chord_body
2012         {
2013                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
2014                                        $3, $2, $1);
2015         }
2016         ;
2017
2018 embedded_scm_chord_body:
2019         embedded_scm_bare_arg
2020         | SCM_FUNCTION music_function_chord_body_arglist {
2021                 $$ = MAKE_SYNTAX ("music-function", @$,
2022                                          $1, $2);
2023         }
2024         | bare_number
2025         | fraction
2026         | lyric_element
2027         | chord_body_element
2028         ;
2029
2030 music_function_chord_body:
2031         MUSIC_FUNCTION music_function_chord_body_arglist {
2032                 $$ = MAKE_SYNTAX ("music-function", @$,
2033                                          $1, $2);
2034         }
2035         ;
2036
2037 // Event functions may only take closed arglists, otherwise it would
2038 // not be clear whether a following postevent should be associated
2039 // with the last argument of the event function or with the expression
2040 // for which the function call acts itself as event.
2041
2042 music_function_event:
2043         MUSIC_FUNCTION function_arglist_closed {
2044                 $$ = MAKE_SYNTAX ("music-function", @$,
2045                                          $1, $2);
2046         }
2047         ;
2048
2049 event_function_event:
2050         EVENT_FUNCTION function_arglist_closed {
2051                 $$ = MAKE_SYNTAX ("music-function", @$,
2052                                          $1, $2);
2053         }
2054         ;
2055
2056 command_element:
2057         command_event {
2058                 $$ = $1;
2059         }
2060         | E_BRACKET_OPEN {
2061                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
2062                 m->set_property ("span-direction", scm_from_int (START));
2063                 $$ = m->unprotect();
2064         }
2065         | E_BRACKET_CLOSE {
2066                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
2067                 m->set_property ("span-direction", scm_from_int (STOP));
2068                 $$ = m->unprotect ();
2069         }
2070         | E_BACKSLASH {
2071                 $$ = MAKE_SYNTAX ("voice-separator", @$);
2072         }
2073         | '|'      {
2074                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
2075
2076                 Music *m = unsmob_music (pipe);
2077                 if (m)
2078                 {
2079                         m = m->clone ();
2080                         m->set_spot (@$);
2081                         $$ = m->unprotect ();
2082                 }
2083                 else
2084                         $$ = MAKE_SYNTAX ("bar-check", @$);
2085
2086         }
2087         ;
2088
2089 command_event:
2090         E_TILDE {
2091                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent", @$)->unprotect ();
2092         }
2093         | tempo_event {
2094                 $$ = $1;
2095         }
2096         ;
2097
2098
2099 post_events:
2100         /* empty */ {
2101                 $$ = SCM_EOL;
2102         }
2103         | post_events post_event {
2104                 unsmob_music ($2)->set_spot (@2);
2105                 $$ = scm_cons ($2, $$);
2106         }
2107         ;
2108
2109 post_event_nofinger:
2110         direction_less_event {
2111                 $$ = $1;
2112         }
2113         | script_dir music_function_event {
2114                 $$ = $2;
2115                 if ($1)
2116                 {
2117                         unsmob_music ($$)->set_property ("direction", scm_from_int ($1));
2118                 }
2119         }
2120         | HYPHEN {
2121                 if (!PARSER->lexer_->is_lyric_state ())
2122                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2123                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
2124         }
2125         | EXTENDER {
2126                 if (!PARSER->lexer_->is_lyric_state ())
2127                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2128                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
2129         }
2130         | script_dir direction_reqd_event {
2131                 if ($1)
2132                 {
2133                         Music *m = unsmob_music ($2);
2134                         m->set_property ("direction", scm_from_int ($1));
2135                 }
2136                 $$ = $2;
2137         }
2138         | script_dir direction_less_event {
2139                 if ($1)
2140                 {
2141                         Music *m = unsmob_music ($2);
2142                         m->set_property ("direction", scm_from_int ($1));
2143                 }
2144                 $$ = $2;
2145         }
2146         | string_number_event
2147         ;
2148
2149 post_event:
2150         post_event_nofinger
2151         | script_dir fingering {
2152                 if ($1)
2153                 {
2154                         Music *m = unsmob_music ($2);
2155                         m->set_property ("direction", scm_from_int ($1));
2156                 }
2157                 $$ = $2;
2158         }
2159         ;
2160
2161 string_number_event:
2162         E_UNSIGNED {
2163                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
2164                 s->set_property ("string-number", scm_from_int ($1));
2165                 $$ = s->unprotect ();
2166         }
2167         ;
2168
2169 direction_less_char:
2170         '['  {
2171                 $$ = ly_symbol2scm ("bracketOpenSymbol");
2172         }
2173         | ']'  {
2174                 $$ = ly_symbol2scm ("bracketCloseSymbol");
2175         }
2176         | '~'  {
2177                 $$ = ly_symbol2scm ("tildeSymbol");
2178         }
2179         | '('  {
2180                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
2181         }
2182         | ')'  {
2183                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
2184         }
2185         | E_EXCLAMATION  {
2186                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
2187         }
2188         | E_OPEN  {
2189                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
2190         }
2191         | E_CLOSE  {
2192                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
2193         }
2194         | E_ANGLE_CLOSE  {
2195                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
2196         }
2197         | E_ANGLE_OPEN  {
2198                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
2199         }
2200         ;
2201
2202 direction_less_event:
2203         direction_less_char {
2204                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
2205                 Music *m = 0;
2206                 if (unsmob_music (predefd))
2207                 {
2208                         m = unsmob_music (predefd)->clone ();
2209                         m->set_spot (@$);
2210                 }
2211                 else
2212                 {
2213                         m = MY_MAKE_MUSIC ("Music", @$);
2214                 }
2215                 $$ = m->unprotect ();
2216         }
2217         | EVENT_IDENTIFIER      {
2218                 $$ = $1;
2219         }
2220         | tremolo_type  {
2221                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
2222                a->set_property ("tremolo-type", scm_from_int ($1));
2223                $$ = a->unprotect ();
2224         }
2225         | event_function_event
2226         ;
2227
2228 direction_reqd_event:
2229         gen_text_def {
2230                 $$ = $1;
2231         }
2232         | script_abbreviation {
2233                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
2234                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
2235                 if (scm_is_string (s))
2236                         a->set_property ("articulation-type", s);
2237                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
2238                 $$ = a->unprotect ();
2239         }
2240         ;
2241
2242 octave_check:
2243         /**/ { $$ = SCM_EOL; }
2244         | '='  { $$ = scm_from_int (0); }
2245         | '=' sub_quotes { $$ = scm_from_int (-$2); }
2246         | '=' sup_quotes { $$ = scm_from_int ($2); }
2247         ;
2248
2249 sup_quotes:
2250         '\'' {
2251                 $$ = 1;
2252         }
2253         | sup_quotes '\'' {
2254                 $$ ++;
2255         }
2256         ;
2257
2258 sub_quotes:
2259         ',' {
2260                 $$ = 1;
2261         }
2262         | sub_quotes ',' {
2263                 $$++;
2264         }
2265         ;
2266
2267 steno_pitch:
2268         NOTENAME_PITCH  {
2269                 $$ = $1;
2270         }
2271         | NOTENAME_PITCH sup_quotes     {
2272                 Pitch p = *unsmob_pitch ($1);
2273                 p = p.transposed (Pitch ($2,0,0));
2274                 $$ = p.smobbed_copy ();
2275         }
2276         | NOTENAME_PITCH sub_quotes      {
2277                 Pitch p =* unsmob_pitch ($1);
2278                 p = p.transposed (Pitch (-$2,0,0));
2279                 $$ = p.smobbed_copy ();
2280         }
2281         ;
2282
2283 /*
2284 ugh. duplication
2285 */
2286
2287 steno_tonic_pitch:
2288         TONICNAME_PITCH {
2289                 $$ = $1;
2290         }
2291         | TONICNAME_PITCH sup_quotes    {
2292                 Pitch p = *unsmob_pitch ($1);
2293                 p = p.transposed (Pitch ($2,0,0));
2294                 $$ = p.smobbed_copy ();
2295         }
2296         | TONICNAME_PITCH sub_quotes     {
2297                 Pitch p = *unsmob_pitch ($1);
2298
2299                 p = p.transposed (Pitch (-$2,0,0));
2300                 $$ = p.smobbed_copy ();
2301         }
2302         ;
2303
2304 pitch:
2305         steno_pitch {
2306                 $$ = $1;
2307         }
2308         | PITCH_IDENTIFIER
2309         ;
2310
2311 pitch_also_in_chords:
2312         pitch
2313         | steno_tonic_pitch
2314         ;
2315
2316 gen_text_def:
2317         full_markup {
2318                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2319                 t->set_property ("text", $1);
2320                 $$ = t->unprotect ();
2321         }
2322         | simple_string {
2323                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2324                 t->set_property ("text",
2325                         make_simple_markup ($1));
2326                 $$ = t->unprotect ();
2327         }
2328         ;
2329
2330 fingering:
2331         UNSIGNED {
2332                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
2333                 t->set_property ("digit", $1);
2334                 $$ = t->unprotect ();
2335         }
2336         ;
2337
2338 script_abbreviation:
2339         '^'             {
2340                 $$ = scm_from_locale_string ("Hat");
2341         }
2342         | '+'           {
2343                 $$ = scm_from_locale_string ("Plus");
2344         }
2345         | '-'           {
2346                 $$ = scm_from_locale_string ("Dash");
2347         }
2348         | '|'           {
2349                 $$ = scm_from_locale_string ("Bar");
2350         }
2351         | ANGLE_CLOSE   {
2352                 $$ = scm_from_locale_string ("Larger");
2353         }
2354         | '.'           {
2355                 $$ = scm_from_locale_string ("Dot");
2356         }
2357         | '_' {
2358                 $$ = scm_from_locale_string ("Underscore");
2359         }
2360         ;
2361
2362 script_dir:
2363         '_'     { $$ = DOWN; }
2364         | '^'   { $$ = UP; }
2365         | '-'   { $$ = CENTER; }
2366         ;
2367
2368 duration_length:
2369         multiplied_duration {
2370                 $$ = $1;
2371         }
2372         ;
2373
2374 optional_notemode_duration:
2375         {
2376                 Duration dd = PARSER->default_duration_;
2377                 $$ = dd.smobbed_copy ();
2378         }
2379         | multiplied_duration   {
2380                 $$ = $1;
2381                 PARSER->default_duration_ = *unsmob_duration ($$);
2382         }
2383         ;
2384
2385 steno_duration:
2386         bare_unsigned dots              {
2387                 int len = 0;
2388                 if (!is_duration ($1))
2389                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
2390                 else
2391                         len = intlog2 ($1);
2392
2393                 $$ = Duration (len, $2).smobbed_copy ();
2394         }
2395         | DURATION_IDENTIFIER dots      {
2396                 Duration *d = unsmob_duration ($1);
2397                 Duration k (d->duration_log (), d->dot_count () + $2);
2398                 k = k.compressed (d->factor ());
2399                 *d = k;
2400                 $$ = $1;
2401         }
2402         ;
2403
2404 multiplied_duration:
2405         steno_duration {
2406                 $$ = $1;
2407         }
2408         | multiplied_duration '*' bare_unsigned {
2409                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2410         }
2411         | multiplied_duration '*' FRACTION {
2412                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2413
2414                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2415         }
2416         ;
2417
2418 fraction:
2419         FRACTION { $$ = $1; }
2420         | UNSIGNED '/' UNSIGNED {
2421                 $$ = scm_cons ($1, $3);
2422         }
2423         ;
2424
2425 dots:
2426         /* empty */     {
2427                 $$ = 0;
2428         }
2429         | dots '.' {
2430                 $$ ++;
2431         }
2432         ;
2433
2434 tremolo_type:
2435         ':'     {
2436                 $$ = 0;
2437         }
2438         | ':' bare_unsigned {
2439                 if (!is_duration ($2))
2440                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
2441                 $$ = $2;
2442         }
2443         ;
2444
2445 bass_number:
2446         UNSIGNED { $$ = $1; }
2447         | STRING { $$ = $1; }
2448         | full_markup { $$ = $1; }
2449         ;
2450
2451 figured_bass_alteration:
2452         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
2453         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
2454         | '!'   { $$ = scm_from_int (0); }
2455         ;
2456
2457 bass_figure:
2458         FIGURE_SPACE {
2459                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2460                 $$ = bfr->unprotect ();
2461         }
2462         | bass_number  {
2463                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2464                 $$ = bfr->self_scm ();
2465
2466                 if (scm_is_number ($1))
2467                         bfr->set_property ("figure", $1);
2468                 else if (Text_interface::is_markup ($1))
2469                         bfr->set_property ("text", $1);
2470
2471                 bfr->unprotect ();
2472         }
2473         | bass_figure ']' {
2474                 $$ = $1;
2475                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2476         }
2477         | bass_figure figured_bass_alteration {
2478                 Music *m = unsmob_music ($1);
2479                 if (scm_to_double ($2)) {
2480                         SCM salter = m->get_property ("alteration");
2481                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
2482                         m->set_property ("alteration",
2483                                          scm_sum (alter, $2));
2484                 } else {
2485                         m->set_property ("alteration", scm_from_int (0));
2486                 }
2487         }
2488         | bass_figure figured_bass_modification  {
2489                 Music *m = unsmob_music ($1);
2490                 if ($2 == ly_symbol2scm ("plus"))
2491                         {
2492                         m->set_property ("augmented", SCM_BOOL_T);
2493                         }
2494                 else if ($2 == ly_symbol2scm ("slash"))
2495                         {
2496                         m->set_property ("diminished", SCM_BOOL_T);
2497                         }
2498                 else if ($2 == ly_symbol2scm ("exclamation"))
2499                         {
2500                         m->set_property ("no-continuation", SCM_BOOL_T);
2501                         }
2502                 else if ($2 == ly_symbol2scm ("backslash"))
2503                         {
2504                         m->set_property ("augmented-slash", SCM_BOOL_T);
2505                         }
2506         }
2507         ;
2508
2509
2510 figured_bass_modification:
2511         E_PLUS          {
2512                 $$ = ly_symbol2scm ("plus");
2513         }
2514         | E_EXCLAMATION {
2515                 $$ = ly_symbol2scm ("exclamation");
2516         }
2517         | '/'           {
2518                 $$ = ly_symbol2scm ("slash");
2519         }
2520         | E_BACKSLASH {
2521                 $$ = ly_symbol2scm ("backslash");
2522         }
2523         ;
2524
2525 br_bass_figure:
2526         bass_figure {
2527                 $$ = $1;
2528         }
2529         | '[' bass_figure {
2530                 $$ = $2;
2531                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2532         }
2533         ;
2534
2535 figure_list:
2536         /**/            {
2537                 $$ = SCM_EOL;
2538         }
2539         | figure_list br_bass_figure {
2540                 $$ = scm_cons ($2, $1);
2541         }
2542         ;
2543
2544 figure_spec:
2545         FIGURE_OPEN figure_list FIGURE_CLOSE {
2546                 $$ = scm_reverse_x ($2, SCM_EOL);
2547         }
2548         ;
2549
2550
2551 optional_rest:
2552         /**/   { $$ = 0; }
2553         | REST { $$ = 1; }
2554         ;
2555
2556 simple_element:
2557         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2558                 if (!PARSER->lexer_->is_note_state ())
2559                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
2560
2561                 Music *n = 0;
2562                 if ($6)
2563                         n = MY_MAKE_MUSIC ("RestEvent", @$);
2564                 else
2565                         n = MY_MAKE_MUSIC ("NoteEvent", @$);
2566
2567                 n->set_property ("pitch", $1);
2568                 n->set_property ("duration", $5);
2569
2570                 if (scm_is_number ($4))
2571                 {
2572                         int q = scm_to_int ($4);
2573                         n->set_property ("absolute-octave", scm_from_int (q-1));
2574                 }
2575
2576                 if ($3 % 2)
2577                         n->set_property ("cautionary", SCM_BOOL_T);
2578                 if ($2 % 2 || $3 % 2)
2579                         n->set_property ("force-accidental", SCM_BOOL_T);
2580
2581                 $$ = n->unprotect ();
2582         }
2583         | DRUM_PITCH optional_notemode_duration {
2584                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2585                 n->set_property ("duration", $2);
2586                 n->set_property ("drum-type", $1);
2587
2588                 $$ = n->unprotect ();
2589         }
2590         | RESTNAME optional_notemode_duration           {
2591                 Music *ev = 0;
2592                 if (ly_scm2string ($1) == "s") {
2593                         /* Space */
2594                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
2595                   }
2596                 else {
2597                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
2598
2599                     }
2600                 ev->set_property ("duration", $2);
2601                 $$ = ev->unprotect ();
2602         }
2603         ;
2604
2605 simple_chord_elements:
2606         simple_element  {
2607                 $$ = scm_list_1 ($1);
2608         }
2609         | new_chord {
2610                 if (!PARSER->lexer_->is_chord_state ())
2611                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
2612                 $$ = $1;
2613         }
2614         | figure_spec optional_notemode_duration {
2615                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2616                 {
2617                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2618                 }
2619                 $$ = $1;
2620         }
2621         ;
2622
2623 lyric_element:
2624         lyric_markup {
2625                 $$ = $1;
2626         }
2627         | LYRICS_STRING {
2628                 $$ = $1;
2629         }
2630         | LYRIC_ELEMENT_P
2631         ;
2632
2633 lyric_element_arg:
2634         lyric_element
2635         | lyric_element multiplied_duration post_events {
2636                 SCM lyric_event = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
2637                 $$ = MAKE_SYNTAX ("event-chord", @$,
2638                                   scm_cons (lyric_event,
2639                                             scm_reverse_x ($3, SCM_EOL)));
2640         }
2641         | lyric_element post_event post_events {
2642                 SCM lyric_event =
2643                         MAKE_SYNTAX ("lyric-event", @$, $1,
2644                                      PARSER->default_duration_.smobbed_copy ());
2645                 $$ = MAKE_SYNTAX ("event-chord", @$,
2646                                   scm_cons2 (lyric_event, $2,
2647                                              scm_reverse_x ($3, SCM_EOL)));
2648
2649         }
2650         | LYRIC_ELEMENT optional_notemode_duration post_events {
2651                 SCM lyric_event = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
2652                 $$ = MAKE_SYNTAX ("event-chord", @$,
2653                                   scm_cons (lyric_event,
2654                                             scm_reverse_x ($3, SCM_EOL)));
2655         }
2656         ;
2657
2658
2659 lyric_element_music:
2660         lyric_element optional_notemode_duration post_events {
2661                 SCM lyric_event = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
2662                 $$ = MAKE_SYNTAX ("event-chord", @$,
2663                                   scm_cons (lyric_event,
2664                                             scm_reverse_x ($3, SCM_EOL)));
2665         }
2666         ;
2667
2668 new_chord:
2669         steno_tonic_pitch optional_notemode_duration   {
2670                 $$ = make_chord_elements ($1, $2, SCM_EOL);
2671         }
2672         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2673                 SCM its = scm_reverse_x ($4, SCM_EOL);
2674                 $$ = make_chord_elements ($1, $2, scm_cons ($3, its));
2675         }
2676         ;
2677
2678 chord_items:
2679         /**/ {
2680                 $$ = SCM_EOL;
2681         }
2682         | chord_items chord_item {
2683                 $$ = scm_cons ($2, $$);
2684         }
2685         ;
2686
2687 chord_separator:
2688         CHORD_COLON {
2689                 $$ = ly_symbol2scm ("chord-colon");
2690         }
2691         | CHORD_CARET {
2692                 $$ = ly_symbol2scm ("chord-caret");
2693         }
2694         | CHORD_SLASH steno_tonic_pitch {
2695                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2696         }
2697         | CHORD_BASS steno_tonic_pitch {
2698                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2699         }
2700         ;
2701
2702 chord_item:
2703         chord_separator {
2704                 $$ = $1;
2705         }
2706         | step_numbers {
2707                 $$ = scm_reverse_x ($1, SCM_EOL);
2708         }
2709         | CHORD_MODIFIER  {
2710                 $$ = $1;
2711         }
2712         ;
2713
2714 step_numbers:
2715         step_number { $$ = scm_cons ($1, SCM_EOL); }
2716         | step_numbers '.' step_number {
2717                 $$ = scm_cons ($3, $$);
2718         }
2719         ;
2720
2721 step_number:
2722         bare_unsigned {
2723                 $$ = make_chord_step ($1, 0);
2724         }
2725         | bare_unsigned '+' {
2726                 $$ = make_chord_step ($1, SHARP_ALTERATION);
2727         }
2728         | bare_unsigned CHORD_MINUS {
2729                 $$ = make_chord_step ($1, FLAT_ALTERATION);
2730         }
2731         ;
2732
2733 tempo_range:
2734         bare_unsigned {
2735                 $$ = scm_from_int ($1);
2736         }
2737         | bare_unsigned '~' bare_unsigned {
2738                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2739         }
2740         ;
2741
2742 /*
2743         UTILITIES
2744
2745 TODO: should deprecate in favor of Scheme?
2746
2747  */
2748 number_expression:
2749         number_expression '+' number_term {
2750                 $$ = scm_sum ($1, $3);
2751         }
2752         | number_expression '-' number_term {
2753                 $$ = scm_difference ($1, $3);
2754         }
2755         | number_term
2756         ;
2757
2758 number_term:
2759         number_factor {
2760                 $$ = $1;
2761         }
2762         | number_factor '*' number_factor {
2763                 $$ = scm_product ($1, $3);
2764         }
2765         | number_factor '/' number_factor {
2766                 $$ = scm_divide ($1, $3);
2767         }
2768         ;
2769
2770 number_factor:
2771         '-'  number_factor { /* %prec UNARY_MINUS */
2772                 $$ = scm_difference ($2, SCM_UNDEFINED);
2773         }
2774         | bare_number
2775         ;
2776
2777
2778 bare_number:
2779         bare_number_closed
2780         | UNSIGNED NUMBER_IDENTIFIER    {
2781                 $$ = scm_product ($1, $2)
2782         }
2783         | REAL NUMBER_IDENTIFIER        {
2784                 $$ = scm_product ($1, $2)
2785         }
2786         ;
2787
2788 bare_number_closed:
2789         UNSIGNED
2790         | REAL
2791         | NUMBER_IDENTIFIER
2792         ;
2793
2794 bare_unsigned:
2795         UNSIGNED {
2796                 $$ = scm_to_int ($1);
2797         }
2798         ;
2799
2800 unsigned_number:
2801         UNSIGNED
2802         | NUMBER_IDENTIFIER
2803         ;
2804
2805 exclamations:
2806                 { $$ = 0; }
2807         | exclamations '!'      { $$ ++; }
2808         ;
2809
2810 questions:
2811                 { $$ = 0; }
2812         | questions '?' { $$ ++; }
2813         ;
2814
2815 /*
2816 This should be done more dynamically if possible.
2817 */
2818
2819 lyric_markup:
2820         LYRIC_MARKUP_IDENTIFIER {
2821                 $$ = $1;
2822         }
2823         | LYRIC_MARKUP
2824                 { PARSER->lexer_->push_markup_state (); }
2825         markup_top {
2826                 $$ = $3;
2827                 PARSER->lexer_->pop_state ();
2828         }
2829         ;
2830
2831 full_markup_list:
2832         MARKUPLIST_IDENTIFIER {
2833                 $$ = $1;
2834         }
2835         | MARKUPLIST
2836                 { PARSER->lexer_->push_markup_state (); }
2837         markup_list {
2838                 $$ = $3;
2839                 PARSER->lexer_->pop_state ();
2840         }
2841         ;
2842
2843 full_markup:
2844         MARKUP_IDENTIFIER {
2845                 $$ = $1;
2846         }
2847         | MARKUP
2848                 { PARSER->lexer_->push_markup_state (); }
2849         markup_top {
2850                 $$ = $3;
2851                 PARSER->lexer_->pop_state ();
2852         }
2853         ;
2854
2855 markup_top:
2856         markup_list {
2857                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2858         }
2859         | markup_head_1_list simple_markup      {
2860                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2861         }
2862         | simple_markup {
2863                 $$ = $1;
2864         }
2865         ;
2866
2867 markup_list:
2868         MARKUPLIST_IDENTIFIER {
2869                 $$ = $1;
2870         }
2871         | markup_composed_list {
2872                 $$ = $1;
2873         }
2874         | markup_braced_list {
2875                 $$ = $1;
2876         }
2877         | markup_command_list {
2878                 $$ = scm_list_1 ($1);
2879         }
2880         ;
2881
2882 markup_composed_list:
2883         markup_head_1_list markup_braced_list {
2884                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2885
2886         }
2887         ;
2888
2889 markup_braced_list:
2890         '{' markup_braced_list_body '}' {
2891                 $$ = scm_reverse_x ($2, SCM_EOL);
2892         }
2893         ;
2894
2895 markup_braced_list_body:
2896         /* empty */     {  $$ = SCM_EOL; }
2897         | markup_braced_list_body markup {
2898                 $$ = scm_cons ($2, $1);
2899         }
2900         | markup_braced_list_body markup_list {
2901                 $$ = scm_reverse_x ($2, $1);
2902         }
2903         ;
2904
2905 markup_command_list:
2906         MARKUP_LIST_FUNCTION markup_command_list_arguments {
2907           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
2908         }
2909         ;
2910
2911 markup_command_basic_arguments:
2912         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
2913           $$ = scm_cons ($3, $2);
2914         }
2915         | EXPECT_SCM markup_command_list_arguments embedded_scm_closed {
2916           $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED, $3, $2, $1);
2917         }
2918         | EXPECT_NO_MORE_ARGS {
2919           $$ = SCM_EOL;
2920         }
2921         ;
2922
2923 markup_command_list_arguments:
2924         markup_command_basic_arguments { $$ = $1; }
2925         | EXPECT_MARKUP markup_command_list_arguments markup {
2926           $$ = scm_cons ($3, $2);
2927         }
2928         ;
2929
2930 markup_head_1_item:
2931         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
2932           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
2933         }
2934         ;
2935
2936 markup_head_1_list:
2937         markup_head_1_item      {
2938                 $$ = scm_list_1 ($1);
2939         }
2940         | markup_head_1_list markup_head_1_item {
2941                 $$ = scm_cons ($2, $1);
2942         }
2943         ;
2944
2945 simple_markup:
2946         STRING {
2947                 $$ = make_simple_markup ($1);
2948         }
2949         | MARKUP_IDENTIFIER {
2950                 $$ = $1;
2951         }
2952         | LYRIC_MARKUP_IDENTIFIER {
2953                 $$ = $1;
2954         }
2955         | STRING_IDENTIFIER {
2956                 $$ = $1;
2957         }
2958         | SCORE {
2959                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2960                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2961         } '{' score_body '}' {
2962                 Score * sc = $4;
2963                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2964                 sc->unprotect ();
2965                 PARSER->lexer_->pop_state ();
2966         }
2967         | MARKUP_FUNCTION markup_command_basic_arguments {
2968                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
2969         }
2970         ;
2971
2972 markup:
2973         markup_head_1_list simple_markup        {
2974                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2975                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2976         }
2977         | simple_markup {
2978                 $$ = $1;
2979         }
2980         ;
2981
2982 %%
2983
2984 void
2985 Lily_parser::set_yydebug (bool x)
2986 {
2987         yydebug = x;
2988 }
2989
2990 void
2991 Lily_parser::do_yyparse ()
2992 {
2993         yyparse ((void*)this);
2994 }
2995
2996
2997
2998
2999
3000 /*
3001
3002 It is a little strange to have this function in this file, but
3003 otherwise, we have to import music classes into the lexer.
3004
3005 */
3006 int
3007 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
3008 {
3009         if (scm_is_string (sid)) {
3010                 *destination = sid;
3011                 return STRING_IDENTIFIER;
3012         } else if (unsmob_book (sid)) {
3013                 Book *book =  unsmob_book (sid)->clone ();
3014                 *destination = book->self_scm ();
3015                 book->unprotect ();
3016
3017                 return BOOK_IDENTIFIER;
3018         } else if (scm_is_number (sid)) {
3019                 *destination = sid;
3020                 return NUMBER_IDENTIFIER;
3021         } else if (unsmob_context_def (sid)) {
3022                 Context_def *def= unsmob_context_def (sid)->clone ();
3023
3024                 *destination = def->self_scm ();
3025                 def->unprotect ();
3026
3027                 return CONTEXT_DEF_IDENTIFIER;
3028         } else if (unsmob_context_mod (sid)) {
3029                 *destination = unsmob_context_mod (sid)->smobbed_copy ();
3030
3031                 return CONTEXT_MOD_IDENTIFIER;
3032         } else if (unsmob_score (sid)) {
3033                 Score *score = new Score (*unsmob_score (sid));
3034                 *destination = score->self_scm ();
3035
3036                 score->unprotect ();
3037                 return SCORE_IDENTIFIER;
3038         } else if (Music *mus = unsmob_music (sid)) {
3039                 mus = mus->clone ();
3040                 *destination = mus->self_scm ();
3041                 unsmob_music (*destination)->
3042                         set_property ("origin", make_input (last_input_));
3043
3044                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
3045                         != SCM_BOOL_F;
3046
3047                 mus->unprotect ();
3048                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
3049         } else if (unsmob_pitch (sid)) {
3050                 *destination = unsmob_pitch (sid)->smobbed_copy ();
3051                 return PITCH_IDENTIFIER;
3052         } else if (unsmob_duration (sid)) {
3053                 *destination = unsmob_duration (sid)->smobbed_copy ();
3054                 return DURATION_IDENTIFIER;
3055         } else if (unsmob_output_def (sid)) {
3056                 Output_def *p = unsmob_output_def (sid);
3057                 p = p->clone ();
3058
3059                 *destination = p->self_scm ();
3060                 p->unprotect ();
3061                 return OUTPUT_DEF_IDENTIFIER;
3062         } else if (Text_interface::is_markup (sid)) {
3063                 *destination = sid;
3064                 if (is_lyric_state ())
3065                         return LYRIC_MARKUP_IDENTIFIER;
3066                 return MARKUP_IDENTIFIER;
3067         } else if (Text_interface::is_markup_list (sid)) {
3068                 *destination = sid;
3069                 return MARKUPLIST_IDENTIFIER;
3070         }
3071
3072         return -1;
3073 }
3074
3075 SCM
3076 get_next_unique_context_id ()
3077 {
3078         return scm_from_locale_string ("$uniqueContextId");
3079 }
3080
3081
3082 SCM
3083 get_next_unique_lyrics_context_id ()
3084 {
3085         static int new_context_count;
3086         char s[128];
3087         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
3088         return scm_from_locale_string (s);
3089 }
3090
3091 SCM check_scheme_arg (Lily_parser *my_lily_parser, Input loc, SCM fallback,
3092                       SCM arg, SCM args, SCM pred)
3093 {
3094         SCM unwrap = SCM_UNDEFINED;
3095         if (scm_is_true (scm_call_1 (pred, arg)))
3096                 return scm_cons (arg, args);
3097         unwrap = try_unpack_lyrics (pred, arg);
3098         if (!SCM_UNBNDP (unwrap))
3099                 return scm_cons (unwrap, args);
3100         if (SCM_UNBNDP (fallback)) {
3101                 args = scm_cons (SCM_BOOL_F, args);
3102                 fallback = SCM_BOOL_F;
3103         } else {
3104                 args = scm_cons (loc_on_music (loc, fallback), args);
3105                 fallback = SCM_CDR (scm_last_pair (args));
3106         }
3107         scm_set_cdr_x (scm_last_pair (args), SCM_EOL);
3108         MAKE_SYNTAX ("argument-error", loc, scm_length (args), pred, arg);
3109         scm_set_cdr_x (scm_last_pair (args), fallback);
3110         return args;
3111 }
3112
3113 SCM loc_on_music (Input loc, SCM arg)
3114 {
3115         if (Music *m = unsmob_music (arg))
3116         {
3117                 m = m->clone ();
3118                 m->set_spot (loc);
3119                 return m->unprotect ();
3120         }
3121         return arg;
3122 }
3123
3124 bool
3125 is_regular_identifier (SCM id)
3126 {
3127   string str = ly_scm2string (id);
3128   char const *s = str.c_str ();
3129
3130   bool v = true;
3131 #if 0
3132   isalpha (*s);
3133   s++;
3134 #endif
3135   while (*s && v)
3136    {
3137         v = v && isalnum (*s);
3138         s++;
3139    }
3140   return v;
3141 }
3142
3143 Music *
3144 make_music_with_input (SCM name, Input where)
3145 {
3146        Music *m = make_music_by_name (name);
3147        m->set_spot (where);
3148        return m;
3149 }
3150
3151 SCM
3152 get_first_context_id (SCM type, Music *m)
3153 {
3154         SCM id = m->get_property ("context-id");
3155         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
3156             && scm_is_string (m->get_property ("context-id"))
3157             && scm_c_string_length (id) > 0)
3158         {
3159                 return id;
3160         }
3161         return SCM_EOL;
3162 }
3163
3164 SCM
3165 make_simple_markup (SCM a)
3166 {
3167         return a;
3168 }
3169
3170 bool
3171 is_duration (int t)
3172 {
3173   return t && t == 1 << intlog2 (t);
3174 }
3175
3176 void
3177 set_music_properties (Music *p, SCM a)
3178 {
3179   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
3180         p->set_property (scm_caar (k), scm_cdar (k));
3181 }
3182
3183
3184 SCM
3185 make_chord_step (int step, Rational alter)
3186 {
3187         if (step == 7)
3188                 alter += FLAT_ALTERATION;
3189
3190         while (step < 0)
3191                 step += 7;
3192         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
3193         return m.smobbed_copy ();
3194 }
3195
3196
3197 SCM
3198 make_chord_elements (SCM pitch, SCM dur, SCM modification_list)
3199 {
3200         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
3201         return scm_call_3 (chord_ctor, pitch, dur, modification_list);
3202 }
3203
3204 SCM
3205 try_unpack_lyrics (SCM pred, SCM arg)
3206 {
3207         if (Music *m = unsmob_music (arg))
3208                 if (m->is_mus_type ("lyric-event")) {
3209                         SCM text = m->get_property ("text");
3210                         if (scm_is_true (scm_call_1 (pred, text)))
3211                                         return text;
3212                         }
3213         return SCM_UNDEFINED;
3214 }
3215
3216 /* Todo: actually also use apply iso. call too ...  */
3217 bool
3218 ly_input_procedure_p (SCM x)
3219 {
3220         return ly_is_procedure (x)
3221                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
3222 }
3223
3224 int
3225 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
3226 {
3227         Lily_parser *pars = (Lily_parser*) v;
3228         Lily_lexer *lex = pars->lexer_;
3229
3230         lex->lexval_ = (void*) s;
3231         lex->lexloc_ = loc;
3232         lex->prepare_for_next_token ();
3233         return lex->yylex ();
3234 }