lily/parser.yy

   1 /*
   2   parser.yy -- Bison/C++ parser for LilyPond
   3
   4   source file of the GNU LilyPond music typesetter
   5
   6   (c) 1997--2007 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7                  Jan Nieuwenhuizen <janneke@gnu.org>
   8 */
   9
  10 %{
  11
  12 #define YYDEBUG 1
  13 #define YYERROR_VERBOSE 1
  14 #define YYPARSE_PARAM my_lily_parser
  15 #define YYLEX_PARAM my_lily_parser
  16 #define PARSER ((Lily_parser *) my_lily_parser)
  17
  18 #define yyerror PARSER->parser_error
  19
  20 /* We use custom location type: Input objects */
  21 #define YYLTYPE Input
  22 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  23         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  24
  25
  26 %}
  27
  28 /* We use SCMs to do strings, because it saves us the trouble of
  29 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  30 of the parse stack onto the heap. */
  31
  32 %left PREC_TOP
  33 %left ADDLYRICS
  34 %left PREC_BOT
  35
  36 %expect 1
  37
  38 /* One shift/reduce problem
  39
  40 1.  \repeat
  41         \repeat .. \alternative
  42
  43     \repeat { \repeat .. \alternative }
  44
  45 or
  46
  47     \repeat { \repeat } \alternative
  48 */
  49
  50
  51 %pure_parser
  52 %locations
  53
  54
  55
  56 %{ // -*-Fundamental-*-
  57
  58 /*
  59 FIXME:
  60
  61    * The rules for who is protecting what are very shady.  Uniformise
  62      this.
  63
  64    * There are too many lexical modes?
  65 */
  66
  67 #include "config.hh"
  68
  69 #include <cctype>
  70 #include <cstdlib>
  71 #include <cstdio>
  72 using namespace std;
  73
  74 #include "book.hh"
  75 #include "context-def.hh"
  76 #include "dimensions.hh"
  77 #include "file-path.hh"
  78 #include "input.hh"
  79 #include "international.hh"
  80 #include "lily-guile.hh"
  81 #include "lily-lexer.hh"
  82 #include "lily-parser.hh"
  83 #include "main.hh"
  84 #include "misc.hh"
  85 #include "music.hh"
  86 #include "music.hh"
  87 #include "output-def.hh"
  88 #include "paper-book.hh"
  89 #include "program-option.hh"
  90 #include "scm-hash.hh"
  91 #include "score.hh"
  92 #include "text-interface.hh"
  93 #include "warn.hh"
  94
  95 %}
  96
  97
  98 %union {
  99         Book *book;
 100         Output_def *outputdef;
 101         SCM scm;
 102         std::string *string;
 103         Music *music;
 104         Score *score;
 105         int i;
 106 }
 107
 108 %{
 109
 110 #define MY_MAKE_MUSIC(x, spot)  make_music_with_input (ly_symbol2scm (x), spot)
 111
 112 /* ES TODO:
 113 - Don't use lily module, create a new module instead.
 114 - delay application of the function
 115 */
 116 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 117   scm_apply_0 (proc, args)
 118 /* Syntactic Sugar. */
 119 #define MAKE_SYNTAX(name, location, ...)        \
 120   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (PARSER->self_scm (), make_input (location), __VA_ARGS__, SCM_UNDEFINED));
 121
 122 SCM get_next_unique_context_id ();
 123 SCM get_next_unique_lyrics_context_id ();
 124
 125 #undef _
 126 #if !HAVE_GETTEXT
 127 #define _(x) x
 128 #else
 129 #include <libintl.h>
 130 #define _(x) gettext (x)
 131 #endif
 132
 133
 134 static Music *make_music_with_input (SCM name, Input where);
 135 SCM make_music_relative (Pitch start, SCM music, Input loc);
 136 SCM run_music_function (Lily_parser *, SCM expr);
 137 SCM get_first_context_id (SCM type, Music *m);
 138 SCM make_chord_elements (SCM pitch, SCM dur, SCM modification_list);
 139 SCM make_chord_step (int step, Rational alter);
 140 SCM make_simple_markup (SCM a);
 141 bool is_duration (int t);
 142 bool is_regular_identifier (SCM id);
 143 bool ly_input_procedure_p (SCM x);
 144 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 145 void set_music_properties (Music *p, SCM a);
 146
 147 %}
 148
 149 /* The third option is an alias that will be used to display the
 150    syntax error.  Bison CVS now correctly handles backslash escapes.
 151
 152    FIXME: Bison needs to translate some of these, eg, STRING.
 153
 154 */
 155
 156 /* Keyword tokens with plain escaped name.  */
 157 %token ACCEPTS "\\accepts"
 158 %token ADDLYRICS "\\addlyrics"
 159 %token ALIAS "\\alias"
 160 %token ALTERNATIVE "\\alternative"
 161 %token BOOK "\\book"
 162 %token CHANGE "\\change"
 163 %token CHORDMODE "\\chordmode"
 164 %token CHORDS "\\chords"
 165 %token CONSISTS "\\consists"
 166 %token CONTEXT "\\context"
 167 %token DEFAULT "\\default"
 168 %token DEFAULTCHILD "\\defaultchild"
 169 %token DENIES "\\denies"
 170 %token DESCRIPTION "\\description"
 171 %token DRUMMODE "\\drummode"
 172 %token DRUMS "\\drums"
 173 %token FIGUREMODE "\\figuremode"
 174 %token FIGURES "\\figures"
 175 %token GROBDESCRIPTIONS "\\grobdescriptions"
 176 %token HEADER "\\header"
 177 %token INVALID "\\invalid"
 178 %token KEY "\\key"
 179 %token LAYOUT "\\layout"
 180 %token LYRICMODE "\\lyricmode"
 181 %token LYRICS "\\lyrics"
 182 %token LYRICSTO "\\lyricsto"
 183 %token MARK "\\mark"
 184 %token MARKUP "\\markup"
 185 %token MIDI "\\midi"
 186 %token NAME "\\name"
 187 %token NOTEMODE "\\notemode"
 188 %token OBJECTID "\\objectid"
 189 %token OCTAVE "\\octave"
 190 %token ONCE "\\once"
 191 %token OVERRIDE "\\override"
 192 %token PAPER "\\paper"
 193 %token PARTIAL "\\partial"
 194 %token RELATIVE "\\relative"
 195 %token REMOVE "\\remove"
 196 %token REPEAT "\\repeat"
 197 %token REST "\\rest"
 198 %token REVERT "\\revert"
 199 %token SCORE "\\score"
 200 %token SEQUENTIAL "\\sequential"
 201 %token SET "\\set"
 202 %token SIMULTANEOUS "\\simultaneous"
 203 %token SKIP "\\skip"
 204 %token TEMPO "\\tempo"
 205 %token TIMES "\\times"
 206 %token TRANSPOSE "\\transpose"
 207 %token TYPE "\\type"
 208 %token UNSET "\\unset"
 209 %token WITH "\\with"
 210
 211 /* Keyword token exceptions.  */
 212 %token TIME_T "\\time"
 213 %token NEWCONTEXT "\\new"
 214
 215
 216 /* Other string tokens.  */
 217
 218 %token CHORD_BASS "/+"
 219 %token CHORD_CARET "^"
 220 %token CHORD_COLON ":"
 221 %token CHORD_MINUS "-"
 222 %token CHORD_SLASH "/"
 223 %token ANGLE_OPEN "<"
 224 %token ANGLE_CLOSE ">"
 225 %token DOUBLE_ANGLE_OPEN "<<"
 226 %token DOUBLE_ANGLE_CLOSE ">>"
 227 %token E_BACKSLASH "\\"
 228 %token E_ANGLE_CLOSE "\\>"
 229 %token E_CHAR "\\C[haracter]"
 230 %token E_CLOSE "\\)"
 231 %token E_EXCLAMATION "\\!"
 232 %token E_BRACKET_OPEN "\\["
 233 %token E_OPEN "\\("
 234 %token E_BRACKET_CLOSE "\\]"
 235 %token E_ANGLE_OPEN "\\<"
 236 %token E_PLUS "\\+"
 237 %token E_TILDE "\\~"
 238 %token EXTENDER "__"
 239
 240 /*
 241 If we give names, Bison complains.
 242 */
 243 %token FIGURE_CLOSE /* "\\>" */
 244 %token FIGURE_OPEN /* "\\<" */
 245 %token FIGURE_SPACE "_"
 246 %token HYPHEN "--"
 247
 248 %token CHORDMODIFIERS
 249 %token LYRIC_MARKUP
 250 %token MULTI_MEASURE_REST
 251
 252
 253 %token <i> DIGIT
 254 %token <i> E_UNSIGNED
 255 %token <i> UNSIGNED
 256
 257 /* Artificial tokens, for more generic function syntax */
 258 %token <i> EXPECT_MARKUP;
 259 %token <i> EXPECT_MUSIC;
 260 %token <i> EXPECT_SCM;
 261 /* After the last argument. */
 262 %token <i> EXPECT_NO_MORE_ARGS;
 263
 264 %token <scm> BOOK_IDENTIFIER
 265 %token <scm> CHORDMODIFIER_PITCH
 266 %token <scm> CHORD_MODIFIER
 267 %token <scm> CONTEXT_DEF_IDENTIFIER
 268 %token <scm> DRUM_PITCH
 269 %token <scm> DURATION_IDENTIFIER
 270 %token <scm> EVENT_IDENTIFIER
 271 %token <scm> FRACTION
 272 %token <scm> LYRICS_STRING
 273 %token <scm> LYRIC_MARKUP_IDENTIFIER
 274 %token <scm> MARKUP_HEAD_EMPTY
 275 %token <scm> MARKUP_HEAD_LIST0
 276 %token <scm> MARKUP_HEAD_MARKUP0
 277 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 278 %token <scm> MARKUP_HEAD_SCM0
 279 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 280 %token <scm> MARKUP_HEAD_SCM0_SCM1
 281 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 282 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 283 %token <scm> MARKUP_IDENTIFIER
 284 %token <scm> MUSIC_FUNCTION
 285 %token <scm> MUSIC_IDENTIFIER
 286 %token <scm> NOTENAME_PITCH
 287 %token <scm> NUMBER_IDENTIFIER
 288 %token <scm> OUTPUT_DEF_IDENTIFIER
 289 %token <scm> REAL
 290 %token <scm> RESTNAME
 291 %token <scm> SCM_IDENTIFIER
 292 %token <scm> SCM_TOKEN
 293 %token <scm> SCORE_IDENTIFIER
 294 %token <scm> STRING
 295 %token <scm> STRING_IDENTIFIER
 296 %token <scm> TONICNAME_PITCH
 297
 298
 299 %type <book> book_block
 300 %type <book> book_body
 301
 302 %type <i> bare_unsigned
 303 %type <scm> figured_bass_alteration
 304 %type <i> dots
 305 %type <i> exclamations
 306 %type <i> optional_rest
 307 %type <i> questions
 308 %type <i> script_dir
 309 %type <i> sub_quotes
 310 %type <i> sup_quotes
 311 %type <i> tremolo_type
 312
 313 /* Music */
 314 %type <scm> composite_music
 315 %type <scm> grouped_music_list
 316 %type <scm> music
 317 %type <scm> prefix_composite_music
 318 %type <scm> repeated_music
 319 %type <scm> sequential_music
 320 %type <scm> simple_music
 321 %type <scm> simultaneous_music
 322 %type <scm> chord_body
 323 %type <scm> chord_body_element
 324 %type <scm> command_element
 325 %type <scm> command_event
 326 %type <scm> context_change
 327 %type <scm> direction_less_event
 328 %type <scm> direction_reqd_event
 329 %type <scm> event_chord
 330 %type <scm> gen_text_def
 331 %type <scm> music_property_def
 332 %type <scm> note_chord_element
 333 %type <scm> post_event
 334 %type <scm> re_rhythmed_music
 335 %type <scm> relative_music
 336 %type <scm> simple_element
 337 %type <scm> simple_music_property_def
 338 %type <scm> string_number_event
 339 %type <scm> tempo_event
 340
 341 %type <outputdef> output_def_body
 342 %type <outputdef> output_def_head
 343 %type <outputdef> output_def_head_with_mode_switch
 344 %type <outputdef> output_def
 345 %type <outputdef> paper_block
 346
 347 %type <scm> alternative_music
 348 %type <scm> generic_prefix_music_scm
 349 %type <scm> music_list
 350 %type <scm> absolute_pitch
 351 %type <scm> assignment_id
 352 %type <scm> bare_number
 353 %type <scm> unsigned_number
 354 %type <scm> bass_figure
 355 %type <scm> figured_bass_modification
 356 %type <scm> br_bass_figure
 357 %type <scm> bass_number
 358 %type <scm> chord_body_elements
 359 %type <scm> chord_item
 360 %type <scm> chord_items
 361 %type <scm> chord_separator
 362 %type <scm> context_def_mod
 363 %type <scm> context_def_spec_block
 364 %type <scm> context_def_spec_body
 365 %type <scm> context_mod
 366 %type <scm> context_mod_list
 367 %type <scm> context_prop_spec
 368 %type <scm> direction_less_char
 369 %type <scm> duration_length
 370 %type <scm> embedded_scm
 371 %type <scm> figure_list
 372 %type <scm> figure_spec
 373 %type <scm> fraction
 374 %type <scm> full_markup
 375 %type <scm> function_scm_argument
 376 %type <scm> function_arglist
 377 %type <scm> function_arglist_music_last
 378 %type <scm> function_arglist_nonmusic_last
 379 %type <scm> function_arglist_nonmusic
 380 %type <scm> identifier_init
 381 %type <scm> lilypond_header
 382 %type <scm> lilypond_header_body
 383 %type <scm> lyric_element
 384 %type <scm> lyric_markup
 385 %type <scm> markup
 386 %type <scm> markup_braced_list
 387 %type <scm> markup_braced_list_body
 388 %type <scm> markup_composed_list
 389 %type <scm> markup_head_1_item
 390 %type <scm> markup_head_1_list
 391 %type <scm> markup_list
 392 %type <scm> markup_top
 393 %type <scm> mode_changing_head
 394 %type <scm> mode_changing_head_with_context
 395 %type <scm> multiplied_duration
 396 %type <scm> music_function_identifier_musicless_prefix
 397 %type <scm> music_function_event
 398 %type <scm> music_function_chord_body
 399 %type <scm> new_chord
 400 %type <scm> new_lyrics
 401 %type <scm> number_expression
 402 %type <scm> number_factor
 403 %type <scm> number_term
 404 %type <scm> object_id_setting
 405 %type <scm> octave_check
 406 %type <scm> optional_context_mod
 407 %type <scm> optional_id
 408 %type <scm> optional_notemode_duration
 409 %type <scm> pitch
 410 %type <scm> pitch_also_in_chords
 411 %type <scm> post_events
 412 %type <scm> property_operation
 413 %type <scm> property_path
 414 %type <scm> scalar
 415 %type <scm> script_abbreviation
 416 %type <scm> simple_chord_elements
 417 %type <scm> simple_markup
 418 %type <scm> simple_string
 419 %type <scm> steno_duration
 420 %type <scm> steno_pitch
 421 %type <scm> steno_tonic_pitch
 422 %type <scm> step_number
 423 %type <scm> step_numbers
 424 %type <scm> string
 425
 426 %type <score> score_block
 427 %type <score> score_body
 428
 429
 430 %left '-' '+'
 431
 432 /* We don't assign precedence to / and *, because we might need varied
 433 prec levels in different prods */
 434
 435 %left UNARY_MINUS
 436
 437 %%
 438
 439 lilypond:       /* empty */
 440         | lilypond toplevel_expression {
 441         }
 442         | lilypond assignment {
 443         }
 444         | lilypond error {
 445                 PARSER->error_level_ = 1;
 446         }
 447         | lilypond INVALID      {
 448                 PARSER->error_level_ = 1;
 449         }
 450         ;
 451
 452
 453 object_id_setting:
 454         OBJECTID STRING { $$ = $2; }
 455         ;
 456
 457 toplevel_expression:
 458         lilypond_header {
 459                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 460         }
 461         | book_block {
 462                 Book *book = $1;
 463                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 464                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 465                 book->unprotect ();
 466         }
 467         | score_block {
 468                 Score *score = $1;
 469
 470                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 471                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 472                 score->unprotect ();
 473         }
 474         | composite_music {
 475                 Music *music = unsmob_music ($1);
 476                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 477                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 478         }
 479         | full_markup {
 480                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 481                 scm_call_2 (proc, PARSER->self_scm (), $1);
 482         }
 483         | output_def {
 484                 SCM id = SCM_EOL;
 485                 Output_def * od = $1;
 486
 487                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 488                         id = ly_symbol2scm ("$defaultpaper");
 489                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 490                         id = ly_symbol2scm ("$defaultmidi");
 491                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 492                         id = ly_symbol2scm ("$defaultlayout");
 493
 494                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 495                 od->unprotect();
 496         }
 497         ;
 498
 499 embedded_scm:
 500         SCM_TOKEN
 501         | SCM_IDENTIFIER
 502         ;
 503
 504
 505 lilypond_header_body:
 506         {
 507                 $$ = get_header (PARSER);
 508                 PARSER->lexer_->add_scope ($$);
 509         }
 510         | lilypond_header_body assignment  {
 511
 512         }
 513         ;
 514
 515 lilypond_header:
 516         HEADER '{' lilypond_header_body '}'     {
 517                 $$ = PARSER->lexer_->remove_scope ();
 518         }
 519         ;
 520
 521 /*
 522         DECLARATIONS
 523 */
 524 assignment_id:
 525         STRING          { $$ = $1; }
 526         | LYRICS_STRING { $$ = $1; }
 527         ;
 528
 529 assignment:
 530         assignment_id '=' identifier_init  {
 531                 PARSER->lexer_->set_identifier ($1, $3);
 532
 533 /*
 534  TODO: devise standard for protection in parser.
 535
 536   The parser stack lives on the C-stack, which means that
 537 all objects can be unprotected as soon as they're here.
 538
 539 */
 540         }
 541         | embedded_scm { }
 542         ;
 543
 544
 545 identifier_init:
 546         score_block {
 547                 $$ = $1->self_scm ();
 548                 $1->unprotect ();
 549         }
 550         | book_block {
 551                 $$ = $1->self_scm ();
 552                 $1->unprotect ();
 553         }
 554         | output_def {
 555                 $$ = $1->self_scm ();
 556                 $1->unprotect ();
 557         }
 558         | context_def_spec_block {
 559                 $$ = $1;
 560         }
 561         | music  {
 562                 /* Hack: Create event-chord around standalone events.
 563                    Prevents the identifier from being interpreted as a post-event. */
 564                 Music *mus = unsmob_music ($1);
 565                 bool is_event = mus &&
 566                         (scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
 567                                 != SCM_BOOL_F);
 568                 if (!is_event)
 569                         $$ = $1;
 570                 else
 571                         $$ = MAKE_SYNTAX ("event-chord", @$, scm_list_1 ($1));
 572         }
 573         | post_event {
 574                 $$ = $1;
 575         }
 576         | number_expression {
 577                 $$ = $1;
 578         }
 579         | string {
 580                 $$ = $1;
 581         }
 582         | embedded_scm {
 583                 $$ = $1;
 584         }
 585         | full_markup {
 586                 $$ = $1;
 587         }
 588         | DIGIT {
 589                 $$ = scm_from_int ($1);
 590         }
 591         ;
 592
 593 context_def_spec_block:
 594         CONTEXT '{' context_def_spec_body '}'
 595                 {
 596                 $$ = $3;
 597         }
 598         ;
 599
 600 context_def_spec_body:
 601         /**/ {
 602                 $$ = Context_def::make_scm ();
 603                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 604         }
 605         | CONTEXT_DEF_IDENTIFIER {
 606                 $$ = $1;
 607                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 608         }
 609         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 610                 Context_def*td = unsmob_context_def ($$);
 611
 612                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 613                         SCM tag = scm_caar (p);
 614
 615                         /* TODO: should make new tag "grob-definition" ? */
 616                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 617                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 618                 }
 619         }
 620         | context_def_spec_body context_mod {
 621                 unsmob_context_def ($$)->add_context_mod ($2);
 622         }
 623         ;
 624
 625
 626
 627 book_block:
 628         BOOK '{' book_body '}'  {
 629                 $$ = $3;
 630         }
 631         ;
 632
 633 /* FIXME:
 634    * Use 'handlers' like for toplevel-* stuff?
 635    * grok \layout and \midi?  */
 636 book_body:
 637         {
 638                 $$ = new Book;
 639                 $$->origin ()->set_spot (@$);
 640                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 641                 $$->paper_->unprotect ();
 642                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 643         }
 644         | BOOK_IDENTIFIER {
 645                 $$ = unsmob_book ($1);
 646                 $$->protect ();
 647                 $$->origin ()->set_spot (@$);
 648         }
 649         | book_body paper_block {
 650                 $$->paper_ = $2;
 651                 $2->unprotect ();
 652         }
 653         | book_body score_block {
 654                 SCM s = $2->self_scm ();
 655                 $$->add_score (s);
 656                 $2->unprotect();
 657         }
 658         | book_body full_markup {
 659                 $$->add_score ($2);
 660         }
 661         | book_body lilypond_header {
 662                 $$->header_ = $2;
 663         }
 664         | book_body error {
 665                 $$->paper_ = 0;
 666                 $$->scores_ = SCM_EOL;
 667         }
 668         | book_body object_id_setting {
 669                 $$->user_key_ = ly_scm2string ($2);
 670         }
 671         ;
 672
 673 score_block:
 674         SCORE '{' score_body '}'        {
 675                 $$ = $3;
 676         }
 677         ;
 678
 679 score_body:
 680         music {
 681                 SCM m = $1;
 682                 SCM scorify = ly_lily_module_constant ("scorify-music");
 683                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 684
 685                 // pass ownernship to C++ again.
 686                 $$ = unsmob_score (score);
 687                 $$->protect ();
 688                 $$->origin ()->set_spot (@$);
 689         }
 690         | SCORE_IDENTIFIER {
 691                 $$ = unsmob_score ($1);
 692                 $$->protect ();
 693                 $$->origin ()->set_spot (@$);
 694         }
 695         | score_body object_id_setting {
 696                 $$->user_key_ = ly_scm2string ($2);
 697         }
 698         | score_body lilypond_header    {
 699                 $$->header_ = $2;
 700         }
 701         | score_body output_def {
 702                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 703                 {
 704                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 705
 706                 }
 707                 else
 708                 {
 709                         $$->add_output_def ($2);
 710                 }
 711                 $2->unprotect ();
 712         }
 713         | score_body error {
 714                 $$->error_found_ = true;
 715         }
 716         ;
 717
 718
 719 /*
 720         OUTPUT DEF
 721 */
 722
 723 paper_block:
 724         output_def {
 725                 $$ = $1;
 726                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 727                 {
 728                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
 729                         $1->unprotect ();
 730                         $$ = get_paper (PARSER);
 731                 }
 732         }
 733         ;
 734
 735
 736 output_def:
 737         output_def_body '}' {
 738                 $$ = $1;
 739
 740                 PARSER->lexer_->remove_scope ();
 741                 PARSER->lexer_->pop_state ();
 742         }
 743         ;
 744
 745 output_def_head:
 746         PAPER {
 747                 $$ = get_paper (PARSER);
 748                 $$->input_origin_ = @$;
 749                 PARSER->lexer_->add_scope ($$->scope_);
 750         }
 751         | MIDI    {
 752                 Output_def *p = get_midi (PARSER);
 753                 $$ = p;
 754                 PARSER->lexer_->add_scope (p->scope_);
 755         }
 756         | LAYOUT        {
 757                 Output_def *p = get_layout (PARSER);
 758
 759                 PARSER->lexer_->add_scope (p->scope_);
 760                 $$ = p;
 761         }
 762         ;
 763
 764 output_def_head_with_mode_switch:
 765         output_def_head {
 766                 PARSER->lexer_->push_initial_state ();
 767                 $$ = $1;
 768         }
 769         ;
 770
 771 output_def_body:
 772         output_def_head_with_mode_switch '{' {
 773                 $$ = $1;
 774                 $$->input_origin_.set_spot (@$);
 775         }
 776         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 777                 $1->unprotect ();
 778
 779                 Output_def *o = unsmob_output_def ($3);
 780                 o->input_origin_.set_spot (@$);
 781                 $$ = o;
 782                 $$->protect ();
 783                 PARSER->lexer_->remove_scope ();
 784                 PARSER->lexer_->add_scope (o->scope_);
 785         }
 786         | output_def_body assignment  {
 787
 788         }
 789         | output_def_body context_def_spec_block        {
 790                 assign_context_def ($$, $2);
 791         }
 792         | output_def_body error {
 793
 794         }
 795         ;
 796
 797 tempo_event:
 798         TEMPO steno_duration '=' bare_unsigned  {
 799                 $$ = MAKE_SYNTAX ("tempo", @$, $2, scm_int2num ($4));
 800         }
 801         ;
 802
 803 /*
 804 The representation of a  list is the
 805
 806   (LIST . LAST-CONS)
 807
 808  to have efficient append.  */
 809
 810 music_list:
 811         /* empty */ {
 812                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 813         }
 814         | music_list music {
 815                 SCM s = $$;
 816                 SCM c = scm_cons ($2, SCM_EOL);
 817
 818                 if (scm_is_pair (scm_cdr (s)))
 819                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 820                 else
 821                         scm_set_car_x (s, c); /* set first cons */
 822                 scm_set_cdr_x (s, c);  /* remember last cell */
 823         }
 824         | music_list embedded_scm {
 825
 826         }
 827         | music_list error {
 828                 Music *m = MY_MAKE_MUSIC("Music", @$);
 829                 // ugh. code dup
 830                 m->set_property ("error-found", SCM_BOOL_T);
 831                 SCM s = $$;
 832                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 833                 m->unprotect (); /* UGH */
 834
 835                 if (scm_is_pair (scm_cdr (s)))
 836                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 837                 else
 838                         scm_set_car_x (s, c); /* set first cons */
 839                 scm_set_cdr_x (s, c);  /* remember last cell */
 840         }
 841         ;
 842
 843 music:
 844         simple_music
 845         | composite_music
 846         ;
 847
 848 alternative_music:
 849         /* empty */ {
 850                 $$ = SCM_EOL;
 851         }
 852         | ALTERNATIVE '{' music_list '}' {
 853                 $$ = scm_car ($3);
 854         }
 855         ;
 856
 857
 858 repeated_music:
 859         REPEAT simple_string unsigned_number music alternative_music
 860         {
 861                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $5);
 862         }
 863         ;
 864
 865 sequential_music:
 866         SEQUENTIAL '{' music_list '}'           {
 867                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($3));
 868         }
 869         | '{' music_list '}'            {
 870                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($2));
 871         }
 872         ;
 873
 874 simultaneous_music:
 875         SIMULTANEOUS '{' music_list '}'{
 876                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($3));
 877         }
 878         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
 879                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($2));
 880         }
 881         ;
 882
 883 simple_music:
 884         event_chord
 885         | MUSIC_IDENTIFIER
 886         | music_property_def
 887         | context_change
 888         ;
 889
 890 optional_context_mod:
 891         /**/ { $$ = SCM_EOL; }
 892         | WITH { PARSER->lexer_->push_initial_state (); }
 893         '{' context_mod_list '}'
 894         {
 895                 PARSER->lexer_->pop_state ();
 896                 $$ = $4;
 897         }
 898         ;
 899
 900 context_mod_list:
 901         /* */  { $$ = SCM_EOL; }
 902         | context_mod_list context_mod  {
 903                  $$ = scm_cons ($2, $1);
 904         }
 905         ;
 906
 907 composite_music:
 908         prefix_composite_music { $$ = $1; }
 909         | grouped_music_list { $$ = $1; }
 910         ;
 911
 912 grouped_music_list:
 913         simultaneous_music              { $$ = $1; }
 914         | sequential_music              { $$ = $1; }
 915         ;
 916
 917 function_scm_argument:
 918         embedded_scm
 919         | simple_string
 920         ;
 921
 922 /* An argument list. If a function \foo expects scm scm music, then the lexer expands \foo into the token sequence:
 923  MUSIC_FUNCTION EXPECT_MUSIC EXPECT_SCM EXPECT_SCM
 924 and this rule returns the reversed list of arguments. */
 925
 926 function_arglist_music_last:
 927         EXPECT_MUSIC function_arglist music {
 928                 $$ = scm_cons ($3, $2);
 929         }
 930         ;
 931
 932 function_arglist_nonmusic_last:
 933         EXPECT_MARKUP function_arglist full_markup {
 934                 $$ = scm_cons ($3, $2);
 935         }
 936         | EXPECT_SCM function_arglist function_scm_argument {
 937                 $$ = scm_cons ($3, $2);
 938         }
 939         ;
 940
 941 function_arglist_nonmusic: EXPECT_NO_MORE_ARGS {
 942                 $$ = SCM_EOL;
 943         }
 944         | EXPECT_MARKUP function_arglist_nonmusic full_markup {
 945                 $$ = scm_cons ($3, $2);
 946         }
 947         | EXPECT_SCM function_arglist_nonmusic function_scm_argument {
 948                 $$ = scm_cons ($3, $2);
 949         }
 950         ;
 951
 952 function_arglist: EXPECT_NO_MORE_ARGS {
 953                 /* This is for 0-ary functions, so they don't need to
 954                    read a lookahead token */
 955                 $$ = SCM_EOL;
 956         }
 957         | function_arglist_music_last
 958         | function_arglist_nonmusic_last
 959         ;
 960
 961 generic_prefix_music_scm:
 962         MUSIC_FUNCTION function_arglist {
 963                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
 964         }
 965         ;
 966
 967
 968 optional_id:
 969         /**/ { $$ = SCM_EOL; }
 970         | '=' simple_string {
 971                 $$ = $2;
 972         }
 973         ;
 974
 975
 976 prefix_composite_music:
 977         generic_prefix_music_scm {
 978                 $$ = run_music_function (PARSER, $1);
 979         }
 980         | CONTEXT simple_string optional_id optional_context_mod music {
 981                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, $4, SCM_BOOL_F);
 982         }
 983         | NEWCONTEXT simple_string optional_id optional_context_mod music {
 984                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, $4, SCM_BOOL_T);
 985         }
 986
 987         | TIMES fraction music {
 988                 $$ = MAKE_SYNTAX ("time-scaled-music", @$, $2, $3);
 989         }
 990         | repeated_music                { $$ = $1; }
 991         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords music {
 992                 Pitch from = *unsmob_pitch ($2);
 993                 Pitch to = *unsmob_pitch ($3);
 994                 SCM pitch = pitch_interval (from, to).smobbed_copy ();
 995                 $$ = MAKE_SYNTAX ("transpose-music", @$, pitch, $4);
 996         }
 997         | mode_changing_head grouped_music_list {
 998                 if ($1 == ly_symbol2scm ("chords"))
 999                 {
1000                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1001                 }
1002                 else
1003                 {
1004                   $$ = $2;
1005                 }
1006                 PARSER->lexer_->pop_state ();
1007         }
1008         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1009                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, $3, $2, SCM_BOOL_T);
1010                 if ($1 == ly_symbol2scm ("ChordNames"))
1011                 {
1012                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1013                 }
1014                 PARSER->lexer_->pop_state ();
1015         }
1016         | relative_music        { $$ = $1; }
1017         | re_rhythmed_music     { $$ = $1; }
1018         ;
1019
1020 mode_changing_head:
1021         NOTEMODE {
1022                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1023                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1024
1025                 $$ = ly_symbol2scm ("notes");
1026         }
1027         | DRUMMODE
1028                 {
1029                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1030                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1031
1032                 $$ = ly_symbol2scm ("drums");
1033         }
1034         | FIGUREMODE {
1035                 PARSER->lexer_->push_figuredbass_state ();
1036
1037                 $$ = ly_symbol2scm ("figures");
1038         }
1039         | CHORDMODE {
1040                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1041                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1042                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1043                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1044                 $$ = ly_symbol2scm ("chords");
1045
1046         }
1047         | LYRICMODE
1048                 { PARSER->lexer_->push_lyric_state ();
1049                 $$ = ly_symbol2scm ("lyrics");
1050         }
1051         ;
1052
1053 mode_changing_head_with_context:
1054         DRUMS {
1055                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1056                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1057
1058                 $$ = ly_symbol2scm ("DrumStaff");
1059         }
1060         | FIGURES {
1061                 PARSER->lexer_->push_figuredbass_state ();
1062
1063                 $$ = ly_symbol2scm ("FiguredBass");
1064         }
1065         | CHORDS {
1066                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1067                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1068                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1069                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1070                 $$ = ly_symbol2scm ("ChordNames");
1071         }
1072         | LYRICS
1073                 { PARSER->lexer_->push_lyric_state ();
1074                 $$ = ly_symbol2scm ("Lyrics");
1075         }
1076         ;
1077
1078
1079 relative_music:
1080         RELATIVE absolute_pitch music {
1081                 Pitch start = *unsmob_pitch ($2);
1082                 $$ = make_music_relative (start, $3, @$);
1083         }
1084         | RELATIVE composite_music {
1085                 Pitch middle_c (0, 0, 0);
1086                 $$ = make_music_relative (middle_c, $2, @$);
1087         }
1088         ;
1089
1090 new_lyrics:
1091         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1092         /*cont */
1093         grouped_music_list {
1094         /* Can also use music at the expensive of two S/Rs similar to
1095            \repeat \alternative */
1096                 PARSER->lexer_->pop_state ();
1097
1098                 $$ = scm_cons ($3, SCM_EOL);
1099         }
1100         | new_lyrics ADDLYRICS {
1101                 PARSER->lexer_->push_lyric_state ();
1102         } grouped_music_list {
1103                 PARSER->lexer_->pop_state ();
1104                 $$ = scm_cons ($4, $1);
1105         }
1106         ;
1107
1108 re_rhythmed_music:
1109         grouped_music_list new_lyrics {
1110                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1111         }
1112         | LYRICSTO simple_string {
1113                 PARSER->lexer_->push_lyric_state ();
1114         } music {
1115                 PARSER->lexer_->pop_state ();
1116                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1117         }
1118         ;
1119
1120 context_change:
1121         CHANGE STRING '=' STRING  {
1122                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1123         }
1124         ;
1125
1126
1127 property_path:
1128         embedded_scm {
1129                 $$ = scm_cons ($1, SCM_EOL);
1130         }
1131         | property_path embedded_scm {
1132                 $$ = scm_cons ($2, $1);
1133         }
1134         ;
1135
1136 property_operation:
1137         STRING '=' scalar {
1138                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1139                         scm_string_to_symbol ($1), $3);
1140         }
1141         | UNSET simple_string {
1142                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1143                         scm_string_to_symbol ($2));
1144         }
1145         | OVERRIDE simple_string property_path '=' embedded_scm {
1146                 $$ = scm_append (scm_list_2 (scm_list_3 (ly_symbol2scm ("push"),
1147                                                         scm_string_to_symbol ($2), $5),
1148                                              $3));
1149         }
1150         | REVERT simple_string embedded_scm {
1151                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1152                         scm_string_to_symbol ($2), $3);
1153         }
1154         ;
1155
1156 context_def_mod:
1157         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1158         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1159
1160         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1161         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1162         | DENIES { $$ = ly_symbol2scm ("denies"); }
1163
1164         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1165         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1166         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1167         | NAME { $$ = ly_symbol2scm ("context-name"); }
1168         ;
1169
1170 context_mod:
1171         property_operation { $$ = $1; }
1172         | context_def_mod STRING {
1173                 $$ = scm_list_2 ($1, $2);
1174         }
1175         ;
1176
1177 context_prop_spec:
1178         simple_string {
1179                 if (!is_regular_identifier ($1))
1180                 {
1181                         @$.error (_("Grob name should be alphanumeric"));
1182                 }
1183
1184                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1185                         scm_string_to_symbol ($1));
1186         }
1187         | simple_string '.' simple_string {
1188                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1189                         scm_string_to_symbol ($3));
1190         }
1191         ;
1192
1193 simple_music_property_def:
1194         OVERRIDE context_prop_spec property_path '=' scalar {
1195                 $$ = scm_append (scm_list_2 (scm_list_n (scm_car ($2),
1196                                 ly_symbol2scm ("OverrideProperty"),
1197                                 scm_cadr ($2),
1198                                 $5, SCM_UNDEFINED),
1199                                 $3));
1200         }
1201         | REVERT context_prop_spec embedded_scm {
1202                 $$ = scm_list_4 (scm_car ($2),
1203                         ly_symbol2scm ("RevertProperty"),
1204                         scm_cadr ($2),
1205                         $3);
1206         }
1207         | SET context_prop_spec '=' scalar {
1208                 $$ = scm_list_4 (scm_car ($2),
1209                         ly_symbol2scm ("PropertySet"),
1210                         scm_cadr ($2),
1211                         $4);
1212         }
1213         | UNSET context_prop_spec {
1214                 $$ = scm_list_3 (scm_car ($2),
1215                         ly_symbol2scm ("PropertyUnset"),
1216                         scm_cadr ($2));
1217         }
1218         ;
1219
1220 music_property_def:
1221         simple_music_property_def {
1222                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_F, $1)));
1223         }
1224         | ONCE simple_music_property_def {
1225                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_T, $2)));
1226         }
1227         ;
1228
1229 string:
1230         STRING {
1231                 $$ = $1;
1232         }
1233         | STRING_IDENTIFIER {
1234                 $$ = $1;
1235         }
1236         | string '+' string {
1237                 $$ = scm_string_append (scm_list_2 ($1, $3));
1238         }
1239         ;
1240
1241 simple_string: STRING {
1242                 $$ = $1;
1243         }
1244         | LYRICS_STRING {
1245                 $$ = $1;
1246         }
1247         | STRING_IDENTIFIER {
1248                 $$ = $1;
1249         }
1250         ;
1251
1252 scalar: string {
1253                 $$ = $1;
1254         }
1255         | LYRICS_STRING {
1256                 $$ = $1;
1257         }
1258         | bare_number {
1259                 $$ = $1;
1260         }
1261         | embedded_scm {
1262                 $$ = $1;
1263         }
1264         | full_markup {
1265                 $$ = $1;
1266         }
1267         | DIGIT {
1268                 $$ = scm_from_int ($1);
1269         }
1270         ;
1271
1272 event_chord:
1273         /* TODO: Create a special case that avoids the creation of
1274            EventChords around simple_elements that have no post_events?
1275          */
1276         simple_chord_elements post_events       {
1277                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1278
1279                 Input i;
1280                 /* why is this giving wrong start location? -ns
1281                  * i = @$; */
1282                 i.set_location (@1, @2);
1283                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1284         }
1285         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1286                 Input i;
1287                 i.set_location (@1, @3);
1288                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2, $3);
1289         }
1290         | command_element
1291         | note_chord_element
1292         ;
1293
1294
1295 note_chord_element:
1296         chord_body optional_notemode_duration post_events
1297         {
1298                 Music *m = unsmob_music ($1);
1299                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1300                 SCM es = m->get_property ("elements");
1301                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1302
1303                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1304                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1305                 es = ly_append2 (es, postevs);
1306
1307                 m-> set_property ("elements", es);
1308                 m->set_spot (@$);
1309                 $$ = m->self_scm ();
1310         }
1311         ;
1312
1313 chord_body:
1314         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1315         {
1316                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1317         }
1318         ;
1319
1320 chord_body_elements:
1321         /* empty */             { $$ = SCM_EOL; }
1322         | chord_body_elements chord_body_element {
1323                 $$ = scm_cons ($2, $1);
1324         }
1325         ;
1326
1327 chord_body_element:
1328         pitch exclamations questions octave_check post_events
1329         {
1330                 int q = $3;
1331                 int ex = $2;
1332                 SCM check = $4;
1333                 SCM post = $5;
1334
1335                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1336                 n->set_property ("pitch", $1);
1337                 if (q % 2)
1338                         n->set_property ("cautionary", SCM_BOOL_T);
1339                 if (ex % 2 || q % 2)
1340                         n->set_property ("force-accidental", SCM_BOOL_T);
1341
1342                 if (scm_is_pair (post)) {
1343                         SCM arts = scm_reverse_x (post, SCM_EOL);
1344                         n->set_property ("articulations", arts);
1345                 }
1346                 if (scm_is_number (check))
1347                 {
1348                         int q = scm_to_int (check);
1349                         n->set_property ("absolute-octave", scm_from_int (q-1));
1350                 }
1351
1352                 $$ = n->unprotect ();
1353         }
1354         | DRUM_PITCH post_events {
1355                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1356                 n->set_property ("duration", $2);
1357                 n->set_property ("drum-type", $1);
1358
1359                 if (scm_is_pair ($2)) {
1360                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1361                         n->set_property ("articulations", arts);
1362                 }
1363                 $$ = n->unprotect ();
1364         }
1365         | music_function_chord_body {
1366                 $$ = run_music_function (PARSER, $1);
1367         }
1368         ;
1369
1370 music_function_identifier_musicless_prefix: MUSIC_FUNCTION {
1371                 SCM sig = scm_object_property (yylval.scm, ly_symbol2scm ("music-function-signature"));
1372                 if (scm_is_pair (sig) && to_boolean (scm_memq (ly_music_p_proc, scm_cdr (scm_reverse (sig)))))
1373                 {
1374                         PARSER->parser_error (@$, "Music function applied to event may not have a Music argument, except as the last argument.");
1375                 }
1376         }
1377         ;
1378
1379 music_function_chord_body:
1380         /* We could allow chord functions to have multiple music arguments,
1381            but it's more consistent with music_function_event if we
1382            prohibit it here too */
1383         music_function_identifier_musicless_prefix EXPECT_MUSIC function_arglist_nonmusic chord_body_element {
1384                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($3, scm_list_1 ($4)));
1385         }
1386         | music_function_identifier_musicless_prefix function_arglist_nonmusic {
1387                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1388         }
1389         ;
1390
1391 music_function_event:
1392         /* Post-events can only have the last argument as music, without this
1393            restriction we get a shift/reduce conflict from e.g.
1394            c8-\partcombine c8 -. */
1395         music_function_identifier_musicless_prefix EXPECT_MUSIC function_arglist_nonmusic post_event {
1396                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($3, scm_list_1 ($4)));
1397         }
1398         | music_function_identifier_musicless_prefix function_arglist_nonmusic {
1399                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1400         }
1401         ;
1402
1403 command_element:
1404         command_event {
1405                 $$ = $1;
1406         }
1407         | SKIP duration_length {
1408                 $$ = MAKE_SYNTAX ("skip-music", @$, $2);
1409         }
1410         | E_BRACKET_OPEN {
1411                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1412                 m->set_property ("span-direction", scm_from_int (START));
1413                 $$ = m->unprotect();
1414         }
1415         | E_BRACKET_CLOSE {
1416                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1417                 m->set_property ("span-direction", scm_from_int (STOP));
1418                 $$ = m->unprotect ();
1419         }
1420         | E_BACKSLASH {
1421                 $$ = MAKE_SYNTAX ("voice-separator", @$, SCM_UNDEFINED);
1422         }
1423         | '|'      {
1424                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
1425
1426                 Music *m = unsmob_music (pipe);
1427                 if (m)
1428                 {
1429                         m = m->clone ();
1430                         m->set_spot (@$);
1431                         $$ = m->unprotect ();
1432                 }
1433                 else
1434                         $$ = MAKE_SYNTAX ("bar-check", @$, SCM_UNDEFINED);
1435
1436         }
1437         | PARTIAL duration_length       {
1438                 Moment m = - unsmob_duration ($2)->get_length ();
1439                 $$ = MAKE_SYNTAX ("property-operation", @$, SCM_BOOL_F, ly_symbol2scm ("Timing"), ly_symbol2scm ("PropertySet"), ly_symbol2scm ("measurePosition"), m.smobbed_copy ());
1440                 $$ = MAKE_SYNTAX ("context-specification", @$, ly_symbol2scm ("Score"), SCM_BOOL_F, $$, SCM_EOL, SCM_BOOL_F);
1441         }
1442
1443         | TIME_T fraction  {
1444                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1445
1446                 $$ = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1447         }
1448         | MARK scalar {
1449                 SCM proc = ly_lily_module_constant ("make-mark-set");
1450
1451                 $$ = scm_call_1 (proc, $2);
1452         }
1453         ;
1454
1455 command_event:
1456         E_TILDE {
1457                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent", @$)->unprotect ();
1458         }
1459         | MARK DEFAULT  {
1460                 Music *m = MY_MAKE_MUSIC ("MarkEvent", @$);
1461                 $$ = m->unprotect ();
1462         }
1463         | tempo_event {
1464                 $$ = $1;
1465         }
1466         | KEY DEFAULT {
1467                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1468                 $$ = key->unprotect ();
1469         }
1470         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1471
1472                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1473                 if (scm_ilength ($3) > 0)
1474                 {
1475                         key->set_property ("pitch-alist", $3);
1476                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1477                         key->transpose (* unsmob_pitch ($2));
1478                 } else {
1479                         PARSER->parser_error (@3, _ ("second argument must be pitch list"));
1480                 }
1481
1482                 $$ = key->unprotect ();
1483         }
1484         ;
1485
1486
1487 post_events:
1488         /* empty */ {
1489                 $$ = SCM_EOL;
1490         }
1491         | post_events post_event {
1492                 unsmob_music ($2)->set_spot (@2);
1493                 $$ = scm_cons ($2, $$);
1494         }
1495         ;
1496
1497 post_event:
1498         direction_less_event {
1499                 $$ = $1;
1500         }
1501         | '-' music_function_event {
1502                 $$ = run_music_function (PARSER, $2);
1503         }
1504         | HYPHEN {
1505                 if (!PARSER->lexer_->is_lyric_state ())
1506                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1507                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
1508         }
1509         | EXTENDER {
1510                 if (!PARSER->lexer_->is_lyric_state ())
1511                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1512                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
1513         }
1514         | script_dir direction_reqd_event {
1515                 if ($1)
1516                 {
1517                         Music *m = unsmob_music ($2);
1518                         m->set_property ("direction", scm_from_int ($1));
1519                 }
1520                 $$ = $2;
1521         }
1522         | script_dir direction_less_event {
1523                 if ($1)
1524                 {
1525                         Music *m = unsmob_music ($2);
1526                         m->set_property ("direction", scm_from_int ($1));
1527                 }
1528                 $$ = $2;
1529         }
1530         | string_number_event
1531         ;
1532
1533 string_number_event:
1534         E_UNSIGNED {
1535                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
1536                 s->set_property ("string-number", scm_from_int ($1));
1537                 $$ = s->unprotect ();
1538         }
1539         ;
1540
1541 direction_less_char:
1542         '['  {
1543                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1544         }
1545         | ']'  {
1546                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1547         }
1548         | '~'  {
1549                 $$ = ly_symbol2scm ("tildeSymbol");
1550         }
1551         | '('  {
1552                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1553         }
1554         | ')'  {
1555                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1556         }
1557         | E_EXCLAMATION  {
1558                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1559         }
1560         | E_OPEN  {
1561                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1562         }
1563         | E_CLOSE  {
1564                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1565         }
1566         | E_ANGLE_CLOSE  {
1567                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1568         }
1569         | E_ANGLE_OPEN  {
1570                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1571         }
1572         ;
1573
1574 direction_less_event:
1575         direction_less_char {
1576                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
1577                 Music *m = 0;
1578                 if (unsmob_music (predefd))
1579                 {
1580                         m = unsmob_music (predefd)->clone ();
1581                         m->set_spot (@$);
1582                 }
1583                 else
1584                 {
1585                         m = MY_MAKE_MUSIC ("Music", @$);
1586                 }
1587                 $$ = m->unprotect ();
1588         }
1589         | EVENT_IDENTIFIER      {
1590                 $$ = $1;
1591         }
1592         | tremolo_type  {
1593                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
1594                a->set_property ("tremolo-type", scm_from_int ($1));
1595                $$ = a->unprotect ();
1596         }
1597         ;
1598
1599 direction_reqd_event:
1600         gen_text_def {
1601                 $$ = $1;
1602         }
1603         | script_abbreviation {
1604                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1605                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
1606                 if (scm_is_string (s))
1607                         a->set_property ("articulation-type", s);
1608                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
1609                 $$ = a->unprotect ();
1610         }
1611         ;
1612
1613 octave_check:
1614         /**/ { $$ = SCM_EOL; }
1615         | '='  { $$ = scm_from_int (0); }
1616         | '=' sub_quotes { $$ = scm_from_int (-$2); }
1617         | '=' sup_quotes { $$ = scm_from_int ($2); }
1618         ;
1619
1620 sup_quotes:
1621         '\'' {
1622                 $$ = 1;
1623         }
1624         | sup_quotes '\'' {
1625                 $$ ++;
1626         }
1627         ;
1628
1629 sub_quotes:
1630         ',' {
1631                 $$ = 1;
1632         }
1633         | sub_quotes ',' {
1634                 $$++;
1635         }
1636         ;
1637
1638 steno_pitch:
1639         NOTENAME_PITCH  {
1640                 $$ = $1;
1641         }
1642         | NOTENAME_PITCH sup_quotes     {
1643                 Pitch p = *unsmob_pitch ($1);
1644                 p = p.transposed (Pitch ($2,0,0));
1645                 $$ = p.smobbed_copy ();
1646         }
1647         | NOTENAME_PITCH sub_quotes      {
1648                 Pitch p =* unsmob_pitch ($1);
1649                 p = p.transposed (Pitch (-$2,0,0));
1650                 $$ = p.smobbed_copy ();
1651         }
1652         ;
1653
1654 /*
1655 ugh. duplication
1656 */
1657
1658 steno_tonic_pitch:
1659         TONICNAME_PITCH {
1660                 $$ = $1;
1661         }
1662         | TONICNAME_PITCH sup_quotes    {
1663                 Pitch p = *unsmob_pitch ($1);
1664                 p = p.transposed (Pitch ($2,0,0));
1665                 $$ = p.smobbed_copy ();
1666         }
1667         | TONICNAME_PITCH sub_quotes     {
1668                 Pitch p = *unsmob_pitch ($1);
1669
1670                 p = p.transposed (Pitch (-$2,0,0));
1671                 $$ = p.smobbed_copy ();
1672         }
1673         ;
1674
1675 pitch:
1676         steno_pitch {
1677                 $$ = $1;
1678         }
1679         ;
1680
1681 pitch_also_in_chords:
1682         pitch
1683         | steno_tonic_pitch
1684         ;
1685
1686 gen_text_def:
1687         full_markup {
1688                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
1689                 t->set_property ("text", $1);
1690                 $$ = t->unprotect ();
1691         }
1692         | string {
1693                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
1694                 t->set_property ("text",
1695                         make_simple_markup ($1));
1696                 $$ = t->unprotect ();
1697         }
1698         | DIGIT {
1699                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
1700                 t->set_property ("digit", scm_from_int ($1));
1701                 $$ = t->unprotect ();
1702         }
1703         ;
1704
1705 script_abbreviation:
1706         '^'             {
1707                 $$ = scm_from_locale_string ("Hat");
1708         }
1709         | '+'           {
1710                 $$ = scm_from_locale_string ("Plus");
1711         }
1712         | '-'           {
1713                 $$ = scm_from_locale_string ("Dash");
1714         }
1715         | '|'           {
1716                 $$ = scm_from_locale_string ("Bar");
1717         }
1718         | ANGLE_CLOSE   {
1719                 $$ = scm_from_locale_string ("Larger");
1720         }
1721         | '.'           {
1722                 $$ = scm_from_locale_string ("Dot");
1723         }
1724         | '_' {
1725                 $$ = scm_from_locale_string ("Underscore");
1726         }
1727         ;
1728
1729 script_dir:
1730         '_'     { $$ = DOWN; }
1731         | '^'   { $$ = UP; }
1732         | '-'   { $$ = CENTER; }
1733         ;
1734
1735
1736 absolute_pitch:
1737         steno_pitch     {
1738                 $$ = $1;
1739         }
1740         ;
1741
1742 duration_length:
1743         multiplied_duration {
1744                 $$ = $1;
1745         }
1746         ;
1747
1748 optional_notemode_duration:
1749         {
1750                 Duration dd = PARSER->default_duration_;
1751                 $$ = dd.smobbed_copy ();
1752         }
1753         | multiplied_duration   {
1754                 $$ = $1;
1755                 PARSER->default_duration_ = *unsmob_duration ($$);
1756         }
1757         ;
1758
1759 steno_duration:
1760         bare_unsigned dots              {
1761                 int len = 0;
1762                 if (!is_duration ($1))
1763                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
1764                 else
1765                         len = intlog2 ($1);
1766
1767                 $$ = Duration (len, $2).smobbed_copy ();
1768         }
1769         | DURATION_IDENTIFIER dots      {
1770                 Duration *d = unsmob_duration ($1);
1771                 Duration k (d->duration_log (), d->dot_count () + $2);
1772                 *d = k;
1773                 $$ = $1;
1774         }
1775         ;
1776
1777 multiplied_duration:
1778         steno_duration {
1779                 $$ = $1;
1780         }
1781         | multiplied_duration '*' bare_unsigned {
1782                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1783         }
1784         | multiplied_duration '*' FRACTION {
1785                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
1786
1787                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1788         }
1789         ;
1790
1791 fraction:
1792         FRACTION { $$ = $1; }
1793         | UNSIGNED '/' UNSIGNED {
1794                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
1795         }
1796         ;
1797
1798 dots:
1799         /* empty */     {
1800                 $$ = 0;
1801         }
1802         | dots '.' {
1803                 $$ ++;
1804         }
1805         ;
1806
1807 tremolo_type:
1808         ':'     {
1809                 $$ = 0;
1810         }
1811         | ':' bare_unsigned {
1812                 if (!is_duration ($2))
1813                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
1814                 $$ = $2;
1815         }
1816         ;
1817
1818 bass_number:
1819         DIGIT   {
1820                 $$ = scm_from_int ($1);
1821         }
1822         | UNSIGNED {
1823                 $$ = scm_from_int ($1);
1824         }
1825         | STRING { $$ = $1; }
1826         | full_markup { $$ = $1; }
1827         ;
1828
1829 figured_bass_alteration:
1830         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
1831         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
1832         | '!'   { $$ = scm_from_int (0); }
1833         ;
1834
1835 bass_figure:
1836         FIGURE_SPACE {
1837                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
1838                 $$ = bfr->unprotect ();
1839         }
1840         | bass_number  {
1841                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
1842                 $$ = bfr->self_scm ();
1843
1844                 if (scm_is_number ($1))
1845                         bfr->set_property ("figure", $1);
1846                 else if (Text_interface::is_markup ($1))
1847                         bfr->set_property ("text", $1);
1848
1849                 bfr->unprotect ();
1850         }
1851         | bass_figure ']' {
1852                 $$ = $1;
1853                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1854         }
1855         | bass_figure figured_bass_alteration {
1856                 Music *m = unsmob_music ($1);
1857                 if (scm_to_double ($2)) {
1858                         SCM salter = m->get_property ("alteration");
1859                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
1860                         m->set_property ("alteration",
1861                                          scm_sum (alter, $2));
1862                 } else {
1863                         m->set_property ("alteration", scm_from_int (0));
1864                 }
1865         }
1866         | bass_figure figured_bass_modification  {
1867                 Music *m = unsmob_music ($1);
1868                 if ($2 == ly_symbol2scm ("plus"))
1869                         {
1870                         m->set_property ("augmented", SCM_BOOL_T);
1871                         }
1872                 else if ($2 == ly_symbol2scm ("slash"))
1873                         {
1874                         m->set_property ("diminished", SCM_BOOL_T);
1875                         }
1876                 else if ($2 == ly_symbol2scm ("exclamation"))
1877                         {
1878                         m->set_property ("no-continuation", SCM_BOOL_T);
1879                         }
1880         }
1881         ;
1882
1883
1884 figured_bass_modification:
1885         E_PLUS          {
1886                 $$ = ly_symbol2scm ("plus");
1887         }
1888         | E_EXCLAMATION {
1889                 $$ = ly_symbol2scm ("exclamation");
1890         }
1891         | '/'           {
1892                 $$ = ly_symbol2scm ("slash");
1893         }
1894         ;
1895
1896 br_bass_figure:
1897         bass_figure {
1898                 $$ = $1;
1899         }
1900         | '[' bass_figure {
1901                 $$ = $2;
1902                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1903         }
1904         ;
1905
1906 figure_list:
1907         /**/            {
1908                 $$ = SCM_EOL;
1909         }
1910         | figure_list br_bass_figure {
1911                 $$ = scm_cons ($2, $1);
1912         }
1913         ;
1914
1915 figure_spec:
1916         FIGURE_OPEN figure_list FIGURE_CLOSE {
1917                 $$ = scm_reverse_x ($2, SCM_EOL);
1918         }
1919         ;
1920
1921
1922 optional_rest:
1923         /**/   { $$ = 0; }
1924         | REST { $$ = 1; }
1925         ;
1926
1927 simple_element:
1928         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
1929                 if (!PARSER->lexer_->is_note_state ())
1930                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
1931
1932                 Music *n = 0;
1933                 if ($6)
1934                         n = MY_MAKE_MUSIC ("RestEvent", @$);
1935                 else
1936                         n = MY_MAKE_MUSIC ("NoteEvent", @$);
1937
1938                 n->set_property ("pitch", $1);
1939                 n->set_property ("duration", $5);
1940
1941                 if (scm_is_number ($4))
1942                 {
1943                         int q = scm_to_int ($4);
1944                         n->set_property ("absolute-octave", scm_from_int (q-1));
1945                 }
1946
1947                 if ($3 % 2)
1948                         n->set_property ("cautionary", SCM_BOOL_T);
1949                 if ($2 % 2 || $3 % 2)
1950                         n->set_property ("force-accidental", SCM_BOOL_T);
1951
1952                 $$ = n->unprotect ();
1953         }
1954         | DRUM_PITCH optional_notemode_duration {
1955                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1956                 n->set_property ("duration", $2);
1957                 n->set_property ("drum-type", $1);
1958
1959                 $$ = n->unprotect ();
1960         }
1961         | RESTNAME optional_notemode_duration           {
1962                 Music *ev = 0;
1963                 if (ly_scm2string ($1) == "s") {
1964                         /* Space */
1965                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
1966                   }
1967                 else {
1968                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
1969
1970                     }
1971                 ev->set_property ("duration", $2);
1972                 $$ = ev->unprotect ();
1973         }
1974         | lyric_element optional_notemode_duration      {
1975                 if (!PARSER->lexer_->is_lyric_state ())
1976                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1977
1978                 Music *levent = MY_MAKE_MUSIC ("LyricEvent", @$);
1979                 levent->set_property ("text", $1);
1980                 levent->set_property ("duration",$2);
1981                 $$= levent->unprotect ();
1982         }
1983         ;
1984
1985 simple_chord_elements:
1986         simple_element  {
1987                 $$ = scm_list_1 ($1);
1988         }
1989         | new_chord {
1990                 if (!PARSER->lexer_->is_chord_state ())
1991                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
1992                 $$ = $1;
1993         }
1994         | figure_spec optional_notemode_duration {
1995                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
1996                 {
1997                         unsmob_music (scm_car (s))->set_property ("duration", $2);
1998                 }
1999                 $$ = $1;
2000         }
2001         ;
2002
2003 lyric_element:
2004         lyric_markup {
2005                 $$ = $1;
2006         }
2007         | LYRICS_STRING {
2008                 $$ = $1;
2009         }
2010         ;
2011
2012 new_chord:
2013         steno_tonic_pitch optional_notemode_duration   {
2014                 $$ = make_chord_elements ($1, $2, SCM_EOL);
2015         }
2016         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2017                 SCM its = scm_reverse_x ($4, SCM_EOL);
2018                 $$ = make_chord_elements ($1, $2, scm_cons ($3, its));
2019         }
2020         ;
2021
2022 chord_items:
2023         /**/ {
2024                 $$ = SCM_EOL;
2025         }
2026         | chord_items chord_item {
2027                 $$ = scm_cons ($2, $$);
2028         }
2029         ;
2030
2031 chord_separator:
2032         CHORD_COLON {
2033                 $$ = ly_symbol2scm ("chord-colon");
2034         }
2035         | CHORD_CARET {
2036                 $$ = ly_symbol2scm ("chord-caret");
2037         }
2038         | CHORD_SLASH steno_tonic_pitch {
2039                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2040         }
2041         | CHORD_BASS steno_tonic_pitch {
2042                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2043         }
2044         ;
2045
2046 chord_item:
2047         chord_separator {
2048                 $$ = $1;
2049         }
2050         | step_numbers {
2051                 $$ = scm_reverse_x ($1, SCM_EOL);
2052         }
2053         | CHORD_MODIFIER  {
2054                 $$ = $1;
2055         }
2056         ;
2057
2058 step_numbers:
2059         step_number { $$ = scm_cons ($1, SCM_EOL); }
2060         | step_numbers '.' step_number {
2061                 $$ = scm_cons ($3, $$);
2062         }
2063         ;
2064
2065 step_number:
2066         bare_unsigned {
2067                 $$ = make_chord_step ($1, 0);
2068         }
2069         | bare_unsigned '+' {
2070                 $$ = make_chord_step ($1, SHARP_ALTERATION);
2071         }
2072         | bare_unsigned CHORD_MINUS {
2073                 $$ = make_chord_step ($1, FLAT_ALTERATION);
2074         }
2075         ;
2076
2077 /*
2078         UTILITIES
2079
2080 TODO: should deprecate in favor of Scheme?
2081
2082  */
2083 number_expression:
2084         number_expression '+' number_term {
2085                 $$ = scm_sum ($1, $3);
2086         }
2087         | number_expression '-' number_term {
2088                 $$ = scm_difference ($1, $3);
2089         }
2090         | number_term
2091         ;
2092
2093 number_term:
2094         number_factor {
2095                 $$ = $1;
2096         }
2097         | number_factor '*' number_factor {
2098                 $$ = scm_product ($1, $3);
2099         }
2100         | number_factor '/' number_factor {
2101                 $$ = scm_divide ($1, $3);
2102         }
2103         ;
2104
2105 number_factor:
2106         '-'  number_factor { /* %prec UNARY_MINUS */
2107                 $$ = scm_difference ($2, SCM_UNDEFINED);
2108         }
2109         | bare_number
2110         ;
2111
2112
2113 bare_number:
2114         UNSIGNED        {
2115                 $$ = scm_from_int ($1);
2116         }
2117         | REAL          {
2118                 $$ = $1;
2119         }
2120         | NUMBER_IDENTIFIER             {
2121                 $$ = $1;
2122         }
2123         | REAL NUMBER_IDENTIFIER        {
2124                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2125         }
2126         | UNSIGNED NUMBER_IDENTIFIER    {
2127                 $$ = scm_from_double ($1 *scm_to_double ($2));
2128         }
2129         ;
2130
2131
2132 bare_unsigned:
2133         UNSIGNED {
2134                         $$ = $1;
2135         }
2136         | DIGIT {
2137                 $$ = $1;
2138         }
2139         ;
2140
2141 unsigned_number:
2142         bare_unsigned  { $$ = scm_from_int ($1); }
2143         | NUMBER_IDENTIFIER {
2144                 $$ = $1;
2145         }
2146         ;
2147
2148
2149 exclamations:
2150                 { $$ = 0; }
2151         | exclamations '!'      { $$ ++; }
2152         ;
2153
2154 questions:
2155                 { $$ = 0; }
2156         | questions '?' { $$ ++; }
2157         ;
2158
2159 /*
2160 This should be done more dynamically if possible.
2161 */
2162
2163 lyric_markup:
2164         LYRIC_MARKUP_IDENTIFIER {
2165                 $$ = $1;
2166         }
2167         | LYRIC_MARKUP
2168                 { PARSER->lexer_->push_markup_state (); }
2169         markup_top {
2170                 $$ = $3;
2171                 PARSER->lexer_->pop_state ();
2172         }
2173         ;
2174
2175 full_markup:
2176         MARKUP_IDENTIFIER {
2177                 $$ = $1;
2178         }
2179         | MARKUP
2180                 { PARSER->lexer_->push_markup_state (); }
2181         markup_top {
2182                 $$ = $3;
2183                 PARSER->lexer_->pop_state ();
2184         }
2185         ;
2186
2187 markup_top:
2188         markup_list {
2189                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2190         }
2191         | markup_head_1_list simple_markup      {
2192                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2193         }
2194         | simple_markup {
2195                 $$ = $1;
2196         }
2197         ;
2198
2199 markup_list:
2200         markup_composed_list {
2201                 $$ = $1;
2202         }
2203         | markup_braced_list {
2204                 $$ = $1;
2205         }
2206         ;
2207
2208 markup_composed_list:
2209         markup_head_1_list markup_braced_list {
2210                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2211
2212         }
2213         ;
2214
2215 markup_braced_list:
2216         '{' markup_braced_list_body '}' {
2217                 $$ = scm_reverse_x ($2, SCM_EOL);
2218         }
2219         ;
2220
2221 markup_braced_list_body:
2222         /* empty */     {  $$ = SCM_EOL; }
2223         | markup_braced_list_body markup {
2224                 $$ = scm_cons ($2, $1);
2225         }
2226         | markup_braced_list_body markup_list {
2227                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2228         }
2229         ;
2230
2231 markup_head_1_item:
2232         MARKUP_HEAD_MARKUP0     {
2233                 $$ = scm_list_1 ($1);
2234         }
2235         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2236                 $$ = scm_list_2 ($1, $2);
2237         }
2238         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2239                 $$ = scm_list_3 ($1, $2, $3);
2240         }
2241         ;
2242
2243 markup_head_1_list:
2244         markup_head_1_item      {
2245                 $$ = scm_list_1 ($1);
2246         }
2247         | markup_head_1_list markup_head_1_item {
2248                 $$ = scm_cons ($2, $1);
2249         }
2250         ;
2251
2252 simple_markup:
2253         STRING {
2254                 $$ = make_simple_markup ($1);
2255         }
2256         | MARKUP_IDENTIFIER {
2257                 $$ = $1;
2258         }
2259         | LYRIC_MARKUP_IDENTIFIER {
2260                 $$ = $1;
2261         }
2262         | STRING_IDENTIFIER {
2263                 $$ = $1;
2264         }
2265         | SCORE {
2266                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2267                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2268         } '{' score_body '}' {
2269                 Score * sc = $4;
2270                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2271                 sc->unprotect ();
2272                 PARSER->lexer_->pop_state ();
2273         }
2274         | MARKUP_HEAD_SCM0 embedded_scm {
2275                 $$ = scm_list_2 ($1, $2);
2276         }
2277         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2278                 $$ = scm_list_4 ($1, $2, $3, $4);
2279         }
2280         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2281                 $$ = scm_list_3 ($1, $2, $3);
2282         }
2283         | MARKUP_HEAD_EMPTY {
2284                 $$ = scm_list_1 ($1);
2285         }
2286         | MARKUP_HEAD_LIST0 markup_list {
2287                 $$ = scm_list_2 ($1,$2);
2288         }
2289         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2290                 $$ = scm_list_3 ($1, $2, $3);
2291         }
2292         ;
2293
2294 markup:
2295         markup_head_1_list simple_markup        {
2296                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2297                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2298         }
2299         | simple_markup {
2300                 $$ = $1;
2301         }
2302         ;
2303
2304 %%
2305
2306 void
2307 Lily_parser::set_yydebug (bool x)
2308 {
2309         yydebug = x;
2310 }
2311
2312 void
2313 Lily_parser::do_yyparse ()
2314 {
2315         yyparse ((void*)this);
2316 }
2317
2318
2319
2320
2321
2322 /*
2323
2324 It is a little strange to have this function in this file, but
2325 otherwise, we have to import music classes into the lexer.
2326
2327 */
2328 int
2329 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2330 {
2331         if (scm_is_string (sid)) {
2332                 *destination = sid;
2333                 return STRING_IDENTIFIER;
2334         } else if (unsmob_book (sid)) {
2335                 Book *book =  unsmob_book (sid)->clone ();
2336                 *destination = book->self_scm ();
2337                 book->unprotect ();
2338
2339                 return BOOK_IDENTIFIER;
2340         } else if (scm_is_number (sid)) {
2341                 *destination = sid;
2342                 return NUMBER_IDENTIFIER;
2343         } else if (unsmob_context_def (sid)) {
2344                 Context_def *def= unsmob_context_def (sid)->clone ();
2345
2346                 *destination = def->self_scm ();
2347                 def->unprotect ();
2348
2349                 return CONTEXT_DEF_IDENTIFIER;
2350         } else if (unsmob_score (sid)) {
2351                 Score *score = new Score (*unsmob_score (sid));
2352                 *destination = score->self_scm ();
2353
2354                 score->unprotect ();
2355                 return SCORE_IDENTIFIER;
2356         } else if (Music *mus = unsmob_music (sid)) {
2357                 mus = mus->clone ();
2358                 *destination = mus->self_scm ();
2359                 unsmob_music (*destination)->
2360                         set_property ("origin", make_input (last_input_));
2361
2362                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2363                         != SCM_BOOL_F;
2364
2365                 mus->unprotect ();
2366                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2367         } else if (unsmob_duration (sid)) {
2368                 *destination = unsmob_duration (sid)->smobbed_copy ();
2369                 return DURATION_IDENTIFIER;
2370         } else if (unsmob_output_def (sid)) {
2371                 Output_def *p = unsmob_output_def (sid);
2372                 p = p->clone ();
2373
2374                 *destination = p->self_scm ();
2375                 p->unprotect ();
2376                 return OUTPUT_DEF_IDENTIFIER;
2377         } else if (Text_interface::is_markup (sid)) {
2378                 *destination = sid;
2379                 if (is_lyric_state ())
2380                         return LYRIC_MARKUP_IDENTIFIER;
2381                 return MARKUP_IDENTIFIER;
2382         }
2383
2384         return -1;
2385 }
2386
2387 SCM
2388 get_next_unique_context_id ()
2389 {
2390         return scm_from_locale_string ("$uniqueContextId");
2391 }
2392
2393
2394 SCM
2395 get_next_unique_lyrics_context_id ()
2396 {
2397         static int new_context_count;
2398         char s[128];
2399         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2400         return scm_from_locale_string (s);
2401 }
2402
2403
2404 SCM
2405 run_music_function (Lily_parser *parser, SCM expr)
2406 {
2407         SCM func = scm_car (expr);
2408         Input *loc = unsmob_input (scm_cadr (expr));
2409         SCM args = scm_cddr (expr);
2410         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2411
2412         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2413
2414         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2415         {
2416                 parser->error_level_ = 1;
2417                 return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("void-music"), scm_list_2 (parser->self_scm (), make_input (*loc)));
2418         }
2419
2420         SCM syntax_args = scm_list_4 (parser->self_scm (), make_input (*loc), func, args);
2421         return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("music-function"), syntax_args);
2422 }
2423
2424 bool
2425 is_regular_identifier (SCM id)
2426 {
2427   string str = ly_scm2string (id);
2428   char const *s = str.c_str ();
2429
2430   bool v = true;
2431 #if 0
2432   isalpha (*s);
2433   s++;
2434 #endif
2435   while (*s && v)
2436    {
2437         v = v && isalnum (*s);
2438         s++;
2439    }
2440   return v;
2441 }
2442
2443 Music *
2444 make_music_with_input (SCM name, Input where)
2445 {
2446        Music *m = make_music_by_name (name);
2447        m->set_spot (where);
2448        return m;
2449 }
2450
2451 SCM
2452 get_first_context_id (SCM type, Music *m)
2453 {
2454         SCM id = m->get_property ("context-id");
2455         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2456             && scm_is_string (m->get_property ("context-id"))
2457             && scm_c_string_length (id) > 0)
2458         {
2459                 return id;
2460         }
2461         return SCM_EOL;
2462 }
2463
2464 SCM
2465 make_simple_markup (SCM a)
2466 {
2467         return a;
2468 }
2469
2470 bool
2471 is_duration (int t)
2472 {
2473   return t && t == 1 << intlog2 (t);
2474 }
2475
2476 void
2477 set_music_properties (Music *p, SCM a)
2478 {
2479   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2480         p->set_property (scm_caar (k), scm_cdar (k));
2481 }
2482
2483
2484 SCM
2485 make_chord_step (int step, Rational alter)
2486 {
2487         if (step == 7)
2488                 alter += FLAT_ALTERATION;
2489
2490         while (step < 0)
2491                 step += 7;
2492         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2493         return m.smobbed_copy ();
2494 }
2495
2496
2497 SCM
2498 make_chord_elements (SCM pitch, SCM dur, SCM modification_list)
2499 {
2500         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
2501         return scm_call_3 (chord_ctor, pitch, dur, modification_list);
2502 }
2503
2504
2505 /* Todo: actually also use apply iso. call too ...  */
2506 bool
2507 ly_input_procedure_p (SCM x)
2508 {
2509         return ly_is_procedure (x)
2510                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2511 }
2512
2513 SCM
2514 make_music_relative (Pitch start, SCM music, Input loc)
2515 {
2516         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic", loc);
2517         relative->set_property ("element", music);
2518
2519         Music *m = unsmob_music (music);
2520         Pitch last = m->to_relative_octave (start);
2521         if (lily_1_8_relative)
2522                 m->set_property ("last-pitch", last.smobbed_copy ());
2523         return relative->unprotect ();
2524 }
2525
2526 int
2527 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2528 {
2529         Lily_parser *pars = (Lily_parser*) v;
2530         Lily_lexer *lex = pars->lexer_;
2531
2532         lex->lexval = (void*) s;
2533         lex->lexloc = loc;
2534         lex->prepare_for_next_token ();
2535         return lex->yylex ();
2536 }