lily/parser.yy

   1 /*
   2   parser.yy -- Bison/C++ parser for LilyPond
   3
   4   source file of the GNU LilyPond music typesetter
   5
   6   (c) 1997--2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7                  Jan Nieuwenhuizen <janneke@gnu.org>
   8 */
   9
  10 %{
  11
  12 #define YYERROR_VERBOSE 1
  13 #define YYPARSE_PARAM my_lily_parser
  14 #define YYLEX_PARAM my_lily_parser
  15 #define PARSER ((Lily_parser *) my_lily_parser)
  16
  17 #define yyerror PARSER->parser_error
  18
  19 /* We use custom location type: Input objects */
  20 #define YYLTYPE Input
  21 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  22         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  23
  24
  25 %}
  26
  27 /* We use SCMs to do strings, because it saves us the trouble of
  28 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  29 of the parse stack onto the heap. */
  30
  31 %left PREC_TOP
  32 %left ADDLYRICS
  33 %left PREC_BOT
  34
  35 %expect 1
  36
  37 /* One shift/reduce problem
  38
  39 1.  \repeat
  40         \repeat .. \alternative
  41
  42     \repeat { \repeat .. \alternative }
  43
  44 or
  45
  46     \repeat { \repeat } \alternative
  47 */
  48
  49
  50 %pure_parser
  51 %locations
  52
  53
  54
  55 %{ // -*-Fundamental-*-
  56
  57 /*
  58 FIXME:
  59
  60    * The rules for who is protecting what are very shady.  Uniformise
  61      this.
  62
  63    * There are too many lexical modes?
  64 */
  65
  66 #include "config.hh"
  67
  68 #include <cctype>
  69 #include <cstdlib>
  70 #include <cstdio>
  71 using namespace std;
  72
  73 #include "book.hh"
  74 #include "context-def.hh"
  75 #include "dimensions.hh"
  76 #include "file-path.hh"
  77 #include "input-smob.hh"
  78 #include "input.hh"
  79 #include "international.hh"
  80 #include "lily-guile.hh"
  81 #include "lily-lexer.hh"
  82 #include "lily-parser.hh"
  83 #include "lilypond-input-version.hh"
  84 #include "main.hh"
  85 #include "misc.hh"
  86 #include "music.hh"
  87 #include "music.hh"
  88 #include "output-def.hh"
  89 #include "paper-book.hh"
  90 #include "program-option.hh"
  91 #include "scm-hash.hh"
  92 #include "score.hh"
  93 #include "text-interface.hh"
  94 #include "warn.hh"
  95
  96 %}
  97
  98
  99 %union {
 100         Book *book;
 101         Output_def *outputdef;
 102         SCM scm;
 103         std::string *string;
 104         Music *music;
 105         Score *score;
 106         int i;
 107 }
 108
 109 %{
 110
 111 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
 112
 113 /* ES TODO:
 114 - Don't use lily module, create a new module instead.
 115 - delay application of the function
 116 */
 117 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 118   scm_apply_0 (proc, args)
 119 /* Syntactic Sugar. */
 120 #define MAKE_SYNTAX(name, location, ...)        \
 121   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (PARSER->self_scm (), make_input (location), __VA_ARGS__, SCM_UNDEFINED));
 122
 123 SCM get_next_unique_context_id ();
 124 SCM get_next_unique_lyrics_context_id ();
 125
 126 #undef _
 127 #if !HAVE_GETTEXT
 128 #define _(x) x
 129 #else
 130 #include <libintl.h>
 131 #define _(x) gettext (x)
 132 #endif
 133
 134
 135
 136 SCM make_music_relative (Pitch start, SCM music);
 137 SCM run_music_function (Lily_parser *, SCM expr);
 138 SCM get_first_context_id (SCM type, Music *m);
 139 SCM make_chord_elements (SCM pitch, SCM dur, SCM modification_list);
 140 SCM make_chord_step (int step, int alter);
 141 SCM make_simple_markup (SCM a);
 142 bool is_duration (int t);
 143 bool is_regular_identifier (SCM id);
 144 bool ly_input_procedure_p (SCM x);
 145 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 146 void set_music_properties (Music *p, SCM a);
 147
 148 %}
 149
 150 /* The third option is an alias that will be used to display the
 151    syntax error.  Bison CVS now correctly handles backslash escapes.
 152
 153    FIXME: Bison needs to translate some of these, eg, STRING.
 154
 155 */
 156
 157 /* Keyword tokens with plain escaped name.  */
 158 %token ACCEPTS "\\accepts"
 159 %token ADDLYRICS "\\addlyrics"
 160 %token ADDQUOTE "\\addquote"
 161 %token ALIAS "\\alias"
 162 %token ALTERNATIVE "\\alternative"
 163 %token BOOK "\\book"
 164 %token CHANGE "\\change"
 165 %token CHORDMODE "\\chordmode"
 166 %token CHORDS "\\chords"
 167 %token CONSISTS "\\consists"
 168 %token CONTEXT "\\context"
 169 %token DEFAULT "\\default"
 170 %token DEFAULTCHILD "\\defaultchild"
 171 %token DENIES "\\denies"
 172 %token DESCRIPTION "\\description"
 173 %token DRUMMODE "\\drummode"
 174 %token DRUMS "\\drums"
 175 %token FIGUREMODE "\\figuremode"
 176 %token FIGURES "\\figures"
 177 %token GROBDESCRIPTIONS "\\grobdescriptions"
 178 %token HEADER "\\header"
 179 %token INVALID "\\invalid"
 180 %token KEY "\\key"
 181 %token LAYOUT "\\layout"
 182 %token LYRICMODE "\\lyricmode"
 183 %token LYRICS "\\lyrics"
 184 %token LYRICSTO "\\lyricsto"
 185 %token MARK "\\mark"
 186 %token MARKUP "\\markup"
 187 %token MIDI "\\midi"
 188 %token NAME "\\name"
 189 %token NOTEMODE "\\notemode"
 190 %token OBJECTID "\\objectid"
 191 %token OCTAVE "\\octave"
 192 %token ONCE "\\once"
 193 %token OVERRIDE "\\override"
 194 %token PAPER "\\paper"
 195 %token PARTIAL "\\partial"
 196 %token RELATIVE "\\relative"
 197 %token REMOVE "\\remove"
 198 %token REPEAT "\\repeat"
 199 %token REST "\\rest"
 200 %token REVERT "\\revert"
 201 %token SCORE "\\score"
 202 %token SEQUENTIAL "\\sequential"
 203 %token SET "\\set"
 204 %token SIMULTANEOUS "\\simultaneous"
 205 %token SKIP "\\skip"
 206 %token TEMPO "\\tempo"
 207 %token TIMES "\\times"
 208 %token TRANSPOSE "\\transpose"
 209 %token TYPE "\\type"
 210 %token UNSET "\\unset"
 211 %token WITH "\\with"
 212
 213 /* Keyword token exceptions.  */
 214 %token TIME_T "\\time"
 215 %token NEWCONTEXT "\\new"
 216
 217
 218 /* Other string tokens.  */
 219
 220 %token CHORD_BASS "/+"
 221 %token CHORD_CARET "^"
 222 %token CHORD_COLON ":"
 223 %token CHORD_MINUS "-"
 224 %token CHORD_SLASH "/"
 225 %token ANGLE_OPEN "<"
 226 %token ANGLE_CLOSE ">"
 227 %token DOUBLE_ANGLE_OPEN "<<"
 228 %token DOUBLE_ANGLE_CLOSE ">>"
 229 %token E_BACKSLASH "\\"
 230 %token E_ANGLE_CLOSE "\\>"
 231 %token E_CHAR "\\C[haracter]"
 232 %token E_CLOSE "\\)"
 233 %token E_EXCLAMATION "\\!"
 234 %token E_BRACKET_OPEN "\\["
 235 %token E_OPEN "\\("
 236 %token E_BRACKET_CLOSE "\\]"
 237 %token E_ANGLE_OPEN "\\<"
 238 %token E_PLUS "\\+"
 239 %token E_TILDE "\\~"
 240 %token EXTENDER "__"
 241
 242 /*
 243 If we give names, Bison complains.
 244 */
 245 %token FIGURE_CLOSE /* "\\>" */
 246 %token FIGURE_OPEN /* "\\<" */
 247 %token FIGURE_SPACE "_"
 248 %token HYPHEN "--"
 249
 250 %token CHORDMODIFIERS
 251 %token LYRIC_MARKUP
 252 %token MULTI_MEASURE_REST
 253
 254
 255 %token <i> DIGIT
 256 %token <i> E_UNSIGNED
 257 %token <i> UNSIGNED
 258
 259 %token <scm> BOOK_IDENTIFIER
 260 %token <scm> CHORDMODIFIER_PITCH
 261 %token <scm> CHORD_MODIFIER
 262 %token <scm> CONTEXT_DEF_IDENTIFIER
 263 %token <scm> DRUM_PITCH
 264 %token <scm> DURATION_IDENTIFIER
 265 %token <scm> EVENT_IDENTIFIER
 266 %token <scm> FRACTION
 267 %token <scm> LYRICS_STRING
 268 %token <scm> LYRIC_MARKUP_IDENTIFIER
 269 %token <scm> MARKUP_HEAD_EMPTY
 270 %token <scm> MARKUP_HEAD_LIST0
 271 %token <scm> MARKUP_HEAD_MARKUP0
 272 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 273 %token <scm> MARKUP_HEAD_SCM0
 274 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 275 %token <scm> MARKUP_HEAD_SCM0_SCM1
 276 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 277 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 278 %token <scm> MARKUP_IDENTIFIER
 279 %token <scm> MUSIC_FUNCTION
 280 %token <scm> MUSIC_FUNCTION_MARKUP
 281 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 282 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 283 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 284 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 285 %token <scm> MUSIC_FUNCTION_MUSIC
 286 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 287 %token <scm> MUSIC_FUNCTION_SCM
 288 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 289 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 290 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC_MUSIC
 291 %token <scm> MUSIC_FUNCTION_SCM_SCM
 292 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 293 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM
 294 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM_MUSIC
 295 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM_SCM_MUSIC
 296 %token <scm> MUSIC_IDENTIFIER
 297 %token <scm> NOTENAME_PITCH
 298 %token <scm> NUMBER_IDENTIFIER
 299 %token <scm> OUTPUT_DEF_IDENTIFIER
 300 %token <scm> REAL
 301 %token <scm> RESTNAME
 302 %token <scm> SCM_IDENTIFIER
 303 %token <scm> SCM_TOKEN
 304 %token <scm> SCORE_IDENTIFIER
 305 %token <scm> STRING
 306 %token <scm> STRING_IDENTIFIER
 307 %token <scm> TONICNAME_PITCH
 308
 309
 310 %type <book> book_block
 311 %type <book> book_body
 312
 313 %type <i> bare_unsigned
 314 %type <i> figured_bass_alteration
 315 %type <i> dots
 316 %type <i> exclamations
 317 %type <i> optional_rest
 318 %type <i> questions
 319 %type <i> script_dir
 320 %type <i> sub_quotes
 321 %type <i> sup_quotes
 322 %type <i> tremolo_type
 323
 324 /* Music */
 325 %type <scm> composite_music
 326 %type <scm> grouped_music_list
 327 %type <scm> music
 328 %type <scm> prefix_composite_music
 329 %type <scm> repeated_music
 330 %type <scm> sequential_music
 331 %type <scm> simple_music
 332 %type <scm> simultaneous_music
 333 %type <scm> chord_body
 334 %type <scm> chord_body_element
 335 %type <scm> command_element
 336 %type <scm> command_event
 337 %type <scm> context_change
 338 %type <scm> direction_less_event
 339 %type <scm> direction_reqd_event
 340 %type <scm> event_chord
 341 %type <scm> gen_text_def
 342 %type <scm> music_property_def
 343 %type <scm> note_chord_element
 344 %type <scm> post_event
 345 %type <scm> re_rhythmed_music
 346 %type <scm> relative_music
 347 %type <scm> simple_element
 348 %type <scm> simple_music_property_def
 349 %type <scm> string_number_event
 350 %type <scm> tempo_event
 351
 352 %type <outputdef> output_def_body
 353 %type <outputdef> output_def_head
 354 %type <outputdef> output_def_head_with_mode_switch
 355 %type <outputdef> output_def
 356 %type <outputdef> paper_block
 357
 358 %type <scm> alternative_music
 359 %type <scm> generic_prefix_music_scm
 360 %type <scm> music_list
 361 %type <scm> absolute_pitch
 362 %type <scm> assignment_id
 363 %type <scm> bare_number
 364 %type <scm> music_function_event
 365 %type <scm> music_function_chord_body
 366 %type <scm> music_function_musicless_prefix
 367 %type <scm> music_function_musicless_function
 368 %type <scm> bass_figure
 369 %type <scm> figured_bass_modification
 370 %type <scm> br_bass_figure
 371 %type <scm> bass_number
 372 %type <scm> chord_body_elements
 373 %type <scm> chord_item
 374 %type <scm> chord_items
 375 %type <scm> chord_separator
 376 %type <scm> context_def_mod
 377 %type <scm> context_def_spec_block
 378 %type <scm> context_def_spec_body
 379 %type <scm> context_mod
 380 %type <scm> context_mod_list
 381 %type <scm> context_prop_spec
 382 %type <scm> direction_less_char
 383 %type <scm> duration_length
 384 %type <scm> embedded_scm
 385 %type <scm> figure_list
 386 %type <scm> figure_spec
 387 %type <scm> fraction
 388 %type <scm> full_markup
 389 %type <scm> identifier_init
 390 %type <scm> lilypond_header
 391 %type <scm> lilypond_header_body
 392 %type <scm> lyric_element
 393 %type <scm> lyric_markup
 394 %type <scm> markup
 395 %type <scm> markup_braced_list
 396 %type <scm> markup_braced_list_body
 397 %type <scm> markup_composed_list
 398 %type <scm> markup_head_1_item
 399 %type <scm> markup_head_1_list
 400 %type <scm> markup_list
 401 %type <scm> markup_top
 402 %type <scm> mode_changing_head
 403 %type <scm> mode_changing_head_with_context
 404 %type <scm> multiplied_duration
 405 %type <scm> new_chord
 406 %type <scm> new_lyrics
 407 %type <scm> number_expression
 408 %type <scm> number_factor
 409 %type <scm> number_term
 410 %type <scm> object_id_setting
 411 %type <scm> octave_check
 412 %type <scm> optional_context_mod
 413 %type <scm> optional_id
 414 %type <scm> optional_notemode_duration
 415 %type <scm> pitch
 416 %type <scm> pitch_also_in_chords
 417 %type <scm> post_events
 418 %type <scm> property_operation
 419 %type <scm> scalar
 420 %type <scm> script_abbreviation
 421 %type <scm> simple_chord_elements
 422 %type <scm> simple_markup
 423 %type <scm> simple_string
 424 %type <scm> steno_duration
 425 %type <scm> steno_pitch
 426 %type <scm> steno_tonic_pitch
 427 %type <scm> step_number
 428 %type <scm> step_numbers
 429 %type <scm> string
 430 %type <scm> function_scm_argument
 431
 432 %type <score> score_block
 433 %type <score> score_body
 434
 435
 436 %left '-' '+'
 437
 438 /* We don't assign precedence to / and *, because we might need varied
 439 prec levels in different prods */
 440
 441 %left UNARY_MINUS
 442
 443 %%
 444
 445 lilypond:       /* empty */
 446         | lilypond toplevel_expression {
 447         }
 448         | lilypond assignment {
 449         }
 450         | lilypond error {
 451                 PARSER->error_level_ = 1;
 452         }
 453         | lilypond INVALID      {
 454                 PARSER->error_level_ = 1;
 455         }
 456         ;
 457
 458
 459 object_id_setting:
 460         OBJECTID STRING { $$ = $2; }
 461         ;
 462
 463 toplevel_expression:
 464         lilypond_header {
 465                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 466         }
 467         | book_block {
 468                 Book *book = $1;
 469                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 470                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 471                 book->unprotect ();
 472         }
 473         | score_block {
 474                 Score *score = $1;
 475
 476                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 477                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 478                 score->unprotect ();
 479         }
 480         | composite_music {
 481                 Music *music = unsmob_music ($1);
 482                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 483                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 484         }
 485         | full_markup {
 486                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 487                 scm_call_2 (proc, PARSER->self_scm (), $1);
 488         }
 489         | output_def {
 490                 SCM id = SCM_EOL;
 491                 Output_def * od = $1;
 492
 493                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 494                         id = ly_symbol2scm ("$defaultpaper");
 495                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 496                         id = ly_symbol2scm ("$defaultmidi");
 497                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 498                         id = ly_symbol2scm ("$defaultlayout");
 499
 500                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 501                 od->unprotect();
 502         }
 503         ;
 504
 505 embedded_scm:
 506         SCM_TOKEN
 507         | SCM_IDENTIFIER
 508         ;
 509
 510
 511 lilypond_header_body:
 512         {
 513                 $$ = get_header(PARSER);
 514                 PARSER->lexer_->add_scope ($$);
 515         }
 516         | lilypond_header_body assignment  {
 517
 518         }
 519         ;
 520
 521 lilypond_header:
 522         HEADER '{' lilypond_header_body '}'     {
 523                 $$ = PARSER->lexer_->remove_scope ();
 524         }
 525         ;
 526
 527 /*
 528         DECLARATIONS
 529 */
 530 assignment_id:
 531         STRING          { $$ = $1; }
 532         | LYRICS_STRING { $$ = $1; }
 533         ;
 534
 535 assignment:
 536         assignment_id '=' identifier_init  {
 537                 PARSER->lexer_->set_identifier ($1, $3);
 538
 539 /*
 540  TODO: devise standard for protection in parser.
 541
 542   The parser stack lives on the C-stack, which means that
 543 all objects can be unprotected as soon as they're here.
 544
 545 */
 546         }
 547         | embedded_scm { }
 548         ;
 549
 550
 551 identifier_init:
 552         score_block {
 553                 $$ = $1->self_scm ();
 554                 $1->unprotect ();
 555         }
 556         | book_block {
 557                 $$ = $1->self_scm ();
 558                 $1->unprotect ();
 559         }
 560         | output_def {
 561                 $$ = $1->self_scm ();
 562                 $1->unprotect ();
 563         }
 564         | context_def_spec_block {
 565                 $$ = $1;
 566         }
 567         | music  {
 568                 /* Hack: Create event-chord around standalone events.
 569                    Prevents the identifier from being interpreted as a post-event. */
 570                 Music *mus = unsmob_music ($1);
 571                 bool is_event = mus &&
 572                         (scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
 573                                 != SCM_BOOL_F);
 574                 if (!is_event)
 575                         $$ = $1;
 576                 else
 577                         $$ = MAKE_SYNTAX ("event-chord", @$, scm_list_1 ($1));
 578         }
 579         | post_event {
 580                 $$ = $1;
 581         }
 582         | number_expression {
 583                 $$ = $1;
 584         }
 585         | string {
 586                 $$ = $1;
 587         }
 588         | embedded_scm {
 589                 $$ = $1;
 590         }
 591         | full_markup {
 592                 $$ = $1;
 593         }
 594         | DIGIT {
 595                 $$ = scm_from_int ($1);
 596         }
 597         ;
 598
 599 context_def_spec_block:
 600         CONTEXT '{' context_def_spec_body '}'
 601                 {
 602                 $$ = $3;
 603         }
 604         ;
 605
 606 context_def_spec_body:
 607         /**/ {
 608                 $$ = Context_def::make_scm ();
 609                 unsmob_context_def ($$)->set_spot (@$);
 610         }
 611         | CONTEXT_DEF_IDENTIFIER {
 612                 $$ = $1;
 613                 unsmob_context_def ($$)->set_spot (@$);
 614         }
 615         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 616                 Context_def*td = unsmob_context_def ($$);
 617
 618                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 619                         SCM tag = scm_caar (p);
 620
 621                         /* TODO: should make new tag "grob-definition" ? */
 622                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 623                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 624                 }
 625         }
 626         | context_def_spec_body context_mod {
 627                 unsmob_context_def ($$)->add_context_mod ($2);
 628         }
 629         ;
 630
 631
 632
 633 book_block:
 634         BOOK '{' book_body '}'  {
 635                 $$ = $3;
 636         }
 637         ;
 638
 639 /* FIXME:
 640    * Use 'handlers' like for toplevel-* stuff?
 641    * grok \layout and \midi?  */
 642 book_body:
 643         {
 644                 $$ = new Book;
 645                 $$->set_spot (@$);
 646                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 647                 $$->paper_->unprotect ();
 648                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 649         }
 650         | BOOK_IDENTIFIER {
 651                 $$ = unsmob_book ($1);
 652                 $$->set_spot (@$);
 653         }
 654         | book_body paper_block {
 655                 $$->paper_ = $2;
 656                 $2->unprotect ();
 657         }
 658         | book_body score_block {
 659                 SCM s = $2->self_scm ();
 660                 $$->add_score (s);
 661                 $2->unprotect();
 662         }
 663         | book_body full_markup {
 664                 $$->add_score ($2);
 665         }
 666         | book_body lilypond_header {
 667                 $$->header_ = $2;
 668         }
 669         | book_body error {
 670                 $$->paper_ = 0;
 671                 $$->scores_ = SCM_EOL;
 672         }
 673         | book_body object_id_setting {
 674                 $$->user_key_ = ly_scm2string ($2);
 675         }
 676         ;
 677
 678 score_block:
 679         SCORE '{' score_body '}'        {
 680                 $$ = $3;
 681         }
 682         ;
 683
 684 score_body:
 685         music {
 686                 SCM m = $1;
 687                 SCM scorify = ly_lily_module_constant ("scorify-music");
 688                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 689
 690                 // pass ownernship to C++ again.
 691                 $$ = unsmob_score (score);
 692                 $$->protect ();
 693                 $$->set_spot (@$);
 694         }
 695         | SCORE_IDENTIFIER {
 696                 $$ = unsmob_score ($1);
 697                 $$->protect ();
 698                 $$->set_spot (@$);
 699         }
 700         | score_body object_id_setting {
 701                 $$->user_key_ = ly_scm2string ($2);
 702         }
 703         | score_body lilypond_header    {
 704                 $$->header_ = $2;
 705         }
 706         | score_body output_def {
 707                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 708                 {
 709                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 710
 711                 }
 712                 else
 713                 {
 714                         $$->add_output_def ($2);
 715                 }
 716                 $2->unprotect ();
 717         }
 718         | score_body error {
 719                 $$->error_found_ = true;
 720         }
 721         ;
 722
 723
 724 /*
 725         OUTPUT DEF
 726 */
 727
 728 paper_block:
 729         output_def {
 730                 $$ = $1;
 731                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 732                 {
 733                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
 734                         $$ = get_paper (PARSER);
 735                 }
 736         }
 737         ;
 738
 739
 740 output_def:
 741         output_def_body '}' {
 742                 $$ = $1;
 743
 744                 PARSER->lexer_->remove_scope ();
 745                 PARSER->lexer_->pop_state ();
 746         }
 747         ;
 748
 749 output_def_head:
 750         PAPER {
 751                 $$ = get_paper (PARSER);
 752                 $$->input_origin_ = @$;
 753                 PARSER->lexer_->add_scope ($$->scope_);
 754         }
 755         | MIDI    {
 756                 Output_def *p = get_midi (PARSER);
 757                 $$ = p;
 758                 PARSER->lexer_->add_scope (p->scope_);
 759         }
 760         | LAYOUT        {
 761                 Output_def *p = get_layout (PARSER);
 762
 763                 PARSER->lexer_->add_scope (p->scope_);
 764                 $$ = p;
 765         }
 766         ;
 767
 768 output_def_head_with_mode_switch:
 769         output_def_head {
 770                 PARSER->lexer_->push_initial_state ();
 771                 $$ = $1;
 772         }
 773         ;
 774
 775 output_def_body:
 776         output_def_head_with_mode_switch '{' {
 777                 $$ = $1;
 778                 $$->input_origin_.set_spot (@$);
 779         }
 780         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 781                 $1->unprotect ();
 782                 Output_def *o = unsmob_output_def ($3);
 783                 o->input_origin_.set_spot (@$);
 784                 $$ = o;
 785                 PARSER->lexer_->remove_scope ();
 786                 PARSER->lexer_->add_scope (o->scope_);
 787         }
 788         | output_def_body assignment  {
 789
 790         }
 791         | output_def_body context_def_spec_block        {
 792                 assign_context_def ($$, $2);
 793         }
 794         | output_def_body error {
 795
 796         }
 797         ;
 798
 799 tempo_event:
 800         TEMPO steno_duration '=' bare_unsigned  {
 801                 $$ = MAKE_SYNTAX ("tempo", @$, $2, scm_int2num ($4));
 802         }
 803         ;
 804
 805 /*
 806 The representation of a  list is the
 807
 808   (LIST . LAST-CONS)
 809
 810  to have efficient append.  */
 811
 812 music_list:
 813         /* empty */ {
 814                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 815         }
 816         | music_list music {
 817                 SCM s = $$;
 818                 SCM c = scm_cons ($2, SCM_EOL);
 819
 820                 if (scm_is_pair (scm_cdr (s)))
 821                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 822                 else
 823                         scm_set_car_x (s, c); /* set first cons */
 824                 scm_set_cdr_x (s, c);  /* remember last cell */
 825         }
 826         | music_list embedded_scm {
 827
 828         }
 829         | music_list error {
 830                 Music *m = MY_MAKE_MUSIC("Music");
 831                 // ugh. code dup
 832                 m->set_property ("error-found", SCM_BOOL_T);
 833                 SCM s = $$;
 834                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 835                 m->unprotect (); /* UGH */
 836
 837                 if (scm_is_pair (scm_cdr (s)))
 838                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 839                 else
 840                         scm_set_car_x (s, c); /* set first cons */
 841                 scm_set_cdr_x (s, c);  /* remember last cell */
 842         }
 843         ;
 844
 845 music:
 846         simple_music
 847         | composite_music
 848         ;
 849
 850 alternative_music:
 851         /* empty */ {
 852                 $$ = SCM_EOL;
 853         }
 854         | ALTERNATIVE '{' music_list '}' {
 855                 $$ = scm_car ($3);
 856         }
 857         ;
 858
 859
 860 repeated_music:
 861         REPEAT simple_string bare_unsigned music alternative_music
 862         {
 863                 $$ = MAKE_SYNTAX ("repeat", @$, $2, scm_int2num ($3), $4, $5);
 864         }
 865         ;
 866
 867 sequential_music:
 868         SEQUENTIAL '{' music_list '}'           {
 869                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($3));
 870         }
 871         | '{' music_list '}'            {
 872                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($2));
 873         }
 874         ;
 875
 876 simultaneous_music:
 877         SIMULTANEOUS '{' music_list '}'{
 878                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($3));
 879         }
 880         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
 881                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($2));
 882         }
 883         ;
 884
 885 simple_music:
 886         event_chord
 887         | MUSIC_IDENTIFIER
 888         | music_property_def
 889         | context_change
 890         ;
 891
 892 optional_context_mod:
 893         /**/ { $$ = SCM_EOL; }
 894         | WITH { PARSER->lexer_->push_initial_state (); }
 895         '{' context_mod_list '}'
 896         {
 897                 PARSER->lexer_->pop_state ();
 898                 $$ = $4;
 899         }
 900         ;
 901
 902 context_mod_list:
 903         /* */  { $$ = SCM_EOL; }
 904         | context_mod_list context_mod  {
 905                  $$ = scm_cons ($2, $1);
 906         }
 907         ;
 908
 909 composite_music:
 910         prefix_composite_music { $$ = $1; }
 911         | grouped_music_list { $$ = $1; }
 912         ;
 913
 914 grouped_music_list:
 915         simultaneous_music              { $$ = $1; }
 916         | sequential_music              { $$ = $1; }
 917         ;
 918
 919 function_scm_argument:
 920         embedded_scm
 921         | simple_string
 922         ;
 923
 924 /*
 925 TODO: use code generation for this
 926 */
 927 music_function_musicless_function:
 928         MUSIC_FUNCTION {
 929                 $$ = scm_list_2 ($1, make_input (@$));
 930         }
 931         | MUSIC_FUNCTION_SCM function_scm_argument {
 932                 $$ = scm_list_3 ($1, make_input (@$), $2);
 933         }
 934         | MUSIC_FUNCTION_MARKUP full_markup {
 935                 $$ = scm_list_3 ($1, make_input (@$), $2);
 936         }
 937         | MUSIC_FUNCTION_SCM_SCM function_scm_argument function_scm_argument {
 938                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
 939         }
 940         | MUSIC_FUNCTION_SCM_SCM_SCM function_scm_argument function_scm_argument function_scm_argument {
 941                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
 942         }
 943         | MUSIC_FUNCTION_MARKUP_MARKUP full_markup full_markup {
 944                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
 945         }
 946         ;
 947
 948 /*
 949 TODO: use code generation for this
 950 */
 951 music_function_musicless_prefix:
 952         MUSIC_FUNCTION_MUSIC {
 953                 $$ = scm_list_2 ($1, make_input (@$));
 954         }
 955         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument {
 956                 $$ = scm_list_3 ($1, make_input (@$), $2);
 957         }
 958         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument {
 959                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
 960         }
 961         | MUSIC_FUNCTION_SCM_SCM_SCM_MUSIC function_scm_argument function_scm_argument function_scm_argument {
 962                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
 963         }
 964         | MUSIC_FUNCTION_SCM_SCM_SCM_SCM_MUSIC function_scm_argument function_scm_argument function_scm_argument function_scm_argument {
 965                 $$ = scm_list_n ($1, make_input (@$), $2, $3, $4, $5, SCM_UNDEFINED);
 966         }
 967         | MUSIC_FUNCTION_MARKUP_MUSIC full_markup {
 968                 $$ = scm_list_3 ($1, make_input (@$), $2);
 969         }
 970         ;
 971
 972 generic_prefix_music_scm:
 973         music_function_musicless_function {
 974                 $$ = $1;
 975         }
 976         | music_function_musicless_prefix music {
 977                 $$ = ly_append2 ($1, scm_list_1 ($2));
 978         }
 979         | MUSIC_FUNCTION_MUSIC_MUSIC music music {
 980                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
 981         }
 982         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC function_scm_argument music music {
 983                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
 984         }
 985         | MUSIC_FUNCTION_SCM_SCM_MUSIC_MUSIC function_scm_argument function_scm_argument music music {
 986                 $$ = scm_list_n ($1, make_input (@$), $2, $3, $4, $5, SCM_UNDEFINED);
 987         }
 988         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC full_markup music music {
 989                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
 990         }
 991         ;
 992
 993
 994 optional_id:
 995         /**/ { $$ = SCM_EOL; }
 996         | '=' simple_string {
 997                 $$ = $2;
 998         }
 999         ;
1000
1001
1002 prefix_composite_music:
1003         generic_prefix_music_scm {
1004                 $$ = run_music_function (PARSER, $1);
1005         }
1006         | CONTEXT    simple_string optional_id optional_context_mod music {
1007                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, $4, SCM_BOOL_F);
1008         }
1009         | NEWCONTEXT simple_string optional_id optional_context_mod music {
1010                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, $4, SCM_BOOL_T);
1011         }
1012
1013         | TIMES fraction music {
1014                 $$ = MAKE_SYNTAX ("time-scaled-music", @$, $2, $3);
1015         }
1016         | repeated_music                { $$ = $1; }
1017         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords music {
1018                 Pitch from = *unsmob_pitch ($2);
1019                 Pitch to = *unsmob_pitch ($3);
1020                 SCM pitch = pitch_interval (from, to).smobbed_copy ();
1021                 $$ = MAKE_SYNTAX ("transpose-music", @$, pitch, $4);
1022         }
1023         | mode_changing_head grouped_music_list {
1024                 if ($1 == ly_symbol2scm ("chords"))
1025                 {
1026                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1027                 }
1028                 else
1029                 {
1030                   $$ = $2;
1031                 }
1032                 PARSER->lexer_->pop_state ();
1033         }
1034         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1035                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, $3, $2, SCM_BOOL_T);
1036                 if ($1 == ly_symbol2scm ("ChordNames"))
1037                 {
1038                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1039                 }
1040                 PARSER->lexer_->pop_state ();
1041         }
1042         | relative_music        { $$ = $1; }
1043         | re_rhythmed_music     { $$ = $1; }
1044         ;
1045
1046 mode_changing_head:
1047         NOTEMODE {
1048                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1049                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1050
1051                 $$ = ly_symbol2scm ("notes");
1052         }
1053         | DRUMMODE
1054                 {
1055                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1056                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1057
1058                 $$ = ly_symbol2scm ("drums");
1059         }
1060         | FIGUREMODE {
1061                 PARSER->lexer_->push_figuredbass_state ();
1062
1063                 $$ = ly_symbol2scm ("figures");
1064         }
1065         | CHORDMODE {
1066                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1067                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1068                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1069                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1070                 $$ = ly_symbol2scm ("chords");
1071
1072         }
1073         | LYRICMODE
1074                 { PARSER->lexer_->push_lyric_state ();
1075                 $$ = ly_symbol2scm ("lyrics");
1076         }
1077         ;
1078
1079 mode_changing_head_with_context:
1080         DRUMS {
1081                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1082                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1083
1084                 $$ = ly_symbol2scm ("DrumStaff");
1085         }
1086         | FIGURES {
1087                 PARSER->lexer_->push_figuredbass_state ();
1088
1089                 $$ = ly_symbol2scm ("FiguredBass");
1090         }
1091         | CHORDS {
1092                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1093                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1094                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1095                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1096                 $$ = ly_symbol2scm ("ChordNames");
1097         }
1098         | LYRICS
1099                 { PARSER->lexer_->push_lyric_state ();
1100                 $$ = ly_symbol2scm ("Lyrics");
1101         }
1102         ;
1103
1104
1105 relative_music:
1106         RELATIVE absolute_pitch music {
1107                 Pitch start = *unsmob_pitch ($2);
1108                 $$ = make_music_relative (start, $3);
1109         }
1110         | RELATIVE composite_music {
1111                 Pitch middle_c (0, 0, 0);
1112                 $$ = make_music_relative (middle_c, $2);
1113         }
1114         ;
1115
1116 new_lyrics:
1117         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1118         /*cont */
1119         grouped_music_list {
1120         /* Can also use music at the expensive of two S/Rs similar to
1121            \repeat \alternative */
1122                 PARSER->lexer_->pop_state ();
1123
1124                 $$ = scm_cons ($3, SCM_EOL);
1125         }
1126         | new_lyrics ADDLYRICS {
1127                 PARSER->lexer_->push_lyric_state ();
1128         } grouped_music_list {
1129                 PARSER->lexer_->pop_state ();
1130                 $$ = scm_cons ($4, $1);
1131         }
1132         ;
1133
1134 re_rhythmed_music:
1135         grouped_music_list new_lyrics {
1136                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1137         }
1138         | LYRICSTO simple_string {
1139                 PARSER->lexer_->push_lyric_state ();
1140         } music {
1141                 PARSER->lexer_->pop_state ();
1142                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1143         }
1144         ;
1145
1146 context_change:
1147         CHANGE STRING '=' STRING  {
1148                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1149         }
1150         ;
1151
1152 property_operation:
1153         STRING '=' scalar {
1154                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1155                         scm_string_to_symbol ($1), $3);
1156         }
1157         | UNSET simple_string {
1158                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1159                         scm_string_to_symbol ($2));
1160         }
1161         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1162                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1163                         scm_string_to_symbol ($2), $5, $3);
1164         }
1165         | OVERRIDE simple_string embedded_scm embedded_scm '=' embedded_scm {
1166                 $$ = scm_list_5 (ly_symbol2scm ("push"),
1167                                 scm_string_to_symbol ($2), $6, $4, $3);
1168         }
1169         | REVERT simple_string embedded_scm {
1170                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1171                         scm_string_to_symbol ($2), $3);
1172         }
1173         ;
1174
1175 context_def_mod:
1176         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1177         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1178
1179         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1180         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1181         | DENIES { $$ = ly_symbol2scm ("denies"); }
1182
1183         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1184         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1185         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1186         | NAME { $$ = ly_symbol2scm ("context-name"); }
1187         ;
1188
1189 context_mod:
1190         property_operation { $$ = $1; }
1191         | context_def_mod STRING {
1192                 $$ = scm_list_2 ($1, $2);
1193         }
1194         ;
1195
1196 context_prop_spec:
1197         simple_string {
1198                 if (!is_regular_identifier ($1))
1199                 {
1200                         @$.error (_("Grob name should be alphanumeric"));
1201                 }
1202
1203                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1204                         scm_string_to_symbol ($1));
1205         }
1206         | simple_string '.' simple_string {
1207                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1208                         scm_string_to_symbol ($3));
1209         }
1210         ;
1211
1212 simple_music_property_def:
1213         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1214                 $$ = scm_list_5 (scm_car ($2),
1215                         ly_symbol2scm ("OverrideProperty"),
1216                         scm_cadr ($2),
1217                         $5, $3);
1218         }
1219         | OVERRIDE context_prop_spec embedded_scm  embedded_scm '=' scalar {
1220                 $$ = scm_list_n (scm_car ($2),
1221                         ly_symbol2scm ("OverrideProperty"),
1222                         scm_cadr ($2),
1223                         $6, $4, $3, SCM_UNDEFINED);
1224         }
1225         | REVERT context_prop_spec embedded_scm {
1226                 $$ = scm_list_4 (scm_car ($2),
1227                         ly_symbol2scm ("RevertProperty"),
1228                         scm_cadr ($2),
1229                         $3);
1230         }
1231         | SET context_prop_spec '=' scalar {
1232                 $$ = scm_list_4 (scm_car ($2),
1233                         ly_symbol2scm ("PropertySet"),
1234                         scm_cadr ($2),
1235                         $4);
1236         }
1237         | UNSET context_prop_spec {
1238                 $$ = scm_list_3 (scm_car ($2),
1239                         ly_symbol2scm ("PropertyUnset"),
1240                         scm_cadr ($2));
1241         }
1242         ;
1243
1244 music_property_def:
1245         simple_music_property_def {
1246                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_F, $1)));
1247         }
1248         | ONCE simple_music_property_def {
1249                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_T, $2)));
1250         }
1251         ;
1252
1253 string:
1254         STRING {
1255                 $$ = $1;
1256         }
1257         | STRING_IDENTIFIER {
1258                 $$ = $1;
1259         }
1260         | string '+' string {
1261                 $$ = scm_string_append (scm_list_2 ($1, $3));
1262         }
1263         ;
1264
1265 simple_string: STRING {
1266                 $$ = $1;
1267         }
1268         | LYRICS_STRING {
1269                 $$ = $1;
1270         }
1271         | STRING_IDENTIFIER {
1272                 $$ = $1;
1273         }
1274         ;
1275
1276 scalar: string {
1277                 $$ = $1;
1278         }
1279         | LYRICS_STRING {
1280                 $$ = $1;
1281         }
1282         | bare_number {
1283                 $$ = $1;
1284         }
1285         | embedded_scm {
1286                 $$ = $1;
1287         }
1288         | full_markup {
1289                 $$ = $1;
1290         }
1291         | DIGIT {
1292                 $$ = scm_from_int ($1);
1293         }
1294         ;
1295
1296 event_chord:
1297         /* TODO: Create a special case that avoids the creation of
1298            EventChords around simple_elements that have no post_events?
1299          */
1300         simple_chord_elements post_events       {
1301                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1302
1303                 Input i;
1304                 /* why is this giving wrong start location? -ns
1305                  * i = @$; */
1306                 i.set_location (@1, @2);
1307                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1308         }
1309         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1310                 Input i;
1311                 i.set_location (@1, @3);
1312                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2, $3);
1313         }
1314         | command_element
1315         | note_chord_element
1316         ;
1317
1318
1319 note_chord_element:
1320         chord_body optional_notemode_duration post_events
1321         {
1322                 Music *m = unsmob_music ($1);
1323                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1324                 SCM es = m->get_property ("elements");
1325                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1326
1327                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1328                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1329                 es = ly_append2 (es, postevs);
1330
1331                 m-> set_property ("elements", es);
1332                 m->set_spot (@$);
1333                 $$ = m->self_scm ();
1334         }
1335         ;
1336
1337 chord_body:
1338         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1339         {
1340                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1341         }
1342         ;
1343
1344 chord_body_elements:
1345         /* empty */             { $$ = SCM_EOL; }
1346         | chord_body_elements chord_body_element {
1347                 $$ = scm_cons ($2, $1);
1348         }
1349         ;
1350
1351 chord_body_element:
1352         pitch exclamations questions octave_check post_events
1353         {
1354                 int q = $3;
1355                 int ex = $2;
1356                 SCM check = $4;
1357                 SCM post = $5;
1358
1359                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1360                 n->set_property ("pitch", $1);
1361                 n->set_spot (@$);
1362                 if (q % 2)
1363                         n->set_property ("cautionary", SCM_BOOL_T);
1364                 if (ex % 2 || q % 2)
1365                         n->set_property ("force-accidental", SCM_BOOL_T);
1366
1367                 if (scm_is_pair (post)) {
1368                         SCM arts = scm_reverse_x (post, SCM_EOL);
1369                         n->set_property ("articulations", arts);
1370                 }
1371                 if (scm_is_number (check))
1372                 {
1373                         int q = scm_to_int (check);
1374                         n->set_property ("absolute-octave", scm_from_int (q-1));
1375                 }
1376
1377                 $$ = n->unprotect ();
1378         }
1379         | DRUM_PITCH post_events {
1380                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1381                 n->set_property ("duration", $2);
1382                 n->set_property ("drum-type", $1);
1383                 n->set_spot (@$);
1384
1385                 if (scm_is_pair ($2)) {
1386                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1387                         n->set_property ("articulations", arts);
1388                 }
1389                 $$ = n->unprotect ();
1390         }
1391         | music_function_chord_body {
1392                 $$ = run_music_function (PARSER, $1);
1393         }
1394         ;
1395
1396 music_function_chord_body:
1397         music_function_musicless_function {
1398                 $$ = $1;
1399         }
1400         | music_function_musicless_prefix chord_body_element {
1401                 $$ = ly_append2 ($1, scm_list_1 ($2));
1402         }
1403         ;
1404
1405 music_function_event:
1406         music_function_musicless_prefix post_event {
1407                 $$ = ly_append2 ($1, scm_list_1 ($2));
1408         }
1409         | music_function_musicless_function {
1410                 $$ = $1;
1411         }
1412         ;
1413
1414
1415 command_element:
1416         command_event {
1417                 $$ = $1;
1418         }
1419         | SKIP duration_length {
1420                 $$ = MAKE_SYNTAX ("skip-music", @$, $2);
1421         }
1422         | E_BRACKET_OPEN {
1423                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1424                 m->set_property ("span-direction", scm_from_int (START));
1425                 m->set_spot (@$);
1426                 $$ = m->unprotect();
1427         }
1428         | E_BRACKET_CLOSE {
1429                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1430                 m->set_property ("span-direction", scm_from_int (STOP));
1431                 m->set_spot (@$);
1432                 $$ = m->unprotect ();
1433         }
1434         | E_BACKSLASH {
1435                 $$ = MAKE_SYNTAX ("voice-separator", @$, SCM_UNDEFINED);
1436         }
1437         | '|'      {
1438                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
1439
1440                 Music *m = unsmob_music (pipe);
1441                 if (m)
1442                 {
1443                         m = m->clone ();
1444                         m->set_spot (@$);
1445                         $$ = m->unprotect ();
1446                 }
1447                 else
1448                         $$ = MAKE_SYNTAX ("bar-check", @$, SCM_UNDEFINED);
1449
1450         }
1451         | PARTIAL duration_length       {
1452                 Moment m = - unsmob_duration ($2)->get_length ();
1453                 $$ = MAKE_SYNTAX ("property-operation", @$, SCM_BOOL_F, ly_symbol2scm ("Timing"), ly_symbol2scm ("PropertySet"), ly_symbol2scm ("measurePosition"), m.smobbed_copy ());
1454                 $$ = MAKE_SYNTAX ("context-specification", @$, ly_symbol2scm ("Score"), SCM_BOOL_F, $$, SCM_EOL, SCM_BOOL_F);
1455         }
1456
1457         | TIME_T fraction  {
1458                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1459
1460                 $$ = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1461         }
1462         | MARK scalar {
1463                 SCM proc = ly_lily_module_constant ("make-mark-set");
1464
1465                 $$ = scm_call_1 (proc, $2);
1466         }
1467         ;
1468
1469 command_event:
1470         E_TILDE {
1471                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent")->unprotect ();
1472         }
1473         | MARK DEFAULT  {
1474                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1475                 $$ = m->unprotect ();
1476         }
1477         | tempo_event {
1478                 $$ = $1;
1479         }
1480         | KEY DEFAULT {
1481                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1482                 $$ = key->unprotect ();
1483         }
1484         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1485
1486                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1487                 if (scm_ilength ($3) > 0)
1488                 {
1489                         key->set_property ("pitch-alist", $3);
1490                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1491                         key->transpose (* unsmob_pitch ($2));
1492                 } else {
1493                         PARSER->parser_error (@3, _ ("second argument must be pitch list"));
1494                 }
1495
1496                 $$ = key->unprotect ();
1497         }
1498         ;
1499
1500
1501 post_events:
1502         /* empty */ {
1503                 $$ = SCM_EOL;
1504         }
1505         | post_events post_event {
1506                 unsmob_music ($2)->set_spot (@2);
1507                 $$ = scm_cons ($2, $$);
1508         }
1509         ;
1510
1511 post_event:
1512         direction_less_event {
1513                 $$ = $1;
1514         }
1515         | '-' music_function_event {
1516                 $$ = run_music_function (PARSER, $2);
1517         }
1518         | HYPHEN {
1519                 if (!PARSER->lexer_->is_lyric_state ())
1520                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1521                 $$ = MY_MAKE_MUSIC ("HyphenEvent")->unprotect ();
1522         }
1523         | EXTENDER {
1524                 if (!PARSER->lexer_->is_lyric_state ())
1525                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1526                 $$ = MY_MAKE_MUSIC ("ExtenderEvent")->unprotect ();
1527         }
1528         | script_dir direction_reqd_event {
1529                 if ($1)
1530                 {
1531                         Music *m = unsmob_music ($2);
1532                         m->set_property ("direction", scm_from_int ($1));
1533                 }
1534                 $$ = $2;
1535         }
1536         | script_dir direction_less_event {
1537                 if ($1)
1538                 {
1539                         Music *m = unsmob_music ($2);
1540                         m->set_property ("direction", scm_from_int ($1));
1541                 }
1542                 $$ = $2;
1543         }
1544         | string_number_event
1545         ;
1546
1547 string_number_event:
1548         E_UNSIGNED {
1549                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1550                 s->set_property ("string-number", scm_from_int ($1));
1551                 s->set_spot (@$);
1552                 $$ = s->unprotect ();
1553         }
1554         ;
1555
1556 direction_less_char:
1557         '['  {
1558                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1559         }
1560         | ']'  {
1561                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1562         }
1563         | '~'  {
1564                 $$ = ly_symbol2scm ("tildeSymbol");
1565         }
1566         | '('  {
1567                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1568         }
1569         | ')'  {
1570                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1571         }
1572         | E_EXCLAMATION  {
1573                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1574         }
1575         | E_OPEN  {
1576                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1577         }
1578         | E_CLOSE  {
1579                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1580         }
1581         | E_ANGLE_CLOSE  {
1582                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1583         }
1584         | E_ANGLE_OPEN  {
1585                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1586         }
1587         ;
1588
1589 direction_less_event:
1590         direction_less_char {
1591                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
1592                 Music *m = 0;
1593                 if (unsmob_music (predefd))
1594                 {
1595                         m = unsmob_music (predefd)->clone ();
1596                 }
1597                 else
1598                 {
1599                         m = MY_MAKE_MUSIC ("Music");
1600                 }
1601                 m->set_spot (@$);
1602                 $$ = m->unprotect ();
1603         }
1604         | EVENT_IDENTIFIER      {
1605                 $$ = $1;
1606         }
1607         | tremolo_type  {
1608                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1609                a->set_spot (@$);
1610                a->set_property ("tremolo-type", scm_from_int ($1));
1611                $$ = a->unprotect ();
1612         }
1613         ;
1614
1615 direction_reqd_event:
1616         gen_text_def {
1617                 $$ = $1;
1618         }
1619         | script_abbreviation {
1620                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1621                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1622                 if (scm_is_string (s))
1623                         a->set_property ("articulation-type", s);
1624                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
1625                 $$ = a->unprotect ();
1626         }
1627         ;
1628
1629 octave_check:
1630         /**/ { $$ = SCM_EOL; }
1631         | '='  { $$ = scm_from_int (0); }
1632         | '=' sub_quotes { $$ = scm_from_int ($2); }
1633         | '=' sup_quotes { $$ = scm_from_int ($2); }
1634         ;
1635
1636 sup_quotes:
1637         '\'' {
1638                 $$ = 1;
1639         }
1640         | sup_quotes '\'' {
1641                 $$ ++;
1642         }
1643         ;
1644
1645 sub_quotes:
1646         ',' {
1647                 $$ = 1;
1648         }
1649         | sub_quotes ',' {
1650                 $$++;
1651         }
1652         ;
1653
1654 steno_pitch:
1655         NOTENAME_PITCH  {
1656                 $$ = $1;
1657         }
1658         | NOTENAME_PITCH sup_quotes     {
1659                 Pitch p = *unsmob_pitch ($1);
1660                 p = p.transposed (Pitch ($2,0,0));
1661                 $$ = p.smobbed_copy ();
1662         }
1663         | NOTENAME_PITCH sub_quotes      {
1664                 Pitch p =* unsmob_pitch ($1);
1665                 p = p.transposed (Pitch (-$2,0,0));
1666                 $$ = p.smobbed_copy ();
1667         }
1668         ;
1669
1670 /*
1671 ugh. duplication
1672 */
1673
1674 steno_tonic_pitch:
1675         TONICNAME_PITCH {
1676                 $$ = $1;
1677         }
1678         | TONICNAME_PITCH sup_quotes    {
1679                 Pitch p = *unsmob_pitch ($1);
1680                 p = p.transposed (Pitch ($2,0,0));
1681                 $$ = p.smobbed_copy ();
1682         }
1683         | TONICNAME_PITCH sub_quotes     {
1684                 Pitch p =* unsmob_pitch ($1);
1685
1686                 p = p.transposed (Pitch (-$2,0,0));
1687                 $$ = p.smobbed_copy ();
1688         }
1689         ;
1690
1691 pitch:
1692         steno_pitch {
1693                 $$ = $1;
1694         }
1695         ;
1696
1697 pitch_also_in_chords:
1698         pitch
1699         | steno_tonic_pitch
1700         ;
1701
1702 gen_text_def:
1703         full_markup {
1704                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1705                 t->set_property ("text", $1);
1706                 t->set_spot (@$);
1707                 $$ = t->unprotect ();
1708         }
1709         | string {
1710                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1711                 t->set_property ("text",
1712                         make_simple_markup ($1));
1713                 t->set_spot (@$);
1714                 $$ = t->unprotect ();
1715         }
1716         | DIGIT {
1717                 Music *t = MY_MAKE_MUSIC ("FingeringEvent");
1718                 t->set_property ("digit", scm_from_int ($1));
1719                 t->set_spot (@$);
1720                 $$ = t->unprotect ();
1721         }
1722         ;
1723
1724 script_abbreviation:
1725         '^'             {
1726                 $$ = scm_makfrom0str ("Hat");
1727         }
1728         | '+'           {
1729                 $$ = scm_makfrom0str ("Plus");
1730         }
1731         | '-'           {
1732                 $$ = scm_makfrom0str ("Dash");
1733         }
1734         | '|'           {
1735                 $$ = scm_makfrom0str ("Bar");
1736         }
1737         | ANGLE_CLOSE   {
1738                 $$ = scm_makfrom0str ("Larger");
1739         }
1740         | '.'           {
1741                 $$ = scm_makfrom0str ("Dot");
1742         }
1743         | '_' {
1744                 $$ = scm_makfrom0str ("Underscore");
1745         }
1746         ;
1747
1748 script_dir:
1749         '_'     { $$ = DOWN; }
1750         | '^'   { $$ = UP; }
1751         | '-'   { $$ = CENTER; }
1752         ;
1753
1754
1755 absolute_pitch:
1756         steno_pitch     {
1757                 $$ = $1;
1758         }
1759         ;
1760
1761 duration_length:
1762         multiplied_duration {
1763                 $$ = $1;
1764         }
1765         ;
1766
1767 optional_notemode_duration:
1768         {
1769                 Duration dd = PARSER->default_duration_;
1770                 $$ = dd.smobbed_copy ();
1771         }
1772         | multiplied_duration   {
1773                 $$ = $1;
1774                 PARSER->default_duration_ = *unsmob_duration ($$);
1775         }
1776         ;
1777
1778 steno_duration:
1779         bare_unsigned dots              {
1780                 int len = 0;
1781                 if (!is_duration ($1))
1782                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
1783                 else
1784                         len = intlog2 ($1);
1785
1786                 $$ = Duration (len, $2).smobbed_copy ();
1787         }
1788         | DURATION_IDENTIFIER dots      {
1789                 Duration *d = unsmob_duration ($1);
1790                 Duration k (d->duration_log (), d->dot_count () + $2);
1791                 *d = k;
1792                 $$ = $1;
1793         }
1794         ;
1795
1796 multiplied_duration:
1797         steno_duration {
1798                 $$ = $1;
1799         }
1800         | multiplied_duration '*' bare_unsigned {
1801                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1802         }
1803         | multiplied_duration '*' FRACTION {
1804                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
1805
1806                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1807         }
1808         ;
1809
1810 fraction:
1811         FRACTION { $$ = $1; }
1812         | UNSIGNED '/' UNSIGNED {
1813                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
1814         }
1815         ;
1816
1817 dots:
1818         /* empty */     {
1819                 $$ = 0;
1820         }
1821         | dots '.' {
1822                 $$ ++;
1823         }
1824         ;
1825
1826 tremolo_type:
1827         ':'     {
1828                 $$ = 0;
1829         }
1830         | ':' bare_unsigned {
1831                 if (!is_duration ($2))
1832                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
1833                 $$ = $2;
1834         }
1835         ;
1836
1837 bass_number:
1838         DIGIT   {
1839                 $$ = scm_from_int ($1);
1840         }
1841         | UNSIGNED {
1842                 $$ = scm_from_int ($1);
1843         }
1844         | STRING { $$ = $1; }
1845         | full_markup { $$ = $1; }
1846         ;
1847
1848 figured_bass_alteration:
1849         '-'     { $$ = -2; }
1850         | '+'   { $$ = 2; }
1851         | '!'   { $$ = 0; }
1852         ;
1853
1854 bass_figure:
1855         FIGURE_SPACE {
1856                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1857                 $$ = bfr->self_scm ();
1858                 bfr->unprotect ();
1859                 bfr->set_spot (@1);
1860         }
1861         | bass_number  {
1862                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1863                 $$ = bfr->self_scm ();
1864
1865                 if (scm_is_number ($1))
1866                         bfr->set_property ("figure", $1);
1867                 else if (Text_interface::is_markup ($1))
1868                         bfr->set_property ("text", $1);
1869
1870                 bfr->unprotect ();
1871                 bfr->set_spot (@1);
1872         }
1873         | bass_figure ']' {
1874                 $$ = $1;
1875                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1876         }
1877         | bass_figure figured_bass_alteration {
1878                 Music *m = unsmob_music ($1);
1879                 if ($2) {
1880                         SCM salter = m->get_property ("alteration");
1881                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
1882                         m->set_property ("alteration",
1883                                 scm_from_int (alter + $2));
1884                 } else {
1885                         m->set_property ("alteration", scm_from_int (0));
1886                 }
1887         }
1888         | bass_figure figured_bass_modification  {
1889                 Music *m = unsmob_music ($1);
1890                 if ($2 == ly_symbol2scm ("plus"))
1891                         {
1892                         m->set_property ("augmented", SCM_BOOL_T);
1893                         }
1894                 else if ($2 == ly_symbol2scm ("slash"))
1895                         {
1896                         m->set_property ("diminished", SCM_BOOL_T);
1897                         }
1898                 else if ($2 == ly_symbol2scm ("exclamation"))
1899                         {
1900                         m->set_property ("no-continuation", SCM_BOOL_T);
1901                         }
1902         }
1903         ;
1904
1905
1906 figured_bass_modification:
1907         E_PLUS          {
1908                 $$ = ly_symbol2scm ("plus");
1909         }
1910         | E_EXCLAMATION {
1911                 $$ = ly_symbol2scm ("exclamation");
1912         }
1913         | '/'           {
1914                 $$ = ly_symbol2scm ("slash");
1915         }
1916         ;
1917
1918 br_bass_figure:
1919         bass_figure {
1920                 $$ = $1;
1921         }
1922         | '[' bass_figure {
1923                 $$ = $2;
1924                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1925         }
1926         ;
1927
1928 figure_list:
1929         /**/            {
1930                 $$ = SCM_EOL;
1931         }
1932         | figure_list br_bass_figure {
1933                 $$ = scm_cons ($2, $1);
1934         }
1935         ;
1936
1937 figure_spec:
1938         FIGURE_OPEN figure_list FIGURE_CLOSE {
1939                 $$ = scm_reverse_x ($2, SCM_EOL);
1940         }
1941         ;
1942
1943
1944 optional_rest:
1945         /**/   { $$ = 0; }
1946         | REST { $$ = 1; }
1947         ;
1948
1949 simple_element:
1950         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
1951                 if (!PARSER->lexer_->is_note_state ())
1952                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
1953
1954                 Music *n = 0;
1955                 if ($6)
1956                         n = MY_MAKE_MUSIC ("RestEvent");
1957                 else
1958                         n = MY_MAKE_MUSIC ("NoteEvent");
1959
1960                 n->set_property ("pitch", $1);
1961                 n->set_property ("duration", $5);
1962
1963                 if (scm_is_number ($4))
1964                 {
1965                         int q = scm_to_int ($4);
1966                         n->set_property ("absolute-octave", scm_from_int (q-1));
1967                 }
1968
1969                 if ($3 % 2)
1970                         n->set_property ("cautionary", SCM_BOOL_T);
1971                 if ($2 % 2 || $3 % 2)
1972                         n->set_property ("force-accidental", SCM_BOOL_T);
1973
1974                 n->set_spot (@$);
1975                 $$ = n->unprotect ();
1976         }
1977         | DRUM_PITCH optional_notemode_duration {
1978                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1979                 n->set_property ("duration", $2);
1980                 n->set_property ("drum-type", $1);
1981
1982                 $$ = n->unprotect ();
1983         }
1984         | RESTNAME optional_notemode_duration           {
1985                 Music *ev = 0;
1986                 if (ly_scm2string ($1) == "s") {
1987                         /* Space */
1988                         ev = MY_MAKE_MUSIC ("SkipEvent");
1989                   }
1990                 else {
1991                         ev = MY_MAKE_MUSIC ("RestEvent");
1992
1993                     }
1994                 ev->set_property ("duration", $2);
1995                 ev->set_spot (@$);
1996                 $$ = ev->unprotect ();
1997         }
1998         | lyric_element optional_notemode_duration      {
1999                 if (!PARSER->lexer_->is_lyric_state ())
2000                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2001
2002                 Music *levent = MY_MAKE_MUSIC ("LyricEvent");
2003                 levent->set_property ("text", $1);
2004                 levent->set_property ("duration",$2);
2005                 levent->set_spot (@$);
2006                 $$= levent->unprotect ();
2007         }
2008         ;
2009
2010 simple_chord_elements:
2011         simple_element  {
2012                 $$ = scm_list_1 ($1);
2013         }
2014         | new_chord {
2015                 if (!PARSER->lexer_->is_chord_state ())
2016                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
2017                 $$ = $1;
2018         }
2019         | figure_spec optional_notemode_duration {
2020                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2021                 {
2022                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2023                 }
2024                 $$ = $1;
2025         }
2026         ;
2027
2028 lyric_element:
2029         lyric_markup {
2030                 $$ = $1;
2031         }
2032         | LYRICS_STRING {
2033                 $$ = $1;
2034         }
2035         ;
2036
2037 new_chord:
2038         steno_tonic_pitch optional_notemode_duration   {
2039                 $$ = make_chord_elements ($1, $2, SCM_EOL);
2040         }
2041         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2042                 SCM its = scm_reverse_x ($4, SCM_EOL);
2043                 $$ = make_chord_elements ($1, $2, scm_cons ($3, its));
2044         }
2045         ;
2046
2047 chord_items:
2048         /**/ {
2049                 $$ = SCM_EOL;
2050         }
2051         | chord_items chord_item {
2052                 $$ = scm_cons ($2, $$);
2053         }
2054         ;
2055
2056 chord_separator:
2057         CHORD_COLON {
2058                 $$ = ly_symbol2scm ("chord-colon");
2059         }
2060         | CHORD_CARET {
2061                 $$ = ly_symbol2scm ("chord-caret");
2062         }
2063         | CHORD_SLASH steno_tonic_pitch {
2064                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2065         }
2066         | CHORD_BASS steno_tonic_pitch {
2067                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2068         }
2069         ;
2070
2071 chord_item:
2072         chord_separator {
2073                 $$ = $1;
2074         }
2075         | step_numbers {
2076                 $$ = scm_reverse_x ($1, SCM_EOL);
2077         }
2078         | CHORD_MODIFIER  {
2079                 $$ = $1;
2080         }
2081         ;
2082
2083 step_numbers:
2084         step_number { $$ = scm_cons ($1, SCM_EOL); }
2085         | step_numbers '.' step_number {
2086                 $$ = scm_cons ($3, $$);
2087         }
2088         ;
2089
2090 step_number:
2091         bare_unsigned {
2092                 $$ = make_chord_step ($1, 0);
2093         }
2094         | bare_unsigned '+' {
2095                 $$ = make_chord_step ($1, SHARP);
2096         }
2097         | bare_unsigned CHORD_MINUS {
2098                 $$ = make_chord_step ($1, FLAT);
2099         }
2100         ;
2101
2102 /*
2103         UTILITIES
2104
2105 TODO: should deprecate in favor of Scheme?
2106
2107  */
2108 number_expression:
2109         number_expression '+' number_term {
2110                 $$ = scm_sum ($1, $3);
2111         }
2112         | number_expression '-' number_term {
2113                 $$ = scm_difference ($1, $3);
2114         }
2115         | number_term
2116         ;
2117
2118 number_term:
2119         number_factor {
2120                 $$ = $1;
2121         }
2122         | number_factor '*' number_factor {
2123                 $$ = scm_product ($1, $3);
2124         }
2125         | number_factor '/' number_factor {
2126                 $$ = scm_divide ($1, $3);
2127         }
2128         ;
2129
2130 number_factor:
2131         '-'  number_factor { /* %prec UNARY_MINUS */
2132                 $$ = scm_difference ($2, SCM_UNDEFINED);
2133         }
2134         | bare_number
2135         ;
2136
2137
2138 bare_number:
2139         UNSIGNED        {
2140                 $$ = scm_from_int ($1);
2141         }
2142         | REAL          {
2143                 $$ = $1;
2144         }
2145         | NUMBER_IDENTIFIER             {
2146                 $$ = $1;
2147         }
2148         | REAL NUMBER_IDENTIFIER        {
2149                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2150         }
2151         | UNSIGNED NUMBER_IDENTIFIER    {
2152                 $$ = scm_from_double ($1 *scm_to_double ($2));
2153         }
2154         ;
2155
2156
2157 bare_unsigned:
2158         UNSIGNED {
2159                         $$ = $1;
2160         }
2161         | DIGIT {
2162                 $$ = $1;
2163         }
2164         ;
2165
2166 exclamations:
2167                 { $$ = 0; }
2168         | exclamations '!'      { $$ ++; }
2169         ;
2170
2171 questions:
2172                 { $$ = 0; }
2173         | questions '?' { $$ ++; }
2174         ;
2175
2176 /*
2177 This should be done more dynamically if possible.
2178 */
2179
2180 lyric_markup:
2181         LYRIC_MARKUP_IDENTIFIER {
2182                 $$ = $1;
2183         }
2184         | LYRIC_MARKUP
2185                 { PARSER->lexer_->push_markup_state (); }
2186         markup_top {
2187                 $$ = $3;
2188                 PARSER->lexer_->pop_state ();
2189         }
2190         ;
2191
2192 full_markup:
2193         MARKUP_IDENTIFIER {
2194                 $$ = $1;
2195         }
2196         | MARKUP
2197                 { PARSER->lexer_->push_markup_state (); }
2198         markup_top {
2199                 $$ = $3;
2200                 PARSER->lexer_->pop_state ();
2201         }
2202         ;
2203
2204 markup_top:
2205         markup_list {
2206                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2207         }
2208         | markup_head_1_list simple_markup      {
2209                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2210         }
2211         | simple_markup {
2212                 $$ = $1;
2213         }
2214         ;
2215
2216 markup_list:
2217         markup_composed_list {
2218                 $$ = $1;
2219         }
2220         | markup_braced_list {
2221                 $$ = $1;
2222         }
2223         ;
2224
2225 markup_composed_list:
2226         markup_head_1_list markup_braced_list {
2227                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2228
2229         }
2230         ;
2231
2232 markup_braced_list:
2233         '{' markup_braced_list_body '}' {
2234                 $$ = scm_reverse_x ($2, SCM_EOL);
2235         }
2236         ;
2237
2238 markup_braced_list_body:
2239         /* empty */     {  $$ = SCM_EOL; }
2240         | markup_braced_list_body markup {
2241                 $$ = scm_cons ($2, $1);
2242         }
2243         | markup_braced_list_body markup_list {
2244                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2245         }
2246         ;
2247
2248 markup_head_1_item:
2249         MARKUP_HEAD_MARKUP0     {
2250                 $$ = scm_list_1 ($1);
2251         }
2252         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2253                 $$ = scm_list_2 ($1, $2);
2254         }
2255         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2256                 $$ = scm_list_3 ($1, $2, $3);
2257         }
2258         ;
2259
2260 markup_head_1_list:
2261         markup_head_1_item      {
2262                 $$ = scm_list_1 ($1);
2263         }
2264         | markup_head_1_list markup_head_1_item {
2265                 $$ = scm_cons ($2, $1);
2266         }
2267         ;
2268
2269 simple_markup:
2270         STRING {
2271                 $$ = make_simple_markup ($1);
2272         }
2273         | MARKUP_IDENTIFIER {
2274                 $$ = $1;
2275         }
2276         | LYRIC_MARKUP_IDENTIFIER {
2277                 $$ = $1;
2278         }
2279         | STRING_IDENTIFIER {
2280                 $$ = $1;
2281         }
2282         | SCORE {
2283                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2284                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2285         } '{' score_body '}' {
2286                 Score * sc = $4;
2287                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2288                 sc->unprotect ();
2289                 PARSER->lexer_->pop_state ();
2290         }
2291         | MARKUP_HEAD_SCM0 embedded_scm {
2292                 $$ = scm_list_2 ($1, $2);
2293         }
2294         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2295                 $$ = scm_list_4 ($1, $2, $3, $4);
2296         }
2297         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2298                 $$ = scm_list_3 ($1, $2, $3);
2299         }
2300         | MARKUP_HEAD_EMPTY {
2301                 $$ = scm_list_1 ($1);
2302         }
2303         | MARKUP_HEAD_LIST0 markup_list {
2304                 $$ = scm_list_2 ($1,$2);
2305         }
2306         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2307                 $$ = scm_list_3 ($1, $2, $3);
2308         }
2309         ;
2310
2311 markup:
2312         markup_head_1_list simple_markup        {
2313                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2314                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2315         }
2316         | simple_markup {
2317                 $$ = $1;
2318         }
2319         ;
2320
2321 %%
2322
2323 void
2324 Lily_parser::set_yydebug (bool )
2325 {
2326 #if 0
2327         yydebug = 1;
2328 #endif
2329 }
2330
2331 void
2332 Lily_parser::do_yyparse ()
2333 {
2334         yyparse ((void*)this);
2335 }
2336
2337
2338
2339
2340
2341 /*
2342
2343 It is a little strange to have this function in this file, but
2344 otherwise, we have to import music classes into the lexer.
2345
2346 */
2347 int
2348 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2349 {
2350         if (scm_is_string (sid)) {
2351                 *destination = sid;
2352                 return STRING_IDENTIFIER;
2353         } else if (unsmob_book (sid)) {
2354                 Book *book =  unsmob_book (sid)->clone ();
2355                 *destination = book->self_scm ();
2356                 book->unprotect ();
2357
2358                 return BOOK_IDENTIFIER;
2359         } else if (scm_is_number (sid)) {
2360                 *destination = sid;
2361                 return NUMBER_IDENTIFIER;
2362         } else if (unsmob_context_def (sid)) {
2363                 Context_def *def= unsmob_context_def (sid)->clone ();
2364
2365                 *destination = def->self_scm ();
2366                 def->unprotect ();
2367
2368                 return CONTEXT_DEF_IDENTIFIER;
2369         } else if (unsmob_score (sid)) {
2370                 Score *score = new Score (*unsmob_score (sid));
2371                 *destination = score->self_scm ();
2372
2373                 score->unprotect ();
2374                 return SCORE_IDENTIFIER;
2375         } else if (Music *mus = unsmob_music (sid)) {
2376                 mus = mus->clone ();
2377                 *destination = mus->self_scm ();
2378                 unsmob_music (*destination)->
2379                         set_property ("origin", make_input (last_input_));
2380
2381                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2382                         != SCM_BOOL_F;
2383
2384                 mus->unprotect ();
2385                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2386         } else if (unsmob_duration (sid)) {
2387                 *destination = unsmob_duration (sid)->smobbed_copy ();
2388                 return DURATION_IDENTIFIER;
2389         } else if (unsmob_output_def (sid)) {
2390                 Output_def *p = unsmob_output_def (sid);
2391                 p = p->clone ();
2392
2393                 *destination = p->self_scm ();
2394                 p->unprotect ();
2395                 return OUTPUT_DEF_IDENTIFIER;
2396         } else if (Text_interface::is_markup (sid)) {
2397                 *destination = sid;
2398                 if (is_lyric_state ())
2399                         return LYRIC_MARKUP_IDENTIFIER;
2400                 return MARKUP_IDENTIFIER;
2401         }
2402
2403         return -1;
2404 }
2405
2406 SCM
2407 get_next_unique_context_id ()
2408 {
2409         return scm_makfrom0str ("$uniqueContextId");
2410 }
2411
2412
2413 SCM
2414 get_next_unique_lyrics_context_id ()
2415 {
2416         static int new_context_count;
2417         char s[128];
2418         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2419         return scm_makfrom0str (s);
2420 }
2421
2422
2423 SCM
2424 run_music_function (Lily_parser *parser, SCM expr)
2425 {
2426         SCM func = scm_car (expr);
2427         Input *loc = unsmob_input (scm_cadr (expr));
2428         SCM args = scm_cddr (expr);
2429         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2430
2431         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2432
2433         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2434         {
2435                 parser->error_level_ = 1;
2436                 return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("void-music"), scm_list_2 (parser->self_scm (), make_input (*loc)));
2437         }
2438
2439         SCM syntax_args = scm_list_4 (parser->self_scm (), make_input (*loc), func, args);
2440         return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("music-function"), syntax_args);
2441 }
2442
2443 bool
2444 is_regular_identifier (SCM id)
2445 {
2446   string str = ly_scm2string (id);
2447   char const *s = str.c_str ();
2448
2449   bool v = true;
2450 #if 0
2451   isalpha (*s);
2452   s++;
2453 #endif
2454   while (*s && v)
2455    {
2456         v = v && isalnum (*s);
2457         s++;
2458    }
2459   return v;
2460 }
2461
2462
2463 SCM
2464 get_first_context_id (SCM type, Music *m)
2465 {
2466         SCM id = m->get_property ("context-id");
2467         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2468             && scm_is_string (m->get_property ("context-id"))
2469             && scm_c_string_length (id) > 0)
2470         {
2471                 return id;
2472         }
2473         return SCM_EOL;
2474 }
2475
2476 SCM
2477 make_simple_markup (SCM a)
2478 {
2479         return a;
2480 }
2481
2482 bool
2483 is_duration (int t)
2484 {
2485   return t && t == 1 << intlog2 (t);
2486 }
2487
2488 void
2489 set_music_properties (Music *p, SCM a)
2490 {
2491   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2492         p->internal_set_property (scm_caar (k), scm_cdar (k));
2493 }
2494
2495
2496 SCM
2497 make_chord_step (int step, int alter)
2498 {
2499         if (step == 7)
2500                 alter += FLAT;
2501
2502         while (step < 0)
2503                 step += 7;
2504         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2505         return m.smobbed_copy ();
2506 }
2507
2508
2509 SCM
2510 make_chord_elements (SCM pitch, SCM dur, SCM modification_list)
2511 {
2512         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
2513         return scm_call_3 (chord_ctor, pitch, dur, modification_list);
2514 }
2515
2516
2517 /* Todo: actually also use apply iso. call too ...  */
2518 bool
2519 ly_input_procedure_p (SCM x)
2520 {
2521         return ly_is_procedure (x)
2522                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2523 }
2524
2525 SCM
2526 make_music_relative (Pitch start, SCM music)
2527 {
2528         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
2529         relative->set_property ("element", music);
2530
2531         Music *m = unsmob_music (music);
2532         Pitch last = m->to_relative_octave (start);
2533         if (lily_1_8_relative)
2534                 m->set_property ("last-pitch", last.smobbed_copy ());
2535         return relative->unprotect ();
2536 }
2537
2538 int
2539 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2540 {
2541         Lily_parser *pars = (Lily_parser*) v;
2542         Lily_lexer *lex = pars->lexer_;
2543
2544         lex->lexval = (void*) s;
2545         lex->lexloc = loc;
2546         lex->prepare_for_next_token ();
2547         return lex->yylex ();
2548 }