lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29 #include "context-def.hh"
  30 #include "dimensions.hh"
  31 #include "event.hh"
  32 #include "file-path.hh"
  33 #include "input-smob.hh"
  34 #include "input.hh"
  35 #include "lily-guile.hh"
  36 #include "lilypond-input-version.hh"
  37 #include "ly-module.hh"
  38 #include "main.hh"
  39 #include "midi-def.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "paper-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Music_output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDLYRICS
 246 %token ADDQUOTE
 247 %token LYRICSTO
 248 %token ALIAS
 249 %token ALTERNATIVE
 250 %token APPLYCONTEXT
 251 %token APPLYOUTPUT
 252 %token AUTOCHANGE
 253 %token BAR
 254 %token BOOK
 255 %token BREATHE
 256 %token CHANGE
 257 %token CHORDMODIFIERS
 258 %token CHORDS
 259 %token DOUBLE_ANGLE_OPEN
 260 %token DOUBLE_ANGLE_CLOSE
 261 %token CLEF
 262 %token COMMANDSPANREQUEST
 263 %token CONSISTS
 264 %token CONSISTSEND
 265 %token CONTEXT
 266 %token DEFAULT
 267 %token DENIES
 268 %token DESCRIPTION
 269 %token EXTENDER
 270 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 271 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 272 %token GRACE
 273 %token ACCIACCATURA
 274 %token APPOGGIATURA
 275 %token GROBDESCRIPTIONS
 276 %token HEADER
 277 %token HYPHEN
 278 %token INVALID
 279 %token KEY
 280 %token LYRICS
 281 %token LYRICS_STRING
 282 %token MARK
 283 %token MIDI
 284 %token MULTI_MEASURE_REST
 285 %token NAME
 286 %token NEWCONTEXT
 287 %token NOTES
 288 %token OCTAVE
 289 %token ONCE
 290 %token OVERRIDE SET REVERT
 291 %token PAPER
 292 %token PARTCOMBINE
 293 %token PARTIAL
 294 %token QUOTE
 295 %token RELATIVE
 296 %token REMOVE
 297 %token REPEAT
 298 %token REST
 299 %token SCM_T
 300 %token SCORE
 301 %token SEQUENTIAL
 302 %token NEWLYRICS
 303 %token SIMULTANEOUS
 304 %token SKIP
 305 %token SPANREQUEST
 306 %token TAG
 307 %token TEMPO
 308 %token TIMES
 309 %token TIME_T
 310 %token TRANSPOSE
 311 %token TRANSPOSITION
 312 %token TYPE
 313 %token UNSET
 314 %token WITH
 315
 316 /* escaped */
 317 /* FIXME: this sucks.  The user will get to see these names:
 318     syntax error, unexpected E_CHAR:
 319                 \
 320                  %%
 321   */
 322 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 323 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 324 %token E_BACKSLASH
 325 %token <i> E_UNSIGNED
 326 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 327 %token FIGURE_SPACE
 328
 329 %token <i>      DIGIT
 330 %token <scm>    NOTENAME_PITCH
 331 %token <scm>    TONICNAME_PITCH
 332 %token <scm>    CHORDMODIFIER_PITCH
 333 %token <scm>    DURATION_IDENTIFIER
 334 %token <scm>    FRACTION
 335 %token <id>     IDENTIFIER
 336 %token DRUMS
 337 %token <scm>    DRUM_PITCH
 338 %token <scm>    CHORD_MODIFIER
 339 %token <scm>    SCORE_IDENTIFIER
 340 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 341 %token <scm>    NUMBER_IDENTIFIER
 342 %token <scm>    EVENT_IDENTIFIER
 343 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 344 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 345 %token <scm>    RESTNAME
 346 %token <scm>    STRING
 347 %token <scm>    SCM_T
 348 %token <i>      UNSIGNED
 349 %token <scm>   REAL
 350
 351 %token MARKUP
 352 %token <scm> MARKUP_HEAD_MARKUP0
 353 %token <scm> MARKUP_HEAD_EMPTY
 354 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 355 %token <scm> MARKUP_HEAD_SCM0
 356 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 357 %token <scm> MARKUP_HEAD_SCM0_SCM1
 358 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 359 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 360
 361 %token <scm> MUSIC_FUNCTION_SCM
 362 %token <scm> MUSIC_FUNCTION_MUSIC
 363 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 364 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 365 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 366 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 367
 368 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 369 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 370
 371 %type <book>    book_block book_body
 372 %type <i>       exclamations questions dots optional_rest
 373 %type <i>       bass_mod
 374 %type <scm>     grace_head
 375 %type <scm>     oct_check
 376 %type <scm>     context_mod_list
 377 %type <scm>     lyric_element
 378 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 379 %type <scm>     new_lyrics
 380 %type <outputdef> output_def
 381 %type <scm>     lilypond_header lilypond_header_body
 382 %type <music>   open_event close_event
 383 %type <i>       sub_quotes sup_quotes
 384 %type <music>   toplevel_music
 385 %type <music>   simple_element event_chord command_element
 386 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 387 %type <scm>     Generic_prefix_music_scm
 388 %type <music>   Grouped_music_list
 389 %type <music>   Repeated_music
 390 %type <scm>     Alternative_music
 391 %type <i>       tremolo_type
 392 %type <i>       bare_int  bare_unsigned
 393 %type <i>       script_dir
 394 %type <scm>     identifier_init
 395 %type <scm>     simple_string
 396
 397 %type <music>   note_chord_element chord_body chord_body_element
 398 %type <scm>     chord_body_elements
 399 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 400
 401 %type <scm>     post_events
 402 %type <music>   gen_text_def direction_less_event direction_reqd_event
 403 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 404 %type <scm>     steno_tonic_pitch
 405 %type <scm>     duration_length fraction
 406
 407 %type <scm>     chord_item chord_items chord_separator new_chord
 408 %type <scm>     step_number step_numbers
 409
 410 %type <scm>     embedded_scm scalar
 411 %type <music>   Music Sequential_music Simultaneous_music
 412 %type <music>   relative_music re_rhythmed_music
 413 %type <music>   music_property_def context_change
 414 %type <scm>     context_prop_spec
 415 %type <scm>     Music_list
 416 %type <scm>     property_operation
 417 %type <scm>     context_mod context_def_mod optional_context_mod
 418 %type <outputdef>       music_output_def_body music_output_def_head
 419 %type <music>   post_event tagged_post_event
 420 %type <music>   command_req
 421 %type <music>   string_number_event
 422 %type <scm>     string bare_number number_expression number_term number_factor
 423 %type <score>   score_block score_body
 424
 425 %type <scm>     context_def_spec_block context_def_spec_body
 426 %type <music>   tempo_event
 427 %type <scm>     script_abbreviation
 428
 429
 430
 431 %left '-' '+'
 432
 433 /* We don't assign precedence to / and *, because we might need varied
 434 prec levels in different prods */
 435
 436 %left UNARY_MINUS
 437
 438 %%
 439
 440 lilypond:       /* empty */
 441         | lilypond toplevel_expression {
 442         }
 443         | lilypond assignment {
 444         }
 445         | lilypond error {
 446                 THIS->error_level_ = 1;
 447         }
 448         | lilypond INVALID      {
 449                 THIS->error_level_ = 1;
 450         }
 451         ;
 452
 453 toplevel_expression:
 454         lilypond_header {
 455                 THIS->header_ = $1;
 456         }
 457         | add_quote {
 458
 459         }
 460         | book_block {
 461                 Book *book = $1;
 462                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 463                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 464                 scm_gc_unprotect_object (book->self_scm ());
 465         }
 466         | score_block {
 467                 Score *score = $1;
 468
 469                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 470                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 471                 scm_gc_unprotect_object (score->self_scm ());
 472         }
 473         | toplevel_music {
 474                 Music *music = $1;
 475                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 476                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 477                 scm_gc_unprotect_object (music->self_scm ());
 478         }
 479         | output_def {
 480                 SCM id = SCM_EOL;
 481                 if (dynamic_cast<Paper_def*> ($1))
 482                         id = scm_makfrom0str ("$defaultpaper");
 483                 else if (dynamic_cast<Midi_def*> ($1))
 484                         id = scm_makfrom0str ("$defaultmidi");
 485                 THIS->lexer_->set_identifier (id, $1->self_scm ());
 486                 scm_gc_unprotect_object ($1->self_scm ());
 487         }
 488         ;
 489
 490 toplevel_music:
 491         Composite_music {
 492         }
 493         ;
 494
 495 embedded_scm:
 496         SCM_T
 497         | SCM_IDENTIFIER
 498         ;
 499
 500
 501 lilypond_header_body:
 502         {
 503                 $$ = ly_make_anonymous_module ();
 504                 THIS->lexer_->add_scope ($$);
 505         }
 506         | lilypond_header_body assignment  {
 507
 508         }
 509         ;
 510
 511 lilypond_header:
 512         HEADER '{' lilypond_header_body '}'     {
 513                 $$ = THIS->lexer_->remove_scope ();
 514         }
 515         ;
 516
 517
 518 /*
 519         DECLARATIONS
 520 */
 521 assignment:
 522         STRING {
 523                 THIS->push_spot ();
 524         }
 525         /* cont */ '=' identifier_init  {
 526
 527         /*
 528                 Should find generic way of associating input with objects.
 529         */
 530                 Input ip = THIS->pop_spot ();
 531
 532                 if (! is_regular_identifier ($1))
 533                 {
 534                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 535                 }
 536
 537                 THIS->lexer_->set_identifier ($1, $4);
 538
 539 /*
 540  TODO: devise standard for protection in parser.
 541
 542   The parser stack lives on the C-stack, which means that
 543 all objects can be unprotected as soon as they're here.
 544
 545 */
 546         }
 547         | embedded_scm { }
 548         ;
 549
 550
 551 identifier_init:
 552         score_block {
 553                 $$ = $1->self_scm ();
 554                 scm_gc_unprotect_object ($$);
 555         }
 556         | full_markup {
 557                 $$ = $1;
 558         }
 559         | output_def {
 560                 $$ = $1->self_scm ();
 561                 scm_gc_unprotect_object ($$);
 562         }
 563         | context_def_spec_block {
 564                 $$ = $1;
 565         }
 566         | Music  {
 567                 $$ = $1->self_scm ();
 568                 scm_gc_unprotect_object ($$);
 569         }
 570         | post_event {
 571                 $$ = $1->self_scm ();
 572                 scm_gc_unprotect_object ($$);
 573         }
 574         | number_expression {
 575                 $$ = $1;
 576         }
 577         | string {
 578                 $$ = $1;
 579         }
 580         | embedded_scm  {
 581                 $$ = $1;
 582         }
 583         ;
 584
 585 context_def_spec_block:
 586         CONTEXT '{' context_def_spec_body '}'
 587                 {
 588                 $$ = $3;
 589         }
 590         ;
 591
 592 context_def_spec_body:
 593         /**/ {
 594                 $$ = Context_def::make_scm ();
 595                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 596         }
 597         | CONTEXT_DEF_IDENTIFIER {
 598                 $$ = $1;
 599                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 600         }
 601         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 602                 Context_def*td = unsmob_context_def ($$);
 603
 604                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 605                         SCM tag = ly_caar (p);
 606
 607                         /* TODO: should make new tag "grob-definition" ? */
 608                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 609                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 610                 }
 611         }
 612         | context_def_spec_body context_mod {
 613                 unsmob_context_def ($$)->add_context_mod ($2);
 614         }
 615         ;
 616
 617 book_block:
 618         BOOK {
 619                 THIS->push_spot ();
 620         }
 621         /*cont*/ '{' book_body '}'      {
 622                 THIS->pop_spot ();
 623                 $$ = $4;
 624         }
 625         ;
 626
 627 book_body:
 628         {
 629                 $$ = new Book;
 630                 $$->set_spot (THIS->here_input ());
 631         }
 632         | book_body score_block {
 633                 $$->scores_.push ($2);
 634                 scm_gc_unprotect_object ($2->self_scm ());
 635         }
 636         | book_body error {
 637         }
 638         ;
 639
 640 score_block:
 641         SCORE {
 642                 THIS->push_spot ();
 643         }
 644         /*cont*/ '{' score_body '}'     {
 645                 THIS->pop_spot ();
 646                 $$ = $4;
 647         }
 648         ;
 649
 650 score_body:
 651         Music   {
 652                 $$ = new Score;
 653
 654                 $$->set_spot (THIS->here_input ());
 655                 SCM m = $1->self_scm ();
 656                 scm_gc_unprotect_object (m);
 657
 658                 /*
 659                         guh.
 660                 */
 661                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 662                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 663                         m = scm_call_1 (ly_car (check_funcs), m);
 664                 $$->music_ = m;
 665
 666         }
 667         | SCORE_IDENTIFIER {
 668                 $$ = new Score ( *unsmob_score ($1));
 669                 $$->set_spot (THIS->here_input ());
 670         }
 671         | score_body lilypond_header    {
 672                 $$->header_ = $2;
 673         }
 674         | score_body output_def {
 675                 $$->defs_.push ($2);
 676                 scm_gc_unprotect_object ($2->self_scm ());
 677         }
 678         | score_body error {
 679
 680         }
 681         ;
 682
 683
 684 /*
 685         MIDI
 686 */
 687 output_def:
 688         music_output_def_body '}' {
 689                 $$ = $1;
 690                 THIS->lexer_->remove_scope ();
 691                 THIS->lexer_->pop_state ();
 692         }
 693         ;
 694
 695 music_output_def_head:
 696         MIDI    {
 697                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 698
 699
 700                 Midi_def *p = 0;
 701                 if (id)
 702                         p = dynamic_cast<Midi_def*> (id->clone ());
 703                 else
 704                         p = new Midi_def;
 705
 706                 $$ = p;
 707                 THIS->lexer_->add_scope (p->scope_);
 708         }
 709         | PAPER         {
 710                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 711                   Paper_def *p = 0;
 712                 if (id)
 713                         p = dynamic_cast<Paper_def*> (id->clone ());
 714                 else
 715                         p = new Paper_def;
 716
 717                 THIS->lexer_->add_scope (p->scope_);
 718                 $$ = p;
 719         }
 720         ;
 721
 722
 723 music_output_def_body:
 724         music_output_def_head '{' {
 725                 $$ = $1;
 726                 $$->input_origin_. set_spot (THIS->here_input ());
 727                 THIS->lexer_->push_initial_state ();
 728         }
 729         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 730                 scm_gc_unprotect_object ($1->self_scm ());
 731                 Music_output_def *o = unsmob_music_output_def ($3);
 732                 o->input_origin_.set_spot (THIS->here_input ());
 733                 $$ = o;
 734                 THIS->lexer_->remove_scope ();
 735                 THIS->lexer_->add_scope (o->scope_);
 736                 THIS->lexer_->push_initial_state ();
 737         }
 738         | music_output_def_body assignment  {
 739
 740         }
 741         | music_output_def_body context_def_spec_block  {
 742                 $$->assign_context_def ($2);
 743         }
 744         | music_output_def_body tempo_event  {
 745                 /*
 746                         junk this ? there already is tempo stuff in
 747                         music.
 748                 */
 749                 int m = ly_scm2int ( $2->get_property ("metronome-count"));
 750                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 751                 Midi_def *md = dynamic_cast<Midi_def*> ($$);
 752                 if (md)
 753                         md->set_tempo (d->get_length (), m);
 754                 scm_gc_unprotect_object ($2->self_scm ());
 755         }
 756         | music_output_def_body error {
 757
 758         }
 759         ;
 760
 761 tempo_event:
 762         TEMPO steno_duration '=' bare_unsigned  {
 763                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 764                 $$->set_property ("tempo-unit", $2);
 765                 $$->set_property ("metronome-count", scm_int2num ( $4));
 766         }
 767         ;
 768
 769 /*
 770 The representation of a  list is the
 771
 772   (LIST . LAST-CONS)
 773
 774  to have  efficient append.
 775 */
 776 Music_list:
 777         /* empty */ {
 778                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 779         }
 780         | Music_list Music {
 781                 SCM s = $$;
 782                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 783                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 784                 if (ly_c_pair_p (ly_cdr (s)))
 785                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 786                 else
 787                         scm_set_car_x (s, c); /* set first cons */
 788                 scm_set_cdr_x (s, c);  /* remember last cell */
 789         }
 790         | Music_list embedded_scm {
 791         }
 792         | Music_list error {
 793         }
 794         ;
 795
 796
 797 Music:
 798         Simple_music
 799         | Composite_music
 800         ;
 801
 802 Alternative_music:
 803         /* empty */ {
 804                 $$ = SCM_EOL;
 805         }
 806         | ALTERNATIVE '{' Music_list '}' {
 807                 $$ = $3;
 808         }
 809         ;
 810
 811
 812 Repeated_music:
 813         REPEAT simple_string bare_unsigned Music Alternative_music
 814         {
 815                 Music *beg = $4;
 816                 int times = $3;
 817                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 818                 if (times < scm_ilength (alts)) {
 819                   unsmob_music (ly_car (alts))
 820                     ->origin ()->warning (
 821                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 822                   alts = ly_truncate_list (times, alts);
 823                 }
 824
 825
 826                 SCM proc = ly_scheme_function ("make-repeated-music");
 827
 828                 SCM mus = scm_call_1 (proc, $2);
 829                 scm_gc_protect_object (mus); // UGH.
 830                 Music *r = unsmob_music (mus);
 831                 if (beg)
 832                         {
 833                         r-> set_property ("element", beg->self_scm ());
 834                         scm_gc_unprotect_object (beg->self_scm ());
 835                         }
 836                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 837
 838                 r-> set_property ("elements",alts);
 839                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 840                         /*
 841                         TODO: move this code to Scheme.
 842                         */
 843
 844                         /*
 845                         we can not get durations and other stuff correct down the line, so we have to
 846                         add to the duration log here.
 847                         */
 848                         SCM func = ly_scheme_function ("shift-duration-log");
 849
 850                         int dots = ($3 % 3) ? 0 : 1;
 851                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 852
 853                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 854
 855                         if (seq) {
 856                                 int list_len = scm_ilength (seq->music_list ());
 857                                 if (list_len != 2)
 858                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 859                                 shift -= 1;
 860                                 r->compress (Moment (Rational (1, list_len)));
 861                                 }
 862                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 863
 864                 }
 865                 r->set_spot (*$4->origin ());
 866
 867                 $$ = r;
 868         }
 869         ;
 870
 871 Sequential_music:
 872         SEQUENTIAL '{' Music_list '}'           {
 873                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 874                 $$->set_property ("elements", ly_car ($3));
 875                 $$->set_spot (THIS->here_input ());
 876         }
 877         | '{' Music_list '}'            {
 878                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 879                 $$->set_property ("elements", ly_car ($2));
 880                 $$->set_spot (THIS->here_input ());
 881         }
 882         ;
 883
 884 Simultaneous_music:
 885         SIMULTANEOUS '{' Music_list '}'{
 886                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 887                 $$->set_property ("elements", ly_car ($3));
 888                 $$->set_spot (THIS->here_input ());
 889
 890         }
 891         | simul_open Music_list simul_close     {
 892                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 893                 $$->set_property ("elements", ly_car ($2));
 894                 $$->set_spot (THIS->here_input ());
 895         }
 896         ;
 897
 898 Simple_music:
 899         event_chord             { $$ = $1; }
 900         | APPLYOUTPUT embedded_scm {
 901                 if (!ly_input_procedure_p ($2))
 902                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 903                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 904                 $$->set_property ("procedure", $2);
 905                 $$->set_spot (THIS->here_input ());
 906         }
 907         | APPLYCONTEXT embedded_scm {
 908                 if (!ly_input_procedure_p ($2))
 909                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 910                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 911                 $$->set_property ("procedure", $2);
 912                 $$->set_spot (THIS->here_input ());
 913         }
 914         | MUSIC_IDENTIFIER {
 915                 $$ = unsmob_music ($1);
 916         }
 917         | music_property_def
 918         | context_change
 919         ;
 920
 921
 922 optional_context_mod:
 923         /**/ { $$ = SCM_EOL; }
 924         | WITH { THIS->lexer_->push_initial_state (); }
 925         '{' context_mod_list '}'
 926         {
 927                 THIS->lexer_->pop_state ();
 928                 $$ = $4;
 929         }
 930         ;
 931
 932 grace_head:
 933         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 934         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 935         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 936         ;
 937
 938 context_mod_list:
 939         /* */  { $$ = SCM_EOL; }
 940         | context_mod_list context_mod  {
 941                  $$ = scm_cons ($2, $1);
 942         }
 943         ;
 944
 945
 946 Composite_music:
 947         Prefix_composite_music { $$ = $1; }
 948         | Grouped_music_list { $$ = $1; }
 949         ;
 950
 951 Grouped_music_list:
 952         Simultaneous_music              { $$ = $1; }
 953         | Sequential_music              { $$ = $1; }
 954         ;
 955
 956 Generic_prefix_music_scm:
 957         MUSIC_FUNCTION_SCM {
 958                 THIS->push_spot ();
 959         } embedded_scm {
 960                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 961         }
 962         | MUSIC_FUNCTION_MUSIC {
 963                 THIS->push_spot ();
 964         } Music {
 965                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 966                 scm_gc_unprotect_object ($3->self_scm ());
 967         }
 968         | MUSIC_FUNCTION_SCM_MUSIC {
 969                 THIS->push_spot ();
 970         }  embedded_scm Music {
 971                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 972                 scm_gc_unprotect_object ($4->self_scm ());
 973         }
 974         | MUSIC_FUNCTION_MUSIC_MUSIC {
 975                 THIS->push_spot ();
 976         }  Music  Music {
 977                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
 978                 scm_gc_unprotect_object ($3->self_scm ());
 979                 scm_gc_unprotect_object ($4->self_scm ());
 980         }
 981         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
 982                 THIS->push_spot ();
 983         } embedded_scm Music Music {
 984                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
 985                         $3, $4->self_scm (), $5->self_scm ());
 986                 scm_gc_unprotect_object ($5->self_scm ());
 987                 scm_gc_unprotect_object ($4->self_scm ());
 988         }
 989         ;
 990
 991 Generic_prefix_music:
 992         Generic_prefix_music_scm {
 993                 SCM func = ly_car ($1);
 994                 Input *loc = unsmob_input (ly_cadr ($1));
 995                 SCM args = ly_cddr ($1);
 996                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-head-signature"));
 997                 int k = 0;
 998                 bool ok  = true;
 999                 for (SCM s = sig, t = args;
1000                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1001                         s = ly_cdr (s), t = ly_cdr (t)) {
1002                         k++;
1003                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1004                         {
1005                                 loc->error (_f ("Argument %d failed typecheck", k));
1006                                 THIS->error_level_ = 1;
1007                                 ok = false;
1008                         }
1009                 }
1010                 SCM m = SCM_EOL;
1011                 if (ok)
1012                         m = scm_apply_0 (func, ly_cdr ($1));
1013                 if (unsmob_music (m))
1014                         {
1015                         $$ = unsmob_music (m);
1016                         scm_gc_protect_object (m);
1017                         }
1018                 else
1019                         {
1020                         loc->error (_ ("Music head function should return Music object."));
1021                         $$ = MY_MAKE_MUSIC ("Music");
1022                         }
1023                 $$->set_spot (*loc);
1024         }
1025         ;
1026
1027
1028 Prefix_composite_music:
1029         Generic_prefix_music {
1030                 $$ = $1;
1031         }
1032         |AUTOCHANGE Music       {
1033                 SCM proc = ly_scheme_function ("make-autochange-music");
1034
1035                 SCM res = scm_call_1 (proc, $2->self_scm ());
1036                 scm_gc_unprotect_object ($2->self_scm ());
1037                 $$ = unsmob_music (res);
1038                 scm_gc_protect_object (res);
1039                 $$->set_spot (THIS->here_input ());
1040         }
1041         | PARTCOMBINE Music Music {
1042                 SCM proc = ly_scheme_function ("make-part-combine-music");
1043
1044                 SCM res = scm_call_1 (proc, scm_listify ($2->self_scm (),
1045                         $3->self_scm (), SCM_UNDEFINED));
1046                 scm_gc_unprotect_object ($3->self_scm ());
1047                 scm_gc_unprotect_object ($2->self_scm ());
1048                 $$ = unsmob_music (res);
1049                 scm_gc_protect_object (res);
1050                 $$->set_spot (THIS->here_input ());
1051         }
1052         | grace_head Music {
1053 #if 1
1054         /*
1055                 The other version is for easier debugging  of
1056                 Sequential_music_iterator in combination with grace notes.
1057         */
1058
1059 /*
1060
1061 TODO: should distinguish between both grace types in the
1062 basic music objects too, since the meaning is different.
1063
1064 */
1065
1066                 String start_str = "start" + ly_scm2string ($1) + "Music";
1067                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
1068
1069                 SCM start = THIS->lexer_->lookup_identifier (start_str);
1070                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
1071
1072                 Music *startm = unsmob_music (start);
1073                 Music *stopm = unsmob_music (stop);
1074
1075                 SCM ms = SCM_EOL;
1076                 if (stopm) {
1077                         stopm = stopm->clone ();
1078                         ms = scm_cons (stopm->self_scm (), ms);
1079                         scm_gc_unprotect_object (stopm->self_scm ());
1080                 }
1081                 ms = scm_cons ($2->self_scm (), ms);
1082                 scm_gc_unprotect_object ($2->self_scm ());
1083                 if (startm) {
1084                         startm = startm->clone ();
1085                         ms = scm_cons (startm->self_scm (), ms);
1086                         scm_gc_unprotect_object (startm->self_scm ());
1087                 }
1088
1089                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
1090                 seq->set_property ("elements", ms);
1091
1092
1093                 $$ = MY_MAKE_MUSIC ("GraceMusic");
1094                 $$->set_property ("element", seq->self_scm ());
1095                 scm_gc_unprotect_object (seq->self_scm ());
1096 #else
1097                 $$ = MY_MAKE_MUSIC ("GraceMusic");
1098                 $$->set_property ("element", $2->self_scm ());
1099                 scm_gc_unprotect_object ($2->self_scm ());
1100 #endif
1101         }
1102         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1103                 $$ = context_spec_music ($2, $4, $6, $5);
1104
1105         }
1106         | CONTEXT simple_string optional_context_mod Music {
1107                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1108         }
1109         | NEWCONTEXT simple_string optional_context_mod Music {
1110                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1111                         $3);
1112         }
1113
1114         | TIMES {
1115                 THIS->push_spot ();
1116         }
1117         /* CONTINUED */
1118                 fraction Music
1119
1120         {
1121                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1122                 Music *mp = $4;
1123
1124                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1125                 $$->set_spot (THIS->pop_spot ());
1126
1127                 $$->set_property ("element", mp->self_scm ());
1128                 scm_gc_unprotect_object (mp->self_scm ());
1129                 $$->set_property ("numerator", scm_int2num (n));
1130                 $$->set_property ("denominator", scm_int2num (d));
1131                 $$->compress (Moment (Rational (n,d)));
1132
1133         }
1134         | Repeated_music                { $$ = $1; }
1135         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1136                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1137                 Music *p = $4;
1138                 Pitch from = *unsmob_pitch ($2);
1139                 Pitch to = *unsmob_pitch ($3);
1140
1141                 p->transpose (interval (from, to));
1142                 $$->set_property ("element", p->self_scm ());
1143                 scm_gc_unprotect_object (p->self_scm ());
1144         }
1145         | NOTES
1146                 {
1147                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1148                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1149         }
1150         Music
1151                 { $$ = $3;
1152                   THIS->lexer_->pop_state ();
1153                 }
1154         | DRUMS
1155                 {
1156                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1157                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1158         }
1159         /* FIXME: This used to be: */
1160         Music
1161 /*      Grouped_music_list */
1162                 { $$ = $3;
1163                   THIS->lexer_->pop_state ();
1164                 }
1165         | FIGURES
1166                 { THIS->lexer_->push_figuredbass_state (); }
1167         /* FIXME: This used to be:
1168         Music
1169         but that breaks web build
1170         */
1171         Grouped_music_list
1172                 {
1173                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1174                   chm->set_property ("element", $3->self_scm ());
1175                   $$ = chm;
1176                   scm_gc_unprotect_object ($3->self_scm ());
1177
1178                   THIS->lexer_->pop_state ();
1179         }
1180         | CHORDS {
1181                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1182                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1183                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1184                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1185
1186         }
1187         /* FIXME:
1188         Music
1189 */
1190         Grouped_music_list
1191         {
1192                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1193                   chm->set_property ("element", $3->self_scm ());
1194                   scm_gc_unprotect_object ($3->self_scm ());
1195                   $$ = chm;
1196
1197                   THIS->lexer_->pop_state ();
1198         }
1199         | LYRICS
1200                 { THIS->lexer_->push_lyric_state (); }
1201         /* FIXME:
1202         Music
1203 */
1204         Grouped_music_list
1205                 {
1206                   $$ = $3;
1207                   THIS->lexer_->pop_state ();
1208         }
1209         | relative_music        { $$ = $1; }
1210         | re_rhythmed_music     { $$ = $1; }
1211         | TAG embedded_scm Music {
1212                 tag_music ($3, $2, THIS->here_input ());
1213                 $$ = $3;
1214         }
1215         ;
1216
1217 relative_music:
1218         RELATIVE absolute_pitch Music {
1219                 Music *m = $3;
1220                 Pitch start = *unsmob_pitch ($2);
1221                 $$ = make_music_relative (start, m);
1222                 scm_gc_unprotect_object (m->self_scm ());
1223         }
1224         | RELATIVE Composite_music {
1225                 Music *m = $2;
1226                 /* FIXME: why is octave==0 and default not middleC? */
1227                 Pitch middle_c (-1, 0, 0);
1228                 $$ = make_music_relative (middle_c, m);
1229                 scm_gc_unprotect_object (m->self_scm ());
1230         }
1231         ;
1232
1233 new_lyrics:
1234         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1235         /*cont */
1236         Grouped_music_list {
1237         /* Can also use Music at the expensive of two S/Rs similar to
1238            \repeat \alternative */
1239                 THIS->lexer_->pop_state ();
1240 #if 0
1241                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1242                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1243                 $$ = music;
1244 #else
1245                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1246 #endif
1247         }
1248         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1249         Grouped_music_list {
1250                 THIS->lexer_->pop_state ();
1251                 $$ = scm_cons ($4->self_scm (), $1);
1252         }
1253         ;
1254
1255 re_rhythmed_music:
1256         ADDLYRICS Music Music {
1257                 Music *m = MY_MAKE_MUSIC ("LyricCombineMusic");
1258                 m->set_property ("elements", scm_listify ($2->self_scm (),
1259                         $3->self_scm (), SCM_UNDEFINED));
1260                 scm_gc_unprotect_object ($3->self_scm ());
1261                 scm_gc_unprotect_object ($2->self_scm ());
1262                 $$ = m;
1263         }
1264         | Grouped_music_list new_lyrics {
1265
1266                 /* FIXME: should find out uniqueXXX name from music */
1267                 SCM name = $1->get_property ("context-id");
1268                 //if (name == SCM_EOL)
1269                 if (!ly_c_string_p (name))
1270                         name = scm_makfrom0str ("");
1271
1272                 SCM context = scm_makfrom0str ("Lyrics");
1273                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1274
1275                 SCM lst = SCM_EOL;
1276                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1277                 {
1278                         Music *music = unsmob_music (ly_car (s));
1279                         Music *com = make_lyric_combine_music (name, music);
1280                         Music *csm = context_spec_music (context,
1281                                 get_next_unique_context (), com, SCM_EOL);
1282                         lst = scm_cons (csm->self_scm (), lst);
1283                 }
1284                 /* FIXME: only first lyric music is accepted,
1285                           the rest is junked */
1286                 all->set_property ("elements", scm_cons ($1->self_scm (),
1287                         lst));
1288                 $$ = all;
1289                 scm_gc_unprotect_object ($1->self_scm ());
1290         }
1291         | LYRICSTO string Music {
1292                 Music *music = $3;
1293                 SCM name = $2;
1294                 $$ = make_lyric_combine_music (name, music);
1295                 scm_gc_unprotect_object (music->self_scm ());
1296         }
1297         ;
1298
1299 context_change:
1300         CHANGE STRING '=' STRING  {
1301                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1302                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1303                 t-> set_property ("change-to-id", $4);
1304
1305                 $$ = t;
1306                 $$->set_spot (THIS->here_input ());
1307         }
1308         ;
1309
1310 property_operation:
1311         STRING '=' scalar {
1312                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1313                         scm_string_to_symbol ($1), $3);
1314         }
1315         | UNSET simple_string {
1316                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1317                         scm_string_to_symbol ($2));
1318         }
1319         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1320                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1321                         scm_string_to_symbol ($2), $3, $5);
1322         }
1323         | REVERT simple_string embedded_scm {
1324                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1325                         scm_string_to_symbol ($2), $3);
1326         }
1327         ;
1328
1329 context_def_mod:
1330         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1331         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1332         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1333
1334         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1335         | DENIES { $$ = ly_symbol2scm ("denies"); }
1336
1337         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1338         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1339         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1340         | NAME { $$ = ly_symbol2scm ("context-name"); }
1341         ;
1342
1343 context_mod:
1344         property_operation { $$ = $1; }
1345         | context_def_mod STRING {
1346                 $$ = scm_list_2 ($1, $2);
1347         }
1348         ;
1349
1350 context_prop_spec:
1351         simple_string {
1352                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1353                         scm_string_to_symbol ($1));
1354         }
1355         | simple_string '.' simple_string {
1356                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1357                         scm_string_to_symbol ($3));
1358         }
1359         ;
1360
1361 music_property_def:
1362         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1363                 $$ = property_op_to_music (scm_list_4 (
1364                         ly_symbol2scm ("poppush"),
1365                         ly_cadr ($2),
1366                         $3, $5));
1367                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1368         }
1369         | REVERT context_prop_spec embedded_scm {
1370                 $$ = property_op_to_music (scm_list_3 (
1371                         ly_symbol2scm ("pop"),
1372                         ly_cadr ($2),
1373                         $3));
1374
1375                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1376         }
1377         | SET context_prop_spec '=' scalar {
1378                 $$ = property_op_to_music (scm_list_3 (
1379                         ly_symbol2scm ("assign"),
1380                         ly_cadr ($2),
1381                         $4));
1382                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1383         }
1384         | UNSET context_prop_spec {
1385                 $$ = property_op_to_music (scm_list_2 (
1386                         ly_symbol2scm ("unset"),
1387                         ly_cadr ($2)));
1388                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1389         }
1390         | ONCE music_property_def {
1391                 SCM e = $2->get_property ("element");
1392                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1393                 $$ = $2;
1394
1395         }
1396         ;
1397
1398
1399 string:
1400         STRING {
1401                 $$ = $1;
1402         }
1403         | STRING_IDENTIFIER {
1404                 $$ = $1;
1405         }
1406         | string '+' string {
1407                 $$ = scm_string_append (scm_list_2 ($1, $3));
1408         }
1409         ;
1410
1411 simple_string: STRING {
1412         }
1413         | LYRICS_STRING {
1414         }
1415         ;
1416
1417 scalar: string {
1418         }
1419         | LYRICS_STRING {
1420         }
1421         | bare_int {
1422                 $$ = scm_int2num ($1);
1423         }
1424         | embedded_scm {
1425         }
1426         | full_markup {
1427         }
1428         | DIGIT {
1429                 $$ = scm_int2num ($1);
1430         }
1431         ;
1432
1433 /*
1434 FIXME: remove or fix this comment.  What is `This'?
1435
1436 This is a trick:
1437
1438 Adding pre_events to the simple_element
1439 makes the choice between
1440
1441   string:  STRING
1442
1443 and
1444
1445   simple_element: STRING
1446
1447 a single shift/reduction conflict.
1448
1449 nevertheless, this is not very clean, and we should find a different
1450 solution.
1451
1452 */
1453 pre_events: {
1454                 THIS->push_spot ();
1455         }
1456         ;
1457
1458 event_chord:
1459         pre_events simple_element post_events   {
1460                 SCM elts = $2-> get_property ("elements");
1461
1462                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1463
1464                 $2->set_property ("elements", elts);
1465                 $$ = $2;
1466         }
1467         | command_element
1468         | note_chord_element
1469         ;
1470
1471
1472 note_chord_element:
1473         chord_body optional_notemode_duration post_events
1474         {
1475                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1476                 SCM es = $1->get_property ("elements");
1477                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1478
1479                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1480                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1481                 es = ly_append2 (es, postevs);
1482
1483                 $1-> set_property ("elements", es);
1484                 $$ = $1;
1485         }
1486         ;
1487
1488 chord_open: '<'
1489         ;
1490
1491 chord_close: '>'
1492         ;
1493
1494 simul_open: DOUBLE_ANGLE_OPEN
1495         ;
1496
1497 simul_close: DOUBLE_ANGLE_CLOSE
1498         ;
1499
1500 chord_body:
1501         chord_open chord_body_elements chord_close
1502         {
1503                 $$ = MY_MAKE_MUSIC ("EventChord");
1504                 $$->set_property ("elements",
1505                         scm_reverse_x ($2, SCM_EOL));
1506         }
1507         ;
1508
1509 chord_body_elements:
1510         /* empty */             { $$ = SCM_EOL; }
1511         | chord_body_elements chord_body_element {
1512                 $$ = scm_cons ($2->self_scm (), $1);
1513                 scm_gc_unprotect_object ($2->self_scm ());
1514         }
1515         ;
1516
1517 chord_body_element:
1518         pitch exclamations questions post_events
1519         {
1520                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1521                 n->set_property ("pitch", $1);
1522                 if ($3 % 2)
1523                         n->set_property ("cautionary", SCM_BOOL_T);
1524                 if ($2 % 2 || $3 % 2)
1525                         n->set_property ("force-accidental", SCM_BOOL_T);
1526
1527                 if (ly_c_pair_p ($4)) {
1528                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1529                         n->set_property ("articulations", arts);
1530                 }
1531                 $$ = n;
1532         }
1533         | DRUM_PITCH post_events {
1534                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1535                 n->set_property ("duration", $2);
1536                 n->set_property ("drum-type", $1);
1537                 n->set_spot (THIS->here_input ());
1538
1539                 if (ly_c_pair_p ($2)) {
1540                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1541                         n->set_property ("articulations", arts);
1542                 }
1543                 $$ = n;
1544         }
1545         ;
1546
1547 add_quote:
1548         ADDQUOTE string Music {
1549                 SCM adder = ly_scheme_function ("add-quotable");
1550
1551                 scm_call_2 (adder, $2, $3->self_scm ());
1552                 scm_gc_unprotect_object ($3->self_scm ());
1553         }
1554         ;
1555
1556 command_element:
1557         command_req {
1558                 $$ = MY_MAKE_MUSIC ("EventChord");
1559                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1560                 scm_gc_unprotect_object ($1->self_scm ());
1561
1562                 $$-> set_spot (THIS->here_input ());
1563                 $1-> set_spot (THIS->here_input ());
1564         }
1565         | SKIP duration_length {
1566                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1567                 skip->set_property ("duration", $2);
1568
1569                 $$ = skip;
1570         }
1571         | QUOTE STRING duration_length {
1572                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1573                 SCM evs = SCM_EOL;
1574                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1575                 {
1576                         SCM key = $2; // use symbol?
1577                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1578                 }
1579                 Music *quote = 0;
1580                 if (ly_c_vector_p (evs))
1581                 {
1582                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1583                         quote->set_property ("duration", $3);
1584                         quote->set_property ("quoted-events", evs);
1585                 } else {
1586                         THIS->here_input ().warning (_f ("Can\'t find music"));
1587                         quote = MY_MAKE_MUSIC ("Event");
1588                 }
1589                 quote->set_spot (THIS->here_input ());
1590                 $$ = quote;
1591         }
1592         | OCTAVE { THIS->push_spot (); }
1593           pitch {
1594                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1595                 $$ = m;
1596                 $$->set_spot (THIS->pop_spot ());
1597                 $$->set_property ("pitch", $3);
1598         }
1599         | E_LEFTSQUARE {
1600                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1601                 m->set_property ("span-direction", scm_int2num (START));
1602                 m->set_spot (THIS->here_input ());
1603
1604                 $$ = MY_MAKE_MUSIC ("EventChord");
1605                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1606                 scm_gc_unprotect_object (m->self_scm ());
1607                 $$->set_spot (THIS->here_input ());
1608         }
1609         | E_RIGHTSQUARE {
1610                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1611                 m->set_property ("span-direction", scm_int2num (STOP));
1612                 m->set_spot (THIS->here_input ());
1613
1614                 $$ = MY_MAKE_MUSIC ("EventChord");
1615                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1616                 $$->set_spot (THIS->here_input ());
1617                 scm_gc_unprotect_object (m->self_scm ());
1618         }
1619         | E_BACKSLASH {
1620                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1621                 $$->set_spot (THIS->here_input ());
1622         }
1623         | '|'      {
1624                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1625
1626                 if (Music * m = unsmob_music (pipe))
1627                         $$ = m->clone ();
1628                 else
1629                         $$ = MY_MAKE_MUSIC ("BarCheck");
1630
1631                 $$->set_spot (THIS->here_input ());
1632         }
1633         | TRANSPOSITION pitch {
1634                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1635                                         $2);
1636                 $$->set_spot (THIS-> here_input ());
1637                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1638                         $$, SCM_EOL);
1639         }
1640         | BAR STRING                    {
1641                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1642
1643                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1644                                         t, SCM_EOL);
1645                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1646                 $$->set_spot (THIS->here_input ());
1647                 t->set_spot (THIS->here_input ());
1648         }
1649         | PARTIAL duration_length       {
1650                 Moment m = - unsmob_duration ($2)->get_length ();
1651                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1652                 p->set_spot (THIS->here_input ());
1653                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1654                                         p, SCM_EOL);
1655                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1656                                         p, SCM_EOL);
1657                 $$ = p;
1658         }
1659         | CLEF STRING  {
1660                 SCM proc = ly_scheme_function ("make-clef-set");
1661
1662                 SCM result = scm_call_1 (proc, $2);
1663                 scm_gc_protect_object (result);
1664                 $$ = unsmob_music (result);
1665         }
1666         | TIME_T fraction  {
1667                 SCM proc= ly_scheme_function ("make-time-signature-set");
1668
1669                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1670                 scm_gc_protect_object (result);
1671                 $$ = unsmob_music (result);
1672         }
1673         | MARK scalar {
1674                 SCM proc = ly_scheme_function ("make-mark-set");
1675
1676                 SCM result = scm_call_1 (proc, $2);
1677                 scm_gc_protect_object (result);
1678                 $$ = unsmob_music (result);
1679         }
1680         ;
1681
1682 command_req:
1683         BREATHE {
1684                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1685         }
1686         | E_TILDE {
1687                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1688         }
1689         | MARK DEFAULT  {
1690                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1691                 $$ = m;
1692         }
1693         | tempo_event {
1694                 $$ = $1;
1695         }
1696         | KEY DEFAULT {
1697                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1698                 $$ = key;
1699         }
1700         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1701
1702                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1703                 if (scm_ilength ($3) > 0)
1704                 {
1705                         key->set_property ("pitch-alist", $3);
1706                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1707                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1708                 } else {
1709                         THIS->parser_error (_ ("Second argument must be pitch list."));
1710                 }
1711
1712                 $$ = key;
1713         }
1714         ;
1715
1716 post_events:
1717         /* empty */ {
1718                 $$ = SCM_EOL;
1719         }
1720         | post_events post_event {
1721                 $2->set_spot (THIS->here_input ());
1722                 $$ = scm_cons ($2->self_scm (), $$);
1723                 scm_gc_unprotect_object ($2->self_scm ());
1724         }
1725         | post_events tagged_post_event {
1726                 $2 -> set_spot (THIS->here_input ());
1727                 $$ = scm_cons ($2->self_scm (), $$);
1728                 scm_gc_unprotect_object ($2->self_scm ());
1729         }
1730         ;
1731
1732
1733 tagged_post_event:
1734         '-' TAG embedded_scm post_event {
1735                 tag_music ($4, $3, THIS->here_input ());
1736                 $$ = $4;
1737         }
1738         ;
1739
1740 post_event:
1741         direction_less_event {
1742                 $$ = $1;
1743         }
1744         | HYPHEN {
1745                 if (!THIS->lexer_->is_lyric_state ())
1746                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1747                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1748         }
1749         | EXTENDER {
1750                 if (!THIS->lexer_->is_lyric_state ())
1751                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1752                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1753         }
1754         | script_dir direction_reqd_event {
1755                 if ($1)
1756                         $2->set_property ("direction", scm_int2num ($1));
1757                 $$ = $2;
1758         }
1759         | script_dir direction_less_event {
1760                 if ($1)
1761                         $2->set_property ("direction", scm_int2num ($1));
1762                 $$ = $2;
1763         }
1764         | string_number_event
1765         ;
1766
1767 string_number_event:
1768         E_UNSIGNED {
1769                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1770                 s->set_property ("string-number", scm_int2num ($1));
1771                 s->set_spot (THIS->here_input ());
1772                 $$ = s;
1773         }
1774         ;
1775
1776
1777 direction_less_event:
1778         '['  {
1779
1780
1781 /*
1782
1783 TODO: should take all these defs out of the parser, adn make use
1784 configurable, i.e.
1785
1786
1787 (set-articulation '~ "trill")
1788
1789 */
1790                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1791                 m->set_spot (THIS->here_input ());
1792                 m->set_property ("span-direction", scm_int2num (START));
1793                 $$ = m;
1794         }
1795         | ']'  {
1796                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1797                 m->set_spot (THIS->here_input ());
1798                 m->set_property ("span-direction", scm_int2num (STOP));
1799                 $$ = m;
1800         }
1801         | '~' {
1802                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1803                 m->set_spot (THIS->here_input ());
1804                 $$ = m;
1805         }
1806         | close_event {
1807                 $$ = $1;
1808                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1809                         scm_int2num (START));
1810         }
1811         | open_event {
1812                 $$ = $1;
1813                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1814                         scm_int2num (STOP));
1815         }
1816         | EVENT_IDENTIFIER      {
1817                 $$ = unsmob_music ($1);
1818         }
1819         | tremolo_type  {
1820                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1821                a->set_spot (THIS->here_input ());
1822                a->set_property ("tremolo-type", scm_int2num ($1));
1823                $$ = a;
1824         }
1825         ;
1826
1827 direction_reqd_event:
1828         gen_text_def {
1829                 $$ = $1;
1830         }
1831         | script_abbreviation {
1832                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1833                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1834                 if (ly_c_string_p (s))
1835                         a->set_property ("articulation-type", s);
1836                 else THIS->parser_error (_ ("Expecting string as script definition"));
1837                 $$ = a;
1838         }
1839         ;
1840
1841 oct_check:
1842         /**/ { $$ = SCM_EOL; }
1843         | '='  { $$ = scm_int2num (0); }
1844         | '=' sub_quotes { $$ = scm_int2num ($2); }
1845         | '=' sup_quotes { $$ = scm_int2num ($2); }
1846         ;
1847
1848 sup_quotes:
1849         '\'' {
1850                 $$ = 1;
1851         }
1852         | sup_quotes '\'' {
1853                 $$ ++;
1854         }
1855         ;
1856
1857 sub_quotes:
1858         ',' {
1859                 $$ = 1;
1860         }
1861         | sub_quotes ',' {
1862                 $$++;
1863         }
1864         ;
1865
1866 steno_pitch:
1867         NOTENAME_PITCH  {
1868                 $$ = $1;
1869         }
1870         | NOTENAME_PITCH sup_quotes     {
1871                 Pitch p = *unsmob_pitch ($1);
1872                 p = p.transposed (Pitch ($2,0,0));
1873                 $$ = p.smobbed_copy ();
1874         }
1875         | NOTENAME_PITCH sub_quotes      {
1876                 Pitch p =* unsmob_pitch ($1);
1877                 p = p.transposed (Pitch (-$2,0,0));
1878                 $$ = p.smobbed_copy ();
1879         }
1880         ;
1881
1882 /*
1883 ugh. duplication
1884 */
1885
1886 steno_tonic_pitch:
1887         TONICNAME_PITCH {
1888                 $$ = $1;
1889         }
1890         | TONICNAME_PITCH sup_quotes    {
1891                 Pitch p = *unsmob_pitch ($1);
1892                 p = p.transposed (Pitch ($2,0,0));
1893                 $$ = p.smobbed_copy ();
1894         }
1895         | TONICNAME_PITCH sub_quotes     {
1896                 Pitch p =* unsmob_pitch ($1);
1897
1898                 p = p.transposed (Pitch (-$2,0,0));
1899                 $$ = p.smobbed_copy ();
1900         }
1901         ;
1902
1903 pitch:
1904         steno_pitch {
1905                 $$ = $1;
1906         }
1907         ;
1908
1909 pitch_also_in_chords:
1910         pitch
1911         | steno_tonic_pitch
1912         ;
1913
1914 close_event:
1915         '('     {
1916                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1917                 $$ = s;
1918                 s->set_spot (THIS->here_input ());
1919         }
1920         | E_OPEN        {
1921                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1922                 $$ = s;
1923                 s->set_spot (THIS->here_input ());
1924         }
1925         | E_SMALLER {
1926                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1927                 $$ = s;
1928                 s->set_spot (THIS->here_input ());
1929         }
1930         | E_BIGGER {
1931                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1932                 $$ = s;
1933                 s->set_spot (THIS->here_input ());
1934         }
1935         ;
1936
1937
1938 open_event:
1939         E_EXCLAMATION   {
1940                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1941                 s->set_spot (THIS->here_input ());
1942
1943                 $$ = s;
1944         }
1945         | ')'   {
1946                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1947                 $$ = s;
1948                 s->set_spot (THIS->here_input ());
1949
1950         }
1951         | E_CLOSE       {
1952                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1953                 $$ = s;
1954                 s->set_property ("span-type",
1955                         scm_makfrom0str ("phrasing-slur"));
1956                 s->set_spot (THIS->here_input ());
1957         }
1958         ;
1959
1960 gen_text_def:
1961         full_markup {
1962                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1963                 t->set_property ("text", $1);
1964                 t->set_spot (THIS->here_input ());
1965                 $$ = t;
1966         }
1967         | string {
1968                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1969                 t->set_property ("text",
1970                         make_simple_markup (THIS->lexer_->encoding (), $1));
1971                 t->set_spot (THIS->here_input ());
1972                 $$ = t;
1973
1974         }
1975         | DIGIT {
1976                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1977                 t->set_property ("digit", scm_int2num ($1));
1978                 t->set_spot (THIS->here_input ());
1979                 $$ = t;
1980         }
1981         ;
1982
1983 script_abbreviation:
1984         '^'             {
1985                 $$ = scm_makfrom0str ("Hat");
1986         }
1987         | '+'           {
1988                 $$ = scm_makfrom0str ("Plus");
1989         }
1990         | '-'           {
1991                 $$ = scm_makfrom0str ("Dash");
1992         }
1993         | '|'           {
1994                 $$ = scm_makfrom0str ("Bar");
1995         }
1996         | '>'           {
1997                 $$ = scm_makfrom0str ("Larger");
1998         }
1999         | '.'           {
2000                 $$ = scm_makfrom0str ("Dot");
2001         }
2002         | '_' {
2003                 $$ = scm_makfrom0str ("Underscore");
2004         }
2005         ;
2006
2007 script_dir:
2008         '_'     { $$ = DOWN; }
2009         | '^'   { $$ = UP; }
2010         | '-'   { $$ = CENTER; }
2011         ;
2012
2013
2014 absolute_pitch:
2015         steno_pitch     {
2016                 $$ = $1;
2017         }
2018         ;
2019
2020 duration_length:
2021         multiplied_duration {
2022                 $$ = $1;
2023         }
2024         ;
2025
2026 optional_notemode_duration:
2027         {
2028                 Duration dd = THIS->default_duration_;
2029                 $$ = dd.smobbed_copy ();
2030
2031                 THIS->beam_check ($$);
2032         }
2033         | multiplied_duration   {
2034                 $$ = $1;
2035                 THIS->default_duration_ = *unsmob_duration ($$);
2036
2037                 THIS->beam_check ($$);
2038         }
2039         ;
2040
2041 steno_duration:
2042         bare_unsigned dots              {
2043                 int len = 0;
2044                 if (!is_duration ($1))
2045                         THIS->parser_error (_f ("not a duration: %d", $1));
2046                 else
2047                         len = intlog2 ($1);
2048
2049                 $$ = Duration (len, $2).smobbed_copy ();
2050         }
2051         | DURATION_IDENTIFIER dots      {
2052                 Duration *d = unsmob_duration ($1);
2053                 Duration k (d->duration_log (), d->dot_count () + $2);
2054                 *d = k;
2055                 $$ = $1;
2056         }
2057         ;
2058
2059 multiplied_duration:
2060         steno_duration {
2061                 $$ = $1;
2062         }
2063         | multiplied_duration '*' bare_unsigned {
2064                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2065         }
2066         | multiplied_duration '*' FRACTION {
2067                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
2068
2069                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2070         }
2071         ;
2072
2073 fraction:
2074         FRACTION { $$ = $1; }
2075         | UNSIGNED '/' UNSIGNED {
2076                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2077         }
2078         ;
2079
2080 dots:
2081         /* empty */     {
2082                 $$ = 0;
2083         }
2084         | dots '.' {
2085                 $$ ++;
2086         }
2087         ;
2088
2089 tremolo_type:
2090         ':'     {
2091                 $$ = 0;
2092         }
2093         | ':' bare_unsigned {
2094                 if (!is_duration ($2))
2095                         THIS->parser_error (_f ("not a duration: %d", $2));
2096                 $$ = $2;
2097         }
2098         ;
2099
2100 bass_number:
2101         DIGIT   {
2102                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2103         }
2104         | UNSIGNED {
2105                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2106         }
2107         | STRING { $$ = $1; }
2108         ;
2109
2110 bass_mod:
2111         '-'     { $$ = -2; }
2112         | '+'   { $$ = 2; }
2113         | '!'   { $$ = 0; }
2114         ;
2115
2116 bass_figure:
2117         FIGURE_SPACE {
2118                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2119                 $$ = bfr->self_scm ();
2120                 scm_gc_unprotect_object ($$);
2121         }
2122         | bass_number  {
2123                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2124                 $$ = bfr->self_scm ();
2125
2126                 bfr->set_property ("figure", $1);
2127
2128                 scm_gc_unprotect_object ($$);
2129         }
2130         | bass_figure bass_mod {
2131                 Music *m = unsmob_music ($1);
2132                 if ($2) {
2133                         SCM salter = m->get_property ("alteration");
2134                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2135                         m->set_property ("alteration",
2136                                 scm_int2num (alter + $2));
2137                 } else {
2138                         m->set_property ("alteration", scm_int2num (0));
2139                 }
2140         }
2141         ;
2142
2143 br_bass_figure:
2144         '[' bass_figure {
2145                 $$ = $2;
2146                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2147         }
2148         | bass_figure   {
2149                 $$ = $1;
2150         }
2151         | br_bass_figure ']' {
2152                 $$ = $1;
2153                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2154         }
2155         ;
2156
2157 figure_list:
2158         /**/            {
2159                 $$ = SCM_EOL;
2160         }
2161         | figure_list br_bass_figure {
2162                 $$ = scm_cons ($2, $1);
2163         }
2164         ;
2165
2166 figure_spec:
2167         FIGURE_OPEN figure_list FIGURE_CLOSE {
2168                 Music *m = MY_MAKE_MUSIC ("EventChord");
2169                 $2 = scm_reverse_x ($2, SCM_EOL);
2170                 m->set_property ("elements", $2);
2171                 $$ = m->self_scm ();
2172         }
2173         ;
2174
2175
2176 optional_rest:
2177         /**/   { $$ = 0; }
2178         | REST { $$ = 1; }
2179         ;
2180
2181 simple_element:
2182         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
2183
2184                 Input i = THIS->pop_spot ();
2185                 if (!THIS->lexer_->is_note_state ())
2186                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2187
2188                 Music *n = 0;
2189                 if ($6)
2190                         n = MY_MAKE_MUSIC ("RestEvent");
2191                 else
2192                         n = MY_MAKE_MUSIC ("NoteEvent");
2193
2194                 n->set_property ("pitch", $1);
2195                 n->set_property ("duration", $5);
2196
2197                 if (ly_c_number_p ($4))
2198                 {
2199                         int q = ly_scm2int ($4);
2200                         n->set_property ("absolute-octave", scm_int2num (q-1));
2201                 }
2202
2203                 if ($3 % 2)
2204                         n->set_property ("cautionary", SCM_BOOL_T);
2205                 if ($2 % 2 || $3 % 2)
2206                         n->set_property ("force-accidental", SCM_BOOL_T);
2207
2208                 Music *v = MY_MAKE_MUSIC ("EventChord");
2209                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2210                 scm_gc_unprotect_object (n->self_scm ());
2211
2212                 v->set_spot (i);
2213                 n->set_spot (i);
2214                 $$ = v;
2215         }
2216         | DRUM_PITCH optional_notemode_duration {
2217                 Input i = THIS->pop_spot ();
2218
2219                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2220                 n->set_property ("duration", $2);
2221                 n->set_property ("drum-type", $1);
2222
2223                 Music *v = MY_MAKE_MUSIC ("EventChord");
2224                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2225                 scm_gc_unprotect_object (n->self_scm ());
2226                 v->set_spot (i);
2227                 n->set_spot (i);
2228                 $$ = v;
2229
2230         }
2231         | figure_spec optional_notemode_duration {
2232                 Music *m = unsmob_music ($1);
2233                 Input i = THIS->pop_spot ();
2234                 m->set_spot (i);
2235                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2236                 {
2237                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2238                 }
2239                 $$ = m;
2240         }
2241         | RESTNAME optional_notemode_duration           {
2242
2243                 Input i = THIS->pop_spot ();
2244                 Music *ev = 0;
2245                 if (ly_scm2string ($1) == "s") {
2246                         /* Space */
2247                         ev = MY_MAKE_MUSIC ("SkipEvent");
2248                   }
2249                 else {
2250                         ev = MY_MAKE_MUSIC ("RestEvent");
2251
2252                     }
2253                 ev->set_property ("duration", $2);
2254                 ev->set_spot (i);
2255                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2256                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2257                 velt->set_spot (i);
2258
2259                 scm_gc_unprotect_object (ev->self_scm ());
2260
2261                 $$ = velt;
2262         }
2263         | MULTI_MEASURE_REST optional_notemode_duration         {
2264                 THIS->pop_spot ();
2265
2266                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2267                 SCM mus = scm_call_2 (proc, $2,
2268                         make_input (THIS->here_input ()));
2269                 scm_gc_protect_object (mus);
2270                 $$ = unsmob_music (mus);
2271         }
2272
2273         | lyric_element optional_notemode_duration      {
2274                 Input i = THIS->pop_spot ();
2275                 if (!THIS->lexer_->is_lyric_state ())
2276                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2277
2278                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2279                 lreq->set_property ("text", $1);
2280                 lreq->set_property ("duration",$2);
2281                 lreq->set_spot (i);
2282                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2283                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2284
2285                 $$= velt;
2286         }
2287         | new_chord {
2288                 THIS->pop_spot ();
2289
2290                 if (!THIS->lexer_->is_chord_state ())
2291                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2292                 $$ = unsmob_music ($1);
2293         }
2294         ;
2295
2296 lyric_element:
2297         /* FIXME: lyric flavoured markup would be better */
2298         full_markup {
2299         }
2300         | LYRICS_STRING {
2301         }
2302         ;
2303
2304 new_chord:
2305         steno_tonic_pitch optional_notemode_duration   {
2306                 $$ = make_chord ($1, $2, SCM_EOL);
2307         }
2308         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2309                 SCM its = scm_reverse_x ($4, SCM_EOL);
2310                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2311         }
2312         ;
2313
2314 chord_items:
2315         /**/ {
2316                 $$ = SCM_EOL;
2317         }
2318         | chord_items chord_item {
2319                 $$ = scm_cons ($2, $$);
2320         }
2321         ;
2322
2323 chord_separator:
2324         CHORD_COLON {
2325                 $$ = ly_symbol2scm ("chord-colon");
2326         }
2327         | CHORD_CARET {
2328                 $$ = ly_symbol2scm ("chord-caret");
2329         }
2330         | CHORD_SLASH steno_tonic_pitch {
2331                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2332         }
2333         | CHORD_BASS steno_tonic_pitch {
2334                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2335         }
2336         ;
2337
2338 chord_item:
2339         chord_separator {
2340                 $$ = $1;
2341         }
2342         | step_numbers {
2343                 $$ = scm_reverse_x ($1, SCM_EOL);
2344         }
2345         | CHORD_MODIFIER  {
2346                 $$ = $1;
2347         }
2348         ;
2349
2350 step_numbers:
2351         step_number { $$ = scm_cons ($1, SCM_EOL); }
2352         | step_numbers '.' step_number {
2353                 $$ = scm_cons ($3, $$);
2354         }
2355         ;
2356
2357 step_number:
2358         bare_unsigned {
2359                 $$ = make_chord_step ($1, 0);
2360         }
2361         | bare_unsigned '+' {
2362                 $$ = make_chord_step ($1, SHARP);
2363         }
2364         | bare_unsigned CHORD_MINUS {
2365                 $$ = make_chord_step ($1, FLAT);
2366         }
2367         ;
2368
2369 /*
2370         UTILITIES
2371
2372 TODO: should deprecate in favor of Scheme?
2373
2374  */
2375 number_expression:
2376         number_expression '+' number_term {
2377                 $$ = scm_sum ($1, $3);
2378         }
2379         | number_expression '-' number_term {
2380                 $$ = scm_difference ($1, $3);
2381         }
2382         | number_term
2383         ;
2384
2385 number_term:
2386         number_factor {
2387                 $$ = $1;
2388         }
2389         | number_factor '*' number_factor {
2390                 $$ = scm_product ($1, $3);
2391         }
2392         | number_factor '/' number_factor {
2393                 $$ = scm_divide ($1, $3);
2394         }
2395         ;
2396
2397 number_factor:
2398         '-'  number_factor { /* %prec UNARY_MINUS */
2399                 $$ = scm_difference ($2, SCM_UNDEFINED);
2400         }
2401         | bare_number
2402         ;
2403
2404
2405 bare_number:
2406         UNSIGNED        {
2407                 $$ = scm_int2num ($1);
2408         }
2409         | REAL          {
2410                 $$ = $1;
2411         }
2412         | NUMBER_IDENTIFIER             {
2413                 $$ = $1;
2414         }
2415         | REAL NUMBER_IDENTIFIER        {
2416                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2417         }
2418         | UNSIGNED NUMBER_IDENTIFIER    {
2419                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2420         }
2421         ;
2422
2423
2424 bare_unsigned:
2425         UNSIGNED {
2426                         $$ = $1;
2427         }
2428         | DIGIT {
2429                 $$ = $1;
2430         }
2431         ;
2432
2433 bare_int:
2434         bare_number {
2435                 if (scm_integer_p ($1) == SCM_BOOL_T)
2436                 {
2437                         int k = ly_scm2int ($1);
2438                         $$ = k;
2439                 } else
2440                 {
2441                         THIS->parser_error (_ ("need integer number arg"));
2442                         $$ = 0;
2443                 }
2444         }
2445         | '-' bare_int {
2446                 $$ = -$2;
2447         }
2448         ;
2449
2450 exclamations:
2451                 { $$ = 0; }
2452         | exclamations '!'      { $$ ++; }
2453         ;
2454
2455 questions:
2456                 { $$ = 0; }
2457         | questions '?' { $$ ++; }
2458         ;
2459
2460
2461
2462 full_markup:
2463         MARKUP_IDENTIFIER {
2464                 $$ = $1;
2465         }
2466         | MARKUP
2467                 { THIS->lexer_->push_markup_state (); }
2468         markup
2469                 { $$ = $3;
2470                   THIS->lexer_->pop_state ();
2471                 }
2472         ;
2473
2474
2475 /*
2476 This should be done more dynamically if possible.
2477 */
2478 markup:
2479         STRING {
2480                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2481         }
2482         | MARKUP_HEAD_EMPTY {
2483                 $$ = scm_list_1 ($1);
2484         }
2485         | MARKUP_HEAD_MARKUP0 markup {
2486                 $$ = scm_list_2 ($1, $2);
2487         }
2488         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2489                 $$ = scm_list_3 ($1, $2, $3);
2490         }
2491         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2492                 $$ = scm_list_3 ($1, $2, $3);
2493         }
2494         | markup_line {
2495                 $$ = $1;
2496         }
2497         | MARKUP_HEAD_LIST0 markup_list {
2498                 $$ = scm_list_2 ($1,$2);
2499         }
2500         | MARKUP_HEAD_SCM0 embedded_scm {
2501                 $$ = scm_list_2 ($1, $2);
2502         }
2503         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2504                 $$ = scm_list_4 ($1, $2, $3, $4);
2505         }
2506         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2507                 $$ = scm_list_4 ($1, $2, $3, $4);
2508         }
2509         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2510                 $$ = scm_list_3 ($1, $2, $3);
2511         }
2512         | MARKUP_IDENTIFIER {
2513                 $$ = $1;
2514         }
2515         | STRING_IDENTIFIER {
2516                 $$ = $1;
2517         }
2518         | score_block {
2519                 /* WIP this is a bit arbitrary,
2520                    we should also allow \book or Composite_music.
2521                    However, you'd typically want to change paper
2522                    settings, and need a \score block anyway.  */
2523                 Score *score = $1;
2524                 Book *book = new Book;
2525                 book->scores_.push (score);
2526                 extern Music_output_def* get_paper (My_lily_parser *parser);
2527                 Music_output_def *paper = get_paper (THIS);
2528                 SCM s = book->to_stencil (paper, THIS->header_);
2529                 scm_gc_unprotect_object (score->self_scm ());
2530                 scm_gc_unprotect_object (book->self_scm ());
2531                 $$ = scm_list_2 (ly_scheme_function ("stencil-markup"), s);
2532         }
2533         ;
2534
2535 markup_list:
2536         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2537         ;
2538
2539 markup_line:
2540         '{' markup_list_body '}' {
2541                 SCM line = ly_scheme_function ("line-markup");
2542
2543                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2544         }
2545         ;
2546
2547 markup_list_body:
2548         /**/ {  $$ = SCM_EOL; }
2549         | markup_list_body markup {
2550                 $$ = scm_cons ($2, $1);
2551         }
2552         ;
2553
2554
2555 %%
2556
2557 void
2558 My_lily_parser::set_yydebug (bool )
2559 {
2560 #if 0
2561         yydebug = 1;
2562 #endif
2563 }
2564
2565 void
2566 My_lily_parser::do_yyparse ()
2567 {
2568         yyparse ((void*)this);
2569 }
2570
2571
2572 /*
2573 Should make this optional?    It will also complain when you do
2574
2575         [s4]
2576
2577 which is entirely legitimate.
2578
2579 Or we can scrap it. Barchecks should detect wrong durations, and
2580 skipTypesetting speeds it up a lot.
2581 */
2582
2583 void
2584 My_lily_parser::beam_check (SCM dur)
2585 {
2586   Duration *d = unsmob_duration (dur);
2587   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2588     {
2589       Music *m = unsmob_music (last_beam_start_);
2590       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2591     }
2592   last_beam_start_ = SCM_EOL;
2593 }
2594
2595
2596
2597
2598 /*
2599
2600 It is a little strange to have this function in this file, but
2601 otherwise, we have to import music classes into the lexer.
2602
2603 */
2604 int
2605 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2606 {
2607         if (ly_c_string_p (sid)) {
2608                 *destination = sid;
2609                 return STRING_IDENTIFIER;
2610         } else if (ly_c_number_p (sid)) {
2611                 *destination = sid;
2612                 return NUMBER_IDENTIFIER;
2613         } else if (unsmob_context_def (sid)) {
2614                 *destination = unsmob_context_def (sid)->clone_scm ();
2615                 return CONTEXT_DEF_IDENTIFIER;
2616         } else if (unsmob_score (sid)) {
2617                 Score *score = new Score (*unsmob_score (sid));
2618                 *destination = score->self_scm ();
2619                 return SCORE_IDENTIFIER;
2620         } else if (Music *mus = unsmob_music (sid)) {
2621                 mus = mus->clone ();
2622                 *destination = mus->self_scm ();
2623                 unsmob_music (*destination)->
2624                         set_property ("origin", make_input (last_input_));
2625                 return dynamic_cast<Event*> (mus)
2626                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2627         } else if (unsmob_duration (sid)) {
2628                 *destination = unsmob_duration (sid)->smobbed_copy ();
2629                 return DURATION_IDENTIFIER;
2630         } else if (unsmob_music_output_def (sid)) {
2631                 Music_output_def *p = unsmob_music_output_def (sid);
2632                 p = p->clone ();
2633
2634                 *destination = p->self_scm ();
2635                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2636         } else if (Text_item::markup_p (sid)) {
2637                 *destination = sid;
2638                 return MARKUP_IDENTIFIER;
2639         }
2640
2641         return -1;
2642 }
2643
2644 Music *
2645 property_op_to_music (SCM op)
2646 {
2647         Music *m = 0;
2648         SCM tag = ly_car (op);
2649         SCM symbol = ly_cadr (op);
2650         SCM args = ly_cddr (op);
2651         SCM grob_val = SCM_UNDEFINED;
2652         SCM grob_sym = SCM_UNDEFINED;
2653         SCM val = SCM_UNDEFINED;
2654
2655         if (tag == ly_symbol2scm ("assign"))
2656                 {
2657                 m = MY_MAKE_MUSIC ("PropertySet");
2658                 val = ly_car (args);
2659                 }
2660         else if (tag == ly_symbol2scm ("unset"))
2661                 m = MY_MAKE_MUSIC ("PropertyUnset");
2662         else if (tag == ly_symbol2scm ("poppush")
2663                  || tag == ly_symbol2scm ("push"))
2664                 {
2665                 m = MY_MAKE_MUSIC ("OverrideProperty");
2666                 grob_sym = ly_car (args);
2667                 grob_val = ly_cadr (args);
2668                 }
2669         else if (tag == ly_symbol2scm ("pop")) {
2670                 m = MY_MAKE_MUSIC ("RevertProperty");
2671                 grob_sym = ly_car (args);
2672                 }
2673
2674         m->set_property ("symbol", symbol);
2675
2676         if (val != SCM_UNDEFINED)
2677                 m->set_property ("value", val);
2678         if (grob_val != SCM_UNDEFINED)
2679                 m->set_property ("grob-value", grob_val);
2680
2681         if (grob_sym != SCM_UNDEFINED)
2682                 {
2683                 bool itc = internal_type_checking_global_b;
2684                 /* UGH.
2685                 */
2686                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2687                 if (autobeam)
2688                         internal_type_checking_global_b = false;
2689                 m->set_property ("grob-property", grob_sym);
2690                 if (autobeam)
2691                         internal_type_checking_global_b = itc;
2692                 }
2693
2694         if (op == ly_symbol2scm ("poppush"))
2695                 m->set_property ("pop-first", SCM_BOOL_T);
2696
2697
2698         return m;
2699 }
2700
2701 Music*
2702 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2703 {
2704         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2705
2706         csm->set_property ("element", m->self_scm ());
2707         scm_gc_unprotect_object (m->self_scm ());
2708
2709         csm->set_property ("context-type",
2710                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2711         csm->set_property ("property-operations", ops);
2712
2713         if (ly_c_string_p (id))
2714                 csm->set_property ("context-id", id);
2715         return csm;
2716 }
2717
2718 SCM
2719 get_next_unique_context ()
2720 {
2721         static int new_context_count;
2722         char s[1024];
2723         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2724         return scm_makfrom0str (s);
2725 }
2726