lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "lily-lexer.hh"
  44 #include "lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((Lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (scm_is_symbol (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (scm_is_symbol (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left ADDLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         Lily_parser *pars = (Lily_parser*) v;
 209         Lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226   (what? --hwn)
 227
 228 3. \markup { }
 229
 230   (what? --hwn)
 231
 232
 233 4.  \repeat
 234         \repeat .. \alternative
 235
 236
 237     \repeat { \repeat .. \alternative }
 238
 239 or
 240
 241     \repeat { \repeat } \alternative
 242
 243 )
 244  */
 245
 246
 247 %pure_parser
 248
 249 %token ACCEPTS
 250 %token ADDQUOTE
 251 %token LYRICSTO
 252 %token ALIAS
 253 %token ALTERNATIVE
 254 %token BAR
 255 %token BOOK
 256 %token BOOKPAPER
 257 %token CHANGE
 258 %token CHORDMODIFIERS
 259 %token CHORDS
 260 %token CHORDMODE
 261 %token DOUBLE_ANGLE_OPEN
 262 %token DOUBLE_ANGLE_CLOSE
 263 %token CLEF
 264 %token COMMANDSPANREQUEST
 265 %token CONSISTS
 266 %token CONTEXT
 267 %token DEFAULT
 268 %token DENIES
 269 %token DESCRIPTION
 270 %token EXTENDER
 271 %token FIGURES
 272 %token FIGUREMODE
 273 %token FIGURE_OPEN FIGURE_CLOSE
 274 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 275 %token GROBDESCRIPTIONS
 276 %token HEADER
 277 %token HYPHEN
 278 %token INVALID
 279 %token KEY
 280 %token LYRICS
 281 %token LYRICMODE
 282 %token MARK
 283 %token MIDI
 284 %token MULTI_MEASURE_REST
 285 %token NAME
 286 %token NEWCONTEXT
 287 %token NOTEMODE
 288 %token OCTAVE
 289 %token ONCE
 290 %token OVERRIDE SET REVERT
 291 %token PAPER
 292 %token PARTIAL
 293 %token QUOTE
 294 %token RELATIVE
 295 %token REMOVE
 296 %token REPEAT
 297 %token REST
 298 %token SCM_T
 299 %token SCORE
 300 %token SEQUENTIAL
 301 %token ADDLYRICS
 302 %token SIMULTANEOUS
 303 %token SKIP
 304 %token SPANREQUEST
 305 %token TAG
 306 %token TEMPO
 307 %token TIMES
 308 %token TIME_T
 309 %token TRANSPOSE
 310 %token TRANSPOSITION
 311 %token TYPE
 312 %token UNSET
 313 %token WITH
 314 %token MARKUP
 315
 316 /* escaped */
 317 /* FIXME: this sucks.  The user will get to see these names:
 318     syntax error, unexpected E_CHAR:
 319                 \
 320                  %%
 321   */
 322
 323 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 324 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 325 %token E_BACKSLASH
 326 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 327 %token FIGURE_SPACE
 328
 329 %token <i>      DIGIT
 330 %token <i>      UNSIGNED
 331 %token <i> E_UNSIGNED
 332 %token <id>     IDENTIFIER
 333 %token <scm>    CHORDMODIFIER_PITCH
 334 %token <scm>    DRUM_PITCH
 335 %token <scm>    DURATION_IDENTIFIER
 336 %token <scm>    EVENT_IDENTIFIER
 337 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 338 %token <scm>    NOTENAME_PITCH
 339 %token <scm>    NUMBER_IDENTIFIER
 340 %token <scm>    OUTPUT_DEF_IDENTIFIER
 341 %token <scm>    RESTNAME
 342 %token <scm> LYRICS_STRING
 343 %token <scm>    SCM_T
 344 %token <scm>    SCORE_IDENTIFIER
 345 %token <scm>    STRING
 346 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 347 %token <scm>    TONICNAME_PITCH
 348 %token <scm>    CHORD_MODIFIER
 349 %token <scm>    FRACTION
 350 %token <scm>   REAL
 351 %token <scm> MARKUP_HEAD_EMPTY
 352 %token <scm> MARKUP_HEAD_MARKUP0
 353 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 354 %token <scm> MARKUP_HEAD_SCM0
 355 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 356 %token <scm> MARKUP_HEAD_SCM0_SCM1
 357 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 358 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 359 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 360 %token <scm> MUSIC_FUNCTION
 361 %token <scm> MUSIC_FUNCTION_MUSIC
 362 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 363 %token <scm> MUSIC_FUNCTION_SCM
 364 %token <scm> MUSIC_FUNCTION_SCM_SCM
 365 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 366 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 367 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 368
 369 %token DRUMS
 370 %token DRUMMODE
 371
 372
 373 %type <book>    book_block book_body
 374 %type <i>       bare_int  bare_unsigned
 375 %type <i>       exclamations questions dots optional_rest
 376 %type <i>       script_dir
 377 %type <i>       sub_quotes sup_quotes
 378 %type <i>       tremolo_type
 379 %type <i>       bass_mod
 380
 381 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 382 %type <music>   Grouped_music_list
 383 %type <music>   Music Sequential_music Simultaneous_music
 384 %type <music>   Repeated_music
 385 %type <music>   command_req
 386 %type <music>   gen_text_def direction_less_event direction_reqd_event
 387 %type <music>   music_property_def context_change
 388 %type <music>   note_chord_element chord_body chord_body_element
 389 %type <music>   open_event close_event
 390 %type <music>   post_event tagged_post_event
 391 %type <music>   relative_music re_rhythmed_music
 392 %type <music>   simple_element event_chord command_element
 393 %type <music>   string_number_event
 394 %type <music>   toplevel_music
 395 %type <music>   tempo_event
 396
 397 %type <outputdef>       output_def_body output_def_head
 398 %type <outputdef> output_def book_paper_block
 399
 400 %type <scm>     Music_list
 401 %type <scm>     chord_body_elements
 402 %type <scm>     chord_item chord_items chord_separator new_chord
 403 %type <scm>     context_def_spec_block context_def_spec_body
 404 %type <scm>     context_mod context_def_mod optional_context_mod
 405 %type <scm>     context_prop_spec
 406 %type <scm>     direction_less_char
 407 %type <scm>     duration_length fraction
 408 %type <scm>     embedded_scm scalar
 409 %type <scm>     identifier_init
 410 %type <scm>     lilypond_header lilypond_header_body
 411 %type <scm>     new_lyrics
 412 %type <scm>     post_events
 413 %type <scm>     property_operation
 414 %type <scm>     script_abbreviation
 415 %type <scm>     simple_string
 416 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 417 %type <scm>     steno_tonic_pitch
 418 %type <scm>     step_number step_numbers
 419 %type <scm>     string bare_number number_expression number_term number_factor
 420 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 421 %type <scm>     context_mod_list
 422 %type <scm>     octave_check
 423 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 424 %type <scm>     Generic_prefix_music_scm
 425 %type <scm>     lyric_element
 426 %type <scm>     Alternative_music
 427 %type <scm>     markup markup_line markup_list markup_list_body full_markup
 428 %type <scm>     mode_changing_head
 429 %type <scm>     mode_changing_head_with_context
 430
 431 %type <score>   score_block score_body
 432
 433
 434 %left '-' '+'
 435
 436 /* We don't assign precedence to / and *, because we might need varied
 437 prec levels in different prods */
 438
 439 %left UNARY_MINUS
 440
 441 %%
 442
 443 lilypond:       /* empty */
 444         | lilypond toplevel_expression {
 445         }
 446         | lilypond assignment {
 447         }
 448         | lilypond error {
 449                 THIS->error_level_ = 1;
 450         }
 451         | lilypond INVALID      {
 452                 THIS->error_level_ = 1;
 453         }
 454         ;
 455
 456 toplevel_expression:
 457         lilypond_header {
 458                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 459         }
 460         | add_quote {
 461
 462         }
 463         | book_block {
 464                 Book *book = $1;
 465                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 466                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 467                 scm_gc_unprotect_object (book->self_scm ());
 468         }
 469         | score_block {
 470                 Score *score = $1;
 471
 472                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 473                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 474                 scm_gc_unprotect_object (score->self_scm ());
 475         }
 476         | toplevel_music {
 477                 Music *music = $1;
 478                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 479                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 480                 scm_gc_unprotect_object (music->self_scm ());
 481         }
 482         | output_def {
 483                 SCM id = SCM_EOL;
 484                 Output_def * od = $1;
 485
 486                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 487                         id = ly_symbol2scm ("$defaultpaper");
 488                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 489                         id = ly_symbol2scm ("$defaultmidi");
 490                 else if ($1->c_variable ("is-bookpaper") == SCM_BOOL_T)
 491                         id = ly_symbol2scm ("$defaultbookpaper");
 492
 493                 THIS->lexer_->set_identifier (id, od->self_scm ());
 494                 scm_gc_unprotect_object (od->self_scm ());
 495         }
 496         ;
 497
 498 toplevel_music:
 499         Composite_music {
 500         }
 501         ;
 502
 503 embedded_scm:
 504         SCM_T
 505         | SCM_IDENTIFIER
 506         ;
 507
 508
 509 lilypond_header_body:
 510         {
 511                 $$ = ly_make_anonymous_module (safe_global_b);
 512                 THIS->lexer_->add_scope ($$);
 513         }
 514         | lilypond_header_body assignment  {
 515
 516         }
 517         ;
 518
 519 lilypond_header:
 520         HEADER '{' lilypond_header_body '}'     {
 521                 $$ = THIS->lexer_->remove_scope ();
 522         }
 523         ;
 524
 525
 526 /*
 527         DECLARATIONS
 528 */
 529 assignment:
 530         STRING {
 531                 THIS->push_spot ();
 532         }
 533         /* cont */ '=' identifier_init  {
 534
 535         /*
 536                 Should find generic way of associating input with objects.
 537         */
 538                 Input ip = THIS->pop_spot ();
 539
 540                 if (! is_regular_identifier ($1))
 541                 {
 542                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 543                 }
 544
 545                 THIS->lexer_->set_identifier ($1, $4);
 546
 547 /*
 548  TODO: devise standard for protection in parser.
 549
 550   The parser stack lives on the C-stack, which means that
 551 all objects can be unprotected as soon as they're here.
 552
 553 */
 554         }
 555         | embedded_scm { }
 556         ;
 557
 558
 559 identifier_init:
 560         score_block {
 561                 $$ = $1->self_scm ();
 562                 scm_gc_unprotect_object ($$);
 563         }
 564         | output_def {
 565                 $$ = $1->self_scm ();
 566                 scm_gc_unprotect_object ($$);
 567         }
 568         | context_def_spec_block {
 569                 $$ = $1;
 570         }
 571         | Music  {
 572                 $$ = $1->self_scm ();
 573                 scm_gc_unprotect_object ($$);
 574         }
 575         | post_event {
 576                 $$ = $1->self_scm ();
 577                 scm_gc_unprotect_object ($$);
 578         }
 579         | number_expression {
 580                 $$ = $1;
 581         }
 582         | string {
 583                 $$ = $1;
 584         }
 585         | embedded_scm {
 586                 $$ = $1;
 587         }
 588         | full_markup {
 589                 $$ = $1;
 590         }
 591         | DIGIT {
 592                 $$ = scm_int2num ($1);
 593         }
 594         ;
 595
 596 context_def_spec_block:
 597         CONTEXT '{' context_def_spec_body '}'
 598                 {
 599                 $$ = $3;
 600         }
 601         ;
 602
 603 context_def_spec_body:
 604         /**/ {
 605                 $$ = Context_def::make_scm ();
 606                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 607         }
 608         | CONTEXT_DEF_IDENTIFIER {
 609                 $$ = $1;
 610                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 611         }
 612         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 613                 Context_def*td = unsmob_context_def ($$);
 614
 615                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 616                         SCM tag = ly_caar (p);
 617
 618                         /* TODO: should make new tag "grob-definition" ? */
 619                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 620                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 621                 }
 622         }
 623         | context_def_spec_body context_mod {
 624                 unsmob_context_def ($$)->add_context_mod ($2);
 625         }
 626         ;
 627
 628
 629
 630 book_block:
 631         BOOK {
 632                 THIS->push_spot ();
 633         }
 634         /*cont*/ '{' book_body '}'      {
 635                 THIS->pop_spot ();
 636                 $$ = $4;
 637         }
 638         ;
 639
 640 /* FIXME:
 641    * Use 'handlers' like for toplevel-* stuff?
 642    * grok \paper and \midi?  */
 643 book_body:
 644         {
 645                 $$ = new Book;
 646                 $$->set_spot (THIS->here_input ());
 647                 $$->bookpaper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 648                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 649                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 650         }
 651         | book_body book_paper_block {
 652                 $$->bookpaper_ = $2;
 653                 scm_gc_unprotect_object ($2->self_scm ());
 654         }
 655         | book_body score_block {
 656                 Score *score = $2;
 657                 $$->scores_.push (score);
 658                 scm_gc_unprotect_object (score->self_scm ());
 659         }
 660         | book_body lilypond_header {
 661                 $$->header_ = $2;
 662         }
 663         | book_body error {
 664
 665         }
 666         ;
 667
 668 score_block:
 669         SCORE {
 670                 THIS->push_spot ();
 671         }
 672         /*cont*/ '{' score_body '}'     {
 673                 THIS->pop_spot ();
 674                 $$ = $4;
 675         }
 676         ;
 677
 678 score_body:
 679         /**/    {
 680                 $$ = new Score;
 681
 682                 $$->set_spot (THIS->here_input ());
 683         }
 684         | SCORE_IDENTIFIER {
 685                 $$ = new Score ( *unsmob_score ($1));
 686                 $$->set_spot (THIS->here_input ());
 687         }
 688         | score_body Music {
 689                 SCM m = $2->self_scm ();
 690                 scm_gc_unprotect_object (m);
 691                 $$->set_music (m, THIS->self_scm ());
 692         }
 693         | score_body lilypond_header    {
 694                 $$->header_ = $2;
 695         }
 696         | score_body output_def {
 697                 $$->defs_.push ($2);
 698                 scm_gc_unprotect_object ($2->self_scm ());
 699         }
 700         | score_body error {
 701
 702         }
 703         ;
 704
 705
 706 /*
 707         OUTPUT DEF
 708 */
 709
 710 book_paper_block:
 711         output_def {
 712                 $$ = $1;
 713                 if ($$->lookup_variable (ly_symbol2scm ("is-bookpaper")) != SCM_BOOL_T)
 714                 {
 715                         THIS->parser_error (_("Need \\bookpaper for bookpaper block."));
 716                         $$ = get_bookpaper (THIS);
 717                 }
 718         }
 719         ;
 720
 721
 722 output_def:
 723         output_def_body '}' {
 724                 $$ = $1;
 725                 if ($1->parent_)
 726                         THIS->lexer_->remove_scope ();
 727
 728                 THIS->lexer_->remove_scope ();
 729                 THIS->lexer_->pop_state ();
 730         }
 731         ;
 732
 733 output_def_head:
 734         BOOKPAPER {
 735                 $$ = get_bookpaper (THIS);
 736                 $$->input_origin_ = THIS->here_input ();
 737                 THIS->lexer_->add_scope ($$->scope_);
 738         }
 739         | MIDI    {
 740                 Output_def *p = get_midi (THIS);
 741                 $$ = p;
 742                 THIS->lexer_->add_scope (p->scope_);
 743         }
 744         | PAPER         {
 745                 Output_def *p = get_paper (THIS);
 746
 747                 if (p->parent_)
 748                         THIS->lexer_->add_scope (p->parent_->scope_);
 749
 750                 THIS->lexer_->add_scope (p->scope_);
 751                 $$ = p;
 752         }
 753         ;
 754
 755
 756 output_def_body:
 757         output_def_head '{' {
 758                 $$ = $1;
 759                 $$->input_origin_.set_spot (THIS->here_input ());
 760                 THIS->lexer_->push_initial_state ();
 761         }
 762         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 763                 scm_gc_unprotect_object ($1->self_scm ());
 764                 Output_def *o = unsmob_output_def ($3);
 765                 o->input_origin_.set_spot (THIS->here_input ());
 766                 $$ = o;
 767                 THIS->lexer_->remove_scope ();
 768                 THIS->lexer_->add_scope (o->scope_);
 769                 THIS->lexer_->push_initial_state ();
 770         }
 771         | output_def_body assignment  {
 772
 773         }
 774         | output_def_body context_def_spec_block        {
 775                 assign_context_def ($$, $2);
 776         }
 777         | output_def_body tempo_event  {
 778                 /*
 779                         junk this ? there already is tempo stuff in
 780                         music.
 781                 */
 782                 int m = scm_to_int ($2->get_property ("metronome-count"));
 783                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 784                 set_tempo ($$, d->get_length (), m);
 785                 scm_gc_unprotect_object ($2->self_scm ());
 786         }
 787         | output_def_body error {
 788
 789         }
 790         ;
 791
 792 tempo_event:
 793         TEMPO steno_duration '=' bare_unsigned  {
 794                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 795                 $$->set_property ("tempo-unit", $2);
 796                 $$->set_property ("metronome-count", scm_int2num ( $4));
 797         }
 798         ;
 799
 800 /*
 801 The representation of a  list is the
 802
 803   (LIST . LAST-CONS)
 804
 805  to have  efficient append.
 806 */
 807 Music_list:
 808         /* empty */ {
 809                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 810         }
 811         | Music_list Music {
 812                 SCM s = $$;
 813                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 814                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 815                 if (ly_c_pair_p (ly_cdr (s)))
 816                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 817                 else
 818                         scm_set_car_x (s, c); /* set first cons */
 819                 scm_set_cdr_x (s, c);  /* remember last cell */
 820         }
 821         | Music_list embedded_scm {
 822         }
 823         | Music_list error {
 824         }
 825         ;
 826
 827
 828 Music:
 829         Simple_music
 830         | Composite_music
 831         ;
 832
 833 Alternative_music:
 834         /* empty */ {
 835                 $$ = SCM_EOL;
 836         }
 837         | ALTERNATIVE '{' Music_list '}' {
 838                 $$ = $3;
 839         }
 840         ;
 841
 842
 843 Repeated_music:
 844         REPEAT simple_string bare_unsigned Music Alternative_music
 845         {
 846                 Music *beg = $4;
 847                 int times = $3;
 848                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 849                 if (times < scm_ilength (alts)) {
 850                   unsmob_music (ly_car (alts))
 851                     ->origin ()->warning (
 852                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 853                   alts = ly_truncate_list (times, alts);
 854                 }
 855
 856
 857                 SCM proc = ly_scheme_function ("make-repeated-music");
 858
 859                 SCM mus = scm_call_1 (proc, $2);
 860                 scm_gc_protect_object (mus); // UGH.
 861                 Music *r = unsmob_music (mus);
 862                 if (beg)
 863                         {
 864                         r-> set_property ("element", beg->self_scm ());
 865                         scm_gc_unprotect_object (beg->self_scm ());
 866                         }
 867                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 868
 869                 r-> set_property ("elements",alts);
 870                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 871                         /*
 872                         TODO: move this code to Scheme.
 873                         */
 874
 875                         /*
 876                         we can not get durations and other stuff correct down the line, so we have to
 877                         add to the duration log here.
 878                         */
 879                         SCM func = ly_scheme_function ("shift-duration-log");
 880
 881                         int dots = ($3 % 3) ? 0 : 1;
 882                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 883
 884                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 885
 886                         if (seq) {
 887                                 int list_len = scm_ilength (seq->music_list ());
 888                                 if (list_len != 2)
 889                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 890                                 shift -= 1;
 891                                 r->compress (Moment (Rational (1, list_len)));
 892                                 }
 893                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 894
 895                 }
 896                 r->set_spot (*$4->origin ());
 897
 898                 $$ = r;
 899         }
 900         ;
 901
 902 Sequential_music:
 903         SEQUENTIAL '{' Music_list '}'           {
 904                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 905                 $$->set_property ("elements", ly_car ($3));
 906                 $$->set_spot (THIS->here_input ());
 907         }
 908         | '{' Music_list '}'            {
 909                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 910                 $$->set_property ("elements", ly_car ($2));
 911                 $$->set_spot (THIS->here_input ());
 912         }
 913         ;
 914
 915 Simultaneous_music:
 916         SIMULTANEOUS '{' Music_list '}'{
 917                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 918                 $$->set_property ("elements", ly_car ($3));
 919                 $$->set_spot (THIS->here_input ());
 920
 921         }
 922         | simul_open Music_list simul_close     {
 923                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 924                 $$->set_property ("elements", ly_car ($2));
 925                 $$->set_spot (THIS->here_input ());
 926         }
 927         ;
 928
 929 Simple_music:
 930         event_chord             { $$ = $1; }
 931         | MUSIC_IDENTIFIER {
 932                 $$ = unsmob_music ($1);
 933         }
 934         | music_property_def
 935         | context_change
 936         ;
 937
 938
 939 optional_context_mod:
 940         /**/ { $$ = SCM_EOL; }
 941         | WITH { THIS->lexer_->push_initial_state (); }
 942         '{' context_mod_list '}'
 943         {
 944                 THIS->lexer_->pop_state ();
 945                 $$ = $4;
 946         }
 947         ;
 948
 949 context_mod_list:
 950         /* */  { $$ = SCM_EOL; }
 951         | context_mod_list context_mod  {
 952                  $$ = scm_cons ($2, $1);
 953         }
 954         ;
 955
 956
 957 Composite_music:
 958         Prefix_composite_music { $$ = $1; }
 959         | Grouped_music_list { $$ = $1; }
 960         ;
 961
 962 Grouped_music_list:
 963         Simultaneous_music              { $$ = $1; }
 964         | Sequential_music              { $$ = $1; }
 965         ;
 966
 967 Generic_prefix_music_scm:
 968         MUSIC_FUNCTION {
 969                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 970         }
 971         | MUSIC_FUNCTION_SCM {
 972                 THIS->push_spot ();
 973         } embedded_scm {
 974                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 975         }
 976         | MUSIC_FUNCTION_MUSIC {
 977                 THIS->push_spot ();
 978         } Music {
 979                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 980                 scm_gc_unprotect_object ($3->self_scm ());
 981         }
 982         | MUSIC_FUNCTION_SCM_MUSIC {
 983                 THIS->push_spot ();
 984         }  embedded_scm Music {
 985                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 986                 scm_gc_unprotect_object ($4->self_scm ());
 987         }
 988         | MUSIC_FUNCTION_SCM_SCM {
 989                 THIS->push_spot ();
 990         }  embedded_scm embedded_scm {
 991                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4);
 992         }
 993         | MUSIC_FUNCTION_MUSIC_MUSIC {
 994                 THIS->push_spot ();
 995         }  Music  Music {
 996                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
 997                 scm_gc_unprotect_object ($3->self_scm ());
 998                 scm_gc_unprotect_object ($4->self_scm ());
 999         }
1000         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
1001                 THIS->push_spot ();
1002         } embedded_scm Music Music {
1003                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1004                         $3, $4->self_scm (), $5->self_scm ());
1005                 scm_gc_unprotect_object ($5->self_scm ());
1006                 scm_gc_unprotect_object ($4->self_scm ());
1007         }
1008         ;
1009
1010 Generic_prefix_music:
1011         Generic_prefix_music_scm {
1012                 SCM func = ly_car ($1);
1013                 Input *loc = unsmob_input (ly_cadr ($1));
1014                 SCM args = ly_cddr ($1);
1015                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1016                 int k = 0;
1017                 bool ok  = true;
1018                 for (SCM s = sig, t = args;
1019                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1020                         s = ly_cdr (s), t = ly_cdr (t)) {
1021                         k++;
1022                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1023                         {
1024                                 loc->error (_f ("Argument %d failed typecheck", k));
1025                                 THIS->error_level_ = 1;
1026                                 ok = false;
1027                         }
1028                 }
1029                 SCM m = SCM_EOL;
1030                 if (ok)
1031                         m = scm_apply_0 (func, ly_cdr ($1));
1032                 if (unsmob_music (m))
1033                         {
1034                         $$ = unsmob_music (m);
1035                         scm_gc_protect_object (m);
1036                         }
1037                 else
1038                         {
1039                         if (ok)
1040                                 loc->error (_ ("Music head function should return Music object."));
1041                         $$ = MY_MAKE_MUSIC ("Music");
1042                         }
1043                 $$->set_spot (*loc);
1044         }
1045         ;
1046
1047
1048 Prefix_composite_music:
1049         Generic_prefix_music {
1050                 $$ = $1;
1051         }
1052         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1053                 $$ = context_spec_music ($2, $4, $6, $5);
1054
1055         }
1056         | CONTEXT simple_string optional_context_mod Music {
1057                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1058         }
1059         | NEWCONTEXT simple_string optional_context_mod Music {
1060                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1061                         $3);
1062         }
1063
1064         | TIMES {
1065                 THIS->push_spot ();
1066         }
1067         /* CONTINUED */
1068                 fraction Music
1069
1070         {
1071                 int n = scm_to_int (ly_car ($3)); int d = scm_to_int (ly_cdr ($3));
1072                 Music *mp = $4;
1073
1074                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1075                 $$->set_spot (THIS->pop_spot ());
1076
1077                 $$->set_property ("element", mp->self_scm ());
1078                 scm_gc_unprotect_object (mp->self_scm ());
1079                 $$->set_property ("numerator", scm_int2num (n));
1080                 $$->set_property ("denominator", scm_int2num (d));
1081                 $$->compress (Moment (Rational (n,d)));
1082
1083         }
1084         | Repeated_music                { $$ = $1; }
1085         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1086                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1087                 Music *p = $4;
1088                 Pitch from = *unsmob_pitch ($2);
1089                 Pitch to = *unsmob_pitch ($3);
1090
1091                 p->transpose (interval (from, to));
1092                 $$->set_property ("element", p->self_scm ());
1093                 scm_gc_unprotect_object (p->self_scm ());
1094         }
1095         | mode_changing_head Grouped_music_list {
1096                 if ($1 == ly_symbol2scm ("chords"))
1097                 {
1098                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1099                   chm->set_property ("element", $2->self_scm ());
1100                   $$ = chm;
1101                   scm_gc_unprotect_object ($2->self_scm ());
1102                 }
1103                 else
1104                 {
1105                   $$ = $2;
1106                 }
1107                 THIS->lexer_->pop_state ();
1108         }
1109         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1110                 $$ = context_spec_music ($1, get_next_unique_context (),
1111                                          $3, $2);
1112                 if ($1 == ly_symbol2scm ("ChordNames"))
1113                 {
1114                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1115                   chm->set_property ("element", $$->self_scm ());
1116                   scm_gc_unprotect_object ($$->self_scm ());
1117                   $$ = chm;
1118                 }
1119                 THIS->lexer_->pop_state ();
1120         }
1121         | relative_music        { $$ = $1; }
1122         | re_rhythmed_music     { $$ = $1; }
1123         | TAG embedded_scm Music {
1124                 tag_music ($3, $2, THIS->here_input ());
1125                 $$ = $3;
1126         }
1127         ;
1128
1129 mode_changing_head:
1130         NOTEMODE {
1131                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1132                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1133
1134                 $$ = ly_symbol2scm ("notes");
1135         }
1136         | DRUMMODE
1137                 {
1138                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1139                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1140
1141                 $$ = ly_symbol2scm ("drums");
1142         }
1143         | FIGUREMODE {
1144                 THIS->lexer_->push_figuredbass_state ();
1145
1146                 $$ = ly_symbol2scm ("figures");
1147         }
1148         | CHORDMODE {
1149                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1150                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1151                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1152                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1153                 $$ = ly_symbol2scm ("chords");
1154
1155         }
1156         | LYRICMODE
1157                 { THIS->lexer_->push_lyric_state ();
1158                 $$ = ly_symbol2scm ("lyrics");
1159         }
1160         ;
1161
1162 mode_changing_head_with_context:
1163         DRUMS {
1164                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1165                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1166
1167                 $$ = ly_symbol2scm ("DrumStaff");
1168         }
1169         | FIGURES {
1170                 THIS->lexer_->push_figuredbass_state ();
1171
1172                 $$ = ly_symbol2scm ("FiguredBass");
1173         }
1174         | CHORDS {
1175                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1176                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1177                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1178                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1179                 $$ = ly_symbol2scm ("ChordNames");
1180         }
1181         | LYRICS
1182                 { THIS->lexer_->push_lyric_state ();
1183                 $$ = ly_symbol2scm ("Lyrics");
1184         }
1185         ;
1186
1187
1188 relative_music:
1189         RELATIVE absolute_pitch Music {
1190                 Music *m = $3;
1191                 Pitch start = *unsmob_pitch ($2);
1192                 $$ = make_music_relative (start, m);
1193                 scm_gc_unprotect_object (m->self_scm ());
1194         }
1195         | RELATIVE Composite_music {
1196                 Music *m = $2;
1197
1198                 Pitch middle_c (0, 0, 0);
1199                 $$ = make_music_relative (middle_c, m);
1200                 scm_gc_unprotect_object (m->self_scm ());
1201         }
1202         ;
1203
1204 new_lyrics:
1205         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1206         /*cont */
1207         Grouped_music_list {
1208         /* Can also use Music at the expensive of two S/Rs similar to
1209            \repeat \alternative */
1210                 THIS->lexer_->pop_state ();
1211 #if 0
1212                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1213                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1214                 $$ = music;
1215 #else
1216                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1217 #endif
1218         }
1219         | new_lyrics ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1220         Grouped_music_list {
1221                 THIS->lexer_->pop_state ();
1222                 $$ = scm_cons ($4->self_scm (), $1);
1223         }
1224         ;
1225
1226 re_rhythmed_music:
1227         Grouped_music_list new_lyrics {
1228
1229                 /* FIXME: should find out uniqueXXX name from music */
1230                 SCM name = $1->get_property ("context-id");
1231                 //if (name == SCM_EOL)
1232                 if (!scm_is_string (name))
1233                         name = scm_makfrom0str ("");
1234
1235                 SCM context = scm_makfrom0str ("Lyrics");
1236                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1237
1238                 SCM lst = SCM_EOL;
1239                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1240                 {
1241                         Music *music = unsmob_music (ly_car (s));
1242                         Music *com = make_lyric_combine_music (name, music);
1243                         Music *csm = context_spec_music (context,
1244                                 get_next_unique_context (), com, SCM_EOL);
1245                         lst = scm_cons (csm->self_scm (), lst);
1246                 }
1247                 /* FIXME: only first lyric music is accepted,
1248                           the rest is junked */
1249                 all->set_property ("elements", scm_cons ($1->self_scm (),
1250                         lst));
1251                 $$ = all;
1252                 scm_gc_unprotect_object ($1->self_scm ());
1253         }
1254         | LYRICSTO {
1255                 THIS->lexer_->push_lyric_state ();
1256         } simple_string Music {
1257                 THIS->lexer_->pop_state ();
1258                 Music *music = $4;
1259                 SCM name = $3;
1260                 $$ = make_lyric_combine_music (name, music);
1261                 scm_gc_unprotect_object (music->self_scm ());
1262         }
1263         ;
1264
1265 context_change:
1266         CHANGE STRING '=' STRING  {
1267                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1268                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1269                 t-> set_property ("change-to-id", $4);
1270
1271                 $$ = t;
1272                 $$->set_spot (THIS->here_input ());
1273         }
1274         ;
1275
1276 property_operation:
1277         STRING '=' scalar {
1278                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1279                         scm_string_to_symbol ($1), $3);
1280         }
1281         | UNSET simple_string {
1282                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1283                         scm_string_to_symbol ($2));
1284         }
1285         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1286                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1287                         scm_string_to_symbol ($2), $3, $5);
1288         }
1289         | REVERT simple_string embedded_scm {
1290                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1291                         scm_string_to_symbol ($2), $3);
1292         }
1293         ;
1294
1295 context_def_mod:
1296         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1297         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1298
1299         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1300         | DENIES { $$ = ly_symbol2scm ("denies"); }
1301
1302         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1303         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1304         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1305         | NAME { $$ = ly_symbol2scm ("context-name"); }
1306         ;
1307
1308 context_mod:
1309         property_operation { $$ = $1; }
1310         | context_def_mod STRING {
1311                 $$ = scm_list_2 ($1, $2);
1312         }
1313         ;
1314
1315 context_prop_spec:
1316         simple_string {
1317                 if (!is_regular_identifier ($1))
1318                 {
1319                         THIS->here_input ().error (_("Grob name should be alphanumeric"));
1320                 }
1321
1322                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1323                         scm_string_to_symbol ($1));
1324         }
1325         | simple_string '.' simple_string {
1326                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1327                         scm_string_to_symbol ($3));
1328         }
1329         ;
1330
1331 music_property_def:
1332         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1333                 $$ = property_op_to_music (scm_list_4 (
1334                         ly_symbol2scm ("poppush"),
1335                         ly_cadr ($2),
1336                         $3, $5));
1337                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1338         }
1339         | REVERT context_prop_spec embedded_scm {
1340                 $$ = property_op_to_music (scm_list_3 (
1341                         ly_symbol2scm ("pop"),
1342                         ly_cadr ($2),
1343                         $3));
1344
1345                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1346         }
1347         | SET context_prop_spec '=' scalar {
1348                 $$ = property_op_to_music (scm_list_3 (
1349                         ly_symbol2scm ("assign"),
1350                         ly_cadr ($2),
1351                         $4));
1352                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1353         }
1354         | UNSET context_prop_spec {
1355                 $$ = property_op_to_music (scm_list_2 (
1356                         ly_symbol2scm ("unset"),
1357                         ly_cadr ($2)));
1358                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1359         }
1360         | ONCE music_property_def {
1361                 SCM e = $2->get_property ("element");
1362                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1363                 $$ = $2;
1364
1365         }
1366         ;
1367
1368
1369 string:
1370         STRING {
1371                 $$ = $1;
1372         }
1373         | STRING_IDENTIFIER {
1374                 $$ = $1;
1375         }
1376         | string '+' string {
1377                 $$ = scm_string_append (scm_list_2 ($1, $3));
1378         }
1379         ;
1380
1381 simple_string: STRING {
1382                 $$ = $1;
1383         }
1384         | LYRICS_STRING {
1385                 $$ = $1;
1386         }
1387         ;
1388
1389 scalar: string {
1390                 $$ = $1;
1391         }
1392         | LYRICS_STRING {
1393                 $$ = $1;
1394         }
1395         | bare_int {
1396                 $$ = scm_int2num ($1);
1397         }
1398         | embedded_scm {
1399                 $$ = $1;
1400         }
1401         | full_markup {
1402                 $$ = $1;
1403         }
1404         | DIGIT {
1405                 $$ = scm_int2num ($1);
1406         }
1407         ;
1408
1409 /*
1410
1411 pre_events doesn't contain anything. It is a trick:
1412
1413 Adding pre_events to the simple_element
1414 makes the choice between
1415
1416   string:  STRING
1417
1418 and
1419
1420   simple_element: STRING
1421
1422 a single shift/reduction conflict.
1423
1424 nevertheless, this is not very clean, and we should find a different
1425 solution.
1426
1427 */
1428 pre_events: {
1429                 THIS->push_spot ();
1430         }
1431         ;
1432
1433 event_chord:
1434         pre_events simple_element post_events   {
1435                 SCM elts = $2-> get_property ("elements");
1436
1437                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1438
1439                 $2->set_property ("elements", elts);
1440                 $$ = $2;
1441         }
1442         | command_element
1443         | note_chord_element
1444         ;
1445
1446
1447 note_chord_element:
1448         chord_body optional_notemode_duration post_events
1449         {
1450                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1451                 SCM es = $1->get_property ("elements");
1452                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1453
1454                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1455                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1456                 es = ly_append2 (es, postevs);
1457
1458                 $1-> set_property ("elements", es);
1459                 $$ = $1;
1460         }
1461         ;
1462
1463 chord_open: '<'
1464         ;
1465
1466 chord_close: '>'
1467         ;
1468
1469 simul_open: DOUBLE_ANGLE_OPEN
1470         ;
1471
1472 simul_close: DOUBLE_ANGLE_CLOSE
1473         ;
1474
1475 chord_body:
1476         chord_open chord_body_elements chord_close
1477         {
1478                 $$ = MY_MAKE_MUSIC ("EventChord");
1479                 $$->set_property ("elements",
1480                         scm_reverse_x ($2, SCM_EOL));
1481         }
1482         ;
1483
1484 chord_body_elements:
1485         /* empty */             { $$ = SCM_EOL; }
1486         | chord_body_elements chord_body_element {
1487                 $$ = scm_cons ($2->self_scm (), $1);
1488                 scm_gc_unprotect_object ($2->self_scm ());
1489         }
1490         ;
1491
1492 chord_body_element:
1493         pitch  exclamations questions octave_check post_events
1494         {
1495                 int q = $3;
1496                 int ex = $2;
1497                 SCM check = $4;
1498                 SCM post = $5;
1499
1500                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1501                 n->set_property ("pitch", $1);
1502                 if (q % 2)
1503                         n->set_property ("cautionary", SCM_BOOL_T);
1504                 if (ex % 2 || q % 2)
1505                         n->set_property ("force-accidental", SCM_BOOL_T);
1506
1507                 if (ly_c_pair_p (post)) {
1508                         SCM arts = scm_reverse_x (post, SCM_EOL);
1509                         n->set_property ("articulations", arts);
1510                 }
1511                 if (scm_is_number (check))
1512                 {
1513                         int q = scm_to_int (check);
1514                         n->set_property ("absolute-octave", scm_int2num (q-1));
1515                 }
1516
1517
1518                 $$ = n;
1519         }
1520         | DRUM_PITCH post_events {
1521                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1522                 n->set_property ("duration", $2);
1523                 n->set_property ("drum-type", $1);
1524                 n->set_spot (THIS->here_input ());
1525
1526                 if (ly_c_pair_p ($2)) {
1527                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1528                         n->set_property ("articulations", arts);
1529                 }
1530                 $$ = n;
1531         }
1532         ;
1533
1534 add_quote:
1535         ADDQUOTE string Music {
1536                 SCM adder = ly_scheme_function ("add-quotable");
1537
1538                 scm_call_2 (adder, $2, $3->self_scm ());
1539                 scm_gc_unprotect_object ($3->self_scm ());
1540         }
1541         ;
1542
1543 command_element:
1544         command_req {
1545                 $$ = MY_MAKE_MUSIC ("EventChord");
1546                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1547                 scm_gc_unprotect_object ($1->self_scm ());
1548
1549                 $$-> set_spot (THIS->here_input ());
1550                 $1-> set_spot (THIS->here_input ());
1551         }
1552         | SKIP duration_length {
1553                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1554                 skip->set_property ("duration", $2);
1555
1556                 $$ = skip;
1557         }
1558         | QUOTE STRING duration_length {
1559                 Music *quote = MY_MAKE_MUSIC ("QuoteMusic");
1560                 quote->set_property ("duration", $3);
1561                 quote->set_property ("quoted-music-name", $2);
1562                 quote->set_spot (THIS->here_input ());
1563
1564                 $$ = quote;
1565         }
1566         | OCTAVE { THIS->push_spot (); }
1567           pitch {
1568                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1569                 $$ = m;
1570                 $$->set_spot (THIS->pop_spot ());
1571                 $$->set_property ("pitch", $3);
1572         }
1573         | E_LEFTSQUARE {
1574                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1575                 m->set_property ("span-direction", scm_int2num (START));
1576                 m->set_spot (THIS->here_input ());
1577
1578                 $$ = MY_MAKE_MUSIC ("EventChord");
1579                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1580                 scm_gc_unprotect_object (m->self_scm ());
1581                 $$->set_spot (THIS->here_input ());
1582         }
1583         | E_RIGHTSQUARE {
1584                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1585                 m->set_property ("span-direction", scm_int2num (STOP));
1586                 m->set_spot (THIS->here_input ());
1587
1588                 $$ = MY_MAKE_MUSIC ("EventChord");
1589                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1590                 $$->set_spot (THIS->here_input ());
1591                 scm_gc_unprotect_object (m->self_scm ());
1592         }
1593         | E_BACKSLASH {
1594                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1595                 $$->set_spot (THIS->here_input ());
1596         }
1597         | '|'      {
1598                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1599
1600                 if (Music * m = unsmob_music (pipe))
1601                         $$ = m->clone ();
1602                 else
1603                         $$ = MY_MAKE_MUSIC ("BarCheck");
1604
1605                 $$->set_spot (THIS->here_input ());
1606         }
1607         | TRANSPOSITION pitch {
1608                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1609                                         $2);
1610                 $$->set_spot (THIS-> here_input ());
1611                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1612                         $$, SCM_EOL);
1613         }
1614         | BAR STRING                    {
1615                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1616
1617                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1618                                         t, SCM_EOL);
1619                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1620                 $$->set_spot (THIS->here_input ());
1621                 t->set_spot (THIS->here_input ());
1622         }
1623         | PARTIAL duration_length       {
1624                 Moment m = - unsmob_duration ($2)->get_length ();
1625                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1626                 p->set_spot (THIS->here_input ());
1627                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1628                                         p, SCM_EOL);
1629                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1630                                         p, SCM_EOL);
1631                 $$ = p;
1632         }
1633         | CLEF STRING  {
1634                 SCM proc = ly_scheme_function ("make-clef-set");
1635
1636                 SCM result = scm_call_1 (proc, $2);
1637                 scm_gc_protect_object (result);
1638                 $$ = unsmob_music (result);
1639         }
1640         | TIME_T fraction  {
1641                 SCM proc= ly_scheme_function ("make-time-signature-set");
1642
1643                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1644                 scm_gc_protect_object (result);
1645                 $$ = unsmob_music (result);
1646         }
1647         | MARK scalar {
1648                 SCM proc = ly_scheme_function ("make-mark-set");
1649
1650                 SCM result = scm_call_1 (proc, $2);
1651                 scm_gc_protect_object (result);
1652                 $$ = unsmob_music (result);
1653         }
1654         ;
1655
1656 command_req:
1657         E_TILDE {
1658                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1659         }
1660         | MARK DEFAULT  {
1661                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1662                 $$ = m;
1663         }
1664         | tempo_event {
1665                 $$ = $1;
1666         }
1667         | KEY DEFAULT {
1668                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1669                 $$ = key;
1670         }
1671         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1672
1673                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1674                 if (scm_ilength ($3) > 0)
1675                 {
1676                         key->set_property ("pitch-alist", $3);
1677                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1678                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1679                 } else {
1680                         THIS->parser_error (_ ("Second argument must be pitch list."));
1681                 }
1682
1683                 $$ = key;
1684         }
1685         ;
1686
1687 post_events:
1688         /* empty */ {
1689                 $$ = SCM_EOL;
1690         }
1691         | post_events post_event {
1692                 $2->set_spot (THIS->here_input ());
1693                 $$ = scm_cons ($2->self_scm (), $$);
1694                 scm_gc_unprotect_object ($2->self_scm ());
1695         }
1696         | post_events tagged_post_event {
1697                 $2 -> set_spot (THIS->here_input ());
1698                 $$ = scm_cons ($2->self_scm (), $$);
1699                 scm_gc_unprotect_object ($2->self_scm ());
1700         }
1701         ;
1702
1703
1704 tagged_post_event:
1705         '-' TAG embedded_scm post_event {
1706                 tag_music ($4, $3, THIS->here_input ());
1707                 $$ = $4;
1708         }
1709         ;
1710
1711 post_event:
1712         direction_less_event {
1713                 $$ = $1;
1714         }
1715         | HYPHEN {
1716                 if (!THIS->lexer_->is_lyric_state ())
1717                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1718                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1719         }
1720         | EXTENDER {
1721                 if (!THIS->lexer_->is_lyric_state ())
1722                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1723                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1724         }
1725         | script_dir direction_reqd_event {
1726                 if ($1)
1727                         $2->set_property ("direction", scm_int2num ($1));
1728                 $$ = $2;
1729         }
1730         | script_dir direction_less_event {
1731                 if ($1)
1732                         $2->set_property ("direction", scm_int2num ($1));
1733                 $$ = $2;
1734         }
1735         | string_number_event
1736         ;
1737
1738 string_number_event:
1739         E_UNSIGNED {
1740                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1741                 s->set_property ("string-number", scm_int2num ($1));
1742                 s->set_spot (THIS->here_input ());
1743                 $$ = s;
1744         }
1745         ;
1746
1747 direction_less_char:
1748         '['  {
1749                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1750         }
1751         | ']'  {
1752                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1753         }
1754         | '~'  {
1755                 $$ = ly_symbol2scm ("tildeSymbol");
1756         }
1757         | '('  {
1758                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1759         }
1760         | ')'  {
1761                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1762         }
1763         | E_EXCLAMATION  {
1764                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1765         }
1766         | E_OPEN  {
1767                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1768         }
1769         | E_CLOSE  {
1770                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1771         }
1772         | E_BIGGER  {
1773                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1774         }
1775         | E_SMALLER  {
1776                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1777         }
1778         ;
1779
1780 direction_less_event:
1781         direction_less_char  {
1782                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1783                 Music * m = 0:
1784                 if (unsmob_music (predefd))
1785                 {
1786                         m = unsmob_music (predefd)->clone ();
1787                 }
1788                 else
1789                 {
1790                         m = MY_MAKE_MUSIC ("Music");
1791                 }
1792                 m->set_spot (THIS->here_input ());
1793                 $$ = m;
1794         }
1795         | EVENT_IDENTIFIER      {
1796                 $$ = unsmob_music ($1);
1797         }
1798         | tremolo_type  {
1799                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1800                a->set_spot (THIS->here_input ());
1801                a->set_property ("tremolo-type", scm_int2num ($1));
1802                $$ = a;
1803         }
1804         ;
1805
1806 direction_reqd_event:
1807         gen_text_def {
1808                 $$ = $1;
1809         }
1810         | script_abbreviation {
1811                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1812                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1813                 if (scm_is_string (s))
1814                         a->set_property ("articulation-type", s);
1815                 else THIS->parser_error (_ ("Expecting string as script definition"));
1816                 $$ = a;
1817         }
1818         ;
1819
1820 octave_check:
1821         /**/ { $$ = SCM_EOL; }
1822         | '='  { $$ = scm_int2num (0); }
1823         | '=' sub_quotes { $$ = scm_int2num ($2); }
1824         | '=' sup_quotes { $$ = scm_int2num ($2); }
1825         ;
1826
1827 sup_quotes:
1828         '\'' {
1829                 $$ = 1;
1830         }
1831         | sup_quotes '\'' {
1832                 $$ ++;
1833         }
1834         ;
1835
1836 sub_quotes:
1837         ',' {
1838                 $$ = 1;
1839         }
1840         | sub_quotes ',' {
1841                 $$++;
1842         }
1843         ;
1844
1845 steno_pitch:
1846         NOTENAME_PITCH  {
1847                 $$ = $1;
1848         }
1849         | NOTENAME_PITCH sup_quotes     {
1850                 Pitch p = *unsmob_pitch ($1);
1851                 p = p.transposed (Pitch ($2,0,0));
1852                 $$ = p.smobbed_copy ();
1853         }
1854         | NOTENAME_PITCH sub_quotes      {
1855                 Pitch p =* unsmob_pitch ($1);
1856                 p = p.transposed (Pitch (-$2,0,0));
1857                 $$ = p.smobbed_copy ();
1858         }
1859         ;
1860
1861 /*
1862 ugh. duplication
1863 */
1864
1865 steno_tonic_pitch:
1866         TONICNAME_PITCH {
1867                 $$ = $1;
1868         }
1869         | TONICNAME_PITCH sup_quotes    {
1870                 Pitch p = *unsmob_pitch ($1);
1871                 p = p.transposed (Pitch ($2,0,0));
1872                 $$ = p.smobbed_copy ();
1873         }
1874         | TONICNAME_PITCH sub_quotes     {
1875                 Pitch p =* unsmob_pitch ($1);
1876
1877                 p = p.transposed (Pitch (-$2,0,0));
1878                 $$ = p.smobbed_copy ();
1879         }
1880         ;
1881
1882 pitch:
1883         steno_pitch {
1884                 $$ = $1;
1885         }
1886         ;
1887
1888 pitch_also_in_chords:
1889         pitch
1890         | steno_tonic_pitch
1891         ;
1892
1893 gen_text_def:
1894         full_markup {
1895                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1896                 t->set_property ("text", $1);
1897                 t->set_spot (THIS->here_input ());
1898                 $$ = t;
1899         }
1900         | string {
1901                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1902                 t->set_property ("text",
1903                         make_simple_markup (THIS->lexer_->encoding (), $1));
1904                 t->set_spot (THIS->here_input ());
1905                 $$ = t;
1906
1907         }
1908         | DIGIT {
1909                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1910                 t->set_property ("digit", scm_int2num ($1));
1911                 t->set_spot (THIS->here_input ());
1912                 $$ = t;
1913         }
1914         ;
1915
1916 script_abbreviation:
1917         '^'             {
1918                 $$ = scm_makfrom0str ("Hat");
1919         }
1920         | '+'           {
1921                 $$ = scm_makfrom0str ("Plus");
1922         }
1923         | '-'           {
1924                 $$ = scm_makfrom0str ("Dash");
1925         }
1926         | '|'           {
1927                 $$ = scm_makfrom0str ("Bar");
1928         }
1929         | '>'           {
1930                 $$ = scm_makfrom0str ("Larger");
1931         }
1932         | '.'           {
1933                 $$ = scm_makfrom0str ("Dot");
1934         }
1935         | '_' {
1936                 $$ = scm_makfrom0str ("Underscore");
1937         }
1938         ;
1939
1940 script_dir:
1941         '_'     { $$ = DOWN; }
1942         | '^'   { $$ = UP; }
1943         | '-'   { $$ = CENTER; }
1944         ;
1945
1946
1947 absolute_pitch:
1948         steno_pitch     {
1949                 $$ = $1;
1950         }
1951         ;
1952
1953 duration_length:
1954         multiplied_duration {
1955                 $$ = $1;
1956         }
1957         ;
1958
1959 optional_notemode_duration:
1960         {
1961                 Duration dd = THIS->default_duration_;
1962                 $$ = dd.smobbed_copy ();
1963
1964                 THIS->beam_check ($$);
1965         }
1966         | multiplied_duration   {
1967                 $$ = $1;
1968                 THIS->default_duration_ = *unsmob_duration ($$);
1969
1970                 THIS->beam_check ($$);
1971         }
1972         ;
1973
1974 steno_duration:
1975         bare_unsigned dots              {
1976                 int len = 0;
1977                 if (!is_duration ($1))
1978                         THIS->parser_error (_f ("not a duration: %d", $1));
1979                 else
1980                         len = intlog2 ($1);
1981
1982                 $$ = Duration (len, $2).smobbed_copy ();
1983         }
1984         | DURATION_IDENTIFIER dots      {
1985                 Duration *d = unsmob_duration ($1);
1986                 Duration k (d->duration_log (), d->dot_count () + $2);
1987                 *d = k;
1988                 $$ = $1;
1989         }
1990         ;
1991
1992 multiplied_duration:
1993         steno_duration {
1994                 $$ = $1;
1995         }
1996         | multiplied_duration '*' bare_unsigned {
1997                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1998         }
1999         | multiplied_duration '*' FRACTION {
2000                 Rational  m (scm_to_int (ly_car ($3)), scm_to_int (ly_cdr ($3)));
2001
2002                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2003         }
2004         ;
2005
2006 fraction:
2007         FRACTION { $$ = $1; }
2008         | UNSIGNED '/' UNSIGNED {
2009                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2010         }
2011         ;
2012
2013 dots:
2014         /* empty */     {
2015                 $$ = 0;
2016         }
2017         | dots '.' {
2018                 $$ ++;
2019         }
2020         ;
2021
2022 tremolo_type:
2023         ':'     {
2024                 $$ = 0;
2025         }
2026         | ':' bare_unsigned {
2027                 if (!is_duration ($2))
2028                         THIS->parser_error (_f ("not a duration: %d", $2));
2029                 $$ = $2;
2030         }
2031         ;
2032
2033 bass_number:
2034         DIGIT   {
2035                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2036                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2037                                 $$);
2038         }
2039         | UNSIGNED {
2040                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2041                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2042                                 $$);
2043         }
2044         | STRING { $$ = $1; }
2045         ;
2046
2047 bass_mod:
2048         '-'     { $$ = -2; }
2049         | '+'   { $$ = 2; }
2050         | '!'   { $$ = 0; }
2051         ;
2052
2053 bass_figure:
2054         FIGURE_SPACE {
2055                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2056                 $$ = bfr->self_scm ();
2057                 scm_gc_unprotect_object ($$);
2058         }
2059         | bass_number  {
2060                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2061                 $$ = bfr->self_scm ();
2062
2063                 bfr->set_property ("figure", $1);
2064
2065                 scm_gc_unprotect_object ($$);
2066         }
2067         | bass_figure bass_mod {
2068                 Music *m = unsmob_music ($1);
2069                 if ($2) {
2070                         SCM salter = m->get_property ("alteration");
2071                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2072                         m->set_property ("alteration",
2073                                 scm_int2num (alter + $2));
2074                 } else {
2075                         m->set_property ("alteration", scm_int2num (0));
2076                 }
2077         }
2078         ;
2079
2080 br_bass_figure:
2081         '[' bass_figure {
2082                 $$ = $2;
2083                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2084         }
2085         | bass_figure   {
2086                 $$ = $1;
2087         }
2088         | br_bass_figure ']' {
2089                 $$ = $1;
2090                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2091         }
2092         ;
2093
2094 figure_list:
2095         /**/            {
2096                 $$ = SCM_EOL;
2097         }
2098         | figure_list br_bass_figure {
2099                 $$ = scm_cons ($2, $1);
2100         }
2101         ;
2102
2103 figure_spec:
2104         FIGURE_OPEN figure_list FIGURE_CLOSE {
2105                 Music *m = MY_MAKE_MUSIC ("EventChord");
2106                 $2 = scm_reverse_x ($2, SCM_EOL);
2107                 m->set_property ("elements", $2);
2108                 $$ = m->self_scm ();
2109         }
2110         ;
2111
2112
2113 optional_rest:
2114         /**/   { $$ = 0; }
2115         | REST { $$ = 1; }
2116         ;
2117
2118 simple_element:
2119         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2120
2121                 Input i = THIS->pop_spot ();
2122                 if (!THIS->lexer_->is_note_state ())
2123                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2124
2125                 Music *n = 0;
2126                 if ($6)
2127                         n = MY_MAKE_MUSIC ("RestEvent");
2128                 else
2129                         n = MY_MAKE_MUSIC ("NoteEvent");
2130
2131                 n->set_property ("pitch", $1);
2132                 n->set_property ("duration", $5);
2133
2134                 if (scm_is_number ($4))
2135                 {
2136                         int q = scm_to_int ($4);
2137                         n->set_property ("absolute-octave", scm_int2num (q-1));
2138                 }
2139
2140                 if ($3 % 2)
2141                         n->set_property ("cautionary", SCM_BOOL_T);
2142                 if ($2 % 2 || $3 % 2)
2143                         n->set_property ("force-accidental", SCM_BOOL_T);
2144
2145                 Music *v = MY_MAKE_MUSIC ("EventChord");
2146                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2147                 scm_gc_unprotect_object (n->self_scm ());
2148
2149                 v->set_spot (i);
2150                 n->set_spot (i);
2151                 $$ = v;
2152         }
2153         | DRUM_PITCH optional_notemode_duration {
2154                 Input i = THIS->pop_spot ();
2155
2156                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2157                 n->set_property ("duration", $2);
2158                 n->set_property ("drum-type", $1);
2159
2160                 Music *v = MY_MAKE_MUSIC ("EventChord");
2161                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2162                 scm_gc_unprotect_object (n->self_scm ());
2163                 v->set_spot (i);
2164                 n->set_spot (i);
2165                 $$ = v;
2166
2167         }
2168         | figure_spec optional_notemode_duration {
2169                 Music *m = unsmob_music ($1);
2170                 Input i = THIS->pop_spot ();
2171                 m->set_spot (i);
2172                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2173                 {
2174                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2175                 }
2176                 $$ = m;
2177         }
2178         | RESTNAME optional_notemode_duration           {
2179
2180                 Input i = THIS->pop_spot ();
2181                 Music *ev = 0;
2182                 if (ly_scm2string ($1) == "s") {
2183                         /* Space */
2184                         ev = MY_MAKE_MUSIC ("SkipEvent");
2185                   }
2186                 else {
2187                         ev = MY_MAKE_MUSIC ("RestEvent");
2188
2189                     }
2190                 ev->set_property ("duration", $2);
2191                 ev->set_spot (i);
2192                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2193                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2194                 velt->set_spot (i);
2195
2196                 scm_gc_unprotect_object (ev->self_scm ());
2197
2198                 $$ = velt;
2199         }
2200         | MULTI_MEASURE_REST optional_notemode_duration         {
2201                 THIS->pop_spot ();
2202
2203                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2204                 SCM mus = scm_call_2 (proc, $2,
2205                         make_input (THIS->here_input ()));
2206                 scm_gc_protect_object (mus);
2207                 $$ = unsmob_music (mus);
2208         }
2209
2210         | lyric_element optional_notemode_duration      {
2211                 Input i = THIS->pop_spot ();
2212                 if (!THIS->lexer_->is_lyric_state ())
2213                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2214
2215                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2216                 lreq->set_property ("text", $1);
2217                 lreq->set_property ("duration",$2);
2218                 lreq->set_spot (i);
2219                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2220                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2221
2222                 $$= velt;
2223         }
2224         | new_chord {
2225                 THIS->pop_spot ();
2226
2227                 if (!THIS->lexer_->is_chord_state ())
2228                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2229                 $$ = unsmob_music ($1);
2230         }
2231         ;
2232
2233 lyric_element:
2234         /* FIXME: lyric flavoured markup would be better */
2235         full_markup {
2236                 $$ = $1;
2237         }
2238         | LYRICS_STRING {
2239                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2240         }
2241         ;
2242
2243 new_chord:
2244         steno_tonic_pitch optional_notemode_duration   {
2245                 $$ = make_chord ($1, $2, SCM_EOL);
2246         }
2247         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2248                 SCM its = scm_reverse_x ($4, SCM_EOL);
2249                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2250         }
2251         ;
2252
2253 chord_items:
2254         /**/ {
2255                 $$ = SCM_EOL;
2256         }
2257         | chord_items chord_item {
2258                 $$ = scm_cons ($2, $$);
2259         }
2260         ;
2261
2262 chord_separator:
2263         CHORD_COLON {
2264                 $$ = ly_symbol2scm ("chord-colon");
2265         }
2266         | CHORD_CARET {
2267                 $$ = ly_symbol2scm ("chord-caret");
2268         }
2269         | CHORD_SLASH steno_tonic_pitch {
2270                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2271         }
2272         | CHORD_BASS steno_tonic_pitch {
2273                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2274         }
2275         ;
2276
2277 chord_item:
2278         chord_separator {
2279                 $$ = $1;
2280         }
2281         | step_numbers {
2282                 $$ = scm_reverse_x ($1, SCM_EOL);
2283         }
2284         | CHORD_MODIFIER  {
2285                 $$ = $1;
2286         }
2287         ;
2288
2289 step_numbers:
2290         step_number { $$ = scm_cons ($1, SCM_EOL); }
2291         | step_numbers '.' step_number {
2292                 $$ = scm_cons ($3, $$);
2293         }
2294         ;
2295
2296 step_number:
2297         bare_unsigned {
2298                 $$ = make_chord_step ($1, 0);
2299         }
2300         | bare_unsigned '+' {
2301                 $$ = make_chord_step ($1, SHARP);
2302         }
2303         | bare_unsigned CHORD_MINUS {
2304                 $$ = make_chord_step ($1, FLAT);
2305         }
2306         ;
2307
2308 /*
2309         UTILITIES
2310
2311 TODO: should deprecate in favor of Scheme?
2312
2313  */
2314 number_expression:
2315         number_expression '+' number_term {
2316                 $$ = scm_sum ($1, $3);
2317         }
2318         | number_expression '-' number_term {
2319                 $$ = scm_difference ($1, $3);
2320         }
2321         | number_term
2322         ;
2323
2324 number_term:
2325         number_factor {
2326                 $$ = $1;
2327         }
2328         | number_factor '*' number_factor {
2329                 $$ = scm_product ($1, $3);
2330         }
2331         | number_factor '/' number_factor {
2332                 $$ = scm_divide ($1, $3);
2333         }
2334         ;
2335
2336 number_factor:
2337         '-'  number_factor { /* %prec UNARY_MINUS */
2338                 $$ = scm_difference ($2, SCM_UNDEFINED);
2339         }
2340         | bare_number
2341         ;
2342
2343
2344 bare_number:
2345         UNSIGNED        {
2346                 $$ = scm_int2num ($1);
2347         }
2348         | REAL          {
2349                 $$ = $1;
2350         }
2351         | NUMBER_IDENTIFIER             {
2352                 $$ = $1;
2353         }
2354         | REAL NUMBER_IDENTIFIER        {
2355                 $$ = scm_make_real (scm_to_double ($1) *scm_to_double ($2));
2356         }
2357         | UNSIGNED NUMBER_IDENTIFIER    {
2358                 $$ = scm_make_real ($1 *scm_to_double ($2));
2359         }
2360         ;
2361
2362
2363 bare_unsigned:
2364         UNSIGNED {
2365                         $$ = $1;
2366         }
2367         | DIGIT {
2368                 $$ = $1;
2369         }
2370         ;
2371
2372 bare_int:
2373         bare_number {
2374                 if (scm_integer_p ($1) == SCM_BOOL_T)
2375                 {
2376                         int k = scm_to_int ($1);
2377                         $$ = k;
2378                 } else
2379                 {
2380                         THIS->parser_error (_ ("need integer number arg"));
2381                         $$ = 0;
2382                 }
2383         }
2384         | '-' bare_int {
2385                 $$ = -$2;
2386         }
2387         ;
2388
2389 exclamations:
2390                 { $$ = 0; }
2391         | exclamations '!'      { $$ ++; }
2392         ;
2393
2394 questions:
2395                 { $$ = 0; }
2396         | questions '?' { $$ ++; }
2397         ;
2398
2399
2400
2401 full_markup:
2402         MARKUP_IDENTIFIER {
2403                 $$ = $1;
2404         }
2405         | MARKUP
2406                 { THIS->lexer_->push_markup_state (); }
2407         markup
2408                 { $$ = $3;
2409                   THIS->lexer_->pop_state ();
2410                 }
2411         ;
2412
2413
2414 /*
2415 This should be done more dynamically if possible.
2416 */
2417 markup:
2418         STRING {
2419                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2420         }
2421         | MARKUP_HEAD_EMPTY {
2422                 $$ = scm_list_1 ($1);
2423         }
2424         | MARKUP_HEAD_MARKUP0 markup {
2425                 $$ = scm_list_2 ($1, $2);
2426         }
2427         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2428                 $$ = scm_list_3 ($1, $2, $3);
2429         }
2430         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2431                 $$ = scm_list_3 ($1, $2, $3);
2432         }
2433         | markup_line {
2434                 $$ = $1;
2435         }
2436         | MARKUP_HEAD_LIST0 markup_list {
2437                 $$ = scm_list_2 ($1,$2);
2438         }
2439         | MARKUP_HEAD_SCM0 embedded_scm {
2440                 $$ = scm_list_2 ($1, $2);
2441         }
2442         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2443                 $$ = scm_list_4 ($1, $2, $3, $4);
2444         }
2445         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2446                 $$ = scm_list_4 ($1, $2, $3, $4);
2447         }
2448         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2449                 $$ = scm_list_3 ($1, $2, $3);
2450         }
2451         | MARKUP_IDENTIFIER {
2452                 $$ = $1;
2453         }
2454         | STRING_IDENTIFIER {
2455                 $$ = $1;
2456         }
2457         | SCORE {
2458                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2459                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2460         } '{' score_body '}' {
2461                 Score * sc = $4;
2462                 $$ = scm_list_2 (ly_scheme_function ("score-markup"), sc->self_scm ());
2463                 scm_gc_unprotect_object (sc->self_scm ());
2464                 THIS->lexer_->pop_state ();
2465         }
2466         ;
2467
2468 markup_list:
2469         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2470         ;
2471
2472 markup_line:
2473         '{' markup_list_body '}' {
2474                 SCM line = ly_scheme_function ("line-markup");
2475
2476                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2477         }
2478         ;
2479
2480 markup_list_body:
2481         /**/ {  $$ = SCM_EOL; }
2482         | markup_list_body markup {
2483                 $$ = scm_cons ($2, $1);
2484         }
2485         ;
2486
2487
2488 %%
2489
2490 void
2491 Lily_parser::set_yydebug (bool )
2492 {
2493 #if 0
2494         yydebug = 1;
2495 #endif
2496 }
2497
2498 void
2499 Lily_parser::do_yyparse ()
2500 {
2501         yyparse ((void*)this);
2502 }
2503
2504
2505 /*
2506 Should make this optional?    It will also complain when you do
2507
2508         [s4]
2509
2510 which is entirely legitimate.
2511
2512 Or we can scrap it. Barchecks should detect wrong durations, and
2513 skipTypesetting speeds it up a lot.
2514 */
2515
2516 void
2517 Lily_parser::beam_check (SCM dur)
2518 {
2519   Duration *d = unsmob_duration (dur);
2520   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2521     {
2522       Music *m = unsmob_music (last_beam_start_);
2523       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2524     }
2525   last_beam_start_ = SCM_EOL;
2526 }
2527
2528
2529
2530
2531 /*
2532
2533 It is a little strange to have this function in this file, but
2534 otherwise, we have to import music classes into the lexer.
2535
2536 */
2537 int
2538 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2539 {
2540         if (scm_is_string (sid)) {
2541                 *destination = sid;
2542                 return STRING_IDENTIFIER;
2543         } else if (scm_is_number (sid)) {
2544                 *destination = sid;
2545                 return NUMBER_IDENTIFIER;
2546         } else if (unsmob_context_def (sid)) {
2547                 *destination = unsmob_context_def (sid)->clone_scm ();
2548                 return CONTEXT_DEF_IDENTIFIER;
2549         } else if (unsmob_score (sid)) {
2550                 Score *score = new Score (*unsmob_score (sid));
2551                 *destination = score->self_scm ();
2552                 return SCORE_IDENTIFIER;
2553         } else if (Music *mus = unsmob_music (sid)) {
2554                 mus = mus->clone ();
2555                 *destination = mus->self_scm ();
2556                 unsmob_music (*destination)->
2557                         set_property ("origin", make_input (last_input_));
2558                 return dynamic_cast<Event*> (mus)
2559                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2560         } else if (unsmob_duration (sid)) {
2561                 *destination = unsmob_duration (sid)->smobbed_copy ();
2562                 return DURATION_IDENTIFIER;
2563         } else if (unsmob_output_def (sid)) {
2564                 Output_def *p = unsmob_output_def (sid);
2565                 p = p->clone ();
2566
2567                 *destination = p->self_scm ();
2568                 return OUTPUT_DEF_IDENTIFIER;
2569         } else if (Text_item::markup_p (sid)) {
2570                 *destination = sid;
2571                 return MARKUP_IDENTIFIER;
2572         }
2573
2574         return -1;
2575 }
2576
2577 Music *
2578 property_op_to_music (SCM op)
2579 {
2580         Music *m = 0;
2581         SCM tag = ly_car (op);
2582         SCM symbol = ly_cadr (op);
2583         SCM args = ly_cddr (op);
2584         SCM grob_val = SCM_UNDEFINED;
2585         SCM grob_sym = SCM_UNDEFINED;
2586         SCM val = SCM_UNDEFINED;
2587
2588         if (tag == ly_symbol2scm ("assign"))
2589                 {
2590                 m = MY_MAKE_MUSIC ("PropertySet");
2591                 val = ly_car (args);
2592                 }
2593         else if (tag == ly_symbol2scm ("unset"))
2594                 m = MY_MAKE_MUSIC ("PropertyUnset");
2595         else if (tag == ly_symbol2scm ("poppush")
2596                  || tag == ly_symbol2scm ("push"))
2597                 {
2598                 m = MY_MAKE_MUSIC ("OverrideProperty");
2599                 grob_sym = ly_car (args);
2600                 grob_val = ly_cadr (args);
2601                 }
2602         else if (tag == ly_symbol2scm ("pop")) {
2603                 m = MY_MAKE_MUSIC ("RevertProperty");
2604                 grob_sym = ly_car (args);
2605                 }
2606
2607         m->set_property ("symbol", symbol);
2608
2609         if (val != SCM_UNDEFINED)
2610                 m->set_property ("value", val);
2611         if (grob_val != SCM_UNDEFINED)
2612                 m->set_property ("grob-value", grob_val);
2613
2614         if (grob_sym != SCM_UNDEFINED)
2615                 {
2616                 bool itc = internal_type_checking_global_b;
2617                 /* UGH.
2618                 */
2619                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2620                 if (autobeam)
2621                         internal_type_checking_global_b = false;
2622                 m->set_property ("grob-property", grob_sym);
2623                 if (autobeam)
2624                         internal_type_checking_global_b = itc;
2625                 }
2626
2627         if (tag == ly_symbol2scm ("poppush"))
2628                 m->set_property ("pop-first", SCM_BOOL_T);
2629
2630
2631         return m;
2632 }
2633
2634 Music*
2635 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2636 {
2637         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2638
2639         csm->set_property ("element", m->self_scm ());
2640         scm_gc_unprotect_object (m->self_scm ());
2641
2642         csm->set_property ("context-type",
2643                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2644         csm->set_property ("property-operations", ops);
2645
2646         if (scm_is_string (id))
2647                 csm->set_property ("context-id", id);
2648         return csm;
2649 }
2650
2651 SCM
2652 get_next_unique_context ()
2653 {
2654         static int new_context_count;
2655         char s[1024];
2656         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2657         return scm_makfrom0str (s);
2658 }
2659