lily/parser.yy

   1 /*
   2   parser.yy -- Bison/C++ parser for LilyPond
   3
   4   source file of the GNU LilyPond music typesetter
   5
   6   (c) 1997--2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7                  Jan Nieuwenhuizen <janneke@gnu.org>
   8 */
   9
  10 %{
  11
  12 #define YYERROR_VERBOSE 1
  13 #define YYPARSE_PARAM my_lily_parser
  14 #define YYLEX_PARAM my_lily_parser
  15 #define PARSER ((Lily_parser *) my_lily_parser)
  16
  17 #define yyerror PARSER->parser_error
  18
  19 /* We use custom location type: Input objects */
  20 #define YYLTYPE Input
  21 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  22         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  23
  24
  25 %}
  26
  27 /* We use SCMs to do strings, because it saves us the trouble of
  28 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  29 of the parse stack onto the heap. */
  30
  31 %left PREC_TOP
  32 %left ADDLYRICS
  33 %left PREC_BOT
  34
  35 %expect 1
  36
  37 /* One shift/reduce problem
  38
  39 1.  \repeat
  40         \repeat .. \alternative
  41
  42     \repeat { \repeat .. \alternative }
  43
  44 or
  45
  46     \repeat { \repeat } \alternative
  47 */
  48
  49
  50 %pure_parser
  51 %locations
  52
  53
  54
  55 %{ // -*-Fundamental-*-
  56
  57 /*
  58 FIXME:
  59
  60    * The rules for who is protecting what are very shady.  Uniformise
  61      this.
  62
  63    * There are too many lexical modes?
  64 */
  65
  66 #include "config.hh"
  67
  68 #include <cctype>
  69 #include <cstdlib>
  70 #include <cstdio>
  71 using namespace std;
  72
  73 #include "book.hh"
  74 #include "context-def.hh"
  75 #include "dimensions.hh"
  76 #include "file-path.hh"
  77 #include "input-smob.hh"
  78 #include "input.hh"
  79 #include "international.hh"
  80 #include "lily-guile.hh"
  81 #include "lily-lexer.hh"
  82 #include "lily-parser.hh"
  83 #include "lilypond-input-version.hh"
  84 #include "main.hh"
  85 #include "misc.hh"
  86 #include "music.hh"
  87 #include "music.hh"
  88 #include "output-def.hh"
  89 #include "paper-book.hh"
  90 #include "program-option.hh"
  91 #include "scm-hash.hh"
  92 #include "score.hh"
  93 #include "text-interface.hh"
  94 #include "warn.hh"
  95
  96 %}
  97
  98
  99 %union {
 100         Book *book;
 101         Output_def *outputdef;
 102         SCM scm;
 103         std::string *string;
 104         Music *music;
 105         Score *score;
 106         int i;
 107 }
 108
 109 %{
 110
 111 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
 112
 113 /* ES TODO:
 114 - Don't use lily module, create a new module instead.
 115 - delay application of the function
 116 */
 117 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 118   scm_apply_0 (proc, args)
 119 /* Syntactic Sugar. */
 120 #define MAKE_SYNTAX(name, location, ...)        \
 121   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (PARSER->self_scm (), make_input (location), __VA_ARGS__, SCM_UNDEFINED));
 122
 123 SCM get_next_unique_context_id ();
 124 SCM get_next_unique_lyrics_context_id ();
 125
 126 #undef _
 127 #if !HAVE_GETTEXT
 128 #define _(x) x
 129 #else
 130 #include <libintl.h>
 131 #define _(x) gettext (x)
 132 #endif
 133
 134
 135
 136 SCM make_music_relative (Pitch start, SCM music);
 137 SCM run_music_function (Lily_parser *, SCM expr);
 138 SCM get_first_context_id (SCM type, Music *m);
 139 SCM make_chord_elements (SCM pitch, SCM dur, SCM modification_list);
 140 SCM make_chord_step (int step, int alter);
 141 SCM make_simple_markup (SCM a);
 142 bool is_duration (int t);
 143 bool is_regular_identifier (SCM id);
 144 bool ly_input_procedure_p (SCM x);
 145 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 146 void set_music_properties (Music *p, SCM a);
 147
 148 %}
 149
 150 /* The third option is an alias that will be used to display the
 151    syntax error.  Bison CVS now correctly handles backslash escapes.
 152
 153    FIXME: Bison needs to translate some of these, eg, STRING.
 154
 155 */
 156
 157 /* Keyword tokens with plain escaped name.  */
 158 %token ACCEPTS "\\accepts"
 159 %token ADDLYRICS "\\addlyrics"
 160 %token ADDQUOTE "\\addquote"
 161 %token ALIAS "\\alias"
 162 %token ALTERNATIVE "\\alternative"
 163 %token BOOK "\\book"
 164 %token CHANGE "\\change"
 165 %token CHORDMODE "\\chordmode"
 166 %token CHORDS "\\chords"
 167 %token CONSISTS "\\consists"
 168 %token CONTEXT "\\context"
 169 %token DEFAULT "\\default"
 170 %token DEFAULTCHILD "\\defaultchild"
 171 %token DENIES "\\denies"
 172 %token DESCRIPTION "\\description"
 173 %token DRUMMODE "\\drummode"
 174 %token DRUMS "\\drums"
 175 %token FIGUREMODE "\\figuremode"
 176 %token FIGURES "\\figures"
 177 %token GROBDESCRIPTIONS "\\grobdescriptions"
 178 %token HEADER "\\header"
 179 %token INVALID "\\invalid"
 180 %token KEY "\\key"
 181 %token LAYOUT "\\layout"
 182 %token LYRICMODE "\\lyricmode"
 183 %token LYRICS "\\lyrics"
 184 %token LYRICSTO "\\lyricsto"
 185 %token MARK "\\mark"
 186 %token MARKUP "\\markup"
 187 %token MIDI "\\midi"
 188 %token NAME "\\name"
 189 %token NOTEMODE "\\notemode"
 190 %token OBJECTID "\\objectid"
 191 %token OCTAVE "\\octave"
 192 %token ONCE "\\once"
 193 %token OVERRIDE "\\override"
 194 %token PAPER "\\paper"
 195 %token PARTIAL "\\partial"
 196 %token RELATIVE "\\relative"
 197 %token REMOVE "\\remove"
 198 %token REPEAT "\\repeat"
 199 %token REST "\\rest"
 200 %token REVERT "\\revert"
 201 %token SCORE "\\score"
 202 %token SEQUENTIAL "\\sequential"
 203 %token SET "\\set"
 204 %token SIMULTANEOUS "\\simultaneous"
 205 %token SKIP "\\skip"
 206 %token TEMPO "\\tempo"
 207 %token TIMES "\\times"
 208 %token TRANSPOSE "\\transpose"
 209 %token TYPE "\\type"
 210 %token UNSET "\\unset"
 211 %token WITH "\\with"
 212
 213 /* Keyword token exceptions.  */
 214 %token TIME_T "\\time"
 215 %token NEWCONTEXT "\\new"
 216
 217
 218 /* Other string tokens.  */
 219
 220 %token CHORD_BASS "/+"
 221 %token CHORD_CARET "^"
 222 %token CHORD_COLON ":"
 223 %token CHORD_MINUS "-"
 224 %token CHORD_SLASH "/"
 225 %token ANGLE_OPEN "<"
 226 %token ANGLE_CLOSE ">"
 227 %token DOUBLE_ANGLE_OPEN "<<"
 228 %token DOUBLE_ANGLE_CLOSE ">>"
 229 %token E_BACKSLASH "\\"
 230 %token E_ANGLE_CLOSE "\\>"
 231 %token E_CHAR "\\C[haracter]"
 232 %token E_CLOSE "\\)"
 233 %token E_EXCLAMATION "\\!"
 234 %token E_BRACKET_OPEN "\\["
 235 %token E_OPEN "\\("
 236 %token E_BRACKET_CLOSE "\\]"
 237 %token E_ANGLE_OPEN "\\<"
 238 %token E_PLUS "\\+"
 239 %token E_TILDE "\\~"
 240 %token EXTENDER "__"
 241
 242 /*
 243 If we give names, Bison complains.
 244 */
 245 %token FIGURE_CLOSE /* "\\>" */
 246 %token FIGURE_OPEN /* "\\<" */
 247 %token FIGURE_SPACE "_"
 248 %token HYPHEN "--"
 249
 250 %token CHORDMODIFIERS
 251 %token LYRIC_MARKUP
 252 %token MULTI_MEASURE_REST
 253 %token SCM_T
 254
 255
 256 %token <i> DIGIT
 257 %token <i> E_UNSIGNED
 258 %token <i> UNSIGNED
 259
 260 %token <scm> BOOK_IDENTIFIER
 261 %token <scm> CHORDMODIFIER_PITCH
 262 %token <scm> CHORD_MODIFIER
 263 %token <scm> CONTEXT_DEF_IDENTIFIER
 264 %token <scm> DRUM_PITCH
 265 %token <scm> DURATION_IDENTIFIER
 266 %token <scm> EVENT_IDENTIFIER
 267 %token <scm> FRACTION
 268 %token <scm> LYRICS_STRING
 269 %token <scm> LYRIC_MARKUP_IDENTIFIER
 270 %token <scm> MARKUP_HEAD_EMPTY
 271 %token <scm> MARKUP_HEAD_LIST0
 272 %token <scm> MARKUP_HEAD_MARKUP0
 273 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 274 %token <scm> MARKUP_HEAD_SCM0
 275 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 276 %token <scm> MARKUP_HEAD_SCM0_SCM1
 277 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 278 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 279 %token <scm> MARKUP_IDENTIFIER
 280 %token <scm> MUSIC_FUNCTION
 281 %token <scm> MUSIC_FUNCTION_MARKUP
 282 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 283 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 284 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 285 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 286 %token <scm> MUSIC_FUNCTION_MUSIC
 287 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 288 %token <scm> MUSIC_FUNCTION_SCM
 289 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 290 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 291 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC_MUSIC
 292 %token <scm> MUSIC_FUNCTION_SCM_SCM
 293 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 294 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM
 295 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM_MUSIC
 296 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM_SCM_MUSIC
 297 %token <scm> MUSIC_IDENTIFIER
 298 %token <scm> NOTENAME_PITCH
 299 %token <scm> NUMBER_IDENTIFIER
 300 %token <scm> OUTPUT_DEF_IDENTIFIER
 301 %token <scm> REAL
 302 %token <scm> RESTNAME
 303 %token <scm> SCM_IDENTIFIER
 304 %token <scm> SCM_T
 305 %token <scm> SCORE_IDENTIFIER
 306 %token <scm> STRING
 307 %token <scm> STRING_IDENTIFIER
 308 %token <scm> TONICNAME_PITCH
 309
 310
 311 %type <book> book_block
 312 %type <book> book_body
 313
 314 %type <i> bare_unsigned
 315 %type <i> figured_bass_alteration
 316 %type <i> dots
 317 %type <i> exclamations
 318 %type <i> optional_rest
 319 %type <i> questions
 320 %type <i> script_dir
 321 %type <i> sub_quotes
 322 %type <i> sup_quotes
 323 %type <i> tremolo_type
 324
 325 /* Music */
 326 %type <scm> composite_music
 327 %type <scm> grouped_music_list
 328 %type <scm> music
 329 %type <scm> prefix_composite_music
 330 %type <scm> repeated_music
 331 %type <scm> sequential_music
 332 %type <scm> simple_music
 333 %type <scm> simultaneous_music
 334 %type <scm> chord_body
 335 %type <scm> chord_body_element
 336 %type <scm> command_element
 337 %type <scm> command_event
 338 %type <scm> context_change
 339 %type <scm> direction_less_event
 340 %type <scm> direction_reqd_event
 341 %type <scm> event_chord
 342 %type <scm> gen_text_def
 343 %type <scm> music_property_def
 344 %type <scm> note_chord_element
 345 %type <scm> post_event
 346 %type <scm> re_rhythmed_music
 347 %type <scm> relative_music
 348 %type <scm> simple_element
 349 %type <scm> simple_music_property_def
 350 %type <scm> string_number_event
 351 %type <scm> tempo_event
 352
 353 %type <outputdef> output_def_body
 354 %type <outputdef> output_def_head
 355 %type <outputdef> output_def_head_with_mode_switch
 356 %type <outputdef> output_def
 357 %type <outputdef> paper_block
 358
 359 %type <scm> alternative_music
 360 %type <scm> generic_prefix_music_scm
 361 %type <scm> music_list
 362 %type <scm> absolute_pitch
 363 %type <scm> assignment_id
 364 %type <scm> bare_number
 365 %type <scm> music_function_event
 366 %type <scm> music_function_chord_body
 367 %type <scm> music_function_musicless_prefix
 368 %type <scm> music_function_musicless_function
 369 %type <scm> bass_figure
 370 %type <scm> figured_bass_modification
 371 %type <scm> br_bass_figure
 372 %type <scm> bass_number
 373 %type <scm> chord_body_elements
 374 %type <scm> chord_item
 375 %type <scm> chord_items
 376 %type <scm> chord_separator
 377 %type <scm> context_def_mod
 378 %type <scm> context_def_spec_block
 379 %type <scm> context_def_spec_body
 380 %type <scm> context_mod
 381 %type <scm> context_mod_list
 382 %type <scm> context_prop_spec
 383 %type <scm> direction_less_char
 384 %type <scm> duration_length
 385 %type <scm> embedded_scm
 386 %type <scm> figure_list
 387 %type <scm> figure_spec
 388 %type <scm> fraction
 389 %type <scm> full_markup
 390 %type <scm> identifier_init
 391 %type <scm> lilypond_header
 392 %type <scm> lilypond_header_body
 393 %type <scm> lyric_element
 394 %type <scm> lyric_markup
 395 %type <scm> markup
 396 %type <scm> markup_braced_list
 397 %type <scm> markup_braced_list_body
 398 %type <scm> markup_composed_list
 399 %type <scm> markup_head_1_item
 400 %type <scm> markup_head_1_list
 401 %type <scm> markup_list
 402 %type <scm> markup_top
 403 %type <scm> mode_changing_head
 404 %type <scm> mode_changing_head_with_context
 405 %type <scm> multiplied_duration
 406 %type <scm> new_chord
 407 %type <scm> new_lyrics
 408 %type <scm> number_expression
 409 %type <scm> number_factor
 410 %type <scm> number_term
 411 %type <scm> object_id_setting
 412 %type <scm> octave_check
 413 %type <scm> optional_context_mod
 414 %type <scm> optional_id
 415 %type <scm> optional_notemode_duration
 416 %type <scm> pitch
 417 %type <scm> pitch_also_in_chords
 418 %type <scm> post_events
 419 %type <scm> property_operation
 420 %type <scm> scalar
 421 %type <scm> script_abbreviation
 422 %type <scm> simple_chord_elements
 423 %type <scm> simple_markup
 424 %type <scm> simple_string
 425 %type <scm> steno_duration
 426 %type <scm> steno_pitch
 427 %type <scm> steno_tonic_pitch
 428 %type <scm> step_number
 429 %type <scm> step_numbers
 430 %type <scm> string
 431 %type <scm> function_scm_argument
 432
 433 %type <score> score_block
 434 %type <score> score_body
 435
 436
 437 %left '-' '+'
 438
 439 /* We don't assign precedence to / and *, because we might need varied
 440 prec levels in different prods */
 441
 442 %left UNARY_MINUS
 443
 444 %%
 445
 446 lilypond:       /* empty */
 447         | lilypond toplevel_expression {
 448         }
 449         | lilypond assignment {
 450         }
 451         | lilypond error {
 452                 PARSER->error_level_ = 1;
 453         }
 454         | lilypond INVALID      {
 455                 PARSER->error_level_ = 1;
 456         }
 457         ;
 458
 459
 460 object_id_setting:
 461         OBJECTID STRING { $$ = $2; }
 462         ;
 463
 464 toplevel_expression:
 465         lilypond_header {
 466                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 467         }
 468         | book_block {
 469                 Book *book = $1;
 470                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 471                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 472                 book->unprotect ();
 473         }
 474         | score_block {
 475                 Score *score = $1;
 476
 477                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 478                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 479                 score->unprotect ();
 480         }
 481         | composite_music {
 482                 Music *music = unsmob_music ($1);
 483                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 484                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 485         }
 486         | full_markup {
 487                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 488                 scm_call_2 (proc, PARSER->self_scm (), $1);
 489         }
 490         | output_def {
 491                 SCM id = SCM_EOL;
 492                 Output_def * od = $1;
 493
 494                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 495                         id = ly_symbol2scm ("$defaultpaper");
 496                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 497                         id = ly_symbol2scm ("$defaultmidi");
 498                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 499                         id = ly_symbol2scm ("$defaultlayout");
 500
 501                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 502                 od->unprotect();
 503         }
 504         ;
 505
 506 embedded_scm:
 507         SCM_T
 508         | SCM_IDENTIFIER
 509         ;
 510
 511
 512 lilypond_header_body:
 513         {
 514                 $$ = get_header(PARSER);
 515                 PARSER->lexer_->add_scope ($$);
 516         }
 517         | lilypond_header_body assignment  {
 518
 519         }
 520         ;
 521
 522 lilypond_header:
 523         HEADER '{' lilypond_header_body '}'     {
 524                 $$ = PARSER->lexer_->remove_scope ();
 525         }
 526         ;
 527
 528 /*
 529         DECLARATIONS
 530 */
 531 assignment_id:
 532         STRING          { $$ = $1; }
 533         | LYRICS_STRING { $$ = $1; }
 534         ;
 535
 536 assignment:
 537         assignment_id '=' identifier_init  {
 538                 if (! is_regular_identifier ($1))
 539                 {
 540 #if 0
 541                         /* no longer valid with dashes in \paper{} block. */
 542                         @1.warning (_ ("identifier should have alphabetic characters only"));
 543 #endif
 544                 }
 545
 546
 547                 PARSER->lexer_->set_identifier ($1, $3);
 548
 549 /*
 550  TODO: devise standard for protection in parser.
 551
 552   The parser stack lives on the C-stack, which means that
 553 all objects can be unprotected as soon as they're here.
 554
 555 */
 556         }
 557         | embedded_scm { }
 558         ;
 559
 560
 561 identifier_init:
 562         score_block {
 563                 $$ = $1->self_scm ();
 564                 $1->unprotect ();
 565         }
 566         | book_block {
 567                 $$ = $1->self_scm ();
 568                 $1->unprotect ();
 569         }
 570         | output_def {
 571                 $$ = $1->self_scm ();
 572                 $1->unprotect ();
 573         }
 574         | context_def_spec_block {
 575                 $$ = $1;
 576         }
 577         | music  {
 578                 /* Hack: Create event-chord around standalone events.
 579                    Prevents the identifier from being interpreted as a post-event. */
 580                 Music *mus = unsmob_music ($1);
 581                 bool is_event = mus &&
 582                         (scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
 583                                 != SCM_BOOL_F);
 584                 if (!is_event)
 585                         $$ = $1;
 586                 else
 587                         $$ = MAKE_SYNTAX ("event-chord", @$, scm_list_1 ($1));
 588         }
 589         | post_event {
 590                 $$ = $1;
 591         }
 592         | number_expression {
 593                 $$ = $1;
 594         }
 595         | string {
 596                 $$ = $1;
 597         }
 598         | embedded_scm {
 599                 $$ = $1;
 600         }
 601         | full_markup {
 602                 $$ = $1;
 603         }
 604         | DIGIT {
 605                 $$ = scm_from_int ($1);
 606         }
 607         ;
 608
 609 context_def_spec_block:
 610         CONTEXT '{' context_def_spec_body '}'
 611                 {
 612                 $$ = $3;
 613         }
 614         ;
 615
 616 context_def_spec_body:
 617         /**/ {
 618                 $$ = Context_def::make_scm ();
 619                 unsmob_context_def ($$)->set_spot (@$);
 620         }
 621         | CONTEXT_DEF_IDENTIFIER {
 622                 $$ = $1;
 623                 unsmob_context_def ($$)->set_spot (@$);
 624         }
 625         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 626                 Context_def*td = unsmob_context_def ($$);
 627
 628                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 629                         SCM tag = scm_caar (p);
 630
 631                         /* TODO: should make new tag "grob-definition" ? */
 632                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 633                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 634                 }
 635         }
 636         | context_def_spec_body context_mod {
 637                 unsmob_context_def ($$)->add_context_mod ($2);
 638         }
 639         ;
 640
 641
 642
 643 book_block:
 644         BOOK '{' book_body '}'  {
 645                 $$ = $3;
 646         }
 647         ;
 648
 649 /* FIXME:
 650    * Use 'handlers' like for toplevel-* stuff?
 651    * grok \layout and \midi?  */
 652 book_body:
 653         {
 654                 $$ = new Book;
 655                 $$->set_spot (@$);
 656                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 657                 $$->paper_->unprotect ();
 658                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 659         }
 660         | BOOK_IDENTIFIER {
 661                 $$ = unsmob_book ($1);
 662                 $$->set_spot (@$);
 663         }
 664         | book_body paper_block {
 665                 $$->paper_ = $2;
 666                 $2->unprotect ();
 667         }
 668         | book_body score_block {
 669                 SCM s = $2->self_scm ();
 670                 $$->add_score (s);
 671                 $2->unprotect();
 672         }
 673         | book_body full_markup {
 674                 $$->add_score ($2);
 675         }
 676         | book_body lilypond_header {
 677                 $$->header_ = $2;
 678         }
 679         | book_body error {
 680                 $$->paper_ = 0;
 681                 $$->scores_ = SCM_EOL;
 682         }
 683         | book_body object_id_setting {
 684                 $$->user_key_ = ly_scm2string ($2);
 685         }
 686         ;
 687
 688 score_block:
 689         SCORE '{' score_body '}'        {
 690                 $$ = $3;
 691         }
 692         ;
 693
 694 score_body:
 695         music {
 696                 SCM m = $1;
 697                 SCM scorify = ly_lily_module_constant ("scorify-music");
 698                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 699
 700                 // pass ownernship to C++ again.
 701                 $$ = unsmob_score (score);
 702                 $$->protect ();
 703                 $$->set_spot (@$);
 704         }
 705         | SCORE_IDENTIFIER {
 706                 $$ = unsmob_score ($1);
 707                 $$->set_spot (@$);
 708         }
 709         | score_body object_id_setting {
 710                 $$->user_key_ = ly_scm2string ($2);
 711         }
 712         | score_body lilypond_header    {
 713                 $$->header_ = $2;
 714         }
 715         | score_body output_def {
 716                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 717                 {
 718                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 719
 720                 }
 721                 else
 722                 {
 723                         $$->add_output_def ($2);
 724                 }
 725                 $2->unprotect ();
 726         }
 727         | score_body error {
 728                 $$->error_found_ = true;
 729         }
 730         ;
 731
 732
 733 /*
 734         OUTPUT DEF
 735 */
 736
 737 paper_block:
 738         output_def {
 739                 $$ = $1;
 740                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 741                 {
 742                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
 743                         $$ = get_paper (PARSER);
 744                 }
 745         }
 746         ;
 747
 748
 749 output_def:
 750         output_def_body '}' {
 751                 $$ = $1;
 752
 753                 PARSER->lexer_->remove_scope ();
 754                 PARSER->lexer_->pop_state ();
 755         }
 756         ;
 757
 758 output_def_head:
 759         PAPER {
 760                 $$ = get_paper (PARSER);
 761                 $$->input_origin_ = @$;
 762                 PARSER->lexer_->add_scope ($$->scope_);
 763         }
 764         | MIDI    {
 765                 Output_def *p = get_midi (PARSER);
 766                 $$ = p;
 767                 PARSER->lexer_->add_scope (p->scope_);
 768         }
 769         | LAYOUT        {
 770                 Output_def *p = get_layout (PARSER);
 771
 772                 PARSER->lexer_->add_scope (p->scope_);
 773                 $$ = p;
 774         }
 775         ;
 776
 777 output_def_head_with_mode_switch:
 778         output_def_head {
 779                 PARSER->lexer_->push_initial_state ();
 780                 $$ = $1;
 781         }
 782         ;
 783
 784 output_def_body:
 785         output_def_head_with_mode_switch '{' {
 786                 $$ = $1;
 787                 $$->input_origin_.set_spot (@$);
 788         }
 789         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 790                 $1->unprotect ();
 791                 Output_def *o = unsmob_output_def ($3);
 792                 o->input_origin_.set_spot (@$);
 793                 $$ = o;
 794                 PARSER->lexer_->remove_scope ();
 795                 PARSER->lexer_->add_scope (o->scope_);
 796         }
 797         | output_def_body assignment  {
 798
 799         }
 800         | output_def_body context_def_spec_block        {
 801                 assign_context_def ($$, $2);
 802         }
 803         | output_def_body tempo_event  {
 804                 /*
 805                         junk this ? there already is tempo stuff in
 806                         music.
 807                 */
 808                 int m = scm_to_int (unsmob_music($2)->get_property ("metronome-count"));
 809                 Duration *d = unsmob_duration (unsmob_music($2)->get_property ("tempo-unit"));
 810                 set_tempo ($$, d->get_length (), m);
 811         }
 812         | output_def_body error {
 813
 814         }
 815         ;
 816
 817 tempo_event:
 818         TEMPO steno_duration '=' bare_unsigned  {
 819                 Music *m = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 820                 m->set_property ("tempo-unit", $2);
 821                 m->set_property ("metronome-count", scm_from_int ( $4));
 822                 $$ = m->unprotect ();
 823         }
 824         ;
 825
 826 /*
 827 The representation of a  list is the
 828
 829   (LIST . LAST-CONS)
 830
 831  to have efficient append.  */
 832
 833 music_list:
 834         /* empty */ {
 835                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 836         }
 837         | music_list music {
 838                 SCM s = $$;
 839                 SCM c = scm_cons ($2, SCM_EOL);
 840
 841                 if (scm_is_pair (scm_cdr (s)))
 842                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 843                 else
 844                         scm_set_car_x (s, c); /* set first cons */
 845                 scm_set_cdr_x (s, c);  /* remember last cell */
 846         }
 847         | music_list embedded_scm {
 848
 849         }
 850         | music_list error {
 851                 Music *m = MY_MAKE_MUSIC("Music");
 852                 // ugh. code dup
 853                 m->set_property ("error-found", SCM_BOOL_T);
 854                 SCM s = $$;
 855                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 856                 m->unprotect (); /* UGH */
 857
 858                 if (scm_is_pair (scm_cdr (s)))
 859                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 860                 else
 861                         scm_set_car_x (s, c); /* set first cons */
 862                 scm_set_cdr_x (s, c);  /* remember last cell */
 863         }
 864         ;
 865
 866 music:
 867         simple_music
 868         | composite_music
 869         ;
 870
 871 alternative_music:
 872         /* empty */ {
 873                 $$ = SCM_EOL;
 874         }
 875         | ALTERNATIVE '{' music_list '}' {
 876                 $$ = scm_car ($3);
 877         }
 878         ;
 879
 880
 881 repeated_music:
 882         REPEAT simple_string bare_unsigned music alternative_music
 883         {
 884                 $$ = MAKE_SYNTAX ("repeat", @$, $2, scm_int2num ($3), $4, $5);
 885         }
 886         ;
 887
 888 sequential_music:
 889         SEQUENTIAL '{' music_list '}'           {
 890                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($3));
 891         }
 892         | '{' music_list '}'            {
 893                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($2));
 894         }
 895         ;
 896
 897 simultaneous_music:
 898         SIMULTANEOUS '{' music_list '}'{
 899                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($3));
 900         }
 901         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
 902                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($2));
 903         }
 904         ;
 905
 906 simple_music:
 907         event_chord
 908         | MUSIC_IDENTIFIER
 909         | music_property_def
 910         | context_change
 911         ;
 912
 913 optional_context_mod:
 914         /**/ { $$ = SCM_EOL; }
 915         | WITH { PARSER->lexer_->push_initial_state (); }
 916         '{' context_mod_list '}'
 917         {
 918                 PARSER->lexer_->pop_state ();
 919                 $$ = $4;
 920         }
 921         ;
 922
 923 context_mod_list:
 924         /* */  { $$ = SCM_EOL; }
 925         | context_mod_list context_mod  {
 926                  $$ = scm_cons ($2, $1);
 927         }
 928         ;
 929
 930 composite_music:
 931         prefix_composite_music { $$ = $1; }
 932         | grouped_music_list { $$ = $1; }
 933         ;
 934
 935 grouped_music_list:
 936         simultaneous_music              { $$ = $1; }
 937         | sequential_music              { $$ = $1; }
 938         ;
 939
 940 function_scm_argument:
 941         embedded_scm
 942         | simple_string
 943         ;
 944
 945 /*
 946 TODO: use code generation for this
 947 */
 948 music_function_musicless_function:
 949         MUSIC_FUNCTION {
 950                 $$ = scm_list_2 ($1, make_input (@$));
 951         }
 952         | MUSIC_FUNCTION_SCM function_scm_argument {
 953                 $$ = scm_list_3 ($1, make_input (@$), $2);
 954         }
 955         | MUSIC_FUNCTION_MARKUP full_markup {
 956                 $$ = scm_list_3 ($1, make_input (@$), $2);
 957         }
 958         | MUSIC_FUNCTION_SCM_SCM function_scm_argument function_scm_argument {
 959                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
 960         }
 961         | MUSIC_FUNCTION_SCM_SCM_SCM function_scm_argument function_scm_argument function_scm_argument {
 962                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
 963         }
 964         | MUSIC_FUNCTION_MARKUP_MARKUP full_markup full_markup {
 965                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
 966         }
 967         ;
 968
 969 /*
 970 TODO: use code generation for this
 971 */
 972 music_function_musicless_prefix:
 973         MUSIC_FUNCTION_MUSIC {
 974                 $$ = scm_list_2 ($1, make_input (@$));
 975         }
 976         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument {
 977                 $$ = scm_list_3 ($1, make_input (@$), $2);
 978         }
 979         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument {
 980                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
 981         }
 982         | MUSIC_FUNCTION_SCM_SCM_SCM_MUSIC function_scm_argument function_scm_argument function_scm_argument {
 983                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
 984         }
 985         | MUSIC_FUNCTION_SCM_SCM_SCM_SCM_MUSIC function_scm_argument function_scm_argument function_scm_argument function_scm_argument {
 986                 $$ = scm_list_n ($1, make_input (@$), $2, $3, $4, $5, SCM_UNDEFINED);
 987         }
 988         | MUSIC_FUNCTION_MARKUP_MUSIC full_markup {
 989                 $$ = scm_list_3 ($1, make_input (@$), $2);
 990         }
 991         ;
 992
 993 generic_prefix_music_scm:
 994         music_function_musicless_function {
 995                 $$ = $1;
 996         }
 997         | music_function_musicless_prefix music {
 998                 $$ = ly_append2 ($1, scm_list_1 ($2));
 999         }
1000         | MUSIC_FUNCTION_MUSIC_MUSIC music music {
1001                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1002         }
1003         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC function_scm_argument music music {
1004                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
1005         }
1006         | MUSIC_FUNCTION_SCM_SCM_MUSIC_MUSIC function_scm_argument function_scm_argument music music {
1007                 $$ = scm_list_n ($1, make_input (@$), $2, $3, $4, $5, SCM_UNDEFINED);
1008         }
1009         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC full_markup music music {
1010                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
1011         }
1012         ;
1013
1014
1015 optional_id:
1016         /**/ { $$ = SCM_EOL; }
1017         | '=' simple_string {
1018                 $$ = $2;
1019         }
1020         ;
1021
1022
1023 prefix_composite_music:
1024         generic_prefix_music_scm {
1025                 $$ = run_music_function (PARSER, $1);
1026         }
1027         | CONTEXT    simple_string optional_id optional_context_mod music {
1028                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, $4, SCM_BOOL_F);
1029         }
1030         | NEWCONTEXT simple_string optional_id optional_context_mod music {
1031                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, $4, SCM_BOOL_T);
1032         }
1033
1034         | TIMES fraction music {
1035                 $$ = MAKE_SYNTAX ("time-scaled-music", @$, $2, $3);
1036         }
1037         | repeated_music                { $$ = $1; }
1038         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords music {
1039                 Pitch from = *unsmob_pitch ($2);
1040                 Pitch to = *unsmob_pitch ($3);
1041                 SCM pitch = pitch_interval (from, to).smobbed_copy ();
1042                 $$ = MAKE_SYNTAX ("transpose-music", @$, pitch, $4);
1043         }
1044         | mode_changing_head grouped_music_list {
1045                 if ($1 == ly_symbol2scm ("chords"))
1046                 {
1047                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1048                 }
1049                 else
1050                 {
1051                   $$ = $2;
1052                 }
1053                 PARSER->lexer_->pop_state ();
1054         }
1055         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1056                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, $3, $2, SCM_BOOL_T);
1057                 if ($1 == ly_symbol2scm ("ChordNames"))
1058                 {
1059                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1060                 }
1061                 PARSER->lexer_->pop_state ();
1062         }
1063         | relative_music        { $$ = $1; }
1064         | re_rhythmed_music     { $$ = $1; }
1065         ;
1066
1067 mode_changing_head:
1068         NOTEMODE {
1069                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1070                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1071
1072                 $$ = ly_symbol2scm ("notes");
1073         }
1074         | DRUMMODE
1075                 {
1076                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1077                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1078
1079                 $$ = ly_symbol2scm ("drums");
1080         }
1081         | FIGUREMODE {
1082                 PARSER->lexer_->push_figuredbass_state ();
1083
1084                 $$ = ly_symbol2scm ("figures");
1085         }
1086         | CHORDMODE {
1087                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1088                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1089                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1090                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1091                 $$ = ly_symbol2scm ("chords");
1092
1093         }
1094         | LYRICMODE
1095                 { PARSER->lexer_->push_lyric_state ();
1096                 $$ = ly_symbol2scm ("lyrics");
1097         }
1098         ;
1099
1100 mode_changing_head_with_context:
1101         DRUMS {
1102                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1103                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1104
1105                 $$ = ly_symbol2scm ("DrumStaff");
1106         }
1107         | FIGURES {
1108                 PARSER->lexer_->push_figuredbass_state ();
1109
1110                 $$ = ly_symbol2scm ("FiguredBass");
1111         }
1112         | CHORDS {
1113                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1114                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1115                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1116                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1117                 $$ = ly_symbol2scm ("ChordNames");
1118         }
1119         | LYRICS
1120                 { PARSER->lexer_->push_lyric_state ();
1121                 $$ = ly_symbol2scm ("Lyrics");
1122         }
1123         ;
1124
1125
1126 relative_music:
1127         RELATIVE absolute_pitch music {
1128                 Pitch start = *unsmob_pitch ($2);
1129                 $$ = make_music_relative (start, $3);
1130         }
1131         | RELATIVE composite_music {
1132                 Pitch middle_c (0, 0, 0);
1133                 $$ = make_music_relative (middle_c, $2);
1134         }
1135         ;
1136
1137 new_lyrics:
1138         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1139         /*cont */
1140         grouped_music_list {
1141         /* Can also use music at the expensive of two S/Rs similar to
1142            \repeat \alternative */
1143                 PARSER->lexer_->pop_state ();
1144
1145                 $$ = scm_cons ($3, SCM_EOL);
1146         }
1147         | new_lyrics ADDLYRICS {
1148                 PARSER->lexer_->push_lyric_state ();
1149         } grouped_music_list {
1150                 PARSER->lexer_->pop_state ();
1151                 $$ = scm_cons ($4, $1);
1152         }
1153         ;
1154
1155 re_rhythmed_music:
1156         grouped_music_list new_lyrics {
1157                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1158         }
1159         | LYRICSTO simple_string {
1160                 PARSER->lexer_->push_lyric_state ();
1161         } music {
1162                 PARSER->lexer_->pop_state ();
1163                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1164         }
1165         ;
1166
1167 context_change:
1168         CHANGE STRING '=' STRING  {
1169                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1170         }
1171         ;
1172
1173 property_operation:
1174         STRING '=' scalar {
1175                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1176                         scm_string_to_symbol ($1), $3);
1177         }
1178         | UNSET simple_string {
1179                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1180                         scm_string_to_symbol ($2));
1181         }
1182         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1183                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1184                         scm_string_to_symbol ($2), $5, $3);
1185         }
1186         | OVERRIDE simple_string embedded_scm embedded_scm '=' embedded_scm {
1187                 $$ = scm_list_5 (ly_symbol2scm ("push"),
1188                                 scm_string_to_symbol ($2), $6, $4, $3);
1189         }
1190         | REVERT simple_string embedded_scm {
1191                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1192                         scm_string_to_symbol ($2), $3);
1193         }
1194         ;
1195
1196 context_def_mod:
1197         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1198         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1199
1200         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1201         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1202         | DENIES { $$ = ly_symbol2scm ("denies"); }
1203
1204         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1205         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1206         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1207         | NAME { $$ = ly_symbol2scm ("context-name"); }
1208         ;
1209
1210 context_mod:
1211         property_operation { $$ = $1; }
1212         | context_def_mod STRING {
1213                 $$ = scm_list_2 ($1, $2);
1214         }
1215         ;
1216
1217 context_prop_spec:
1218         simple_string {
1219                 if (!is_regular_identifier ($1))
1220                 {
1221                         @$.error (_("Grob name should be alphanumeric"));
1222                 }
1223
1224                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1225                         scm_string_to_symbol ($1));
1226         }
1227         | simple_string '.' simple_string {
1228                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1229                         scm_string_to_symbol ($3));
1230         }
1231         ;
1232
1233 simple_music_property_def:
1234         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1235                 $$ = scm_list_5 (scm_car ($2),
1236                         ly_symbol2scm ("OverrideProperty"),
1237                         scm_cadr ($2),
1238                         $5, $3);
1239         }
1240         | OVERRIDE context_prop_spec embedded_scm  embedded_scm '=' scalar {
1241                 $$ = scm_list_n (scm_car ($2),
1242                         ly_symbol2scm ("OverrideProperty"),
1243                         scm_cadr ($2),
1244                         $6, $4, $3, SCM_UNDEFINED);
1245         }
1246         | REVERT context_prop_spec embedded_scm {
1247                 $$ = scm_list_4 (scm_car ($2),
1248                         ly_symbol2scm ("RevertProperty"),
1249                         scm_cadr ($2),
1250                         $3);
1251         }
1252         | SET context_prop_spec '=' scalar {
1253                 $$ = scm_list_4 (scm_car ($2),
1254                         ly_symbol2scm ("PropertySet"),
1255                         scm_cadr ($2),
1256                         $4);
1257         }
1258         | UNSET context_prop_spec {
1259                 $$ = scm_list_3 (scm_car ($2),
1260                         ly_symbol2scm ("PropertyUnset"),
1261                         scm_cadr ($2));
1262         }
1263         ;
1264
1265 music_property_def:
1266         simple_music_property_def {
1267                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_F, $1)));
1268         }
1269         | ONCE simple_music_property_def {
1270                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_T, $2)));
1271         }
1272         ;
1273
1274 string:
1275         STRING {
1276                 $$ = $1;
1277         }
1278         | STRING_IDENTIFIER {
1279                 $$ = $1;
1280         }
1281         | string '+' string {
1282                 $$ = scm_string_append (scm_list_2 ($1, $3));
1283         }
1284         ;
1285
1286 simple_string: STRING {
1287                 $$ = $1;
1288         }
1289         | LYRICS_STRING {
1290                 $$ = $1;
1291         }
1292         | STRING_IDENTIFIER {
1293                 $$ = $1;
1294         }
1295         ;
1296
1297 scalar: string {
1298                 $$ = $1;
1299         }
1300         | LYRICS_STRING {
1301                 $$ = $1;
1302         }
1303         | bare_number {
1304                 $$ = $1;
1305         }
1306         | embedded_scm {
1307                 $$ = $1;
1308         }
1309         | full_markup {
1310                 $$ = $1;
1311         }
1312         | DIGIT {
1313                 $$ = scm_from_int ($1);
1314         }
1315         ;
1316
1317 event_chord:
1318         /* TODO: Create a special case that avoids the creation of
1319            EventChords around simple_elements that have no post_events?
1320          */
1321         simple_chord_elements post_events       {
1322                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1323
1324                 Input i;
1325                 /* why is this giving wrong start location? -ns
1326                  * i = @$; */
1327                 i.set_location (@1, @2);
1328                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1329         }
1330         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1331                 Input i;
1332                 i.set_location (@1, @3);
1333                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2, $3);
1334         }
1335         | command_element
1336         | note_chord_element
1337         ;
1338
1339
1340 note_chord_element:
1341         chord_body optional_notemode_duration post_events
1342         {
1343                 Music *m = unsmob_music ($1);
1344                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1345                 SCM es = m->get_property ("elements");
1346                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1347
1348                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1349                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1350                 es = ly_append2 (es, postevs);
1351
1352                 m-> set_property ("elements", es);
1353                 m->set_spot (@$);
1354                 $$ = m->self_scm ();
1355         }
1356         ;
1357
1358 chord_body:
1359         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1360         {
1361                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1362         }
1363         ;
1364
1365 chord_body_elements:
1366         /* empty */             { $$ = SCM_EOL; }
1367         | chord_body_elements chord_body_element {
1368                 $$ = scm_cons ($2, $1);
1369         }
1370         ;
1371
1372 chord_body_element:
1373         pitch exclamations questions octave_check post_events
1374         {
1375                 int q = $3;
1376                 int ex = $2;
1377                 SCM check = $4;
1378                 SCM post = $5;
1379
1380                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1381                 n->set_property ("pitch", $1);
1382                 n->set_spot (@$);
1383                 if (q % 2)
1384                         n->set_property ("cautionary", SCM_BOOL_T);
1385                 if (ex % 2 || q % 2)
1386                         n->set_property ("force-accidental", SCM_BOOL_T);
1387
1388                 if (scm_is_pair (post)) {
1389                         SCM arts = scm_reverse_x (post, SCM_EOL);
1390                         n->set_property ("articulations", arts);
1391                 }
1392                 if (scm_is_number (check))
1393                 {
1394                         int q = scm_to_int (check);
1395                         n->set_property ("absolute-octave", scm_from_int (q-1));
1396                 }
1397
1398                 $$ = n->unprotect ();
1399         }
1400         | DRUM_PITCH post_events {
1401                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1402                 n->set_property ("duration", $2);
1403                 n->set_property ("drum-type", $1);
1404                 n->set_spot (@$);
1405
1406                 if (scm_is_pair ($2)) {
1407                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1408                         n->set_property ("articulations", arts);
1409                 }
1410                 $$ = n->unprotect ();
1411         }
1412         | music_function_chord_body {
1413                 $$ = run_music_function (PARSER, $1);
1414         }
1415         ;
1416
1417 music_function_chord_body:
1418         music_function_musicless_function {
1419                 $$ = $1;
1420         }
1421         | music_function_musicless_prefix chord_body_element {
1422                 $$ = ly_append2 ($1, scm_list_1 ($2));
1423         }
1424         ;
1425
1426 music_function_event:
1427         music_function_musicless_prefix post_event {
1428                 $$ = ly_append2 ($1, scm_list_1 ($2));
1429         }
1430         | music_function_musicless_function {
1431                 $$ = $1;
1432         }
1433         ;
1434
1435
1436 command_element:
1437         command_event {
1438                 $$ = $1;
1439         }
1440         | SKIP duration_length {
1441                 $$ = MAKE_SYNTAX ("skip-music", @$, $2);
1442         }
1443         | E_BRACKET_OPEN {
1444                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1445                 m->set_property ("span-direction", scm_from_int (START));
1446                 m->set_spot (@$);
1447                 $$ = m->unprotect();
1448         }
1449         | E_BRACKET_CLOSE {
1450                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1451                 m->set_property ("span-direction", scm_from_int (STOP));
1452                 m->set_spot (@$);
1453                 $$ = m->unprotect ();
1454         }
1455         | E_BACKSLASH {
1456                 $$ = MAKE_SYNTAX ("voice-separator", @$, SCM_UNDEFINED);
1457         }
1458         | '|'      {
1459                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
1460
1461                 Music *m = unsmob_music (pipe);
1462                 if (m)
1463                 {
1464                         m = m->clone ();
1465                         m->set_spot (@$);
1466                         $$ = m->unprotect ();
1467                 }
1468                 else
1469                         $$ = MAKE_SYNTAX ("bar-check", @$, SCM_UNDEFINED);
1470
1471         }
1472         | PARTIAL duration_length       {
1473                 Moment m = - unsmob_duration ($2)->get_length ();
1474                 $$ = MAKE_SYNTAX ("property-operation", @$, SCM_BOOL_F, ly_symbol2scm ("Timing"), ly_symbol2scm ("PropertySet"), ly_symbol2scm ("measurePosition"), m.smobbed_copy ());
1475                 $$ = MAKE_SYNTAX ("context-specification", @$, ly_symbol2scm ("Score"), SCM_BOOL_F, $$, SCM_EOL, SCM_BOOL_F);
1476         }
1477
1478         | TIME_T fraction  {
1479                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1480
1481                 $$ = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1482         }
1483         | MARK scalar {
1484                 SCM proc = ly_lily_module_constant ("make-mark-set");
1485
1486                 $$ = scm_call_1 (proc, $2);
1487         }
1488         ;
1489
1490 command_event:
1491         E_TILDE {
1492                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent")->unprotect ();
1493         }
1494         | MARK DEFAULT  {
1495                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1496                 $$ = m->unprotect ();
1497         }
1498         | tempo_event {
1499                 $$ = $1;
1500         }
1501         | KEY DEFAULT {
1502                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1503                 $$ = key->unprotect ();
1504         }
1505         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1506
1507                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1508                 if (scm_ilength ($3) > 0)
1509                 {
1510                         key->set_property ("pitch-alist", $3);
1511                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1512                         key->transpose (* unsmob_pitch ($2));
1513                 } else {
1514                         PARSER->parser_error (@3, _ ("second argument must be pitch list"));
1515                 }
1516
1517                 $$ = key->unprotect ();
1518         }
1519         ;
1520
1521
1522 post_events:
1523         /* empty */ {
1524                 $$ = SCM_EOL;
1525         }
1526         | post_events post_event {
1527                 unsmob_music ($2)->set_spot (@2);
1528                 $$ = scm_cons ($2, $$);
1529         }
1530         ;
1531
1532 post_event:
1533         direction_less_event {
1534                 $$ = $1;
1535         }
1536         | '-' music_function_event {
1537                 $$ = run_music_function (PARSER, $2);
1538         }
1539         | HYPHEN {
1540                 if (!PARSER->lexer_->is_lyric_state ())
1541                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1542                 $$ = MY_MAKE_MUSIC ("HyphenEvent")->unprotect ();
1543         }
1544         | EXTENDER {
1545                 if (!PARSER->lexer_->is_lyric_state ())
1546                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1547                 $$ = MY_MAKE_MUSIC ("ExtenderEvent")->unprotect ();
1548         }
1549         | script_dir direction_reqd_event {
1550                 if ($1)
1551                 {
1552                         Music *m = unsmob_music ($2);
1553                         m->set_property ("direction", scm_from_int ($1));
1554                 }
1555                 $$ = $2;
1556         }
1557         | script_dir direction_less_event {
1558                 if ($1)
1559                 {
1560                         Music *m = unsmob_music ($2);
1561                         m->set_property ("direction", scm_from_int ($1));
1562                 }
1563                 $$ = $2;
1564         }
1565         | string_number_event
1566         ;
1567
1568 string_number_event:
1569         E_UNSIGNED {
1570                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1571                 s->set_property ("string-number", scm_from_int ($1));
1572                 s->set_spot (@$);
1573                 $$ = s->unprotect ();
1574         }
1575         ;
1576
1577 direction_less_char:
1578         '['  {
1579                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1580         }
1581         | ']'  {
1582                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1583         }
1584         | '~'  {
1585                 $$ = ly_symbol2scm ("tildeSymbol");
1586         }
1587         | '('  {
1588                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1589         }
1590         | ')'  {
1591                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1592         }
1593         | E_EXCLAMATION  {
1594                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1595         }
1596         | E_OPEN  {
1597                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1598         }
1599         | E_CLOSE  {
1600                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1601         }
1602         | E_ANGLE_CLOSE  {
1603                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1604         }
1605         | E_ANGLE_OPEN  {
1606                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1607         }
1608         ;
1609
1610 direction_less_event:
1611         direction_less_char {
1612                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
1613                 Music *m = 0;
1614                 if (unsmob_music (predefd))
1615                 {
1616                         m = unsmob_music (predefd)->clone ();
1617                 }
1618                 else
1619                 {
1620                         m = MY_MAKE_MUSIC ("Music");
1621                 }
1622                 m->set_spot (@$);
1623                 $$ = m->unprotect ();
1624         }
1625         | EVENT_IDENTIFIER      {
1626                 $$ = $1;
1627         }
1628         | tremolo_type  {
1629                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1630                a->set_spot (@$);
1631                a->set_property ("tremolo-type", scm_from_int ($1));
1632                $$ = a->unprotect ();
1633         }
1634         ;
1635
1636 direction_reqd_event:
1637         gen_text_def {
1638                 $$ = $1;
1639         }
1640         | script_abbreviation {
1641                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1642                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1643                 if (scm_is_string (s))
1644                         a->set_property ("articulation-type", s);
1645                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
1646                 $$ = a->unprotect ();
1647         }
1648         ;
1649
1650 octave_check:
1651         /**/ { $$ = SCM_EOL; }
1652         | '='  { $$ = scm_from_int (0); }
1653         | '=' sub_quotes { $$ = scm_from_int ($2); }
1654         | '=' sup_quotes { $$ = scm_from_int ($2); }
1655         ;
1656
1657 sup_quotes:
1658         '\'' {
1659                 $$ = 1;
1660         }
1661         | sup_quotes '\'' {
1662                 $$ ++;
1663         }
1664         ;
1665
1666 sub_quotes:
1667         ',' {
1668                 $$ = 1;
1669         }
1670         | sub_quotes ',' {
1671                 $$++;
1672         }
1673         ;
1674
1675 steno_pitch:
1676         NOTENAME_PITCH  {
1677                 $$ = $1;
1678         }
1679         | NOTENAME_PITCH sup_quotes     {
1680                 Pitch p = *unsmob_pitch ($1);
1681                 p = p.transposed (Pitch ($2,0,0));
1682                 $$ = p.smobbed_copy ();
1683         }
1684         | NOTENAME_PITCH sub_quotes      {
1685                 Pitch p =* unsmob_pitch ($1);
1686                 p = p.transposed (Pitch (-$2,0,0));
1687                 $$ = p.smobbed_copy ();
1688         }
1689         ;
1690
1691 /*
1692 ugh. duplication
1693 */
1694
1695 steno_tonic_pitch:
1696         TONICNAME_PITCH {
1697                 $$ = $1;
1698         }
1699         | TONICNAME_PITCH sup_quotes    {
1700                 Pitch p = *unsmob_pitch ($1);
1701                 p = p.transposed (Pitch ($2,0,0));
1702                 $$ = p.smobbed_copy ();
1703         }
1704         | TONICNAME_PITCH sub_quotes     {
1705                 Pitch p =* unsmob_pitch ($1);
1706
1707                 p = p.transposed (Pitch (-$2,0,0));
1708                 $$ = p.smobbed_copy ();
1709         }
1710         ;
1711
1712 pitch:
1713         steno_pitch {
1714                 $$ = $1;
1715         }
1716         ;
1717
1718 pitch_also_in_chords:
1719         pitch
1720         | steno_tonic_pitch
1721         ;
1722
1723 gen_text_def:
1724         full_markup {
1725                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1726                 t->set_property ("text", $1);
1727                 t->set_spot (@$);
1728                 $$ = t->unprotect ();
1729         }
1730         | string {
1731                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1732                 t->set_property ("text",
1733                         make_simple_markup ($1));
1734                 t->set_spot (@$);
1735                 $$ = t->unprotect ();
1736         }
1737         | DIGIT {
1738                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1739                 t->set_property ("digit", scm_from_int ($1));
1740                 t->set_spot (@$);
1741                 $$ = t->unprotect ();
1742         }
1743         ;
1744
1745 script_abbreviation:
1746         '^'             {
1747                 $$ = scm_makfrom0str ("Hat");
1748         }
1749         | '+'           {
1750                 $$ = scm_makfrom0str ("Plus");
1751         }
1752         | '-'           {
1753                 $$ = scm_makfrom0str ("Dash");
1754         }
1755         | '|'           {
1756                 $$ = scm_makfrom0str ("Bar");
1757         }
1758         | ANGLE_CLOSE   {
1759                 $$ = scm_makfrom0str ("Larger");
1760         }
1761         | '.'           {
1762                 $$ = scm_makfrom0str ("Dot");
1763         }
1764         | '_' {
1765                 $$ = scm_makfrom0str ("Underscore");
1766         }
1767         ;
1768
1769 script_dir:
1770         '_'     { $$ = DOWN; }
1771         | '^'   { $$ = UP; }
1772         | '-'   { $$ = CENTER; }
1773         ;
1774
1775
1776 absolute_pitch:
1777         steno_pitch     {
1778                 $$ = $1;
1779         }
1780         ;
1781
1782 duration_length:
1783         multiplied_duration {
1784                 $$ = $1;
1785         }
1786         ;
1787
1788 optional_notemode_duration:
1789         {
1790                 Duration dd = PARSER->default_duration_;
1791                 $$ = dd.smobbed_copy ();
1792         }
1793         | multiplied_duration   {
1794                 $$ = $1;
1795                 PARSER->default_duration_ = *unsmob_duration ($$);
1796         }
1797         ;
1798
1799 steno_duration:
1800         bare_unsigned dots              {
1801                 int len = 0;
1802                 if (!is_duration ($1))
1803                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
1804                 else
1805                         len = intlog2 ($1);
1806
1807                 $$ = Duration (len, $2).smobbed_copy ();
1808         }
1809         | DURATION_IDENTIFIER dots      {
1810                 Duration *d = unsmob_duration ($1);
1811                 Duration k (d->duration_log (), d->dot_count () + $2);
1812                 *d = k;
1813                 $$ = $1;
1814         }
1815         ;
1816
1817 multiplied_duration:
1818         steno_duration {
1819                 $$ = $1;
1820         }
1821         | multiplied_duration '*' bare_unsigned {
1822                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1823         }
1824         | multiplied_duration '*' FRACTION {
1825                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
1826
1827                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1828         }
1829         ;
1830
1831 fraction:
1832         FRACTION { $$ = $1; }
1833         | UNSIGNED '/' UNSIGNED {
1834                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
1835         }
1836         ;
1837
1838 dots:
1839         /* empty */     {
1840                 $$ = 0;
1841         }
1842         | dots '.' {
1843                 $$ ++;
1844         }
1845         ;
1846
1847 tremolo_type:
1848         ':'     {
1849                 $$ = 0;
1850         }
1851         | ':' bare_unsigned {
1852                 if (!is_duration ($2))
1853                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
1854                 $$ = $2;
1855         }
1856         ;
1857
1858 bass_number:
1859         DIGIT   {
1860                 $$ = scm_from_int ($1);
1861         }
1862         | UNSIGNED {
1863                 $$ = scm_from_int ($1);
1864         }
1865         | STRING { $$ = $1; }
1866         | full_markup { $$ = $1; }
1867         ;
1868
1869 figured_bass_alteration:
1870         '-'     { $$ = -2; }
1871         | '+'   { $$ = 2; }
1872         | '!'   { $$ = 0; }
1873         ;
1874
1875 bass_figure:
1876         FIGURE_SPACE {
1877                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1878                 $$ = bfr->self_scm ();
1879                 bfr->unprotect ();
1880                 bfr->set_spot (@1);
1881         }
1882         | bass_number  {
1883                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1884                 $$ = bfr->self_scm ();
1885
1886                 if (scm_is_number ($1))
1887                         bfr->set_property ("figure", $1);
1888                 else if (Text_interface::is_markup ($1))
1889                         bfr->set_property ("text", $1);
1890
1891                 bfr->unprotect ();
1892                 bfr->set_spot (@1);
1893         }
1894         | bass_figure ']' {
1895                 $$ = $1;
1896                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1897         }
1898         | bass_figure figured_bass_alteration {
1899                 Music *m = unsmob_music ($1);
1900                 if ($2) {
1901                         SCM salter = m->get_property ("alteration");
1902                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
1903                         m->set_property ("alteration",
1904                                 scm_from_int (alter + $2));
1905                 } else {
1906                         m->set_property ("alteration", scm_from_int (0));
1907                 }
1908         }
1909         | bass_figure figured_bass_modification  {
1910                 Music *m = unsmob_music ($1);
1911                 if ($2 == ly_symbol2scm ("plus"))
1912                         {
1913                         m->set_property ("augmented", SCM_BOOL_T);
1914                         }
1915                 else if ($2 == ly_symbol2scm ("slash"))
1916                         {
1917                         m->set_property ("diminished", SCM_BOOL_T);
1918                         }
1919                 else if ($2 == ly_symbol2scm ("exclamation"))
1920                         {
1921                         m->set_property ("no-continuation", SCM_BOOL_T);
1922                         }
1923         }
1924         ;
1925
1926
1927 figured_bass_modification:
1928         E_PLUS          {
1929                 $$ = ly_symbol2scm ("plus");
1930         }
1931         | E_EXCLAMATION {
1932                 $$ = ly_symbol2scm ("exclamation");
1933         }
1934         | '/'           {
1935                 $$ = ly_symbol2scm ("slash");
1936         }
1937         ;
1938
1939 br_bass_figure:
1940         bass_figure {
1941                 $$ = $1;
1942         }
1943         | '[' bass_figure {
1944                 $$ = $2;
1945                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1946         }
1947         ;
1948
1949 figure_list:
1950         /**/            {
1951                 $$ = SCM_EOL;
1952         }
1953         | figure_list br_bass_figure {
1954                 $$ = scm_cons ($2, $1);
1955         }
1956         ;
1957
1958 figure_spec:
1959         FIGURE_OPEN figure_list FIGURE_CLOSE {
1960                 $$ = scm_reverse_x ($2, SCM_EOL);
1961         }
1962         ;
1963
1964
1965 optional_rest:
1966         /**/   { $$ = 0; }
1967         | REST { $$ = 1; }
1968         ;
1969
1970 simple_element:
1971         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
1972                 if (!PARSER->lexer_->is_note_state ())
1973                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
1974
1975                 Music *n = 0;
1976                 if ($6)
1977                         n = MY_MAKE_MUSIC ("RestEvent");
1978                 else
1979                         n = MY_MAKE_MUSIC ("NoteEvent");
1980
1981                 n->set_property ("pitch", $1);
1982                 n->set_property ("duration", $5);
1983
1984                 if (scm_is_number ($4))
1985                 {
1986                         int q = scm_to_int ($4);
1987                         n->set_property ("absolute-octave", scm_from_int (q-1));
1988                 }
1989
1990                 if ($3 % 2)
1991                         n->set_property ("cautionary", SCM_BOOL_T);
1992                 if ($2 % 2 || $3 % 2)
1993                         n->set_property ("force-accidental", SCM_BOOL_T);
1994
1995                 n->set_spot (@$);
1996                 $$ = n->unprotect ();
1997         }
1998         | DRUM_PITCH optional_notemode_duration {
1999                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2000                 n->set_property ("duration", $2);
2001                 n->set_property ("drum-type", $1);
2002
2003                 $$ = n->unprotect ();
2004         }
2005         | RESTNAME optional_notemode_duration           {
2006                 Music *ev = 0;
2007                 if (ly_scm2string ($1) == "s") {
2008                         /* Space */
2009                         ev = MY_MAKE_MUSIC ("SkipEvent");
2010                   }
2011                 else {
2012                         ev = MY_MAKE_MUSIC ("RestEvent");
2013
2014                     }
2015                 ev->set_property ("duration", $2);
2016                 ev->set_spot (@$);
2017                 $$ = ev->unprotect ();
2018         }
2019         | lyric_element optional_notemode_duration      {
2020                 if (!PARSER->lexer_->is_lyric_state ())
2021                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2022
2023                 Music *levent = MY_MAKE_MUSIC ("LyricEvent");
2024                 levent->set_property ("text", $1);
2025                 levent->set_property ("duration",$2);
2026                 levent->set_spot (@$);
2027                 $$= levent->unprotect ();
2028         }
2029         ;
2030
2031 simple_chord_elements:
2032         simple_element  {
2033                 $$ = scm_list_1 ($1);
2034         }
2035         | new_chord {
2036                 if (!PARSER->lexer_->is_chord_state ())
2037                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
2038                 $$ = $1;
2039         }
2040         | figure_spec optional_notemode_duration {
2041                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2042                 {
2043                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2044                 }
2045                 $$ = $1;
2046         }
2047         ;
2048
2049 lyric_element:
2050         lyric_markup {
2051                 $$ = $1;
2052         }
2053         | LYRICS_STRING {
2054                 $$ = $1;
2055         }
2056         ;
2057
2058 new_chord:
2059         steno_tonic_pitch optional_notemode_duration   {
2060                 $$ = make_chord_elements ($1, $2, SCM_EOL);
2061         }
2062         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2063                 SCM its = scm_reverse_x ($4, SCM_EOL);
2064                 $$ = make_chord_elements ($1, $2, scm_cons ($3, its));
2065         }
2066         ;
2067
2068 chord_items:
2069         /**/ {
2070                 $$ = SCM_EOL;
2071         }
2072         | chord_items chord_item {
2073                 $$ = scm_cons ($2, $$);
2074         }
2075         ;
2076
2077 chord_separator:
2078         CHORD_COLON {
2079                 $$ = ly_symbol2scm ("chord-colon");
2080         }
2081         | CHORD_CARET {
2082                 $$ = ly_symbol2scm ("chord-caret");
2083         }
2084         | CHORD_SLASH steno_tonic_pitch {
2085                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2086         }
2087         | CHORD_BASS steno_tonic_pitch {
2088                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2089         }
2090         ;
2091
2092 chord_item:
2093         chord_separator {
2094                 $$ = $1;
2095         }
2096         | step_numbers {
2097                 $$ = scm_reverse_x ($1, SCM_EOL);
2098         }
2099         | CHORD_MODIFIER  {
2100                 $$ = $1;
2101         }
2102         ;
2103
2104 step_numbers:
2105         step_number { $$ = scm_cons ($1, SCM_EOL); }
2106         | step_numbers '.' step_number {
2107                 $$ = scm_cons ($3, $$);
2108         }
2109         ;
2110
2111 step_number:
2112         bare_unsigned {
2113                 $$ = make_chord_step ($1, 0);
2114         }
2115         | bare_unsigned '+' {
2116                 $$ = make_chord_step ($1, SHARP);
2117         }
2118         | bare_unsigned CHORD_MINUS {
2119                 $$ = make_chord_step ($1, FLAT);
2120         }
2121         ;
2122
2123 /*
2124         UTILITIES
2125
2126 TODO: should deprecate in favor of Scheme?
2127
2128  */
2129 number_expression:
2130         number_expression '+' number_term {
2131                 $$ = scm_sum ($1, $3);
2132         }
2133         | number_expression '-' number_term {
2134                 $$ = scm_difference ($1, $3);
2135         }
2136         | number_term
2137         ;
2138
2139 number_term:
2140         number_factor {
2141                 $$ = $1;
2142         }
2143         | number_factor '*' number_factor {
2144                 $$ = scm_product ($1, $3);
2145         }
2146         | number_factor '/' number_factor {
2147                 $$ = scm_divide ($1, $3);
2148         }
2149         ;
2150
2151 number_factor:
2152         '-'  number_factor { /* %prec UNARY_MINUS */
2153                 $$ = scm_difference ($2, SCM_UNDEFINED);
2154         }
2155         | bare_number
2156         ;
2157
2158
2159 bare_number:
2160         UNSIGNED        {
2161                 $$ = scm_from_int ($1);
2162         }
2163         | REAL          {
2164                 $$ = $1;
2165         }
2166         | NUMBER_IDENTIFIER             {
2167                 $$ = $1;
2168         }
2169         | REAL NUMBER_IDENTIFIER        {
2170                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2171         }
2172         | UNSIGNED NUMBER_IDENTIFIER    {
2173                 $$ = scm_from_double ($1 *scm_to_double ($2));
2174         }
2175         ;
2176
2177
2178 bare_unsigned:
2179         UNSIGNED {
2180                         $$ = $1;
2181         }
2182         | DIGIT {
2183                 $$ = $1;
2184         }
2185         ;
2186
2187 exclamations:
2188                 { $$ = 0; }
2189         | exclamations '!'      { $$ ++; }
2190         ;
2191
2192 questions:
2193                 { $$ = 0; }
2194         | questions '?' { $$ ++; }
2195         ;
2196
2197 /*
2198 This should be done more dynamically if possible.
2199 */
2200
2201 lyric_markup:
2202         LYRIC_MARKUP_IDENTIFIER {
2203                 $$ = $1;
2204         }
2205         | LYRIC_MARKUP
2206                 { PARSER->lexer_->push_markup_state (); }
2207         markup_top {
2208                 $$ = $3;
2209                 PARSER->lexer_->pop_state ();
2210         }
2211         ;
2212
2213 full_markup:
2214         MARKUP_IDENTIFIER {
2215                 $$ = $1;
2216         }
2217         | MARKUP
2218                 { PARSER->lexer_->push_markup_state (); }
2219         markup_top {
2220                 $$ = $3;
2221                 PARSER->lexer_->pop_state ();
2222         }
2223         ;
2224
2225 markup_top:
2226         markup_list {
2227                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2228         }
2229         | markup_head_1_list simple_markup      {
2230                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2231         }
2232         | simple_markup {
2233                 $$ = $1;
2234         }
2235         ;
2236
2237 markup_list:
2238         markup_composed_list {
2239                 $$ = $1;
2240         }
2241         | markup_braced_list {
2242                 $$ = $1;
2243         }
2244         ;
2245
2246 markup_composed_list:
2247         markup_head_1_list markup_braced_list {
2248                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2249
2250         }
2251         ;
2252
2253 markup_braced_list:
2254         '{' markup_braced_list_body '}' {
2255                 $$ = scm_reverse_x ($2, SCM_EOL);
2256         }
2257         ;
2258
2259 markup_braced_list_body:
2260         /* empty */     {  $$ = SCM_EOL; }
2261         | markup_braced_list_body markup {
2262                 $$ = scm_cons ($2, $1);
2263         }
2264         | markup_braced_list_body markup_list {
2265                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2266         }
2267         ;
2268
2269 markup_head_1_item:
2270         MARKUP_HEAD_MARKUP0     {
2271                 $$ = scm_list_1 ($1);
2272         }
2273         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2274                 $$ = scm_list_2 ($1, $2);
2275         }
2276         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2277                 $$ = scm_list_3 ($1, $2, $3);
2278         }
2279         ;
2280
2281 markup_head_1_list:
2282         markup_head_1_item      {
2283                 $$ = scm_list_1 ($1);
2284         }
2285         | markup_head_1_list markup_head_1_item {
2286                 $$ = scm_cons ($2, $1);
2287         }
2288         ;
2289
2290 simple_markup:
2291         STRING {
2292                 $$ = make_simple_markup ($1);
2293         }
2294         | MARKUP_IDENTIFIER {
2295                 $$ = $1;
2296         }
2297         | LYRIC_MARKUP_IDENTIFIER {
2298                 $$ = $1;
2299         }
2300         | STRING_IDENTIFIER {
2301                 $$ = $1;
2302         }
2303         | SCORE {
2304                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2305                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2306         } '{' score_body '}' {
2307                 Score * sc = $4;
2308                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2309                 sc->unprotect ();
2310                 PARSER->lexer_->pop_state ();
2311         }
2312         | MARKUP_HEAD_SCM0 embedded_scm {
2313                 $$ = scm_list_2 ($1, $2);
2314         }
2315         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2316                 $$ = scm_list_4 ($1, $2, $3, $4);
2317         }
2318         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2319                 $$ = scm_list_3 ($1, $2, $3);
2320         }
2321         | MARKUP_HEAD_EMPTY {
2322                 $$ = scm_list_1 ($1);
2323         }
2324         | MARKUP_HEAD_LIST0 markup_list {
2325                 $$ = scm_list_2 ($1,$2);
2326         }
2327         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2328                 $$ = scm_list_3 ($1, $2, $3);
2329         }
2330         ;
2331
2332 markup:
2333         markup_head_1_list simple_markup        {
2334                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2335                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2336         }
2337         | simple_markup {
2338                 $$ = $1;
2339         }
2340         ;
2341
2342 %%
2343
2344 void
2345 Lily_parser::set_yydebug (bool )
2346 {
2347 #if 0
2348         yydebug = 1;
2349 #endif
2350 }
2351
2352 void
2353 Lily_parser::do_yyparse ()
2354 {
2355         yyparse ((void*)this);
2356 }
2357
2358
2359
2360
2361
2362 /*
2363
2364 It is a little strange to have this function in this file, but
2365 otherwise, we have to import music classes into the lexer.
2366
2367 */
2368 int
2369 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2370 {
2371         if (scm_is_string (sid)) {
2372                 *destination = sid;
2373                 return STRING_IDENTIFIER;
2374         } else if (unsmob_book (sid)) {
2375                 *destination = unsmob_book (sid)->clone ()->self_scm ();
2376                 return BOOK_IDENTIFIER;
2377         } else if (scm_is_number (sid)) {
2378                 *destination = sid;
2379                 return NUMBER_IDENTIFIER;
2380         } else if (unsmob_context_def (sid)) {
2381                 *destination = unsmob_context_def (sid)->clone_scm ();
2382                 return CONTEXT_DEF_IDENTIFIER;
2383         } else if (unsmob_score (sid)) {
2384                 Score *score = new Score (*unsmob_score (sid));
2385                 *destination = score->self_scm ();
2386                 return SCORE_IDENTIFIER;
2387         } else if (Music *mus = unsmob_music (sid)) {
2388                 mus = mus->clone ();
2389                 *destination = mus->self_scm ();
2390                 unsmob_music (*destination)->
2391                         set_property ("origin", make_input (last_input_));
2392
2393                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2394                         != SCM_BOOL_F;
2395
2396                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2397         } else if (unsmob_duration (sid)) {
2398                 *destination = unsmob_duration (sid)->smobbed_copy ();
2399                 return DURATION_IDENTIFIER;
2400         } else if (unsmob_output_def (sid)) {
2401                 Output_def *p = unsmob_output_def (sid);
2402                 p = p->clone ();
2403
2404                 *destination = p->self_scm ();
2405                 return OUTPUT_DEF_IDENTIFIER;
2406         } else if (Text_interface::is_markup (sid)) {
2407                 *destination = sid;
2408                 if (is_lyric_state ())
2409                         return LYRIC_MARKUP_IDENTIFIER;
2410                 return MARKUP_IDENTIFIER;
2411         }
2412
2413         return -1;
2414 }
2415
2416 SCM
2417 get_next_unique_context_id ()
2418 {
2419         return scm_makfrom0str ("$uniqueContextId");
2420 }
2421
2422
2423 SCM
2424 get_next_unique_lyrics_context_id ()
2425 {
2426         static int new_context_count;
2427         char s[128];
2428         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2429         return scm_makfrom0str (s);
2430 }
2431
2432
2433 SCM
2434 run_music_function (Lily_parser *parser, SCM expr)
2435 {
2436         SCM func = scm_car (expr);
2437         Input *loc = unsmob_input (scm_cadr (expr));
2438         SCM args = scm_cddr (expr);
2439         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2440
2441         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2442
2443         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2444         {
2445                 parser->error_level_ = 1;
2446                 return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("void-music"), scm_list_2 (parser->self_scm (), make_input (*loc)));
2447         }
2448
2449         SCM syntax_args = scm_list_4 (parser->self_scm (), make_input (*loc), func, args);
2450         return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("music-function"), syntax_args);
2451 }
2452
2453 bool
2454 is_regular_identifier (SCM id)
2455 {
2456   string str = ly_scm2string (id);
2457   char const *s = str.c_str ();
2458
2459   bool v = true;
2460 #if 0
2461   isalpha (*s);
2462   s++;
2463 #endif
2464   while (*s && v)
2465    {
2466         v = v && isalnum (*s);
2467         s++;
2468    }
2469   return v;
2470 }
2471
2472
2473 SCM
2474 get_first_context_id (SCM type, Music *m)
2475 {
2476         SCM id = m->get_property ("context-id");
2477         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2478             && scm_is_string (m->get_property ("context-id"))
2479             && scm_c_string_length (id) > 0)
2480         {
2481                 return id;
2482         }
2483         return SCM_EOL;
2484 }
2485
2486 SCM
2487 make_simple_markup (SCM a)
2488 {
2489         return a;
2490 }
2491
2492 bool
2493 is_duration (int t)
2494 {
2495   return t && t == 1 << intlog2 (t);
2496 }
2497
2498 void
2499 set_music_properties (Music *p, SCM a)
2500 {
2501   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2502         p->internal_set_property (scm_caar (k), scm_cdar (k));
2503 }
2504
2505
2506 SCM
2507 make_chord_step (int step, int alter)
2508 {
2509         if (step == 7)
2510                 alter += FLAT;
2511
2512         while (step < 0)
2513                 step += 7;
2514         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2515         return m.smobbed_copy ();
2516 }
2517
2518
2519 SCM
2520 make_chord_elements (SCM pitch, SCM dur, SCM modification_list)
2521 {
2522         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
2523         return scm_call_3 (chord_ctor, pitch, dur, modification_list);
2524 }
2525
2526
2527 /* Todo: actually also use apply iso. call too ...  */
2528 bool
2529 ly_input_procedure_p (SCM x)
2530 {
2531         return ly_is_procedure (x)
2532                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2533 }
2534
2535 SCM
2536 make_music_relative (Pitch start, SCM music)
2537 {
2538         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
2539         relative->set_property ("element", music);
2540
2541         Music *m = unsmob_music (music);
2542         Pitch last = m->to_relative_octave (start);
2543         if (lily_1_8_relative)
2544                 m->set_property ("last-pitch", last.smobbed_copy ());
2545         return relative->unprotect ();
2546 }
2547
2548 int
2549 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2550 {
2551         Lily_parser *pars = (Lily_parser*) v;
2552         Lily_lexer *lex = pars->lexer_;
2553
2554         lex->lexval = (void*) s;
2555         lex->lexloc = loc;
2556         lex->prepare_for_next_token ();
2557         return lex->yylex ();
2558 }