lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "lily-lexer.hh"
  44 #include "lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((Lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left ADDLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         Lily_parser *pars = (Lily_parser*) v;
 209         Lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226   (what? --hwn)
 227
 228 3. \markup { }
 229
 230   (what? --hwn)
 231
 232
 233 4.  \repeat
 234         \repeat .. \alternative
 235
 236
 237     \repeat { \repeat .. \alternative }
 238
 239 or
 240
 241     \repeat { \repeat } \alternative
 242
 243 )
 244  */
 245
 246
 247 %pure_parser
 248
 249 %token ACCEPTS
 250 %token ADDQUOTE
 251 %token LYRICSTO
 252 %token ALIAS
 253 %token ALTERNATIVE
 254 %token BAR
 255 %token BOOK
 256 %token BOOKPAPER
 257 %token CHANGE
 258 %token CHORDMODIFIERS
 259 %token CHORDS
 260 %token DOUBLE_ANGLE_OPEN
 261 %token DOUBLE_ANGLE_CLOSE
 262 %token CLEF
 263 %token COMMANDSPANREQUEST
 264 %token CONSISTS
 265 %token CONTEXT
 266 %token DEFAULT
 267 %token DENIES
 268 %token DESCRIPTION
 269 %token EXTENDER
 270 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 271 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 272 %token GROBDESCRIPTIONS
 273 %token HEADER
 274 %token HYPHEN
 275 %token INVALID
 276 %token KEY
 277 %token LYRICS
 278 %token MARK
 279 %token MIDI
 280 %token MULTI_MEASURE_REST
 281 %token NAME
 282 %token NEWCONTEXT
 283 %token NOTES
 284 %token OCTAVE
 285 %token ONCE
 286 %token OVERRIDE SET REVERT
 287 %token PAPER
 288 %token PARTIAL
 289 %token QUOTE
 290 %token RELATIVE
 291 %token REMOVE
 292 %token REPEAT
 293 %token REST
 294 %token SCM_T
 295 %token SCORE
 296 %token SEQUENTIAL
 297 %token ADDLYRICS
 298 %token SIMULTANEOUS
 299 %token SKIP
 300 %token SPANREQUEST
 301 %token TAG
 302 %token TEMPO
 303 %token TIMES
 304 %token TIME_T
 305 %token TRANSPOSE
 306 %token TRANSPOSITION
 307 %token TYPE
 308 %token UNSET
 309 %token WITH
 310 %token MARKUP
 311
 312 /* escaped */
 313 /* FIXME: this sucks.  The user will get to see these names:
 314     syntax error, unexpected E_CHAR:
 315                 \
 316                  %%
 317   */
 318
 319 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 320 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 321 %token E_BACKSLASH
 322 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 323 %token FIGURE_SPACE
 324
 325 %token <i>      DIGIT
 326 %token <i>      UNSIGNED
 327 %token <i> E_UNSIGNED
 328 %token <id>     IDENTIFIER
 329 %token <scm>    CHORDMODIFIER_PITCH
 330 %token <scm>    DRUM_PITCH
 331 %token <scm>    DURATION_IDENTIFIER
 332 %token <scm>    EVENT_IDENTIFIER
 333 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 334 %token <scm>    NOTENAME_PITCH
 335 %token <scm>    NUMBER_IDENTIFIER
 336 %token <scm>    OUTPUT_DEF_IDENTIFIER
 337 %token <scm>    RESTNAME
 338 %token <scm> LYRICS_STRING
 339 %token <scm>    SCM_T
 340 %token <scm>    SCORE_IDENTIFIER
 341 %token <scm>    STRING
 342 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 343 %token <scm>    TONICNAME_PITCH
 344 %token <scm>    CHORD_MODIFIER
 345 %token <scm>    FRACTION
 346 %token <scm>   REAL
 347 %token <scm> MARKUP_HEAD_EMPTY
 348 %token <scm> MARKUP_HEAD_MARKUP0
 349 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 350 %token <scm> MARKUP_HEAD_SCM0
 351 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 354 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 355 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 356 %token <scm> MUSIC_FUNCTION
 357 %token <scm> MUSIC_FUNCTION_MUSIC
 358 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 359 %token <scm> MUSIC_FUNCTION_SCM
 360 %token <scm> MUSIC_FUNCTION_SCM_SCM
 361 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 362 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 363 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 364 %token DRUMS
 365
 366
 367
 368 %type <book>    book_block book_body
 369 %type <i>       bare_int  bare_unsigned
 370 %type <i>       exclamations questions dots optional_rest
 371 %type <i>       script_dir
 372 %type <i>       sub_quotes sup_quotes
 373 %type <i>       tremolo_type
 374 %type <i>       bass_mod
 375
 376 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 377 %type <music>   Grouped_music_list
 378 %type <music>   Music Sequential_music Simultaneous_music
 379 %type <music>   Repeated_music
 380 %type <music>   command_req
 381 %type <music>   gen_text_def direction_less_event direction_reqd_event
 382 %type <music>   music_property_def context_change
 383 %type <music>   note_chord_element chord_body chord_body_element
 384 %type <music>   open_event close_event
 385 %type <music>   post_event tagged_post_event
 386 %type <music>   relative_music re_rhythmed_music
 387 %type <music>   simple_element event_chord command_element
 388 %type <music>   string_number_event
 389 %type <music>   toplevel_music
 390 %type <music>   tempo_event
 391
 392 %type <outputdef>       output_def_body output_def_head
 393 %type <outputdef> output_def book_paper_block
 394
 395 %type <scm>     Music_list
 396 %type <scm>     chord_body_elements
 397 %type <scm>     chord_item chord_items chord_separator new_chord
 398 %type <scm>     context_def_spec_block context_def_spec_body
 399 %type <scm>     context_mod context_def_mod optional_context_mod
 400 %type <scm>     context_prop_spec
 401 %type <scm>     duration_length fraction
 402 %type <scm>     embedded_scm scalar
 403 %type <scm>     identifier_init
 404 %type <scm>     lilypond_header lilypond_header_body
 405 %type <scm>     new_lyrics
 406 %type <scm>     post_events
 407 %type <scm>     property_operation
 408 %type <scm>     script_abbreviation
 409 %type <scm>     simple_string
 410 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 411 %type <scm>     steno_tonic_pitch
 412 %type <scm>     step_number step_numbers
 413 %type <scm>     string bare_number number_expression number_term number_factor
 414 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 415 %type <scm>     context_mod_list
 416 %type <scm>     octave_check
 417 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 418 %type <scm>     Generic_prefix_music_scm
 419 %type <scm>     lyric_element
 420 %type <scm>     Alternative_music
 421 %type <scm>     markup markup_line markup_list markup_list_body full_markup
 422
 423 %type <score>   score_block score_body
 424
 425
 426 %left '-' '+'
 427
 428 /* We don't assign precedence to / and *, because we might need varied
 429 prec levels in different prods */
 430
 431 %left UNARY_MINUS
 432
 433 %%
 434
 435 lilypond:       /* empty */
 436         | lilypond toplevel_expression {
 437         }
 438         | lilypond assignment {
 439         }
 440         | lilypond error {
 441                 THIS->error_level_ = 1;
 442         }
 443         | lilypond INVALID      {
 444                 THIS->error_level_ = 1;
 445         }
 446         ;
 447
 448 toplevel_expression:
 449         lilypond_header {
 450                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 451         }
 452         | add_quote {
 453
 454         }
 455         | book_block {
 456                 Book *book = $1;
 457                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 458                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 459                 scm_gc_unprotect_object (book->self_scm ());
 460         }
 461         | score_block {
 462                 Score *score = $1;
 463
 464                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 465                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 466                 scm_gc_unprotect_object (score->self_scm ());
 467         }
 468         | toplevel_music {
 469                 Music *music = $1;
 470                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 471                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 472                 scm_gc_unprotect_object (music->self_scm ());
 473         }
 474         | output_def {
 475                 SCM id = SCM_EOL;
 476                 Output_def * od = $1;
 477
 478                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 479                         id = ly_symbol2scm ("$defaultpaper");
 480                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 481                         id = ly_symbol2scm ("$defaultmidi");
 482                 else if ($1->c_variable ("is-bookpaper") == SCM_BOOL_T)
 483                         id = ly_symbol2scm ("$defaultbookpaper");
 484
 485                 THIS->lexer_->set_identifier (id, od->self_scm ());
 486                 scm_gc_unprotect_object (od->self_scm ());
 487         }
 488         ;
 489
 490 toplevel_music:
 491         Composite_music {
 492         }
 493         ;
 494
 495 embedded_scm:
 496         SCM_T
 497         | SCM_IDENTIFIER
 498         ;
 499
 500
 501 lilypond_header_body:
 502         {
 503                 $$ = ly_make_anonymous_module (safe_global_b);
 504                 THIS->lexer_->add_scope ($$);
 505         }
 506         | lilypond_header_body assignment  {
 507
 508         }
 509         ;
 510
 511 lilypond_header:
 512         HEADER '{' lilypond_header_body '}'     {
 513                 $$ = THIS->lexer_->remove_scope ();
 514         }
 515         ;
 516
 517
 518 /*
 519         DECLARATIONS
 520 */
 521 assignment:
 522         STRING {
 523                 THIS->push_spot ();
 524         }
 525         /* cont */ '=' identifier_init  {
 526
 527         /*
 528                 Should find generic way of associating input with objects.
 529         */
 530                 Input ip = THIS->pop_spot ();
 531
 532                 if (! is_regular_identifier ($1))
 533                 {
 534                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 535                 }
 536
 537                 THIS->lexer_->set_identifier ($1, $4);
 538
 539 /*
 540  TODO: devise standard for protection in parser.
 541
 542   The parser stack lives on the C-stack, which means that
 543 all objects can be unprotected as soon as they're here.
 544
 545 */
 546         }
 547         | embedded_scm { }
 548         ;
 549
 550
 551 identifier_init:
 552         score_block {
 553                 $$ = $1->self_scm ();
 554                 scm_gc_unprotect_object ($$);
 555         }
 556         | output_def {
 557                 $$ = $1->self_scm ();
 558                 scm_gc_unprotect_object ($$);
 559         }
 560         | context_def_spec_block {
 561                 $$ = $1;
 562         }
 563         | Music  {
 564                 $$ = $1->self_scm ();
 565                 scm_gc_unprotect_object ($$);
 566         }
 567         | post_event {
 568                 $$ = $1->self_scm ();
 569                 scm_gc_unprotect_object ($$);
 570         }
 571         | number_expression {
 572                 $$ = $1;
 573         }
 574         | string {
 575                 $$ = $1;
 576         }
 577         | embedded_scm {
 578                 $$ = $1;
 579         }
 580         | full_markup {
 581                 $$ = $1;
 582         }
 583         | DIGIT {
 584                 $$ = scm_int2num ($1);
 585         }
 586         ;
 587
 588 context_def_spec_block:
 589         CONTEXT '{' context_def_spec_body '}'
 590                 {
 591                 $$ = $3;
 592         }
 593         ;
 594
 595 context_def_spec_body:
 596         /**/ {
 597                 $$ = Context_def::make_scm ();
 598                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 599         }
 600         | CONTEXT_DEF_IDENTIFIER {
 601                 $$ = $1;
 602                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 603         }
 604         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 605                 Context_def*td = unsmob_context_def ($$);
 606
 607                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 608                         SCM tag = ly_caar (p);
 609
 610                         /* TODO: should make new tag "grob-definition" ? */
 611                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 612                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 613                 }
 614         }
 615         | context_def_spec_body context_mod {
 616                 unsmob_context_def ($$)->add_context_mod ($2);
 617         }
 618         ;
 619
 620
 621
 622 book_block:
 623         BOOK {
 624                 THIS->push_spot ();
 625         }
 626         /*cont*/ '{' book_body '}'      {
 627                 THIS->pop_spot ();
 628                 $$ = $4;
 629         }
 630         ;
 631
 632 /* FIXME:
 633    * Use 'handlers' like for toplevel-* stuff?
 634    * grok \paper and \midi?  */
 635 book_body:
 636         {
 637                 $$ = new Book;
 638                 $$->set_spot (THIS->here_input ());
 639                 $$->bookpaper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 640                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 641                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 642         }
 643         | book_body book_paper_block {
 644                 $$->bookpaper_ = $2;
 645                 scm_gc_unprotect_object ($2->self_scm ());
 646         }
 647         | book_body score_block {
 648                 Score *score = $2;
 649                 $$->scores_.push (score);
 650                 scm_gc_unprotect_object (score->self_scm ());
 651         }
 652         | book_body lilypond_header {
 653                 $$->header_ = $2;
 654         }
 655         | book_body error {
 656
 657         }
 658         ;
 659
 660 score_block:
 661         SCORE {
 662                 THIS->push_spot ();
 663         }
 664         /*cont*/ '{' score_body '}'     {
 665                 THIS->pop_spot ();
 666                 $$ = $4;
 667         }
 668         ;
 669
 670 score_body:
 671         /**/    {
 672                 $$ = new Score;
 673
 674                 $$->set_spot (THIS->here_input ());
 675         }
 676         | SCORE_IDENTIFIER {
 677                 $$ = new Score ( *unsmob_score ($1));
 678                 $$->set_spot (THIS->here_input ());
 679         }
 680         | score_body Music {
 681                 SCM m = $2->self_scm ();
 682                 scm_gc_unprotect_object (m);
 683
 684                 /*
 685                         guh.
 686                 */
 687                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 688                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 689                         m = scm_call_1 (ly_car (check_funcs), m);
 690                 if (unsmob_music ($$->music_))
 691                 {
 692                         THIS->parser_error (_("Already have music in score"));
 693                         unsmob_music ($$->music_)->origin ()->error (_("This is the previous music"));
 694                 }
 695                 $$->music_ = m;
 696         }
 697         | score_body lilypond_header    {
 698                 $$->header_ = $2;
 699         }
 700         | score_body output_def {
 701                 $$->defs_.push ($2);
 702                 scm_gc_unprotect_object ($2->self_scm ());
 703         }
 704         | score_body error {
 705
 706         }
 707         ;
 708
 709
 710 /*
 711         OUTPUT DEF
 712 */
 713
 714 book_paper_block:
 715         output_def {
 716                 $$ = $1;
 717                 if ($$->lookup_variable (ly_symbol2scm ("is-bookpaper")) != SCM_BOOL_T)
 718                 {
 719                         THIS->parser_error (_("Need \\bookpaper for bookpaper block."));
 720                         $$ = get_bookpaper (THIS);
 721                 }
 722         }
 723         ;
 724
 725
 726 output_def:
 727         output_def_body '}' {
 728                 $$ = $1;
 729                 if ($1->parent_)
 730                         THIS->lexer_->remove_scope ();
 731
 732                 THIS->lexer_->remove_scope ();
 733                 THIS->lexer_->pop_state ();
 734         }
 735         ;
 736
 737 output_def_head:
 738         BOOKPAPER {
 739                 $$ = get_bookpaper (THIS);
 740                 $$->input_origin_ = THIS->here_input ();
 741                 THIS->lexer_->add_scope ($$->scope_);
 742         }
 743         | MIDI    {
 744                 Output_def *p = get_midi (THIS);
 745                 $$ = p;
 746                 THIS->lexer_->add_scope (p->scope_);
 747         }
 748         | PAPER         {
 749                 Output_def *p = get_paper (THIS);
 750
 751                 if (p->parent_)
 752                         THIS->lexer_->add_scope (p->parent_->scope_);
 753
 754                 THIS->lexer_->add_scope (p->scope_);
 755                 $$ = p;
 756         }
 757         ;
 758
 759
 760 output_def_body:
 761         output_def_head '{' {
 762                 $$ = $1;
 763                 $$->input_origin_.set_spot (THIS->here_input ());
 764                 THIS->lexer_->push_initial_state ();
 765         }
 766         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 767                 scm_gc_unprotect_object ($1->self_scm ());
 768                 Output_def *o = unsmob_output_def ($3);
 769                 o->input_origin_.set_spot (THIS->here_input ());
 770                 $$ = o;
 771                 THIS->lexer_->remove_scope ();
 772                 THIS->lexer_->add_scope (o->scope_);
 773                 THIS->lexer_->push_initial_state ();
 774         }
 775         | output_def_body assignment  {
 776
 777         }
 778         | output_def_body context_def_spec_block        {
 779                 assign_context_def ($$, $2);
 780         }
 781         | output_def_body tempo_event  {
 782                 /*
 783                         junk this ? there already is tempo stuff in
 784                         music.
 785                 */
 786                 int m = scm_to_int ($2->get_property ("metronome-count"));
 787                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 788                 set_tempo ($$, d->get_length (), m);
 789                 scm_gc_unprotect_object ($2->self_scm ());
 790         }
 791         | output_def_body error {
 792
 793         }
 794         ;
 795
 796 tempo_event:
 797         TEMPO steno_duration '=' bare_unsigned  {
 798                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 799                 $$->set_property ("tempo-unit", $2);
 800                 $$->set_property ("metronome-count", scm_int2num ( $4));
 801         }
 802         ;
 803
 804 /*
 805 The representation of a  list is the
 806
 807   (LIST . LAST-CONS)
 808
 809  to have  efficient append.
 810 */
 811 Music_list:
 812         /* empty */ {
 813                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 814         }
 815         | Music_list Music {
 816                 SCM s = $$;
 817                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 818                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 819                 if (ly_c_pair_p (ly_cdr (s)))
 820                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 821                 else
 822                         scm_set_car_x (s, c); /* set first cons */
 823                 scm_set_cdr_x (s, c);  /* remember last cell */
 824         }
 825         | Music_list embedded_scm {
 826         }
 827         | Music_list error {
 828         }
 829         ;
 830
 831
 832 Music:
 833         Simple_music
 834         | Composite_music
 835         ;
 836
 837 Alternative_music:
 838         /* empty */ {
 839                 $$ = SCM_EOL;
 840         }
 841         | ALTERNATIVE '{' Music_list '}' {
 842                 $$ = $3;
 843         }
 844         ;
 845
 846
 847 Repeated_music:
 848         REPEAT simple_string bare_unsigned Music Alternative_music
 849         {
 850                 Music *beg = $4;
 851                 int times = $3;
 852                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 853                 if (times < scm_ilength (alts)) {
 854                   unsmob_music (ly_car (alts))
 855                     ->origin ()->warning (
 856                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 857                   alts = ly_truncate_list (times, alts);
 858                 }
 859
 860
 861                 SCM proc = ly_scheme_function ("make-repeated-music");
 862
 863                 SCM mus = scm_call_1 (proc, $2);
 864                 scm_gc_protect_object (mus); // UGH.
 865                 Music *r = unsmob_music (mus);
 866                 if (beg)
 867                         {
 868                         r-> set_property ("element", beg->self_scm ());
 869                         scm_gc_unprotect_object (beg->self_scm ());
 870                         }
 871                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 872
 873                 r-> set_property ("elements",alts);
 874                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 875                         /*
 876                         TODO: move this code to Scheme.
 877                         */
 878
 879                         /*
 880                         we can not get durations and other stuff correct down the line, so we have to
 881                         add to the duration log here.
 882                         */
 883                         SCM func = ly_scheme_function ("shift-duration-log");
 884
 885                         int dots = ($3 % 3) ? 0 : 1;
 886                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 887
 888                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 889
 890                         if (seq) {
 891                                 int list_len = scm_ilength (seq->music_list ());
 892                                 if (list_len != 2)
 893                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 894                                 shift -= 1;
 895                                 r->compress (Moment (Rational (1, list_len)));
 896                                 }
 897                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 898
 899                 }
 900                 r->set_spot (*$4->origin ());
 901
 902                 $$ = r;
 903         }
 904         ;
 905
 906 Sequential_music:
 907         SEQUENTIAL '{' Music_list '}'           {
 908                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 909                 $$->set_property ("elements", ly_car ($3));
 910                 $$->set_spot (THIS->here_input ());
 911         }
 912         | '{' Music_list '}'            {
 913                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 914                 $$->set_property ("elements", ly_car ($2));
 915                 $$->set_spot (THIS->here_input ());
 916         }
 917         ;
 918
 919 Simultaneous_music:
 920         SIMULTANEOUS '{' Music_list '}'{
 921                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 922                 $$->set_property ("elements", ly_car ($3));
 923                 $$->set_spot (THIS->here_input ());
 924
 925         }
 926         | simul_open Music_list simul_close     {
 927                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 928                 $$->set_property ("elements", ly_car ($2));
 929                 $$->set_spot (THIS->here_input ());
 930         }
 931         ;
 932
 933 Simple_music:
 934         event_chord             { $$ = $1; }
 935         | MUSIC_IDENTIFIER {
 936                 $$ = unsmob_music ($1);
 937         }
 938         | music_property_def
 939         | context_change
 940         ;
 941
 942
 943 optional_context_mod:
 944         /**/ { $$ = SCM_EOL; }
 945         | WITH { THIS->lexer_->push_initial_state (); }
 946         '{' context_mod_list '}'
 947         {
 948                 THIS->lexer_->pop_state ();
 949                 $$ = $4;
 950         }
 951         ;
 952
 953 context_mod_list:
 954         /* */  { $$ = SCM_EOL; }
 955         | context_mod_list context_mod  {
 956                  $$ = scm_cons ($2, $1);
 957         }
 958         ;
 959
 960
 961 Composite_music:
 962         Prefix_composite_music { $$ = $1; }
 963         | Grouped_music_list { $$ = $1; }
 964         ;
 965
 966 Grouped_music_list:
 967         Simultaneous_music              { $$ = $1; }
 968         | Sequential_music              { $$ = $1; }
 969         ;
 970
 971 Generic_prefix_music_scm:
 972         MUSIC_FUNCTION {
 973                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 974         }
 975         | MUSIC_FUNCTION_SCM {
 976                 THIS->push_spot ();
 977         } embedded_scm {
 978                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 979         }
 980         | MUSIC_FUNCTION_MUSIC {
 981                 THIS->push_spot ();
 982         } Music {
 983                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 984                 scm_gc_unprotect_object ($3->self_scm ());
 985         }
 986         | MUSIC_FUNCTION_SCM_MUSIC {
 987                 THIS->push_spot ();
 988         }  embedded_scm Music {
 989                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 990                 scm_gc_unprotect_object ($4->self_scm ());
 991         }
 992         | MUSIC_FUNCTION_SCM_SCM {
 993                 THIS->push_spot ();
 994         }  embedded_scm embedded_scm {
 995                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4);
 996         }
 997         | MUSIC_FUNCTION_MUSIC_MUSIC {
 998                 THIS->push_spot ();
 999         }  Music  Music {
1000                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
1001                 scm_gc_unprotect_object ($3->self_scm ());
1002                 scm_gc_unprotect_object ($4->self_scm ());
1003         }
1004         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
1005                 THIS->push_spot ();
1006         } embedded_scm Music Music {
1007                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1008                         $3, $4->self_scm (), $5->self_scm ());
1009                 scm_gc_unprotect_object ($5->self_scm ());
1010                 scm_gc_unprotect_object ($4->self_scm ());
1011         }
1012         ;
1013
1014 Generic_prefix_music:
1015         Generic_prefix_music_scm {
1016                 SCM func = ly_car ($1);
1017                 Input *loc = unsmob_input (ly_cadr ($1));
1018                 SCM args = ly_cddr ($1);
1019                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1020                 int k = 0;
1021                 bool ok  = true;
1022                 for (SCM s = sig, t = args;
1023                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1024                         s = ly_cdr (s), t = ly_cdr (t)) {
1025                         k++;
1026                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1027                         {
1028                                 loc->error (_f ("Argument %d failed typecheck", k));
1029                                 THIS->error_level_ = 1;
1030                                 ok = false;
1031                         }
1032                 }
1033                 SCM m = SCM_EOL;
1034                 if (ok)
1035                         m = scm_apply_0 (func, ly_cdr ($1));
1036                 if (unsmob_music (m))
1037                         {
1038                         $$ = unsmob_music (m);
1039                         scm_gc_protect_object (m);
1040                         }
1041                 else
1042                         {
1043                         if (ok)
1044                                 loc->error (_ ("Music head function should return Music object."));
1045                         $$ = MY_MAKE_MUSIC ("Music");
1046                         }
1047                 $$->set_spot (*loc);
1048         }
1049         ;
1050
1051
1052 Prefix_composite_music:
1053         Generic_prefix_music {
1054                 $$ = $1;
1055         }
1056         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1057                 $$ = context_spec_music ($2, $4, $6, $5);
1058
1059         }
1060         | CONTEXT simple_string optional_context_mod Music {
1061                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1062         }
1063         | NEWCONTEXT simple_string optional_context_mod Music {
1064                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1065                         $3);
1066         }
1067
1068         | TIMES {
1069                 THIS->push_spot ();
1070         }
1071         /* CONTINUED */
1072                 fraction Music
1073
1074         {
1075                 int n = scm_to_int (ly_car ($3)); int d = scm_to_int (ly_cdr ($3));
1076                 Music *mp = $4;
1077
1078                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1079                 $$->set_spot (THIS->pop_spot ());
1080
1081                 $$->set_property ("element", mp->self_scm ());
1082                 scm_gc_unprotect_object (mp->self_scm ());
1083                 $$->set_property ("numerator", scm_int2num (n));
1084                 $$->set_property ("denominator", scm_int2num (d));
1085                 $$->compress (Moment (Rational (n,d)));
1086
1087         }
1088         | Repeated_music                { $$ = $1; }
1089         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1090                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1091                 Music *p = $4;
1092                 Pitch from = *unsmob_pitch ($2);
1093                 Pitch to = *unsmob_pitch ($3);
1094
1095                 p->transpose (interval (from, to));
1096                 $$->set_property ("element", p->self_scm ());
1097                 scm_gc_unprotect_object (p->self_scm ());
1098         }
1099         | NOTES
1100                 {
1101                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1102                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1103         }
1104         Grouped_music_list
1105                 { $$ = $3;
1106                   THIS->lexer_->pop_state ();
1107                 }
1108         | DRUMS
1109                 {
1110                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1111                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1112         }
1113         Grouped_music_list
1114                 { $$ = $3;
1115                   THIS->lexer_->pop_state ();
1116                 }
1117         | FIGURES
1118                 { THIS->lexer_->push_figuredbass_state (); }
1119         Grouped_music_list
1120                 {
1121                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1122                   chm->set_property ("element", $3->self_scm ());
1123                   $$ = chm;
1124                   scm_gc_unprotect_object ($3->self_scm ());
1125
1126                   THIS->lexer_->pop_state ();
1127         }
1128         | CHORDS {
1129                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1130                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1131                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1132                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1133
1134         }
1135         Grouped_music_list
1136         {
1137                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1138                   chm->set_property ("element", $3->self_scm ());
1139                   scm_gc_unprotect_object ($3->self_scm ());
1140                   $$ = chm;
1141
1142                   THIS->lexer_->pop_state ();
1143         }
1144         | LYRICS
1145                 { THIS->lexer_->push_lyric_state (); }
1146         Grouped_music_list
1147                 {
1148                   $$ = $3;
1149                   THIS->lexer_->pop_state ();
1150         }
1151         | relative_music        { $$ = $1; }
1152         | re_rhythmed_music     { $$ = $1; }
1153         | TAG embedded_scm Music {
1154                 tag_music ($3, $2, THIS->here_input ());
1155                 $$ = $3;
1156         }
1157         ;
1158
1159 relative_music:
1160         RELATIVE absolute_pitch Music {
1161                 Music *m = $3;
1162                 Pitch start = *unsmob_pitch ($2);
1163                 $$ = make_music_relative (start, m);
1164                 scm_gc_unprotect_object (m->self_scm ());
1165         }
1166         | RELATIVE Composite_music {
1167                 Music *m = $2;
1168
1169                 Pitch middle_c (0, 0, 0);
1170                 $$ = make_music_relative (middle_c, m);
1171                 scm_gc_unprotect_object (m->self_scm ());
1172         }
1173         ;
1174
1175 new_lyrics:
1176         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1177         /*cont */
1178         Grouped_music_list {
1179         /* Can also use Music at the expensive of two S/Rs similar to
1180            \repeat \alternative */
1181                 THIS->lexer_->pop_state ();
1182 #if 0
1183                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1184                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1185                 $$ = music;
1186 #else
1187                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1188 #endif
1189         }
1190         | new_lyrics ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1191         Grouped_music_list {
1192                 THIS->lexer_->pop_state ();
1193                 $$ = scm_cons ($4->self_scm (), $1);
1194         }
1195         ;
1196
1197 re_rhythmed_music:
1198         Grouped_music_list new_lyrics {
1199
1200                 /* FIXME: should find out uniqueXXX name from music */
1201                 SCM name = $1->get_property ("context-id");
1202                 //if (name == SCM_EOL)
1203                 if (!scm_is_string (name))
1204                         name = scm_makfrom0str ("");
1205
1206                 SCM context = scm_makfrom0str ("Lyrics");
1207                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1208
1209                 SCM lst = SCM_EOL;
1210                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1211                 {
1212                         Music *music = unsmob_music (ly_car (s));
1213                         Music *com = make_lyric_combine_music (name, music);
1214                         Music *csm = context_spec_music (context,
1215                                 get_next_unique_context (), com, SCM_EOL);
1216                         lst = scm_cons (csm->self_scm (), lst);
1217                 }
1218                 /* FIXME: only first lyric music is accepted,
1219                           the rest is junked */
1220                 all->set_property ("elements", scm_cons ($1->self_scm (),
1221                         lst));
1222                 $$ = all;
1223                 scm_gc_unprotect_object ($1->self_scm ());
1224         }
1225         | LYRICSTO {
1226                 THIS->lexer_->push_lyric_state ();
1227         } simple_string Music {
1228                 THIS->lexer_->pop_state ();
1229                 Music *music = $4;
1230                 SCM name = $3;
1231                 $$ = make_lyric_combine_music (name, music);
1232                 scm_gc_unprotect_object (music->self_scm ());
1233         }
1234         ;
1235
1236 context_change:
1237         CHANGE STRING '=' STRING  {
1238                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1239                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1240                 t-> set_property ("change-to-id", $4);
1241
1242                 $$ = t;
1243                 $$->set_spot (THIS->here_input ());
1244         }
1245         ;
1246
1247 property_operation:
1248         STRING '=' scalar {
1249                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1250                         scm_string_to_symbol ($1), $3);
1251         }
1252         | UNSET simple_string {
1253                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1254                         scm_string_to_symbol ($2));
1255         }
1256         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1257                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1258                         scm_string_to_symbol ($2), $3, $5);
1259         }
1260         | REVERT simple_string embedded_scm {
1261                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1262                         scm_string_to_symbol ($2), $3);
1263         }
1264         ;
1265
1266 context_def_mod:
1267         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1268         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1269
1270         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1271         | DENIES { $$ = ly_symbol2scm ("denies"); }
1272
1273         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1274         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1275         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1276         | NAME { $$ = ly_symbol2scm ("context-name"); }
1277         ;
1278
1279 context_mod:
1280         property_operation { $$ = $1; }
1281         | context_def_mod STRING {
1282                 $$ = scm_list_2 ($1, $2);
1283         }
1284         ;
1285
1286 context_prop_spec:
1287         simple_string {
1288                 if (!is_regular_identifier ($1))
1289                 {
1290                         THIS->here_input ().error (_("Grob name should be alphanumeric"));
1291                 }
1292
1293                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1294                         scm_string_to_symbol ($1));
1295         }
1296         | simple_string '.' simple_string {
1297                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1298                         scm_string_to_symbol ($3));
1299         }
1300         ;
1301
1302 music_property_def:
1303         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1304                 $$ = property_op_to_music (scm_list_4 (
1305                         ly_symbol2scm ("poppush"),
1306                         ly_cadr ($2),
1307                         $3, $5));
1308                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1309         }
1310         | REVERT context_prop_spec embedded_scm {
1311                 $$ = property_op_to_music (scm_list_3 (
1312                         ly_symbol2scm ("pop"),
1313                         ly_cadr ($2),
1314                         $3));
1315
1316                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1317         }
1318         | SET context_prop_spec '=' scalar {
1319                 $$ = property_op_to_music (scm_list_3 (
1320                         ly_symbol2scm ("assign"),
1321                         ly_cadr ($2),
1322                         $4));
1323                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1324         }
1325         | UNSET context_prop_spec {
1326                 $$ = property_op_to_music (scm_list_2 (
1327                         ly_symbol2scm ("unset"),
1328                         ly_cadr ($2)));
1329                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1330         }
1331         | ONCE music_property_def {
1332                 SCM e = $2->get_property ("element");
1333                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1334                 $$ = $2;
1335
1336         }
1337         ;
1338
1339
1340 string:
1341         STRING {
1342                 $$ = $1;
1343         }
1344         | STRING_IDENTIFIER {
1345                 $$ = $1;
1346         }
1347         | string '+' string {
1348                 $$ = scm_string_append (scm_list_2 ($1, $3));
1349         }
1350         ;
1351
1352 simple_string: STRING {
1353                 $$ = $1;
1354         }
1355         | LYRICS_STRING {
1356                 $$ = $1;
1357         }
1358         ;
1359
1360 scalar: string {
1361                 $$ = $1;
1362         }
1363         | LYRICS_STRING {
1364                 $$ = $1;
1365         }
1366         | bare_int {
1367                 $$ = scm_int2num ($1);
1368         }
1369         | embedded_scm {
1370                 $$ = $1;
1371         }
1372         | full_markup {
1373                 $$ = $1;
1374         }
1375         | DIGIT {
1376                 $$ = scm_int2num ($1);
1377         }
1378         ;
1379
1380 /*
1381
1382 pre_events doesn't contain anything. It is a trick:
1383
1384 Adding pre_events to the simple_element
1385 makes the choice between
1386
1387   string:  STRING
1388
1389 and
1390
1391   simple_element: STRING
1392
1393 a single shift/reduction conflict.
1394
1395 nevertheless, this is not very clean, and we should find a different
1396 solution.
1397
1398 */
1399 pre_events: {
1400                 THIS->push_spot ();
1401         }
1402         ;
1403
1404 event_chord:
1405         pre_events simple_element post_events   {
1406                 SCM elts = $2-> get_property ("elements");
1407
1408                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1409
1410                 $2->set_property ("elements", elts);
1411                 $$ = $2;
1412         }
1413         | command_element
1414         | note_chord_element
1415         ;
1416
1417
1418 note_chord_element:
1419         chord_body optional_notemode_duration post_events
1420         {
1421                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1422                 SCM es = $1->get_property ("elements");
1423                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1424
1425                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1426                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1427                 es = ly_append2 (es, postevs);
1428
1429                 $1-> set_property ("elements", es);
1430                 $$ = $1;
1431         }
1432         ;
1433
1434 chord_open: '<'
1435         ;
1436
1437 chord_close: '>'
1438         ;
1439
1440 simul_open: DOUBLE_ANGLE_OPEN
1441         ;
1442
1443 simul_close: DOUBLE_ANGLE_CLOSE
1444         ;
1445
1446 chord_body:
1447         chord_open chord_body_elements chord_close
1448         {
1449                 $$ = MY_MAKE_MUSIC ("EventChord");
1450                 $$->set_property ("elements",
1451                         scm_reverse_x ($2, SCM_EOL));
1452         }
1453         ;
1454
1455 chord_body_elements:
1456         /* empty */             { $$ = SCM_EOL; }
1457         | chord_body_elements chord_body_element {
1458                 $$ = scm_cons ($2->self_scm (), $1);
1459                 scm_gc_unprotect_object ($2->self_scm ());
1460         }
1461         ;
1462
1463 chord_body_element:
1464         pitch  exclamations questions octave_check post_events
1465         {
1466                 int q = $3;
1467                 int ex = $2;
1468                 SCM check = $4;
1469                 SCM post = $5;
1470
1471                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1472                 n->set_property ("pitch", $1);
1473                 if (q % 2)
1474                         n->set_property ("cautionary", SCM_BOOL_T);
1475                 if (ex % 2 || q % 2)
1476                         n->set_property ("force-accidental", SCM_BOOL_T);
1477
1478                 if (ly_c_pair_p (post)) {
1479                         SCM arts = scm_reverse_x (post, SCM_EOL);
1480                         n->set_property ("articulations", arts);
1481                 }
1482                 if (ly_c_number_p (check))
1483                 {
1484                         int q = scm_to_int (check);
1485                         n->set_property ("absolute-octave", scm_int2num (q-1));
1486                 }
1487
1488
1489                 $$ = n;
1490         }
1491         | DRUM_PITCH post_events {
1492                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1493                 n->set_property ("duration", $2);
1494                 n->set_property ("drum-type", $1);
1495                 n->set_spot (THIS->here_input ());
1496
1497                 if (ly_c_pair_p ($2)) {
1498                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1499                         n->set_property ("articulations", arts);
1500                 }
1501                 $$ = n;
1502         }
1503         ;
1504
1505 add_quote:
1506         ADDQUOTE string Music {
1507                 SCM adder = ly_scheme_function ("add-quotable");
1508
1509                 scm_call_2 (adder, $2, $3->self_scm ());
1510                 scm_gc_unprotect_object ($3->self_scm ());
1511         }
1512         ;
1513
1514 command_element:
1515         command_req {
1516                 $$ = MY_MAKE_MUSIC ("EventChord");
1517                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1518                 scm_gc_unprotect_object ($1->self_scm ());
1519
1520                 $$-> set_spot (THIS->here_input ());
1521                 $1-> set_spot (THIS->here_input ());
1522         }
1523         | SKIP duration_length {
1524                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1525                 skip->set_property ("duration", $2);
1526
1527                 $$ = skip;
1528         }
1529         | QUOTE STRING duration_length {
1530                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1531                 SCM evs = SCM_EOL;
1532                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1533                 {
1534                         SCM key = $2; // use symbol?
1535                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1536                 }
1537                 Music *quote = 0;
1538                 if (ly_c_vector_p (evs))
1539                 {
1540                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1541                         quote->set_property ("duration", $3);
1542                         quote->set_property ("quoted-events", evs);
1543                 } else {
1544                         THIS->here_input ().warning (_f ("Can\'t find music"));
1545                         quote = MY_MAKE_MUSIC ("Event");
1546                 }
1547                 quote->set_spot (THIS->here_input ());
1548                 $$ = quote;
1549         }
1550         | OCTAVE { THIS->push_spot (); }
1551           pitch {
1552                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1553                 $$ = m;
1554                 $$->set_spot (THIS->pop_spot ());
1555                 $$->set_property ("pitch", $3);
1556         }
1557         | E_LEFTSQUARE {
1558                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1559                 m->set_property ("span-direction", scm_int2num (START));
1560                 m->set_spot (THIS->here_input ());
1561
1562                 $$ = MY_MAKE_MUSIC ("EventChord");
1563                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1564                 scm_gc_unprotect_object (m->self_scm ());
1565                 $$->set_spot (THIS->here_input ());
1566         }
1567         | E_RIGHTSQUARE {
1568                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1569                 m->set_property ("span-direction", scm_int2num (STOP));
1570                 m->set_spot (THIS->here_input ());
1571
1572                 $$ = MY_MAKE_MUSIC ("EventChord");
1573                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1574                 $$->set_spot (THIS->here_input ());
1575                 scm_gc_unprotect_object (m->self_scm ());
1576         }
1577         | E_BACKSLASH {
1578                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1579                 $$->set_spot (THIS->here_input ());
1580         }
1581         | '|'      {
1582                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1583
1584                 if (Music * m = unsmob_music (pipe))
1585                         $$ = m->clone ();
1586                 else
1587                         $$ = MY_MAKE_MUSIC ("BarCheck");
1588
1589                 $$->set_spot (THIS->here_input ());
1590         }
1591         | TRANSPOSITION pitch {
1592                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1593                                         $2);
1594                 $$->set_spot (THIS-> here_input ());
1595                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1596                         $$, SCM_EOL);
1597         }
1598         | BAR STRING                    {
1599                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1600
1601                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1602                                         t, SCM_EOL);
1603                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1604                 $$->set_spot (THIS->here_input ());
1605                 t->set_spot (THIS->here_input ());
1606         }
1607         | PARTIAL duration_length       {
1608                 Moment m = - unsmob_duration ($2)->get_length ();
1609                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1610                 p->set_spot (THIS->here_input ());
1611                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1612                                         p, SCM_EOL);
1613                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1614                                         p, SCM_EOL);
1615                 $$ = p;
1616         }
1617         | CLEF STRING  {
1618                 SCM proc = ly_scheme_function ("make-clef-set");
1619
1620                 SCM result = scm_call_1 (proc, $2);
1621                 scm_gc_protect_object (result);
1622                 $$ = unsmob_music (result);
1623         }
1624         | TIME_T fraction  {
1625                 SCM proc= ly_scheme_function ("make-time-signature-set");
1626
1627                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1628                 scm_gc_protect_object (result);
1629                 $$ = unsmob_music (result);
1630         }
1631         | MARK scalar {
1632                 SCM proc = ly_scheme_function ("make-mark-set");
1633
1634                 SCM result = scm_call_1 (proc, $2);
1635                 scm_gc_protect_object (result);
1636                 $$ = unsmob_music (result);
1637         }
1638         ;
1639
1640 command_req:
1641         E_TILDE {
1642                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1643         }
1644         | MARK DEFAULT  {
1645                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1646                 $$ = m;
1647         }
1648         | tempo_event {
1649                 $$ = $1;
1650         }
1651         | KEY DEFAULT {
1652                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1653                 $$ = key;
1654         }
1655         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1656
1657                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1658                 if (scm_ilength ($3) > 0)
1659                 {
1660                         key->set_property ("pitch-alist", $3);
1661                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1662                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1663                 } else {
1664                         THIS->parser_error (_ ("Second argument must be pitch list."));
1665                 }
1666
1667                 $$ = key;
1668         }
1669         ;
1670
1671 post_events:
1672         /* empty */ {
1673                 $$ = SCM_EOL;
1674         }
1675         | post_events post_event {
1676                 $2->set_spot (THIS->here_input ());
1677                 $$ = scm_cons ($2->self_scm (), $$);
1678                 scm_gc_unprotect_object ($2->self_scm ());
1679         }
1680         | post_events tagged_post_event {
1681                 $2 -> set_spot (THIS->here_input ());
1682                 $$ = scm_cons ($2->self_scm (), $$);
1683                 scm_gc_unprotect_object ($2->self_scm ());
1684         }
1685         ;
1686
1687
1688 tagged_post_event:
1689         '-' TAG embedded_scm post_event {
1690                 tag_music ($4, $3, THIS->here_input ());
1691                 $$ = $4;
1692         }
1693         ;
1694
1695 post_event:
1696         direction_less_event {
1697                 $$ = $1;
1698         }
1699         | HYPHEN {
1700                 if (!THIS->lexer_->is_lyric_state ())
1701                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1702                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1703         }
1704         | EXTENDER {
1705                 if (!THIS->lexer_->is_lyric_state ())
1706                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1707                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1708         }
1709         | script_dir direction_reqd_event {
1710                 if ($1)
1711                         $2->set_property ("direction", scm_int2num ($1));
1712                 $$ = $2;
1713         }
1714         | script_dir direction_less_event {
1715                 if ($1)
1716                         $2->set_property ("direction", scm_int2num ($1));
1717                 $$ = $2;
1718         }
1719         | string_number_event
1720         ;
1721
1722 string_number_event:
1723         E_UNSIGNED {
1724                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1725                 s->set_property ("string-number", scm_int2num ($1));
1726                 s->set_spot (THIS->here_input ());
1727                 $$ = s;
1728         }
1729         ;
1730
1731
1732 direction_less_event:
1733         '['  {
1734
1735
1736 /*
1737
1738 TODO: should take all these defs out of the parser, adn make use
1739 configurable, i.e.
1740
1741
1742 (set-articulation '~ "trill")
1743
1744 */
1745                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1746                 m->set_spot (THIS->here_input ());
1747                 m->set_property ("span-direction", scm_int2num (START));
1748                 $$ = m;
1749         }
1750         | ']'  {
1751                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1752                 m->set_spot (THIS->here_input ());
1753                 m->set_property ("span-direction", scm_int2num (STOP));
1754                 $$ = m;
1755         }
1756         | '~' {
1757                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1758                 m->set_spot (THIS->here_input ());
1759                 $$ = m;
1760         }
1761         | close_event {
1762                 $$ = $1;
1763                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1764                         scm_int2num (START));
1765         }
1766         | open_event {
1767                 $$ = $1;
1768                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1769                         scm_int2num (STOP));
1770         }
1771         | EVENT_IDENTIFIER      {
1772                 $$ = unsmob_music ($1);
1773         }
1774         | tremolo_type  {
1775                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1776                a->set_spot (THIS->here_input ());
1777                a->set_property ("tremolo-type", scm_int2num ($1));
1778                $$ = a;
1779         }
1780         ;
1781
1782 direction_reqd_event:
1783         gen_text_def {
1784                 $$ = $1;
1785         }
1786         | script_abbreviation {
1787                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1788                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1789                 if (scm_is_string (s))
1790                         a->set_property ("articulation-type", s);
1791                 else THIS->parser_error (_ ("Expecting string as script definition"));
1792                 $$ = a;
1793         }
1794         ;
1795
1796 octave_check:
1797         /**/ { $$ = SCM_EOL; }
1798         | '='  { $$ = scm_int2num (0); }
1799         | '=' sub_quotes { $$ = scm_int2num ($2); }
1800         | '=' sup_quotes { $$ = scm_int2num ($2); }
1801         ;
1802
1803 sup_quotes:
1804         '\'' {
1805                 $$ = 1;
1806         }
1807         | sup_quotes '\'' {
1808                 $$ ++;
1809         }
1810         ;
1811
1812 sub_quotes:
1813         ',' {
1814                 $$ = 1;
1815         }
1816         | sub_quotes ',' {
1817                 $$++;
1818         }
1819         ;
1820
1821 steno_pitch:
1822         NOTENAME_PITCH  {
1823                 $$ = $1;
1824         }
1825         | NOTENAME_PITCH sup_quotes     {
1826                 Pitch p = *unsmob_pitch ($1);
1827                 p = p.transposed (Pitch ($2,0,0));
1828                 $$ = p.smobbed_copy ();
1829         }
1830         | NOTENAME_PITCH sub_quotes      {
1831                 Pitch p =* unsmob_pitch ($1);
1832                 p = p.transposed (Pitch (-$2,0,0));
1833                 $$ = p.smobbed_copy ();
1834         }
1835         ;
1836
1837 /*
1838 ugh. duplication
1839 */
1840
1841 steno_tonic_pitch:
1842         TONICNAME_PITCH {
1843                 $$ = $1;
1844         }
1845         | TONICNAME_PITCH sup_quotes    {
1846                 Pitch p = *unsmob_pitch ($1);
1847                 p = p.transposed (Pitch ($2,0,0));
1848                 $$ = p.smobbed_copy ();
1849         }
1850         | TONICNAME_PITCH sub_quotes     {
1851                 Pitch p =* unsmob_pitch ($1);
1852
1853                 p = p.transposed (Pitch (-$2,0,0));
1854                 $$ = p.smobbed_copy ();
1855         }
1856         ;
1857
1858 pitch:
1859         steno_pitch {
1860                 $$ = $1;
1861         }
1862         ;
1863
1864 pitch_also_in_chords:
1865         pitch
1866         | steno_tonic_pitch
1867         ;
1868
1869 close_event:
1870         '('     {
1871                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1872                 $$ = s;
1873                 s->set_spot (THIS->here_input ());
1874         }
1875         | E_OPEN        {
1876                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1877                 $$ = s;
1878                 s->set_spot (THIS->here_input ());
1879         }
1880         | E_SMALLER {
1881                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1882                 $$ = s;
1883                 s->set_spot (THIS->here_input ());
1884         }
1885         | E_BIGGER {
1886                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1887                 $$ = s;
1888                 s->set_spot (THIS->here_input ());
1889         }
1890         ;
1891
1892
1893 open_event:
1894         E_EXCLAMATION   {
1895                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1896                 s->set_spot (THIS->here_input ());
1897
1898                 $$ = s;
1899         }
1900         | ')'   {
1901                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1902                 $$ = s;
1903                 s->set_spot (THIS->here_input ());
1904
1905         }
1906         | E_CLOSE       {
1907                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1908                 $$ = s;
1909                 s->set_property ("span-type",
1910                         scm_makfrom0str ("phrasing-slur"));
1911                 s->set_spot (THIS->here_input ());
1912         }
1913         ;
1914
1915 gen_text_def:
1916         full_markup {
1917                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1918                 t->set_property ("text", $1);
1919                 t->set_spot (THIS->here_input ());
1920                 $$ = t;
1921         }
1922         | string {
1923                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1924                 t->set_property ("text",
1925                         make_simple_markup (THIS->lexer_->encoding (), $1));
1926                 t->set_spot (THIS->here_input ());
1927                 $$ = t;
1928
1929         }
1930         | DIGIT {
1931                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1932                 t->set_property ("digit", scm_int2num ($1));
1933                 t->set_spot (THIS->here_input ());
1934                 $$ = t;
1935         }
1936         ;
1937
1938 script_abbreviation:
1939         '^'             {
1940                 $$ = scm_makfrom0str ("Hat");
1941         }
1942         | '+'           {
1943                 $$ = scm_makfrom0str ("Plus");
1944         }
1945         | '-'           {
1946                 $$ = scm_makfrom0str ("Dash");
1947         }
1948         | '|'           {
1949                 $$ = scm_makfrom0str ("Bar");
1950         }
1951         | '>'           {
1952                 $$ = scm_makfrom0str ("Larger");
1953         }
1954         | '.'           {
1955                 $$ = scm_makfrom0str ("Dot");
1956         }
1957         | '_' {
1958                 $$ = scm_makfrom0str ("Underscore");
1959         }
1960         ;
1961
1962 script_dir:
1963         '_'     { $$ = DOWN; }
1964         | '^'   { $$ = UP; }
1965         | '-'   { $$ = CENTER; }
1966         ;
1967
1968
1969 absolute_pitch:
1970         steno_pitch     {
1971                 $$ = $1;
1972         }
1973         ;
1974
1975 duration_length:
1976         multiplied_duration {
1977                 $$ = $1;
1978         }
1979         ;
1980
1981 optional_notemode_duration:
1982         {
1983                 Duration dd = THIS->default_duration_;
1984                 $$ = dd.smobbed_copy ();
1985
1986                 THIS->beam_check ($$);
1987         }
1988         | multiplied_duration   {
1989                 $$ = $1;
1990                 THIS->default_duration_ = *unsmob_duration ($$);
1991
1992                 THIS->beam_check ($$);
1993         }
1994         ;
1995
1996 steno_duration:
1997         bare_unsigned dots              {
1998                 int len = 0;
1999                 if (!is_duration ($1))
2000                         THIS->parser_error (_f ("not a duration: %d", $1));
2001                 else
2002                         len = intlog2 ($1);
2003
2004                 $$ = Duration (len, $2).smobbed_copy ();
2005         }
2006         | DURATION_IDENTIFIER dots      {
2007                 Duration *d = unsmob_duration ($1);
2008                 Duration k (d->duration_log (), d->dot_count () + $2);
2009                 *d = k;
2010                 $$ = $1;
2011         }
2012         ;
2013
2014 multiplied_duration:
2015         steno_duration {
2016                 $$ = $1;
2017         }
2018         | multiplied_duration '*' bare_unsigned {
2019                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2020         }
2021         | multiplied_duration '*' FRACTION {
2022                 Rational  m (scm_to_int (ly_car ($3)), scm_to_int (ly_cdr ($3)));
2023
2024                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2025         }
2026         ;
2027
2028 fraction:
2029         FRACTION { $$ = $1; }
2030         | UNSIGNED '/' UNSIGNED {
2031                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2032         }
2033         ;
2034
2035 dots:
2036         /* empty */     {
2037                 $$ = 0;
2038         }
2039         | dots '.' {
2040                 $$ ++;
2041         }
2042         ;
2043
2044 tremolo_type:
2045         ':'     {
2046                 $$ = 0;
2047         }
2048         | ':' bare_unsigned {
2049                 if (!is_duration ($2))
2050                         THIS->parser_error (_f ("not a duration: %d", $2));
2051                 $$ = $2;
2052         }
2053         ;
2054
2055 bass_number:
2056         DIGIT   {
2057                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2058                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2059                                 $$);
2060         }
2061         | UNSIGNED {
2062                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2063                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2064                                 $$);
2065         }
2066         | STRING { $$ = $1; }
2067         ;
2068
2069 bass_mod:
2070         '-'     { $$ = -2; }
2071         | '+'   { $$ = 2; }
2072         | '!'   { $$ = 0; }
2073         ;
2074
2075 bass_figure:
2076         FIGURE_SPACE {
2077                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2078                 $$ = bfr->self_scm ();
2079                 scm_gc_unprotect_object ($$);
2080         }
2081         | bass_number  {
2082                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2083                 $$ = bfr->self_scm ();
2084
2085                 bfr->set_property ("figure", $1);
2086
2087                 scm_gc_unprotect_object ($$);
2088         }
2089         | bass_figure bass_mod {
2090                 Music *m = unsmob_music ($1);
2091                 if ($2) {
2092                         SCM salter = m->get_property ("alteration");
2093                         int alter = ly_c_number_p (salter) ? scm_to_int (salter) : 0;
2094                         m->set_property ("alteration",
2095                                 scm_int2num (alter + $2));
2096                 } else {
2097                         m->set_property ("alteration", scm_int2num (0));
2098                 }
2099         }
2100         ;
2101
2102 br_bass_figure:
2103         '[' bass_figure {
2104                 $$ = $2;
2105                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2106         }
2107         | bass_figure   {
2108                 $$ = $1;
2109         }
2110         | br_bass_figure ']' {
2111                 $$ = $1;
2112                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2113         }
2114         ;
2115
2116 figure_list:
2117         /**/            {
2118                 $$ = SCM_EOL;
2119         }
2120         | figure_list br_bass_figure {
2121                 $$ = scm_cons ($2, $1);
2122         }
2123         ;
2124
2125 figure_spec:
2126         FIGURE_OPEN figure_list FIGURE_CLOSE {
2127                 Music *m = MY_MAKE_MUSIC ("EventChord");
2128                 $2 = scm_reverse_x ($2, SCM_EOL);
2129                 m->set_property ("elements", $2);
2130                 $$ = m->self_scm ();
2131         }
2132         ;
2133
2134
2135 optional_rest:
2136         /**/   { $$ = 0; }
2137         | REST { $$ = 1; }
2138         ;
2139
2140 simple_element:
2141         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2142
2143                 Input i = THIS->pop_spot ();
2144                 if (!THIS->lexer_->is_note_state ())
2145                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2146
2147                 Music *n = 0;
2148                 if ($6)
2149                         n = MY_MAKE_MUSIC ("RestEvent");
2150                 else
2151                         n = MY_MAKE_MUSIC ("NoteEvent");
2152
2153                 n->set_property ("pitch", $1);
2154                 n->set_property ("duration", $5);
2155
2156                 if (ly_c_number_p ($4))
2157                 {
2158                         int q = scm_to_int ($4);
2159                         n->set_property ("absolute-octave", scm_int2num (q-1));
2160                 }
2161
2162                 if ($3 % 2)
2163                         n->set_property ("cautionary", SCM_BOOL_T);
2164                 if ($2 % 2 || $3 % 2)
2165                         n->set_property ("force-accidental", SCM_BOOL_T);
2166
2167                 Music *v = MY_MAKE_MUSIC ("EventChord");
2168                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2169                 scm_gc_unprotect_object (n->self_scm ());
2170
2171                 v->set_spot (i);
2172                 n->set_spot (i);
2173                 $$ = v;
2174         }
2175         | DRUM_PITCH optional_notemode_duration {
2176                 Input i = THIS->pop_spot ();
2177
2178                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2179                 n->set_property ("duration", $2);
2180                 n->set_property ("drum-type", $1);
2181
2182                 Music *v = MY_MAKE_MUSIC ("EventChord");
2183                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2184                 scm_gc_unprotect_object (n->self_scm ());
2185                 v->set_spot (i);
2186                 n->set_spot (i);
2187                 $$ = v;
2188
2189         }
2190         | figure_spec optional_notemode_duration {
2191                 Music *m = unsmob_music ($1);
2192                 Input i = THIS->pop_spot ();
2193                 m->set_spot (i);
2194                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2195                 {
2196                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2197                 }
2198                 $$ = m;
2199         }
2200         | RESTNAME optional_notemode_duration           {
2201
2202                 Input i = THIS->pop_spot ();
2203                 Music *ev = 0;
2204                 if (ly_scm2string ($1) == "s") {
2205                         /* Space */
2206                         ev = MY_MAKE_MUSIC ("SkipEvent");
2207                   }
2208                 else {
2209                         ev = MY_MAKE_MUSIC ("RestEvent");
2210
2211                     }
2212                 ev->set_property ("duration", $2);
2213                 ev->set_spot (i);
2214                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2215                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2216                 velt->set_spot (i);
2217
2218                 scm_gc_unprotect_object (ev->self_scm ());
2219
2220                 $$ = velt;
2221         }
2222         | MULTI_MEASURE_REST optional_notemode_duration         {
2223                 THIS->pop_spot ();
2224
2225                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2226                 SCM mus = scm_call_2 (proc, $2,
2227                         make_input (THIS->here_input ()));
2228                 scm_gc_protect_object (mus);
2229                 $$ = unsmob_music (mus);
2230         }
2231
2232         | lyric_element optional_notemode_duration      {
2233                 Input i = THIS->pop_spot ();
2234                 if (!THIS->lexer_->is_lyric_state ())
2235                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2236
2237                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2238                 lreq->set_property ("text", $1);
2239                 lreq->set_property ("duration",$2);
2240                 lreq->set_spot (i);
2241                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2242                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2243
2244                 $$= velt;
2245         }
2246         | new_chord {
2247                 THIS->pop_spot ();
2248
2249                 if (!THIS->lexer_->is_chord_state ())
2250                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2251                 $$ = unsmob_music ($1);
2252         }
2253         ;
2254
2255 lyric_element:
2256         /* FIXME: lyric flavoured markup would be better */
2257         full_markup {
2258                 $$ = $1;
2259         }
2260         | LYRICS_STRING {
2261                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2262         }
2263         ;
2264
2265 new_chord:
2266         steno_tonic_pitch optional_notemode_duration   {
2267                 $$ = make_chord ($1, $2, SCM_EOL);
2268         }
2269         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2270                 SCM its = scm_reverse_x ($4, SCM_EOL);
2271                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2272         }
2273         ;
2274
2275 chord_items:
2276         /**/ {
2277                 $$ = SCM_EOL;
2278         }
2279         | chord_items chord_item {
2280                 $$ = scm_cons ($2, $$);
2281         }
2282         ;
2283
2284 chord_separator:
2285         CHORD_COLON {
2286                 $$ = ly_symbol2scm ("chord-colon");
2287         }
2288         | CHORD_CARET {
2289                 $$ = ly_symbol2scm ("chord-caret");
2290         }
2291         | CHORD_SLASH steno_tonic_pitch {
2292                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2293         }
2294         | CHORD_BASS steno_tonic_pitch {
2295                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2296         }
2297         ;
2298
2299 chord_item:
2300         chord_separator {
2301                 $$ = $1;
2302         }
2303         | step_numbers {
2304                 $$ = scm_reverse_x ($1, SCM_EOL);
2305         }
2306         | CHORD_MODIFIER  {
2307                 $$ = $1;
2308         }
2309         ;
2310
2311 step_numbers:
2312         step_number { $$ = scm_cons ($1, SCM_EOL); }
2313         | step_numbers '.' step_number {
2314                 $$ = scm_cons ($3, $$);
2315         }
2316         ;
2317
2318 step_number:
2319         bare_unsigned {
2320                 $$ = make_chord_step ($1, 0);
2321         }
2322         | bare_unsigned '+' {
2323                 $$ = make_chord_step ($1, SHARP);
2324         }
2325         | bare_unsigned CHORD_MINUS {
2326                 $$ = make_chord_step ($1, FLAT);
2327         }
2328         ;
2329
2330 /*
2331         UTILITIES
2332
2333 TODO: should deprecate in favor of Scheme?
2334
2335  */
2336 number_expression:
2337         number_expression '+' number_term {
2338                 $$ = scm_sum ($1, $3);
2339         }
2340         | number_expression '-' number_term {
2341                 $$ = scm_difference ($1, $3);
2342         }
2343         | number_term
2344         ;
2345
2346 number_term:
2347         number_factor {
2348                 $$ = $1;
2349         }
2350         | number_factor '*' number_factor {
2351                 $$ = scm_product ($1, $3);
2352         }
2353         | number_factor '/' number_factor {
2354                 $$ = scm_divide ($1, $3);
2355         }
2356         ;
2357
2358 number_factor:
2359         '-'  number_factor { /* %prec UNARY_MINUS */
2360                 $$ = scm_difference ($2, SCM_UNDEFINED);
2361         }
2362         | bare_number
2363         ;
2364
2365
2366 bare_number:
2367         UNSIGNED        {
2368                 $$ = scm_int2num ($1);
2369         }
2370         | REAL          {
2371                 $$ = $1;
2372         }
2373         | NUMBER_IDENTIFIER             {
2374                 $$ = $1;
2375         }
2376         | REAL NUMBER_IDENTIFIER        {
2377                 $$ = scm_make_real (scm_to_double ($1) *scm_to_double ($2));
2378         }
2379         | UNSIGNED NUMBER_IDENTIFIER    {
2380                 $$ = scm_make_real ($1 *scm_to_double ($2));
2381         }
2382         ;
2383
2384
2385 bare_unsigned:
2386         UNSIGNED {
2387                         $$ = $1;
2388         }
2389         | DIGIT {
2390                 $$ = $1;
2391         }
2392         ;
2393
2394 bare_int:
2395         bare_number {
2396                 if (scm_integer_p ($1) == SCM_BOOL_T)
2397                 {
2398                         int k = scm_to_int ($1);
2399                         $$ = k;
2400                 } else
2401                 {
2402                         THIS->parser_error (_ ("need integer number arg"));
2403                         $$ = 0;
2404                 }
2405         }
2406         | '-' bare_int {
2407                 $$ = -$2;
2408         }
2409         ;
2410
2411 exclamations:
2412                 { $$ = 0; }
2413         | exclamations '!'      { $$ ++; }
2414         ;
2415
2416 questions:
2417                 { $$ = 0; }
2418         | questions '?' { $$ ++; }
2419         ;
2420
2421
2422
2423 full_markup:
2424         MARKUP_IDENTIFIER {
2425                 $$ = $1;
2426         }
2427         | MARKUP
2428                 { THIS->lexer_->push_markup_state (); }
2429         markup
2430                 { $$ = $3;
2431                   THIS->lexer_->pop_state ();
2432                 }
2433         ;
2434
2435
2436 /*
2437 This should be done more dynamically if possible.
2438 */
2439 markup:
2440         STRING {
2441                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2442         }
2443         | MARKUP_HEAD_EMPTY {
2444                 $$ = scm_list_1 ($1);
2445         }
2446         | MARKUP_HEAD_MARKUP0 markup {
2447                 $$ = scm_list_2 ($1, $2);
2448         }
2449         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2450                 $$ = scm_list_3 ($1, $2, $3);
2451         }
2452         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2453                 $$ = scm_list_3 ($1, $2, $3);
2454         }
2455         | markup_line {
2456                 $$ = $1;
2457         }
2458         | MARKUP_HEAD_LIST0 markup_list {
2459                 $$ = scm_list_2 ($1,$2);
2460         }
2461         | MARKUP_HEAD_SCM0 embedded_scm {
2462                 $$ = scm_list_2 ($1, $2);
2463         }
2464         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2465                 $$ = scm_list_4 ($1, $2, $3, $4);
2466         }
2467         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2468                 $$ = scm_list_4 ($1, $2, $3, $4);
2469         }
2470         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2471                 $$ = scm_list_3 ($1, $2, $3);
2472         }
2473         | MARKUP_IDENTIFIER {
2474                 $$ = $1;
2475         }
2476         | STRING_IDENTIFIER {
2477                 $$ = $1;
2478         }
2479         | SCORE {
2480                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2481                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2482         } '{' score_body '}' {
2483                 Score * sc = $4;
2484                 $$ = scm_list_2 (ly_scheme_function ("score-markup"), sc->self_scm ());
2485                 scm_gc_unprotect_object (sc->self_scm ());
2486                 THIS->lexer_->pop_state ();
2487         }
2488         ;
2489
2490 markup_list:
2491         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2492         ;
2493
2494 markup_line:
2495         '{' markup_list_body '}' {
2496                 SCM line = ly_scheme_function ("line-markup");
2497
2498                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2499         }
2500         ;
2501
2502 markup_list_body:
2503         /**/ {  $$ = SCM_EOL; }
2504         | markup_list_body markup {
2505                 $$ = scm_cons ($2, $1);
2506         }
2507         ;
2508
2509
2510 %%
2511
2512 void
2513 Lily_parser::set_yydebug (bool )
2514 {
2515 #if 0
2516         yydebug = 1;
2517 #endif
2518 }
2519
2520 void
2521 Lily_parser::do_yyparse ()
2522 {
2523         yyparse ((void*)this);
2524 }
2525
2526
2527 /*
2528 Should make this optional?    It will also complain when you do
2529
2530         [s4]
2531
2532 which is entirely legitimate.
2533
2534 Or we can scrap it. Barchecks should detect wrong durations, and
2535 skipTypesetting speeds it up a lot.
2536 */
2537
2538 void
2539 Lily_parser::beam_check (SCM dur)
2540 {
2541   Duration *d = unsmob_duration (dur);
2542   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2543     {
2544       Music *m = unsmob_music (last_beam_start_);
2545       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2546     }
2547   last_beam_start_ = SCM_EOL;
2548 }
2549
2550
2551
2552
2553 /*
2554
2555 It is a little strange to have this function in this file, but
2556 otherwise, we have to import music classes into the lexer.
2557
2558 */
2559 int
2560 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2561 {
2562         if (scm_is_string (sid)) {
2563                 *destination = sid;
2564                 return STRING_IDENTIFIER;
2565         } else if (ly_c_number_p (sid)) {
2566                 *destination = sid;
2567                 return NUMBER_IDENTIFIER;
2568         } else if (unsmob_context_def (sid)) {
2569                 *destination = unsmob_context_def (sid)->clone_scm ();
2570                 return CONTEXT_DEF_IDENTIFIER;
2571         } else if (unsmob_score (sid)) {
2572                 Score *score = new Score (*unsmob_score (sid));
2573                 *destination = score->self_scm ();
2574                 return SCORE_IDENTIFIER;
2575         } else if (Music *mus = unsmob_music (sid)) {
2576                 mus = mus->clone ();
2577                 *destination = mus->self_scm ();
2578                 unsmob_music (*destination)->
2579                         set_property ("origin", make_input (last_input_));
2580                 return dynamic_cast<Event*> (mus)
2581                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2582         } else if (unsmob_duration (sid)) {
2583                 *destination = unsmob_duration (sid)->smobbed_copy ();
2584                 return DURATION_IDENTIFIER;
2585         } else if (unsmob_output_def (sid)) {
2586                 Output_def *p = unsmob_output_def (sid);
2587                 p = p->clone ();
2588
2589                 *destination = p->self_scm ();
2590                 return OUTPUT_DEF_IDENTIFIER;
2591         } else if (Text_item::markup_p (sid)) {
2592                 *destination = sid;
2593                 return MARKUP_IDENTIFIER;
2594         }
2595
2596         return -1;
2597 }
2598
2599 Music *
2600 property_op_to_music (SCM op)
2601 {
2602         Music *m = 0;
2603         SCM tag = ly_car (op);
2604         SCM symbol = ly_cadr (op);
2605         SCM args = ly_cddr (op);
2606         SCM grob_val = SCM_UNDEFINED;
2607         SCM grob_sym = SCM_UNDEFINED;
2608         SCM val = SCM_UNDEFINED;
2609
2610         if (tag == ly_symbol2scm ("assign"))
2611                 {
2612                 m = MY_MAKE_MUSIC ("PropertySet");
2613                 val = ly_car (args);
2614                 }
2615         else if (tag == ly_symbol2scm ("unset"))
2616                 m = MY_MAKE_MUSIC ("PropertyUnset");
2617         else if (tag == ly_symbol2scm ("poppush")
2618                  || tag == ly_symbol2scm ("push"))
2619                 {
2620                 m = MY_MAKE_MUSIC ("OverrideProperty");
2621                 grob_sym = ly_car (args);
2622                 grob_val = ly_cadr (args);
2623                 }
2624         else if (tag == ly_symbol2scm ("pop")) {
2625                 m = MY_MAKE_MUSIC ("RevertProperty");
2626                 grob_sym = ly_car (args);
2627                 }
2628
2629         m->set_property ("symbol", symbol);
2630
2631         if (val != SCM_UNDEFINED)
2632                 m->set_property ("value", val);
2633         if (grob_val != SCM_UNDEFINED)
2634                 m->set_property ("grob-value", grob_val);
2635
2636         if (grob_sym != SCM_UNDEFINED)
2637                 {
2638                 bool itc = internal_type_checking_global_b;
2639                 /* UGH.
2640                 */
2641                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2642                 if (autobeam)
2643                         internal_type_checking_global_b = false;
2644                 m->set_property ("grob-property", grob_sym);
2645                 if (autobeam)
2646                         internal_type_checking_global_b = itc;
2647                 }
2648
2649         if (tag == ly_symbol2scm ("poppush"))
2650                 m->set_property ("pop-first", SCM_BOOL_T);
2651
2652
2653         return m;
2654 }
2655
2656 Music*
2657 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2658 {
2659         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2660
2661         csm->set_property ("element", m->self_scm ());
2662         scm_gc_unprotect_object (m->self_scm ());
2663
2664         csm->set_property ("context-type",
2665                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2666         csm->set_property ("property-operations", ops);
2667
2668         if (scm_is_string (id))
2669                 csm->set_property ("context-id", id);
2670         return csm;
2671 }
2672
2673 SCM
2674 get_next_unique_context ()
2675 {
2676         static int new_context_count;
2677         char s[1024];
2678         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2679         return scm_makfrom0str (s);
2680 }
2681